m4/fdopen.m4

   1 # fdopen.m4 serial 5
   2 dnl Copyright (C) 2011-2020 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FDOPEN],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11   m4_ifdef([gl_MSVC_INVAL], [
  12     AC_REQUIRE([gl_MSVC_INVAL])
  13     if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
  14       REPLACE_FDOPEN=1
  15     fi
  16   ])
  17   if test $REPLACE_FDOPEN = 0; then
  18     dnl Test whether fdopen() sets errno when it fails due to a bad fd argument.
  19     AC_CACHE_CHECK([whether fdopen sets errno], [gl_cv_func_fdopen_works],
  20       [
  21         AC_RUN_IFELSE(
  22           [AC_LANG_SOURCE([[
  23 #include <stdio.h>
  24 #include <errno.h>
  25 ]GL_MDA_DEFINES[
  26 int
  27 main (void)
  28 {
  29   FILE *fp;
  30   errno = 0;
  31   fp = fdopen (-1, "r");
  32   if (fp == NULL && errno == 0)
  33     return 1;
  34   return 0;
  35 }]])],
  36           [gl_cv_func_fdopen_works=yes],
  37           [gl_cv_func_fdopen_works=no],
  38           [case "$host_os" in
  39              mingw*) gl_cv_func_fdopen_works="guessing no" ;;
  40              *)      gl_cv_func_fdopen_works="guessing yes" ;;
  41            esac
  42           ])
  43       ])
  44     case "$gl_cv_func_fdopen_works" in
  45       *no) REPLACE_FDOPEN=1 ;;
  46     esac
  47   fi
  48 ])
  49
  50 dnl Prerequisites of lib/fdopen.c.
  51 AC_DEFUN([gl_PREREQ_FDOPEN], [])