configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.71])
   3 AC_INIT([pwmd],[3.3.5],[Ben Kibbey <bjk@luxsci.net>])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 AC_USE_SYSTEM_EXTENSIONS()
  10 AC_CONFIG_SRCDIR([src/pwmd.c])
  11 AC_CONFIG_HEADERS([config.h])
  12 AM_GNU_GETTEXT_VERSION([0.21])
  13
  14 AM_CONDITIONAL([IS_GIT_REPO], [test -f ".git/HEAD"])
  15 if test -f ".git/HEAD"; then
  16     GIT_BRANCH="`cut -d / -f 3 .git/HEAD`"
  17 fi
  18 AC_SUBST([GIT_BRANCH])
  19
  20 REQUIRE_LIBGCRYPT_VERSION="1.7.0"
  21 REQUIRE_LIBASSUAN_VERSION="2.5.0"
  22 REQUIRE_LIBGPGERROR_VERSION="1.29"
  23 REQUIRE_LIBGPGME_VERSION="1.11.0"
  24 REQUIRE_GNUPG_VERSION="2.2.7"
  25 REQUIRE_LIBGNUTLS_VERSION="3.3.0"
  26
  27 AC_DEFINE_UNQUOTED(REQUIRE_LIBASSUAN_VERSION, "$REQUIRE_LIBASSUAN_VERSION",
  28           [Minimum libassuan version.])
  29 AC_DEFINE_UNQUOTED(REQUIRE_LIBGCRYPT_VERSION, "$REQUIRE_LIBGCRYPT_VERSION",
  30           [Minimum libgcrypt version.])
  31 AC_DEFINE_UNQUOTED(REQUIRE_LIBGPGERROR_VERSION, "$REQUIRE_LIBGPGERROR_VERSION",
  32           [Minimum libgpg-error version.])
  33 AC_DEFINE_UNQUOTED(REQUIRE_LIBGPGME_VERSION, "$REQUIRE_LIBGPGME_VERSION",
  34           [Minimum libgpgme version.])
  35 AC_DEFINE_UNQUOTED(REQUIRE_GNUPG_VERSION, "$REQUIRE_GNUPG_VERSION",
  36           [Minimum gnupg version.])
  37 AC_DEFINE_UNQUOTED(REQUIRE_LIBGNUTLS_VERSION, "$REQUIRE_LIBGNUTLS_VERSION",
  38           [Minimum libgnutls version.])
  39
  40 dnl Checks for programs.
  41 AX_CC_FOR_BUILD
  42 AC_PROG_CXX
  43 AC_PROG_AWK
  44 AC_PROG_CC
  45 AC_PROG_INSTALL
  46 AC_PROG_LN_S
  47 AC_PROG_MAKE_SET
  48 AC_PROG_MKDIR_P
  49 AC_PROG_RANLIB
  50 AC_PROG_YACC
  51
  52 dnl Checks for library functions.
  53 AX_CHECK_COMPILE_FLAG([-D_FORTIFY_SOURCE=2],
  54                       [CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"])
  55 AX_PTHREAD(, AC_MSG_ERROR([POSIX threads are required.]))
  56 CC="$PTHREAD_CC"
  57 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  58 LIBS="$PTHREAD_LIBS $LIBS"
  59
  60 acx_pthread_testcancel_ok=no
  61 AC_MSG_CHECKING([for pthread_testcancel()])
  62 AC_TRY_LINK_FUNC(pthread_testcancel, acx_pthread_testcancel_ok=yes)
  63 AC_MSG_RESULT($acx_pthread_testcancel_ok)
  64 if test x"$acx_pthread_testcancel_ok" = "xyes"; then
  65     AC_DEFINE(HAVE_PTHREAD_TESTCANCEL, 1, [Define if your OS has pthread_testcancel().])
  66 fi
  67
  68 acx_pthread_cancel_ok=no
  69 AC_MSG_CHECKING([for pthread_cancel()])
  70 AC_TRY_LINK_FUNC(pthread_cancel, acx_pthread_cancel_ok=yes)
  71 AC_MSG_RESULT($acx_pthread_cancel_ok)
  72 if test x"$acx_pthread_cancel_ok" = "xyes"; then
  73     AC_DEFINE(HAVE_PTHREAD_CANCEL, 1, [Define if your OS has pthread_cancel().])
  74 fi
  75
  76 acx_pthread_atfork_ok=no
  77 AC_MSG_CHECKING([for pthread_atfork()])
  78 AC_TRY_LINK_FUNC(pthread_atfork, acx_pthread_atfork_ok=yes)
  79 AC_MSG_RESULT($acx_pthread_atfork_ok)
  80 if test x"$acx_pthread_atfork_ok" = "xyes"; then
  81     AC_DEFINE(HAVE_PTHREAD_ATFORK, 1, [Define if your OS has pthread_atfork().])
  82 fi
  83
  84 dnl Checks for header files.
  85 AC_FUNC_ALLOCA
  86 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h getopt.h inttypes.h langinfo.h \
  87                   libintl.h malloc.h netdb.h netinet/in.h stdint.h \
  88                   stdio_ext.h strings.h sys/acl.h sys/file.h s sys/ioctl.h \
  89                   sys/param.h sys/socket.h sys/time.h syslog.h termios.h \
  90                   unistd.h limits.h])
  91
  92 AC_CHECK_DECLS([SO_BINDTODEVICE],,, [[#include <sys/types.h>
  93                                       #include <sys/socket.h>]])
  94
  95 case "${host}" in
  96     *-linux-androideabi)
  97         PTHREAD_CFLAGS="-pthread"
  98         PTHREAD_LIBS="-pthread"
  99         ;;
 100     *)
 101         ;;
 102 esac
 103
 104 case "$target_os" in
 105      linux*)
 106         AC_CHECK_HEADERS([linux/sockios.h sys/prctl.h])
 107         if test "x$ac_cv_header_linux_sockios_h" = xyes; then
 108                 AC_CHECK_DECL([SIOCOUTQ],,, [[#include <linux/sockios.h>]])
 109                 if test "x$ac_cv_have_decl_SIOCOUTQ" = xyes; then
 110                         AC_DEFINE(HAVE_DECL_SIOCOUTQ, 1,
 111                                 [Defined if SIOCOUTQ is available (Linux specific)])
 112                 fi
 113         fi
 114
 115         if test "x$ac_cv_header_sys_prctl_h" = xyes; then
 116            AC_CHECK_DECL([PR_SET_NAME],,, [[#include <sys/prctl.h>]])
 117               if test "x$ac_cv_have_decl_PR_SET_NAME" = xyes; then
 118                     AC_DEFINE(HAVE_PR_SET_NAME, 1,
 119                              [Defined if PR_SET_NAME is available (Linux specific)])
 120               fi
 121
 122            AC_CHECK_DECL([PR_SET_DUMPABLE],,, [[#include <sys/prctl.h>]])
 123               if test "x$ac_cv_have_decl_PR_SET_DUMPABLE" = xyes; then
 124                     AC_DEFINE(HAVE_PR_SET_DUMPABLE, 1,
 125                              [Defined if PR_SET_DUMPABLE is available (Linux specific)])
 126               fi
 127         fi
 128         ;;
 129      openbsd*)
 130         ;;
 131      *bsd*)
 132         AC_CHECK_HEADERS([sys/filio.h])
 133         if test "x$ac_cv_header_sys_filio_h" = xyes; then
 134                 AC_CHECK_DECL([FIONWRITE],,, [[#include <sys/filio.h>]])
 135                 if test "x$ac_cv_have_decl_FIONWRITE" = xyes; then
 136                         AC_DEFINE(HAVE_DECL_FIONWRITE, 1,
 137                                 [Defined if FIONWRITE is available (*BSD specific, not OpenBSD)])
 138                 fi
 139         fi
 140         ;;
 141       *cygwin*)
 142         AC_DEFINE(HAVE_WINLIKE_SYSTEM, 1, [Define if this is a Windows-like system.])
 143         ;;
 144      *)
 145 dnl     All others use SO_SNDLOWAT.
 146         ;;
 147 esac
 148
 149 dnl Checks for typedefs, structures, and compiler characteristics.
 150 AC_CHECK_HEADER_STDBOOL
 151 AC_TYPE_UID_T
 152 AC_C_INLINE
 153 AC_TYPE_MODE_T
 154 AC_TYPE_OFF_T
 155 AC_TYPE_PID_T
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_SSIZE_T
 158 AC_TYPE_UINT16_T
 159 AC_TYPE_UINT32_T
 160 AC_TYPE_UINT64_T
 161 AC_TYPE_UINT8_T
 162 AC_CHECK_TYPES([ptrdiff_t])
 163 AC_SYS_LARGEFILE
 164
 165 dnl Checks for library functions.
 166 AM_GNU_GETTEXT([external])
 167 AC_FUNC_FORK
 168 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 169 AC_FUNC_MALLOC
 170 AC_FUNC_MBRTOWC
 171 AC_FUNC_MMAP
 172 AC_FUNC_REALLOC
 173 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify backtrace \
 174                 clock_gettime explicit_bzero flock getcwd getgrnam_r \
 175                 getpwnam_r getopt_long isascii localeconv mblen mbrlen \
 176                 memchr memmove mempcpy memset memset_s mkdir mlockall \
 177                 munmap nl_langinfo putenv select setlocale setrlimit socket \
 178                 stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp \
 179                 strrchr strstr strtol strtoul])
 180
 181 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 182
 183 AM_PATH_LIBASSUAN($REQUIRE_LIBASSUAN_VERSION,, AC_MSG_ERROR([libassuan >= $REQUIRE_LIBASSUAN_VERSION not found]))
 184 AM_PATH_LIBGCRYPT([1:$REQUIRE_LIBGCRYPT_VERSION],, AC_MSG_ERROR([libgcrypt >= $REQUIRE_LIBGCRYPT_VERSION not found]))
 185 AM_PATH_GPGME_PTHREAD($REQUIRE_LIBGPGME_VERSION,, AC_MSG_ERROR([libgpgme >= $REQUIRE_LIBGPGME_VERSION not found]))
 186 AM_PATH_GPG_ERROR($REQUIRE_LIBGPGERROR_VERSION,, AC_MSG_ERROR([libgpg-error >= $REQUIRE_LIBGPGERROR_VERSION not found]))
 187 AM_PATH_XML2(,, AC_MSG_ERROR([libxml2 not found]))
 188 AC_SEARCH_LIBS([clock_gettime], [rt])
 189
 190 dnl Remote TCP/TLS connections.
 191 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--enable-gnutls],
 192               [Enable TCP (GnuTLS) server support.]), USE_GNUTLS=$enableval,
 193               USE_GNUTLS=no)
 194 if test "x$USE_GNUTLS" = "xyes"; then
 195     PKG_CHECK_MODULES([GNUTLS], [gnutls >= $REQUIRE_LIBGNUTLS_VERSION])
 196     AC_DEFINE(WITH_GNUTLS, 1, [Define if you want TCP (GnuTLS) support.])
 197 fi
 198 AM_CONDITIONAL(WITH_GNUTLS, [test "x$USE_GNUTLS" = "xyes"])
 199
 200 dnl Libacl support (for data files).
 201 AC_ARG_ENABLE(acl, AS_HELP_STRING([--enable-acl],
 202               [Enable Access Control List support for data files]),
 203               [USE_LIBACL=yes], [USE_LIBACL=no])
 204 if test "x$USE_LIBACL" = "xyes"; then
 205     AC_SEARCH_LIBS([acl_get_file], [acl],,
 206                    AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 207     AC_CHECK_HEADER([sys/acl.h],,
 208                    AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 209     AC_DEFINE(WITH_LIBACL, 1, [Define if you want libacl support.])
 210 fi
 211 AM_CONDITIONAL(WITH_LIBACL, [test "x$USE_LIBACL" = "xyes"])
 212
 213 AC_DEFUN([AC_DEBUG],
 214 [
 215     if test "$1"; then
 216         ac_cv_sys_debug=$1
 217     fi
 218
 219     AC_CACHE_CHECK([if debugging is wanted], [ac_cv_sys_debug],
 220         [ac_cv_sys_debug=no])
 221     AM_CONDITIONAL([WITH_DEBUG], [test "$ac_cv_sys_debug" = "yes"])
 222 ])
 223
 224 AC_ARG_ENABLE(debug, AS_HELP_STRING([--enable-debug], [Enable debugging (memory de/allocations output).]),
 225     AC_DEBUG([$enableval]), AC_DEBUG)
 226
 227 AC_DEFUN([AC_MEM_DEBUG],
 228 [
 229     if test "$1"; then
 230         ac_cv_sys_mem_debug=$1
 231     fi
 232
 233     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 234         [ac_cv_sys_mem_debug=no])
 235     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 236 ])
 237
 238 AC_DEFUN([AC_MUTEX_DEBUG],
 239 [
 240     if test "$1"; then
 241         ac_cv_sys_mutex_debug=$1
 242     fi
 243
 244     AC_CACHE_CHECK([if mutex debugging is wanted], [ac_cv_sys_mutex_debug],
 245         [ac_cv_sys_mutex_debug=no])
 246     AM_CONDITIONAL([WITH_MUTEX_DEBUG], [test "$ac_cv_sys_mutex_debug" = "yes"])
 247 ])
 248
 249 AC_ARG_ENABLE(mutex_debug, AS_HELP_STRING([--enable-mutex-debug], [Enable mutex debugging output.]),
 250     AC_MUTEX_DEBUG([$enableval]), AC_MUTEX_DEBUG)
 251
 252 dnl Memory debugging.
 253 AC_ARG_ENABLE(mem_debug, AS_HELP_STRING([--enable-mem-debug], [Disable internal memory manager.]),
 254     AC_MEM_DEBUG([$enableval]), AC_MEM_DEBUG)
 255 AM_CONDITIONAL(MEM_DEBUG, test x"${ac_cv_sys_mem_debug}" != xno)
 256
 257 # Default pwmd home directory.
 258 AC_ARG_WITH(pwmd_homedir, AS_HELP_STRING([--with-pwmd-homedir=PATH],
 259               [Default pwmd home directory (~/.pwmd)]),
 260               pwmd_homedir="$withval", pwmd_homedir=)
 261 if test x"$pwmd_homedir" != "x"; then
 262    AC_DEFINE_UNQUOTED(PWMD_HOMEDIR, ["$pwmd_homedir"],
 263                                     [Default pwmd home directory (~/.pwmd).])
 264 fi
 265
 266 AC_ARG_WITH(invoking_user, AS_HELP_STRING([--with-invoking-user=nobody],
 267             [Default invoking_user when not specified in the configuration.
 268              Setting to blank will have the user that started pwmd be the
 269              invoking_user.]), invoking_user="$withval",
 270              invoking_user="nobody")
 271 if test x"$invoking_user" != "x"; then
 272    AC_DEFINE_UNQUOTED(DEFAULT_INVOKER, ["$invoking_user"],
 273                       [Default invoking_user when not specified in the
 274                        configuration. Set to NULL to have the user that
 275                        started pwmd be the invoking_user.])
 276 else
 277    AC_DEFINE(DEFAULT_INVOKER, [NULL],
 278                       [Default invoking_user when not specified in the
 279                        configuration. Set to NULL to have the user that
 280                        started pwmd be the invoking_user.])
 281 fi
 282
 283 VERSION_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
 284 VERSION_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
 285 VERSION_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
 286 VERSION_NUM="`printf 0x%02x%02x%02X ${VERSION_MAJOR} ${VERSION_MINOR} ${VERSION_PATCH}`"
 287 AC_DEFINE_UNQUOTED(VERSION_HEX, ${VERSION_NUM}, [For the file header.])
 288
 289 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/pwmd-dump.1 \
 290                  po/Makefile.in tests/Makefile])
 291 AC_OUTPUT
 292 echo
 293 echo "Features:"
 294 echo "    TCP (GnuTLS)....: $USE_GNUTLS"
 295 echo "    Data file ACL's.: $USE_LIBACL"
 296
 297 if test x"$pwmd_homedir" != "x"; then
 298 echo "    Home directory..: $pwmd_homedir"
 299 else
 300 echo "    Home directory..: ~/.pwmd"
 301 fi
 302
 303 if test "x$invoking_user" != "x"; then
 304 echo "    Invoking user...: $invoking_user"
 305 else
 306 echo "    Invoking user...: determined on start"
 307 fi
 308
 309 echo "    Debug...........: ${ac_cv_sys_debug}"
 310 echo "    Memory debug....: ${ac_cv_sys_mem_debug}"
 311 echo "    Mutex debug.....: ${ac_cv_sys_mutex_debug}"