configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(pwmd, 3.0.0-dev, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AC_CONFIG_AUX_DIR(build)
   6 AC_CANONICAL_TARGET
   7 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   8 AC_PROG_MAKE_SET
   9 AC_USE_SYSTEM_EXTENSIONS()
  10 AC_PROG_LIBTOOL
  11 AC_CONFIG_SRCDIR([src/pwmd.c])
  12 AM_CONFIG_HEADER([config.h])
  13 AM_GNU_GETTEXT([external])
  14 AM_GNU_GETTEXT_VERSION([0.16.1])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18
  19 if test "$ac_cv_prog_cc_c99" = "no"; then
  20     AC_MSG_WARN("Unable to find a C99 compatible compiler.")
  21 fi
  22
  23 AC_PROG_AWK
  24 AC_PROG_LN_S
  25 AC_PROG_INSTALL
  26 AC_PROG_LN_S
  27 AC_PROG_CPP
  28 AC_PROG_MKDIR_P
  29
  30 dnl Checks for library functions.
  31 AX_PTHREAD(, [POSIX threads are required])
  32 CC="$PTHREAD_CC"
  33 save_CFLAGS="$CFLAGS"
  34 save_LIBS="$LIBS"
  35 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  36 LIBS="$PTHREAD_LIBS $LIBS"
  37
  38 acx_pthread_mutex_timedlock_ok=no
  39 AC_MSG_CHECKING([for pthread_mutex_timedlock()])
  40 AC_TRY_LINK_FUNC(pthread_mutex_timedlock, acx_pthread_mutex_timedlock_ok=yes)
  41 AC_MSG_RESULT($acx_pthread_mutex_timedlock_ok)
  42 if test x"$acx_pthread_mutex_timedlock_ok" = "xyes"; then
  43     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK, 1, [Define if your OS has pthread_mutex_timedlock().])
  44 fi
  45
  46 acx_pthread_testcancel_ok=no
  47 AC_MSG_CHECKING([for pthread_testcancel()])
  48 AC_TRY_LINK_FUNC(pthread_testcancel, acx_pthread_testcancel_ok=yes)
  49 AC_MSG_RESULT($acx_pthread_testcancel_ok)
  50 if test x"$acx_pthread_testcancel_ok" = "xyes"; then
  51     AC_DEFINE(HAVE_PTHREAD_TESTCANCEL, 1, [Define if your OS has pthread_testcancel().])
  52 fi
  53
  54 acx_pthread_cancel_ok=no
  55 AC_MSG_CHECKING([for pthread_cancel()])
  56 AC_TRY_LINK_FUNC(pthread_cancel, acx_pthread_cancel_ok=yes)
  57 AC_MSG_RESULT($acx_pthread_cancel_ok)
  58 if test x"$acx_pthread_cancel_ok" = "xyes"; then
  59     AC_DEFINE(HAVE_PTHREAD_CANCEL, 1, [Define if your OS has pthread_cancel().])
  60 fi
  61
  62 acx_pthread_atfork_ok=no
  63 AC_MSG_CHECKING([for pthread_atfork()])
  64 AC_TRY_LINK_FUNC(pthread_atfork, acx_pthread_atfork_ok=yes)
  65 AC_MSG_RESULT($acx_pthread_atfork_ok)
  66 if test x"$acx_pthread_atfork_ok" = "xyes"; then
  67     AC_DEFINE(HAVE_PTHREAD_ATFORK, 1, [Define if your OS has pthread_atforkl().])
  68 fi
  69
  70 CFLAGS="$save_CFLAGS"
  71 LIBS="$save_LIBS"
  72
  73 dnl Checks for header files.
  74 AC_HEADER_STDC
  75 AC_HEADER_SYS_WAIT
  76
  77 AC_CHECK_DECLS([SO_BINDTODEVICE],,, [[#include <sys/types.h>
  78                                         #include <sys/socket.h>]])
  79
  80 AC_CHECK_HEADER([linux/prctl.h],
  81                 AC_CHECK_DECL([PR_SET_NAME],,, [[#include <linux/prctl.h>]]))
  82 if test "x$ac_cv_have_decl_PR_SET_NAME" = xyes; then
  83    AC_DEFINE(HAVE_PR_SET_NAME, 1,
  84              [Defined if PR_SET_NAME is available (Linux specific)])
  85 fi
  86
  87 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h sys/time.h unistd.h libintl.h \
  88                   locale.h syslog.h termios.h zlib.h getopt.h limits.h \
  89                   time.h])
  90
  91 dnl Checks for typedefs, structures, and compiler characteristics.
  92 AC_SYS_LARGEFILE
  93 AC_C_CONST
  94 AC_C_INLINE
  95 AC_TYPE_MODE_T
  96 AC_TYPE_SIZE_T
  97 AC_STRUCT_TM
  98 AC_TYPE_PID_T
  99 AC_TYPE_SIGNAL
 100 AC_TYPE_UINT8_T
 101 AC_TYPE_UINT32_T
 102 AC_TYPE_UINT64_T
 103
 104 dnl Checks for library functions.
 105 AC_FUNC_STAT
 106 AC_FUNC_FORK
 107 AC_FUNC_MEMCMP
 108 AC_FUNC_STRFTIME
 109 AC_CHECK_FUNCS([memset mkdir munmap setlocale socket strchr strerror strrchr \
 110                 strstr strtol setrlimit mlockall getopt_long backtrace \
 111                 getpwnam_r getgrnam_r])
 112 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
 113
 114 AM_PATH_LIBASSUAN([2.0.2],, AC_MSG_ERROR([libassuan not found]))
 115 PKG_PROG_PKG_CONFIG()
 116 AM_PATH_LIBGCRYPT([1:1.5.0],, AC_MSG_ERROR([libgcrypt not found]))
 117 AM_PATH_XML2(,, AC_MSG_ERROR([libxml2 not found]))
 118 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([libgpg-error not found]))
 119 AC_SEARCH_LIBS([clock_gettime], [rt])
 120
 121 dnl For data file conversion.
 122 AC_CHECK_LIB(z, deflate,,
 123              AC_MSG_ERROR([Version 1.2.2.1 or later of zlib is required]))
 124
 125 dnl Remote TCP/TLS connections.
 126 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
 127               [Enable TCP (GnuTLS) server support.]), USE_GNUTLS=$enableval,
 128               USE_GNUTLS=no)
 129 if test "x$USE_GNUTLS" = "xyes"; then
 130     PKG_CHECK_MODULES([GNUTLS], [gnutls])
 131     AC_DEFINE(WITH_GNUTLS, 1, [Define if you want TCP (GnuTLS) support.])
 132 fi
 133 AM_CONDITIONAL(WITH_GNUTLS, [test "x$USE_GNUTLS" = "xyes"])
 134
 135 dnl Disable gpg-agent.
 136 AC_ARG_ENABLE(agent, AC_HELP_STRING([--disable-agent],
 137               [Disable public key/gpg-agent support.]), WITH_AGENT=$enableval,
 138               WITH_AGENT=yes)
 139 if test "x$WITH_AGENT" = "xyes"; then
 140     AC_DEFINE(WITH_AGENT, 1, [Define if you want gpg-agent support.])
 141 fi
 142 AM_CONDITIONAL(WITH_AGENT, [test "x$WITH_AGENT" = "xyes"])
 143
 144 pinentry="/usr/bin/pinentry"
 145 dnl Default pinentry location.
 146 AC_ARG_WITH(pinentry, AC_HELP_STRING([--with-pinentry=PATH],
 147               [Default location of the pinentry binary (/usr/bin/pinentry)]),
 148               pinentry="$withval")
 149 AC_SUBST(pinentry)
 150 AC_DEFINE_UNQUOTED(PINENTRY_PATH, ["$pinentry"],
 151                    [Default location of the pinentry binary.])
 152
 153 # Cracklib support (requires pinentry support).
 154 AC_ARG_ENABLE(quality, AC_HELP_STRING([--enable-quality],
 155               [Enable password quality checking with cracklib.]),
 156               WITH_QUALITY=$enableval, WITH_QUALITY=no)
 157 if test "x$WITH_QUALITY" = "xyes"; then
 158     AC_CHECK_HEADER([crack.h],, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 159     AC_CHECK_LIB([crack], FascistCheck,, AC_MSG_ERROR([Missing or invalid cracklib installation.]))
 160     AC_DEFINE(WITH_QUALITY, 1, [Define if you want password quality checking.])
 161 fi
 162 AM_CONDITIONAL(WITH_QUALITY, [test "x$WITH_QUALITY" = "xyes"])
 163
 164 crackdict="/var/cache/cracklib/cracklib_dict"
 165 AC_ARG_WITH(crackdict, AC_HELP_STRING([--with-crack-dict=PATH],
 166               [Location of the cracklib dictionary (/var/cache/cracklib/cracklib_dict).]),
 167               crackdict="$withval")
 168 AC_SUBST(crackdict)
 169 AC_DEFINE_UNQUOTED(CRACKLIB_DICT, ["$crackdict"], [The location of the cracklib dictionary.])
 170
 171
 172 dnl Libacl support (for data files).
 173 AC_ARG_ENABLE(acl, AC_HELP_STRING([--enable-acl],
 174               [Enable Access Control List support]), USE_LIBACL=yes,
 175               USE_LIBACL=no)
 176 if test "x$USE_LIBACL" = "xyes"; then
 177     AC_SEARCH_LIBS([acl_get_file], [acl],,
 178                     AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 179     AC_CHECK_HEADER([sys/acl.h],,
 180                     AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 181     AC_DEFINE(WITH_LIBACL, 1, [Define if you want libacl support.])
 182 fi
 183 AM_CONDITIONAL(WITH_LIBACL, [test "x$USE_LIBACL" = "xyes"])
 184
 185 AC_DEFUN([AC_DEBUG],
 186 [
 187     if test "$1"; then
 188         ac_cv_sys_debug=$1
 189     fi
 190
 191     AC_CACHE_CHECK([if debugging is wanted], [ac_cv_sys_debug],
 192         [ac_cv_sys_debug=no])
 193     AM_CONDITIONAL([WITH_DEBUG], [test "$ac_cv_sys_debug" = "yes"])
 194 ])
 195
 196 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging (memory de/allocations output).]),
 197     AC_DEBUG([$enableval]), AC_DEBUG)
 198
 199 AC_DEFUN([AC_MEM_DEBUG],
 200 [
 201     if test "$1"; then
 202         ac_cv_sys_mem_debug=$1
 203     fi
 204
 205     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 206         [ac_cv_sys_mem_debug=no])
 207     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 208 ])
 209
 210 AC_DEFUN([AC_MUTEX_DEBUG],
 211 [
 212     if test "$1"; then
 213         ac_cv_sys_mutex_debug=$1
 214     fi
 215
 216     AC_CACHE_CHECK([if mutex debugging is wanted], [ac_cv_sys_mutex_debug],
 217         [ac_cv_sys_mutex_debug=no])
 218     AM_CONDITIONAL([WITH_MUTEX_DEBUG], [test "$ac_cv_sys_mutex_debug" = "yes"])
 219 ])
 220
 221 AC_ARG_ENABLE(mutex_debug, AC_HELP_STRING([--enable-mutex-debug], [Enable mutex debugging output.]),
 222     AC_MUTEX_DEBUG([$enableval]), AC_MUTEX_DEBUG)
 223
 224 dnl Memory debugging.
 225 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug], [Disable internal memory manager.]),
 226     AC_MEM_DEBUG([$enableval]), AC_MEM_DEBUG)
 227 AM_CONDITIONAL(MEM_DEBUG, test x"${ac_cv_sys_mem_debug}" != xno)
 228
 229 # Default pwmd home directory.
 230 AC_ARG_WITH(pwmd_homedir, AC_HELP_STRING([--with-pwmd-homedir=PATH],
 231               [Default pwmd home directory (~/.pwmd)]),
 232               pwmd_homedir="$withval", pwmd_homedir=)
 233 if test x"$pwmd_homedir" != "x"; then
 234    AC_DEFINE_UNQUOTED(PWMD_HOMEDIR, ["$pwmd_homedir"],
 235                                     [Default pwmd home directory (~/.pwmd).])
 236 fi
 237
 238 VERSION_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
 239 VERSION_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
 240 VERSION_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
 241 VERSION_NUM="`printf 0x%02x%02x%02X ${VERSION_MAJOR} ${VERSION_MINOR} ${VERSION_PATCH}`"
 242 AC_DEFINE_UNQUOTED(VERSION_HEX, ${VERSION_NUM}, [For the file header.])
 243
 244 dnl Disable optimizing of memset(). GCC and CLang (and others?) accept
 245 dnl multiple optimization flags and use the last one specified. The
 246 dnl non-optimized memset() may still use any CPU features found in the
 247 dnl user specified CFLAGS (-mtune) and libc.
 248 CFLAGS_ORIG="$CFLAGS"
 249 CFLAGS_MEMZERO="$CFLAGS -O0"
 250 CFLAGS=
 251 AC_SUBST(CFLAGS_ORIG)
 252 AC_SUBST(CFLAGS_MEMZERO)
 253
 254 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/pwmd.1 po/Makefile.in
 255                  tests/Makefile])
 256 AC_OUTPUT
 257 echo
 258 echo "Features:"
 259 echo "    With gpg-agent..: $WITH_AGENT"
 260 echo "    Pinentry binary.: $pinentry"
 261 echo "    Cracklib........: $WITH_QUALITY"
 262 echo "    Cracklib dict...: $crackdict"
 263 echo "    TCP (GnuTLS)....: $USE_GNUTLS"
 264 echo "    ACL.............: $USE_LIBACL"
 265
 266 if test x"$pwmd_homedir" != "x"; then
 267 echo "    Home directory..: $pwmd_homedir"
 268 else
 269 echo "    Home directory..: ~/.pwmd"
 270 fi
 271
 272 echo "    Debug...........: ${ac_cv_sys_debug}"
 273 echo "    Memory debug....: ${ac_cv_sys_mem_debug}"
 274 echo "    Mutex debug.....: ${ac_cv_sys_mutex_debug}"