m4/pthread-mutex.m4

   1 # pthread-mutex.m4 serial 3
   2 dnl Copyright (C) 2019-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_PTHREAD_MUTEX],
   8 [
   9   AC_REQUIRE([gl_PTHREAD_H])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11
  12   if { case "$host_os" in mingw*) true;; *) false;; esac; } \
  13      && test $gl_threads_api = windows; then
  14     dnl Choose function names that don't conflict with the mingw-w64 winpthreads
  15     dnl library.
  16     REPLACE_PTHREAD_MUTEX_INIT=1
  17     REPLACE_PTHREAD_MUTEXATTR_INIT=1
  18     REPLACE_PTHREAD_MUTEXATTR_GETTYPE=1
  19     REPLACE_PTHREAD_MUTEXATTR_SETTYPE=1
  20     REPLACE_PTHREAD_MUTEXATTR_GETROBUST=1
  21     REPLACE_PTHREAD_MUTEXATTR_SETROBUST=1
  22     REPLACE_PTHREAD_MUTEXATTR_DESTROY=1
  23     REPLACE_PTHREAD_MUTEX_LOCK=1
  24     REPLACE_PTHREAD_MUTEX_TRYLOCK=1
  25     REPLACE_PTHREAD_MUTEX_TIMEDLOCK=1
  26     REPLACE_PTHREAD_MUTEX_UNLOCK=1
  27     REPLACE_PTHREAD_MUTEX_DESTROY=1
  28   else
  29     if test $HAVE_PTHREAD_H = 0; then
  30       HAVE_PTHREAD_MUTEX_INIT=0
  31       HAVE_PTHREAD_MUTEXATTR_INIT=0
  32       HAVE_PTHREAD_MUTEXATTR_GETTYPE=0
  33       HAVE_PTHREAD_MUTEXATTR_SETTYPE=0
  34       HAVE_PTHREAD_MUTEXATTR_GETROBUST=0
  35       HAVE_PTHREAD_MUTEXATTR_SETROBUST=0
  36       HAVE_PTHREAD_MUTEXATTR_DESTROY=0
  37       HAVE_PTHREAD_MUTEX_LOCK=0
  38       HAVE_PTHREAD_MUTEX_TRYLOCK=0
  39       dnl HAVE_PTHREAD_MUTEX_TIMEDLOCK is set in pthread_mutex_timedlock.m4.
  40       HAVE_PTHREAD_MUTEX_UNLOCK=0
  41       HAVE_PTHREAD_MUTEX_DESTROY=0
  42     else
  43       AC_CACHE_CHECK([for pthread_mutexattr_getrobust],
  44         [gl_cv_func_pthread_mutexattr_getrobust],
  45         [saved_LIBS="$LIBS"
  46          LIBS="$LIBS $LIBPMULTITHREAD"
  47          AC_LINK_IFELSE(
  48            [AC_LANG_SOURCE(
  49               [[extern
  50                 #ifdef __cplusplus
  51                 "C"
  52                 #endif
  53                 int pthread_mutexattr_getrobust (void);
  54                 int main ()
  55                 {
  56                   return pthread_mutexattr_getrobust ();
  57                 }
  58               ]])],
  59            [gl_cv_func_pthread_mutexattr_getrobust=yes],
  60            [gl_cv_func_pthread_mutexattr_getrobust=no])
  61          LIBS="$saved_LIBS"
  62         ])
  63       if test $gl_cv_func_pthread_mutexattr_getrobust = no; then
  64         HAVE_PTHREAD_MUTEXATTR_GETROBUST=0
  65         HAVE_PTHREAD_MUTEXATTR_SETROBUST=0
  66         AC_DEFINE([PTHREAD_MUTEXATTR_ROBUST_UNIMPLEMENTED], [1],
  67           [Define if the 'robust' attribute of pthread_mutex* doesn't exist.])
  68       fi
  69     fi
  70   fi
  71 ])