m4/locale-ar.m4

   1 # locale-ar.m4
   2 # serial 11
   3 dnl Copyright (C) 2003, 2005-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
   9
  10 dnl Determine the name of an Arabic locale with traditional encoding.
  11 AC_DEFUN_ONCE([gt_LOCALE_AR],
  12 [
  13   AC_REQUIRE([AC_CANONICAL_HOST])
  14   AC_REQUIRE([AM_LANGINFO_CODESET])
  15   AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
  16     AC_LANG_CONFTEST([AC_LANG_SOURCE([[
  17 #include <locale.h>
  18 #include <time.h>
  19 #if HAVE_LANGINFO_CODESET
  20 # include <langinfo.h>
  21 #endif
  22 #include <stdlib.h>
  23 #include <string.h>
  24 struct tm t;
  25 char buf[16];
  26 int main () {
  27   /* On BeOS and Haiku, locales are not implemented in libc.  Rather, libintl
  28      imitates locale dependent behaviour by looking at the environment
  29      variables, and all locales use the UTF-8 encoding.  */
  30 #if defined __BEOS__ || defined __HAIKU__
  31   return 1;
  32 #else
  33   /* Check whether the given locale name is recognized by the system.  */
  34 # if defined _WIN32 && !defined __CYGWIN__
  35   /* On native Windows, setlocale(category, "") looks at the system settings,
  36      not at the environment variables.  Also, when an encoding suffix such
  37      as ".65001" or ".54936" is specified, it succeeds but sets the LC_CTYPE
  38      category of the locale to "C".  */
  39   if (setlocale (LC_ALL, getenv ("LC_ALL")) == NULL
  40       || strcmp (setlocale (LC_CTYPE, NULL), "C") == 0)
  41     return 1;
  42 # else
  43   if (setlocale (LC_ALL, "") == NULL) return 1;
  44 # endif
  45   /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646"
  46      and ends in "6". */
  47 # if HAVE_LANGINFO_CODESET
  48   {
  49     const char *cs = nl_langinfo (CODESET);
  50     if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
  51         || cs[strlen (cs) - 1] != '6')
  52       return 1;
  53   }
  54 # endif
  55 # ifdef __CYGWIN__
  56   /* On Cygwin, avoid locale names without encoding suffix, because the
  57      locale_charset() function relies on the encoding suffix.  Note that
  58      LC_ALL is set on the command line.  */
  59   if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
  60 # endif
  61   return 0;
  62 #endif
  63 }
  64       ]])])
  65     if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
  66       case "$host_os" in
  67         # Handle native Windows specially, because there setlocale() interprets
  68         # "ar" as "Arabic" or "Arabic_Saudi Arabia.1256",
  69         # "fr" or "fra" as "French" or "French_France.1252",
  70         # "ge"(!) or "deu"(!) as "German" or "German_Germany.1252",
  71         # "ja" as "Japanese" or "Japanese_Japan.932",
  72         # and similar.
  73         mingw* | windows*)
  74           # Note that on native Windows, the Arabic locale is
  75           # "Arabic_Saudi Arabia.1256", and CP1256 is very different from
  76           # ISO-8859-6, so we cannot use it here.
  77           gt_cv_locale_ar=none
  78           ;;
  79         *)
  80           # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
  81           # otherwise on Mac OS X 10.3.5 the LC_TIME=C from the beginning of the
  82           # configure script would override the LC_ALL setting. Likewise for
  83           # LC_CTYPE, which is also set at the beginning of the configure script.
  84           # Values tested:
  85           #   - The usual locale name:                         ar_SA
  86           #   - The locale name with explicit encoding suffix: ar_SA.ISO-8859-6
  87           #   - The HP-UX locale name:                         ar_SA.iso88596
  88           #   - The Solaris 10 locale name:                    ar
  89           # Also try ar_EG instead of ar_SA because Egypt is a large country too.
  90           for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_SA.iso88596 ar_EG ar_EG.ISO-8859-6 ar_EG.iso88596 ar none; do
  91             if test $gt_cv_locale_ar = none; then
  92               break
  93             fi
  94             if (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
  95               break
  96             fi
  97           done
  98           ;;
  99       esac
 100     fi
 101     rm -fr conftest*
 102   ])
 103   LOCALE_AR=$gt_cv_locale_ar
 104   case $LOCALE_AR in #(
 105     '' | *[[[:space:]\"\$\'*@<:@]]*)
 106       dnl This locale name might cause trouble with sh or make.
 107       AC_MSG_WARN([invalid locale "$LOCALE_AR"; assuming "none"])
 108       LOCALE_AR=none;;
 109   esac
 110   AC_SUBST([LOCALE_AR])
 111 ])