m4/pthread-mutex.m4

   1 # pthread-mutex.m4
   2 # serial 4
   3 dnl Copyright (C) 2019-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_PTHREAD_MUTEX],
   9 [
  10   AC_REQUIRE([gl_PTHREAD_H])
  11   AC_REQUIRE([AC_CANONICAL_HOST])
  12
  13   if { case "$host_os" in mingw* | windows*) true;; *) false;; esac; } \
  14      && test $gl_threads_api = windows; then
  15     dnl Choose function names that don't conflict with the mingw-w64 winpthreads
  16     dnl library.
  17     REPLACE_PTHREAD_MUTEX_INIT=1
  18     REPLACE_PTHREAD_MUTEXATTR_INIT=1
  19     REPLACE_PTHREAD_MUTEXATTR_GETTYPE=1
  20     REPLACE_PTHREAD_MUTEXATTR_SETTYPE=1
  21     REPLACE_PTHREAD_MUTEXATTR_GETROBUST=1
  22     REPLACE_PTHREAD_MUTEXATTR_SETROBUST=1
  23     REPLACE_PTHREAD_MUTEXATTR_DESTROY=1
  24     REPLACE_PTHREAD_MUTEX_LOCK=1
  25     REPLACE_PTHREAD_MUTEX_TRYLOCK=1
  26     REPLACE_PTHREAD_MUTEX_TIMEDLOCK=1
  27     REPLACE_PTHREAD_MUTEX_UNLOCK=1
  28     REPLACE_PTHREAD_MUTEX_DESTROY=1
  29   else
  30     if test $HAVE_PTHREAD_H = 0; then
  31       HAVE_PTHREAD_MUTEX_INIT=0
  32       HAVE_PTHREAD_MUTEXATTR_INIT=0
  33       HAVE_PTHREAD_MUTEXATTR_GETTYPE=0
  34       HAVE_PTHREAD_MUTEXATTR_SETTYPE=0
  35       HAVE_PTHREAD_MUTEXATTR_GETROBUST=0
  36       HAVE_PTHREAD_MUTEXATTR_SETROBUST=0
  37       HAVE_PTHREAD_MUTEXATTR_DESTROY=0
  38       HAVE_PTHREAD_MUTEX_LOCK=0
  39       HAVE_PTHREAD_MUTEX_TRYLOCK=0
  40       dnl HAVE_PTHREAD_MUTEX_TIMEDLOCK is set in pthread_mutex_timedlock.m4.
  41       HAVE_PTHREAD_MUTEX_UNLOCK=0
  42       HAVE_PTHREAD_MUTEX_DESTROY=0
  43     else
  44       AC_CACHE_CHECK([for pthread_mutexattr_getrobust],
  45         [gl_cv_func_pthread_mutexattr_getrobust],
  46         [saved_LIBS="$LIBS"
  47          LIBS="$LIBS $LIBPMULTITHREAD"
  48          AC_LINK_IFELSE(
  49            [AC_LANG_SOURCE(
  50               [[extern
  51                 #ifdef __cplusplus
  52                 "C"
  53                 #endif
  54                 int pthread_mutexattr_getrobust (void);
  55                 int main ()
  56                 {
  57                   return pthread_mutexattr_getrobust ();
  58                 }
  59               ]])],
  60            [gl_cv_func_pthread_mutexattr_getrobust=yes],
  61            [gl_cv_func_pthread_mutexattr_getrobust=no])
  62          LIBS="$saved_LIBS"
  63         ])
  64       if test $gl_cv_func_pthread_mutexattr_getrobust = no; then
  65         HAVE_PTHREAD_MUTEXATTR_GETROBUST=0
  66         HAVE_PTHREAD_MUTEXATTR_SETROBUST=0
  67         AC_DEFINE([PTHREAD_MUTEXATTR_ROBUST_UNIMPLEMENTED], [1],
  68           [Define if the 'robust' attribute of pthread_mutex* doesn't exist.])
  69       fi
  70     fi
  71   fi
  72 ])