m4/fdopen.m4

   1 # fdopen.m4
   2 # serial 6
   3 dnl Copyright (C) 2011-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_FDOPEN],
   9 [
  10   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  11   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  12   m4_ifdef([gl_MSVC_INVAL], [
  13     AC_REQUIRE([gl_MSVC_INVAL])
  14     if test $HAVE_MSVC_INVALID_PARAMETER_HANDLER = 1; then
  15       REPLACE_FDOPEN=1
  16     fi
  17   ])
  18   if test $REPLACE_FDOPEN = 0; then
  19     dnl Test whether fdopen() sets errno when it fails due to a bad fd argument.
  20     AC_CACHE_CHECK([whether fdopen sets errno], [gl_cv_func_fdopen_works],
  21       [
  22         AC_RUN_IFELSE(
  23           [AC_LANG_SOURCE([[
  24 #include <stdio.h>
  25 #include <errno.h>
  26 ]GL_MDA_DEFINES[
  27 int
  28 main (void)
  29 {
  30   FILE *fp;
  31   errno = 0;
  32   fp = fdopen (-1, "r");
  33   if (fp == NULL && errno == 0)
  34     return 1;
  35   return 0;
  36 }]])],
  37           [gl_cv_func_fdopen_works=yes],
  38           [gl_cv_func_fdopen_works=no],
  39           [case "$host_os" in
  40              mingw* | windows*) gl_cv_func_fdopen_works="guessing no" ;;
  41              *)                 gl_cv_func_fdopen_works="guessing yes" ;;
  42            esac
  43           ])
  44       ])
  45     case "$gl_cv_func_fdopen_works" in
  46       *no) REPLACE_FDOPEN=1 ;;
  47     esac
  48   fi
  49 ])
  50
  51 dnl Prerequisites of lib/fdopen.c.
  52 AC_DEFUN([gl_PREREQ_FDOPEN], [])