m4/locale-ar.m4

   1 # locale-ar.m4 serial 9
   2 dnl Copyright (C) 2003, 2005-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
   8
   9 dnl Determine the name of an Arabic locale with traditional encoding.
  10 AC_DEFUN([gt_LOCALE_AR],
  11 [
  12   AC_REQUIRE([AC_CANONICAL_HOST])
  13   AC_REQUIRE([AM_LANGINFO_CODESET])
  14   AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
  15     AC_LANG_CONFTEST([AC_LANG_SOURCE([[
  16 #include <locale.h>
  17 #include <time.h>
  18 #if HAVE_LANGINFO_CODESET
  19 # include <langinfo.h>
  20 #endif
  21 #include <stdlib.h>
  22 #include <string.h>
  23 struct tm t;
  24 char buf[16];
  25 int main () {
  26   /* On BeOS and Haiku, locales are not implemented in libc.  Rather, libintl
  27      imitates locale dependent behaviour by looking at the environment
  28      variables, and all locales use the UTF-8 encoding.  */
  29 #if defined __BEOS__ || defined __HAIKU__
  30   return 1;
  31 #else
  32   /* Check whether the given locale name is recognized by the system.  */
  33 # if defined _WIN32 && !defined __CYGWIN__
  34   /* On native Windows, setlocale(category, "") looks at the system settings,
  35      not at the environment variables.  Also, when an encoding suffix such
  36      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  37      category of the locale to "C".  */
  38   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  39       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  40     return 1;
  41 # else
  42   if (setlocale (LC_ALL, "") == NULL) return 1;
  43 # endif
  44   /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646"
  45      and ends in "6". */
  46 # if HAVE_LANGINFO_CODESET
  47   {
  48     const char *cs = nl_langinfo (CODESET);
  49     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  50         || cs[strlen (cs) - 1] != '6')
  51       return 1;
  52   }
  53 # endif
  54 # ifdef __CYGWIN__
  55   /* On Cygwin, avoid locale names without encoding suffix, because the
  56      locale_charset() function relies on the encoding suffix.  Note that
  57      LC_ALL is set on the command line.  */
  58   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  59 # endif
  60   return 0;
  61 #endif
  62 }
  63       ]])])
  64     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  65       case "$host_os" in
  66         # Handle native Windows specially, because there setlocale() interprets
  67         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  68         # "fr" or "fra" as "French" or "French_France.1252",
  69         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  70         # "ja" as "Japanese" or "Japanese_Japan.932",
  71         # and similar.
  72         mingw*)
  73           # Note that on native Windows, the Arabic locale is
  74           # "Arabic_Saudi Arabia.1256", and CP1256 is very different from
  75           # ISO-8859-6, so we cannot use it here.
  76           gt_cv_locale_ar=none
  77           ;;
  78         *)
  79           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  80           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
  81           # configure script would override the LC_ALL setting. Likewise for
  82           # LC_CTYPE, which is also set at the beginning of the configure script.
  83           # Values tested:
  84           #   - The usual locale name:                         ar_SA
  85           #   - The locale name with explicit encoding suffix: ar_SA.ISO-8859-6
  86           #   - The HP-UX locale name:                         ar_SA.iso88596
  87           #   - The Solaris 7 locale name:                     ar
  88           # Also try ar_EG instead of ar_SA because Egypt is a large country too.
  89           for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_SA.iso88596 ar_EG ar_EG.ISO-8859-6 ar_EG.iso88596 ar none; do
  90             if test $gt_cv_locale_ar = none; then
  91               break
  92             fi
  93             if (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  94               break
  95             fi
  96           done
  97           ;;
  98       esac
  99     fi
 100     rm -fr conftest*
 101   ])
 102   LOCALE_AR=$gt_cv_locale_ar
 103   AC_SUBST([LOCALE_AR])
 104 ])