configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.60)
   3 AC_INIT(pwmd, 3.0.0-dev, [Ben Kibbey bjk@luxsci.net])
   4 AC_CONFIG_AUX_DIR(build)
   5 AC_CANONICAL_TARGET
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 AC_PROG_MAKE_SET
   8 AC_USE_SYSTEM_EXTENSIONS()
   9 AC_CONFIG_SRCDIR([src/pwmd.c])
  10 AM_CONFIG_HEADER([config.h])
  11 AM_GNU_GETTEXT([external])
  12 AM_GNU_GETTEXT_VERSION([0.16.1])
  13
  14 dnl Checks for programs.
  15 AC_PROG_CC_C99
  16
  17 if test "$ac_cv_prog_cc_c99" = "no"; then
  18     AC_MSG_WARN("Unable to find a C99 compatible compiler.")
  19 fi
  20
  21 AC_PROG_AWK
  22 AC_PROG_LN_S
  23 AC_PROG_INSTALL
  24 AC_PROG_LN_S
  25 AC_PROG_RANLIB
  26 AC_PROG_CPP
  27 AC_PROG_MKDIR_P
  28
  29 dnl Checks for library functions.
  30 AX_PTHREAD(, [POSIX threads are required])
  31 CC="$PTHREAD_CC"
  32 save_CFLAGS="$CFLAGS"
  33 save_LIBS="$LIBS"
  34 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  35 LIBS="$PTHREAD_LIBS $LIBS"
  36 acx_pthread_mutex_timedlock_ok=no
  37 AC_MSG_CHECKING([for pthread_mutex_timedlock()])
  38 AC_TRY_LINK_FUNC(pthread_mutex_timedlock, acx_pthread_mutex_timedlock_ok=yes)
  39 AC_MSG_RESULT($acx_pthread_mutex_timedlock_ok)
  40 if test x"$acx_pthread_mutex_timedlock_ok" = "xyes"; then
  41     AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK, 1, [Define if your OS has pthread_mutex_timedlock().])
  42 fi
  43 CFLAGS="$save_CFLAGS"
  44 LIBS="$save_LIBS"
  45
  46 AM_PATH_LIBASSUAN([2.0.2],, AC_MSG_ERROR([libassuan not found]))
  47 PKG_PROG_PKG_CONFIG()
  48 AM_PATH_LIBGCRYPT([1:1.5.0],, AC_MSG_ERROR([libgcrypt not found]))
  49 AM_PATH_XML2(,, AC_MSG_ERROR([libxml2 not found]))
  50 AM_PATH_GPG_ERROR(,, AC_MSG_ERROR([libgpg-error not found]))
  51 dnl For data file conversion.
  52 AC_CHECK_LIB(z, deflate,,
  53              AC_MSG_ERROR([Version 1.2.2.1 or later of zlib is required]))
  54
  55 AC_ARG_ENABLE(gnutls, AC_HELP_STRING([--enable-gnutls],
  56               [Enable TCP (GnuTLS) server support.]), USE_GNUTLS=$enableval,
  57               USE_GNUTLS=no)
  58 if test "x$USE_GNUTLS" = "xyes"; then
  59     PKG_CHECK_MODULES([GNUTLS], [gnutls])
  60     AC_DEFINE(WITH_GNUTLS, 1, [Define if you want TCP (GnuTLS) support.])
  61 fi
  62 AM_CONDITIONAL(WITH_GNUTLS, [test "x$USE_GNUTLS" = "xyes"])
  63
  64 dnl Checks for header files.
  65 AC_HEADER_STDC
  66 AC_HEADER_SYS_WAIT
  67 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h sys/time.h unistd.h libintl.h \
  68                   locale.h syslog.h termios.h zlib.h getopt.h limits.h \
  69                   time.h])
  70 AC_CHECK_HEADER([linux/prctl.h],
  71                 AC_CHECK_DECL([PR_SET_NAME],,, [[#include <linux/prctl.h>]]))
  72 if test "x$ac_cv_have_decl_PR_SET_NAME" = xyes; then
  73   AC_DEFINE(HAVE_PR_SET_NAME, 1,
  74             [Defined if PR_SET_NAME is available (Linux specific)])
  75 fi
  76 AC_CHECK_HEADER([sys/socket.h], AC_CHECK_DECLS([SO_BINDTODEVICE,SO_PEERCRED],,, [[#include <sys/socket.h>]]))
  77
  78 dnl Checks for typedefs, structures, and compiler characteristics.
  79 AC_SYS_LARGEFILE
  80 AC_C_CONST
  81 AC_C_INLINE
  82 AC_TYPE_MODE_T
  83 AC_TYPE_SIZE_T
  84 AC_STRUCT_TM
  85 AC_TYPE_PID_T
  86 AC_TYPE_SIGNAL
  87
  88 dnl Checks for library functions.
  89 AC_FUNC_STAT
  90 AC_FUNC_FORK
  91 AC_FUNC_MALLOC
  92 AC_FUNC_MEMCMP
  93 AC_FUNC_STRFTIME
  94 AC_CHECK_FUNCS([memset mkdir munmap setlocale socket strchr strerror strrchr \
  95                 strstr strtol setrlimit mlockall getopt_long backtrace])
  96 AM_CONDITIONAL([NEED_GETOPT_LONG], [test "$ac_cv_func_getopt_long" != "yes"])
  97
  98 AC_DEFUN([AC_DEBUG],
  99 [
 100     if test "$1"; then
 101         ac_cv_sys_debug=$1
 102     fi
 103
 104     AC_CACHE_CHECK([if debugging is wanted], [ac_cv_sys_debug],
 105         [ac_cv_sys_debug=no])
 106     AM_CONDITIONAL([WITH_DEBUG], [test "$ac_cv_sys_debug" = "yes"])
 107 ])
 108
 109 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [Enable debugging (memory de/allocations output).]),
 110     AC_DEBUG([$enableval]), AC_DEBUG)
 111
 112 AC_DEFUN([AC_MEM_DEBUG],
 113 [
 114     if test "$1"; then
 115         ac_cv_sys_mem_debug=$1
 116     fi
 117
 118     AC_CACHE_CHECK([if memory debugging is wanted], [ac_cv_sys_mem_debug],
 119         [ac_cv_sys_mem_debug=no])
 120     AM_CONDITIONAL([WITH_MEM_DEBUG], [test "$ac_cv_sys_mem_debug" = "yes"])
 121 ])
 122
 123 AC_DEFUN([AC_MUTEX_DEBUG],
 124 [
 125     if test "$1"; then
 126         ac_cv_sys_mutex_debug=$1
 127     fi
 128
 129     AC_CACHE_CHECK([if mutex debugging is wanted], [ac_cv_sys_mutex_debug],
 130         [ac_cv_sys_mutex_debug=no])
 131     AM_CONDITIONAL([WITH_MUTEX_DEBUG], [test "$ac_cv_sys_mutex_debug" = "yes"])
 132 ])
 133
 134 AC_ARG_ENABLE(mutex_debug, AC_HELP_STRING([--enable-mutex-debug], [Enable mutex debugging output.]),
 135     AC_MUTEX_DEBUG([$enableval]), AC_MUTEX_DEBUG)
 136
 137 # Libacl support (for data files).
 138 AC_ARG_ENABLE(acl, AC_HELP_STRING([--enable-acl],
 139               [Enable Access Control List support]), USE_LIBACL=yes,
 140               USE_LIBACL=no)
 141 if test "x$USE_LIBACL" = "xyes"; then
 142     AC_CHECK_LIB(acl, acl_get_file,,
 143                     AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 144     AC_CHECK_HEADER([sys/acl.h],,
 145                     AC_MSG_ERROR([Missing or incomplete libacl installation.]))
 146     AC_DEFINE(WITH_LIBACL, 1, [Define if you want libacl support.])
 147 fi
 148 AM_CONDITIONAL(WITH_LIBACL, [test "x$USE_LIBACL" = "xyes"])
 149
 150 # Memory debugging.
 151 AC_ARG_ENABLE(mem_debug, AC_HELP_STRING([--enable-mem-debug], [Disable internal memory manager.]),
 152     AC_MEM_DEBUG([$enableval]), AC_MEM_DEBUG)
 153 AM_CONDITIONAL(MEM_DEBUG, test x"${ac_cv_sys_mem_debug}" != xno)
 154
 155 VERSION_MAJOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`"
 156 VERSION_MINOR="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`"
 157 VERSION_PATCH="`echo "$VERSION" | sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`"
 158 VERSION_NUM="`printf 0x%02x%02x%02X ${VERSION_MAJOR} ${VERSION_MINOR} ${VERSION_PATCH}`"
 159 AC_DEFINE_UNQUOTED(VERSION_HEX, ${VERSION_NUM}, [For the file header.])
 160
 161 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/pwmd.1 po/Makefile.in
 162                  tests/Makefile])
 163 AC_OUTPUT
 164 echo
 165 echo "Features:"
 166 echo "    TCP (GnuTLS): $USE_GNUTLS"
 167 echo "    ACL: $USE_LIBACL"
 168 echo "    Debug: ${ac_cv_sys_debug}"
 169 echo "    Memory debug: ${ac_cv_sys_mem_debug}"
 170 echo "    Mutex debug: ${ac_cv_sys_mutex_debug}"