gcc/testsuite/lib/target-supports.exp

   1 #   Copyright (C) 1999, 2001, 2003 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 2 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program; if not, write to the Free Software
  15 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # Please email any bugs, comments, and/or additions to this file to:
  18 # gcc-patches@gcc.gnu.org
  19
  20 # This file defines procs for determining features supported by the target.
  21
  22 ###############################
  23 # proc check_weak_available { }
  24 ###############################
  25
  26 # weak symbols are only supported in some configs/object formats
  27 # this proc returns 1 if they're supported, 0 if they're not, or -1 if unsure
  28
  29 proc check_weak_available { } {
  30     global target_triplet
  31     global target_cpu
  32
  33     # All mips targets should support it
  34
  35     if { [ string first "mips" $target_cpu ] >= 0 } {
  36         return 1
  37     }
  38
  39     # All solaris2 targets should support it
  40
  41     if { [regexp ".*-solaris2.*" $target_triplet] } {
  42         return 1
  43     }
  44
  45     # DEC OSF/1/Digital UNIX/Tru64 UNIX supports it
  46
  47     if { [regexp "alpha.*osf.*" $target_triplet] } {
  48         return 1
  49     }
  50
  51     # ELF and ECOFF support it. a.out does with gas/gld but may also with
  52     # other linkers, so we should try it
  53
  54     set objformat [gcc_target_object_format]
  55
  56     switch $objformat {
  57         elf      { return 1 }
  58         ecoff    { return 1 }
  59         a.out    { return 1 }
  60         unknown  { return -1 }
  61         default  { return 0 }
  62     }
  63 }
  64
  65 ###############################
  66 # proc check_visibility_available { }
  67 ###############################
  68
  69 # The visibility attribute is only support in some object formats
  70 # This proc returns 1 if it is supported, 0 if not, -1 if unsure.
  71
  72 proc check_visibility_available { } {
  73     global target_triplet
  74     global target_cpu
  75
  76     # On NetWare, support makes no sense.
  77
  78     if { [string match "*-*-netware*" $target_triplet] } {
  79         return 0
  80     }
  81
  82     # ELF supports it if the system has recent GNU ld and gas.
  83     # As a start we return 1 for all ELF systems; we'll let people
  84     # add exceptions as necessary.
  85
  86     set objformat [gcc_target_object_format]
  87
  88     switch $objformat {
  89         elf      { return 1 }
  90         unknown  { return -1 }
  91         default  { return 0 }
  92     }
  93 }
  94
  95 ###############################
  96 # proc check_alias_available { }
  97 ###############################
  98
  99 # Determine if the target toolchain supports the alias attribute.
 100
 101 # Returns 2 if the target supports aliases.  Returns 1 if the target
 102 # only supports weak aliased.  Returns 0 if the target does not
 103 # support aliases at all.  Returns -1 if support for aliases could not
 104 # be determined.
 105
 106 proc check_alias_available { } {
 107     global alias_available_saved
 108     global tool
 109
 110     if [info exists alias_available_saved] {
 111         verbose "check_alias_available  returning saved $alias_available_saved" 2
 112     } else {
 113         set src alias[pid].c
 114         set obj alias[pid].o
 115         verbose "check_alias_available  compiling testfile $src" 2
 116         set f [open $src "w"]
 117         # Compile a small test program.  The definition of "g" is
 118         # necessary to keep the Solaris assembler from complaining
 119         # about the program.
 120         puts $f "#ifdef __cplusplus\nextern \"C\"\n#endif\n"
 121         puts $f "void g() {} void f() __attribute__((alias(\"g\")));"
 122         close $f
 123         set lines [${tool}_target_compile $src $obj object ""]
 124         file delete $src
 125         remote_file build delete $obj
 126
 127         if [string match "" $lines] then {
 128             # No error messages, everything is OK.
 129             set alias_available_saved 2
 130         } else {
 131             if [regexp "alias definitions not supported" $lines] {
 132                 verbose "check_alias_available  target does not support aliases" 2
 133
 134                 set objformat [gcc_target_object_format]
 135
 136                 if { $objformat == "elf" } {
 137                     verbose "check_alias_available  but target uses ELF format, so it ought to" 2
 138                     set alias_available_saved -1
 139                 } else {
 140                     set alias_available_saved 0
 141                 }
 142             } else {
 143                 if [regexp "only weak aliases are supported" $lines] {
 144                 verbose "check_alias_available  target supports only weak aliases" 2
 145                 set alias_available_saved 1
 146                 } else {
 147                     set alias_available_saved -1
 148                 }
 149             }
 150         }
 151
 152         verbose "check_alias_available  returning $alias_available_saved" 2
 153     }
 154
 155     return $alias_available_saved
 156 }
 157
 158 # Returns true if --gc-sections is supported on the target.
 159
 160 proc check_gc_sections_available { } {
 161     global gc_sections_available_saved
 162     global tool
 163
 164     if {![info exists gc_sections_available_saved]} {
 165         # Check if the ld used by gcc supports --gc-sections.
 166         set gcc_spec [${tool}_target_compile "-dumpspecs" "" "none" ""]
 167         regsub ".*\n\*linker:\[ \t\]*\n(\[^ \t\n\]*).*" "$gcc_spec" {\1} linker
 168         set gcc_ld [lindex [${tool}_target_compile "-print-prog-name=$linker" "" "none" ""] 0]
 169         set ld_output [remote_exec host "$gcc_ld" "--help"]
 170         if { [ string first "--gc-sections" $ld_output ] >= 0 } {
 171             set gc_sections_available_saved 1
 172         } else {
 173             set gc_sections_available_saved 0
 174         }
 175     }
 176     return $gc_sections_available_saved
 177 }
 178
 179 # Return true if profiling is supported on the target.
 180
 181 proc check_profiling_available { test_what } {
 182     global profiling_available_saved
 183
 184     verbose "Profiling argument is <$test_what>" 1
 185
 186     # These conditions depend on the argument so examine them before
 187     # looking at the cache variable.
 188
 189     # Support for -p on solaris2 relies on mcrt1.o which comes with the
 190     # vendor compiler.  We cannot reliably predict the directory where the
 191     # vendor compiler (and thus mcrt1.o) is installed so we can't
 192     # necessarily find mcrt1.o even if we have it.
 193     if { [istarget *-*-solaris2*] && [lindex $test_what 1] == "-p" } {
 194         return 0
 195     }
 196
 197     # Support for -p on irix relies on libprof1.a which doesn't appear to
 198     # exist on any irix6 system currently posting testsuite results.
 199     # Support for -pg on irix relies on gcrt1.o which doesn't exist yet.
 200     # See: http://gcc.gnu.org/ml/gcc/2002-10/msg00169.html
 201     if { [istarget mips*-*-irix*]
 202     && ([lindex $test_what 1] == "-p" || [lindex $test_what 1] == "-pg") } {
 203         return 0
 204     }
 205
 206     # Now examine the cache variable.
 207     if {![info exists profiling_available_saved]} {
 208         # Some targets don't have any implementation of __bb_init_func or are
 209         # missing other needed machinery.
 210         if { [istarget mmix-*-*]
 211              || [istarget arm*-*-eabi*]
 212              || [istarget arm*-*-elf]
 213              || [istarget arm*-*-symbianelf*]
 214              || [istarget powerpc-*-eabi*]
 215              || [istarget strongarm*-*-elf]
 216              || [istarget xscale*-*-elf]
 217              || [istarget cris-*-*]
 218              || [istarget h8300-*-*]
 219              || [istarget mips*-*-elf]
 220              || [istarget *-*-windiss] } {
 221             set profiling_available_saved 0
 222         } else {
 223             set profiling_available_saved 1
 224         }
 225     }
 226
 227     return $profiling_available_saved
 228 }
 229
 230 # Return true if iconv is supported on the target. In particular IBM-1047.
 231
 232 proc check_iconv_available { test_what } {
 233     global tool
 234     global libiconv
 235
 236     set result ""
 237
 238     set src iconv[pid].c
 239     set exe iconv[pid].x
 240     verbose "check_iconv_available compiling testfile $src" 2
 241     set f [open $src "w"]
 242     # Compile a small test program.
 243     puts $f "#include <iconv.h>\n"
 244     puts $f "int main (void)\n {\n iconv_t cd; \n"
 245     puts $f "cd = iconv_open (\"[lindex $test_what 1]\", \"UTF-8\");\n"
 246     puts $f "if (cd == (iconv_t) -1)\n return 1;\n"
 247     puts $f "return 0;\n}"
 248     close $f
 249
 250     set lines [${tool}_target_compile $src $exe executable "libs=$libiconv" ]
 251     file delete $src
 252
 253     if [string match "" $lines] then {
 254         # No error messages, everything is OK.
 255
 256         set result [${tool}_load "./$exe" "" ""]
 257         set status [lindex $result 0];
 258         remote_file build delete $exe
 259
 260         verbose "check_iconv_available status is <$status>" 2
 261
 262         if { $status == "pass" } then {
 263             return 1
 264         }
 265     }
 266
 267     return 0
 268 }
 269
 270 # Return true if named sections are supported on this target.
 271 # This proc does not cache results, because the answer may vary
 272 # when cycling over subtarget options (e.g. irix o32/n32/n64) in
 273 # the same test run.
 274 proc check_named_sections_available { } {
 275     global tool
 276
 277     set src named[pid].c
 278     set obj named[pid].o
 279     verbose "check_named_sections_available compiling testfile $src" 2
 280     set f [open $src "w"]
 281     # Compile a small test program.
 282     puts $f "int __attribute__ ((section(\"whatever\"))) foo;"
 283     close $f
 284     set lines [${tool}_target_compile $src $obj object ""]
 285     file delete $src
 286     remote_file build delete $obj
 287
 288     # If we got no error messages, everything is OK.
 289     set answer [string match "" $lines]
 290     verbose "check_named_sections_available  returning $answer" 2
 291     return $answer
 292 }
 293
 294 # Return 1 if the target supports executing AltiVec instructions, 0
 295 # otherwise.  Cache the result.
 296
 297 proc check_vmx_hw_available { } {
 298     global vmx_hw_available_saved
 299     global tool
 300
 301     if [info exists vmx_hw_available_saved] {
 302         verbose "check_hw_available  returning saved $vmx_hw_available_saved" 2
 303     } else {
 304         set vmx_hw_available_saved 0
 305
 306         # Some simulators are known to not support VMX instructions.
 307         if { [istarget powerpc-*-eabi] || [istarget powerpc*-*-eabispe] } {
 308             verbose "check_hw_available  returning 0" 2
 309             return $vmx_hw_available_saved
 310         }
 311
 312         # Set up, compile, and execute a test program containing VMX
 313         # instructions.  Include the current process ID in the file
 314         # names to prevent conflicts with invocations for multiple
 315         # testsuites.
 316         set src vmx[pid].c
 317         set exe vmx[pid].x
 318
 319         set f [open $src "w"]
 320         puts $f "int main() {"
 321         puts $f "#ifdef __MACH__"
 322         puts $f "  asm volatile (\"vor v0,v0,v0\");"
 323         puts $f "#else"
 324         puts $f "  asm volatile (\"vor 0,0,0\");"
 325         puts $f "#endif"
 326         puts $f "  return 0; }"
 327         close $f
 328
 329         verbose "check_vmx_hw_available  compiling testfile $src" 2
 330         set lines [${tool}_target_compile $src $exe executable ""]
 331         file delete $src
 332
 333         if [string match "" $lines] then {
 334             # No error message, compilation succeeded.
 335             set result [${tool}_load "./$exe" "" ""]
 336             set status [lindex $result 0]
 337             remote_file build delete $exe
 338             verbose "check_vmx_hw_available testfile status is <$status>" 2
 339
 340             if { $status == "pass" } then {
 341                 set vmx_hw_available_saved 1
 342             }
 343         } else {
 344             verbose "check_vmx_hw_availalble testfile compilation failed" 2
 345         }
 346     }
 347
 348     return $vmx_hw_available_saved
 349 }