configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.69])
   3 AC_INIT([pwmd],[3.3.8],[Ben Kibbey <bjk@luxsci.net>])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 AC_USE_SYSTEM_EXTENSIONS()
  10 AC_CONFIG_SRCDIR([src/pwmd.c])
  11 AC_CONFIG_HEADERS([config.h])
  12 AM_GNU_GETTEXT_VERSION([0.21])
  13
  14 AM_CONDITIONAL([IS_GIT_REPO], [test -f ".git/HEAD"])
  15 if test -f ".git/HEAD"; then
  16     GIT_BRANCH="`cut -d / -f 3 .git/HEAD`"
  17 fi
  18 AC_SUBST([GIT_BRANCH])
  19
  20 REQUIRE_LIBGCRYPT_VERSION="1.7.0"
  21 REQUIRE_LIBASSUAN_VERSION="2.5.0"
  22 REQUIRE_LIBGPGERROR_VERSION="1.29"
  23 REQUIRE_LIBGPGME_VERSION="1.11.0"
  24 REQUIRE_GNUPG_VERSION="2.2.7"
  25 REQUIRE_LIBGNUTLS_VERSION="3.3.0"
  26
  27 AC_DEFINE_UNQUOTED(REQUIRE_LIBASSUAN_VERSION, "$REQUIRE_LIBASSUAN_VERSION",
  28           [Minimum libassuan version.])
  29 AC_DEFINE_UNQUOTED(REQUIRE_LIBGCRYPT_VERSION, "$REQUIRE_LIBGCRYPT_VERSION",
  30           [Minimum libgcrypt version.])
  31 AC_DEFINE_UNQUOTED(REQUIRE_LIBGPGERROR_VERSION, "$REQUIRE_LIBGPGERROR_VERSION",
  32           [Minimum libgpg-error version.])
  33 AC_DEFINE_UNQUOTED(REQUIRE_LIBGPGME_VERSION, "$REQUIRE_LIBGPGME_VERSION",
  34           [Minimum libgpgme version.])
  35 AC_DEFINE_UNQUOTED(REQUIRE_GNUPG_VERSION, "$REQUIRE_GNUPG_VERSION",
  36           [Minimum gnupg version.])
  37 AC_DEFINE_UNQUOTED(REQUIRE_LIBGNUTLS_VERSION, "$REQUIRE_LIBGNUTLS_VERSION",
  38           [Minimum libgnutls version.])
  39
  40 dnl Checks for programs.
  41 AX_PROG_CC_FOR_BUILD
  42 AC_PROG_CXX
  43 AC_PROG_AWK
  44 AC_PROG_CC
  45 AC_PROG_INSTALL
  46 AC_PROG_LN_S
  47 AC_PROG_MAKE_SET
  48 AC_PROG_MKDIR_P
  49 AC_PROG_RANLIB
  50 AC_PROG_YACC
  51
  52 dnl Checks for library functions.
  53 AX_PTHREAD(, AC_MSG_ERROR([POSIX threads are required.]))
  54 CC="$PTHREAD_CC"
  55 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  56 LIBS="$PTHREAD_LIBS $LIBS"
  57
  58 acx_pthread_testcancel_ok=no
  59 AC_MSG_CHECKING([for pthread_testcancel()])
  60 AC_TRY_LINK_FUNC(pthread_testcancel, acx_pthread_testcancel_ok=yes)
  61 AC_MSG_RESULT($acx_pthread_testcancel_ok)
  62 if test x"$acx_pthread_testcancel_ok" = "xyes"; then
  63     AC_DEFINE(HAVE_PTHREAD_TESTCANCEL, 1, [Define if your OS has pthread_testcancel().])
  64 fi
  65
  66 acx_pthread_cancel_ok=no
  67 AC_MSG_CHECKING([for pthread_cancel()])
  68 AC_TRY_LINK_FUNC(pthread_cancel, acx_pthread_cancel_ok=yes)
  69 AC_MSG_RESULT($acx_pthread_cancel_ok)
  70 if test x"$acx_pthread_cancel_ok" = "xyes"; then
  71     AC_DEFINE(HAVE_PTHREAD_CANCEL, 1, [Define if your OS has pthread_cancel().])
  72 fi
  73
  74 acx_pthread_atfork_ok=no
  75 AC_MSG_CHECKING([for pthread_atfork()])
  76 AC_TRY_LINK_FUNC(pthread_atfork, acx_pthread_atfork_ok=yes)
  77 AC_MSG_RESULT($acx_pthread_atfork_ok)
  78 if test x"$acx_pthread_atfork_ok" = "xyes"; then
  79     AC_DEFINE(HAVE_PTHREAD_ATFORK, 1, [Define if your OS has pthread_atfork().])
  80 fi
  81
  82 dnl Checks for header files.
  83 AC_FUNC_ALLOCA
  84 AC_CHECK_HEADERS([argz.h arpa/inet.h fcntl.h getopt.h inttypes.h langinfo.h \
  85                   libintl.h locale.h malloc.h netdb.h netinet/in.h stdint.h \
  86                   stdio_ext.h strings.h sys/acl.h sys/file.h sys/ioctl.h \
  87                   sys/param.h sys/socket.h sys/time.h syslog.h termios.h \
  88                   unistd.h limits.h])
  89
  90 AC_CHECK_DECLS([SO_BINDTODEVICE],,, [[#include <sys/types.h>
  91                                       #include <sys/socket.h>]])
  92
  93 case "${host}" in
  94     *-linux-androideabi)
  95         PTHREAD_CFLAGS="-pthread"
  96         PTHREAD_LIBS="-pthread"
  97         ;;
  98     *)
  99         ;;
 100 esac
 101
 102 case "$target_os" in
 103      linux*)
 104         AC_CHECK_HEADERS([linux/sockios.h sys/prctl.h])
 105         if test "x$ac_cv_header_linux_sockios_h" = xyes; then
 106                 AC_CHECK_DECL([SIOCOUTQ],,, [[#include <linux/sockios.h>]])
 107                 if test "x$ac_cv_have_decl_SIOCOUTQ" = xyes; then
 108                         AC_DEFINE(HAVE_DECL_SIOCOUTQ, 1,
 109                                 [Defined if SIOCOUTQ is available (Linux specific)])
 110                 fi
 111         fi
 112
 113         if test "x$ac_cv_header_sys_prctl_h" = xyes; then
 114            AC_CHECK_DECL([PR_SET_NAME],,, [[#include <sys/prctl.h>]])
 115               if test "x$ac_cv_have_decl_PR_SET_NAME" = xyes; then
 116                     AC_DEFINE(HAVE_PR_SET_NAME, 1,
 117                              [Defined if PR_SET_NAME is available (Linux specific)])
 118               fi
 119
 120            AC_CHECK_DECL([PR_SET_DUMPABLE],,, [[#include <sys/prctl.h>]])
 121               if test "x$ac_cv_have_decl_PR_SET_DUMPABLE" = xyes; then
 122                     AC_DEFINE(HAVE_PR_SET_DUMPABLE, 1,
 123                              [Defined if PR_SET_DUMPABLE is available (Linux specific)])
 124               fi
 125         fi
 126         ;;
 127      openbsd*)
 128         ;;
 129      *bsd*)
 130         AC_CHECK_HEADERS([sys/filio.h])
 131         if test "x$ac_cv_header_sys_filio_h" = xyes; then
 132                 AC_CHECK_DECL([FIONWRITE],,, [[#include <sys/filio.h>]])
 133                 if test "x$ac_cv_have_decl_FIONWRITE" = xyes; then
 134                         AC_DEFINE(HAVE_DECL_FIONWRITE, 1,
 135                                 [Defined if FIONWRITE is available (*BSD specific, not OpenBSD)])
 136                 fi
 137         fi
 138         ;;
 139       *cygwin*)
 140         AC_DEFINE(HAVE_WINLIKE_SYSTEM, 1, [Define if this is a Windows-like system.])
 141         ;;
 142      *)
 143 dnl     All others use SO_SNDLOWAT.
 144         ;;
 145 esac
 146
 147 with_proc_symlink=
 148 AC_MSG_CHECKING([for /proc/self/ executable path symlink])
 149 for f in exe file; do
 150     if test -h "/proc/self/$f"; then
 151         with_proc_symlink="$f"
 152         break
 153     fi
 154 done
 155 if test x"$with_proc_symlink" != "x"; then
 156    AC_DEFINE_UNQUOTED(WITH_PROC_SYMLINK, ["$with_proc_symlink"],
 157                       [Define to your systems idea of an exe path in /proc/self/.])
 158 else
 159     with_proc_symlink="none"
 160 fi
 161 AC_MSG_RESULT([$with_proc_symlink])
 162
 163 dnl Checks for typedefs, structures, and compiler characteristics.
 164 AC_CHECK_HEADER_STDBOOL
 165 AC_TYPE_UID_T
 166 AC_C_INLINE
 167 AC_TYPE_MODE_T
 168 AC_TYPE_OFF_T
 169 AC_TYPE_PID_T
 170 AC_TYPE_SIZE_T
 171 AC_TYPE_SSIZE_T
 172 AC_TYPE_UINT16_T
 173 AC_TYPE_UINT32_T
 174 AC_TYPE_UINT64_T
 175 AC_TYPE_UINT8_T
 176 AC_CHECK_TYPES([ptrdiff_t])
 177 AC_SYS_LARGEFILE
 178
 179 dnl Checks for library functions.
 180 AM_GNU_GETTEXT([external])
 181 AC_FUNC_FORK
 182 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 183 AC_FUNC_MALLOC
 184 AC_FUNC_MBRTOWC
 185 AC_FUNC_MMAP
 186 AC_FUNC_REALLOC
 187 AC_CHECK_FUNCS([__argz_count __argz_next __argz_stringify backtrace \
 188                 clock_gettime explicit_bzero flock getcwd getgrnam_r \
 189                 getpwnam_r getopt_long isascii localeconv mblen mbrlen \
 190                 memchr memmove mempcpy memset memset_s mkdir mlockall \
 191                 munmap nl_langinfo putenv select setlocale setrlimit socket \
 192                 stpcpy strcasecmp strchr strcspn strdup strerror strncasecmp \
 193                 strrchr strstr strtol strtoul sigwaitinfo])
 194
 195 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 196
 197 AM_PATH_LIBASSUAN($REQUIRE_LIBASSUAN_VERSION,, AC_MSG_ERROR([libassuan >= $REQUIRE_LIBASSUAN_VERSION not found]))
 198 AM_PATH_LIBGCRYPT([1:$REQUIRE_LIBGCRYPT_VERSION],, AC_MSG_ERROR([libgcrypt >= $REQUIRE_LIBGCRYPT_VERSION not found]))
 199 AM_PATH_GPGME($REQUIRE_LIBGPGME_VERSION,, AC_MSG_ERROR([libgpgme >= $REQUIRE_LIBGPGME_VERSION not found]))
 200 AM_PATH_GPG_ERROR($REQUIRE_LIBGPGERROR_VERSION,, AC_MSG_ERROR([libgpg-error >= $REQUIRE_LIBGPGERROR_VERSION not found]))
 201 AM_PATH_XML2(,, AC_MSG_ERROR([libxml2 not found]))
 202 AC_SEARCH_LIBS([clock_gettime], [rt])
 203
 204 dnl Remote TCP/TLS connections.
 205 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--enable-gnutls],
 206               [Enable TCP (GnuTLS) server support.]), USE_GNUTLS=$enableval,
 207               USE_GNUTLS=no)
 208 if test "x$USE_GNUTLS" = "xyes"; then
 209     PKG_CHECK_MODULES([GNUTLS], [gnutls >= $REQUIRE_LIBGNUTLS_VERSION])
 210     AC_DEFINE(WITH_GNUTLS, 1, [Define if you want TCP (GnuTLS) support.])
 211 fi
 212 AM_CONDITIONAL(WITH_GNUTLS, [test "x$USE_GNUTLS" = "xyes"])
 213
 214 dnl Libacl support (for data files).
 215 AC_ARG_ENABLE(acl, AS_HELP_STRING([--enable-acl],
 216               [Enable Access Control List support for data files]),
 217               [USE_LIBACL=yes], [USE_LIBACL=no])
 218 if test "x$USE_LIBACL" = "xyes"; then
 219     AC_SEARCH_LIBS([acl_get_file], [acl],,
 220                    AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 221     AC_CHECK_HEADER([sys/acl.h],,
 222                    AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 223     AC_DEFINE(WITH_LIBACL, 1, [Define if you want libacl support.])
 224 fi
 225 AM_CONDITIONAL(WITH_LIBACL, [test "x$USE_LIBACL" = "xyes"])
 226
 227 AC_DEFUN([AC_DEBUG],
 228 [
 229     if test "$1"; then
 230         ac_cv_sys_debug=$1
 231     fi
 232
 233     AC_CACHE_CHECK([if debugging is wanted], [ac_cv_sys_debug],
 234         [ac_cv_sys_debug=no])
 235     AM_CONDITIONAL([WITH_DEBUG], [test "$ac_cv_sys_debug" = "yes"])
 236 ])
 237
 238 AC_ARG_ENABLE(debug, AS_HELP_STRING([--enable-debug], [Enable debugging (memory de/allocations output).]),
 239     AC_DEBUG([$enableval]), AC_DEBUG)
 240
 241 AC_DEFUN([AC_MEM_DEBUG],
 242 [
 243     if test "$1"; then
 244         ac_cv_sys_mem_debug=$1
 245     fi
 246
 247     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 248         [ac_cv_sys_mem_debug=no])
 249     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 250 ])
 251
 252 AC_DEFUN([AC_MUTEX_DEBUG],
 253 [
 254     if test "$1"; then
 255         ac_cv_sys_mutex_debug=$1
 256     fi
 257
 258     AC_CACHE_CHECK([if mutex debugging is wanted], [ac_cv_sys_mutex_debug],
 259         [ac_cv_sys_mutex_debug=no])
 260     AM_CONDITIONAL([WITH_MUTEX_DEBUG], [test "$ac_cv_sys_mutex_debug" = "yes"])
 261 ])
 262
 263 AC_ARG_ENABLE(mutex_debug, AS_HELP_STRING([--enable-mutex-debug], [Enable mutex debugging output.]),
 264     AC_MUTEX_DEBUG([$enableval]), AC_MUTEX_DEBUG)
 265
 266 dnl Memory debugging.
 267 AC_ARG_ENABLE(mem_debug, AS_HELP_STRING([--enable-mem-debug], [Disable internal memory manager.]),
 268     AC_MEM_DEBUG([$enableval]), AC_MEM_DEBUG)
 269 AM_CONDITIONAL(MEM_DEBUG, test x"${ac_cv_sys_mem_debug}" != xno)
 270
 271 # Default pwmd home directory.
 272 AC_ARG_WITH(pwmd_homedir, AS_HELP_STRING([--with-pwmd-homedir=PATH],
 273               [Default pwmd home directory (~/.pwmd)]),
 274               pwmd_homedir="$withval", pwmd_homedir=)
 275 if test x"$pwmd_homedir" != "x"; then
 276    AC_DEFINE_UNQUOTED(PWMD_HOMEDIR, ["$pwmd_homedir"],
 277                                     [Default pwmd home directory (~/.pwmd).])
 278 fi
 279
 280 AC_ARG_WITH(invoking_user, AS_HELP_STRING([--with-invoking-user=nobody],
 281             [Default invoking_user when not specified in the configuration.
 282              Setting to blank will have the user that started pwmd be the
 283              invoking_user.]), invoking_user="$withval",
 284              invoking_user="nobody")
 285 if test x"$invoking_user" != "x"; then
 286    AC_DEFINE_UNQUOTED(DEFAULT_INVOKER, ["$invoking_user"],
 287                       [Default invoking_user when not specified in the
 288                        configuration. Set to NULL to have the user that
 289                        started pwmd be the invoking_user.])
 290 else
 291    AC_DEFINE(DEFAULT_INVOKER, [NULL],
 292                       [Default invoking_user when not specified in the
 293                        configuration. Set to NULL to have the user that
 294                        started pwmd be the invoking_user.])
 295 fi
 296
 297 VERSION_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
 298 VERSION_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
 299 VERSION_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
 300 VERSION_NUM="`printf 0x%02x%02x%02X ${VERSION_MAJOR} ${VERSION_MINOR} ${VERSION_PATCH}`"
 301 AC_DEFINE_UNQUOTED(VERSION_HEX, ${VERSION_NUM}, [For the file header.])
 302
 303 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/pwmd-dump.1 \
 304                  po/Makefile.in tests/Makefile])
 305 AC_OUTPUT
 306 echo
 307 echo "Features:"
 308 echo "    TCP (GnuTLS)....: $USE_GNUTLS"
 309 echo "    Data file ACL's.: $USE_LIBACL"
 310
 311 if test x"$pwmd_homedir" != "x"; then
 312 echo "    Home directory..: $pwmd_homedir"
 313 else
 314 echo "    Home directory..: ~/.pwmd"
 315 fi
 316
 317 if test "x$invoking_user" != "x"; then
 318 echo "    Invoking user...: $invoking_user"
 319 else
 320 echo "    Invoking user...: determined on start"
 321 fi
 322
 323 echo "    Exec symlink....: $with_proc_symlink"
 324 echo "    Debug...........: ${ac_cv_sys_debug}"
 325 echo "    Memory debug....: ${ac_cv_sys_mem_debug}"
 326 echo "    Mutex debug.....: ${ac_cv_sys_mutex_debug}"