libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos || test $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # In the case that we're building without headers, we won't have <stdio.h>
  62 # available. In these cases, we have to instruct autotools to never include
  63 # <stdio.h> as a part of default headers.
  64 m4_version_prereq([2.70], [], [
  65 if test "x$with_headers" = "xno"; then
  66   ac_includes_default=`echo "$ac_includes_default" | sed '/^#include <stdio.h>$/d'`
  67 fi
  68 ])
  69
  70 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  71 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  72 #  1.x:  minimum required version
  73 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  74 #              of other PACKAGE_* variables will, however, and there's nothing
  75 #              we can do about that; they come from AC_INIT).
  76 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  77 #            file in the top srcdir, etc, etc), so stop complaining.
  78 #  no-dependencies:  turns off auto dependency generation (just for now)
  79 #  no-dist:  we don't want 'dist' and related rules.
  80 #  -Wall:  turns on all automake warnings...
  81 #  -Wno-portability:  ...except this one, since GNU make is now required.
  82 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  83 AH_TEMPLATE(PACKAGE, [Name of package])
  84 AH_TEMPLATE(VERSION, [Version number of package])
  85
  86 # -fno-builtin must be present here so that a non-conflicting form of
  87 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  88
  89 save_CXXFLAGS="$CXXFLAGS"
  90 CXXFLAGS="$CXXFLAGS -fno-builtin"
  91 AC_PROG_CC
  92 AC_PROG_CXX
  93 CXXFLAGS="$save_CXXFLAGS"
  94
  95 AC_SYS_LARGEFILE
  96
  97 # Runs configure.host, and assorted other critical bits.  Sets
  98 # up critical shell variables.
  99 GLIBCXX_CONFIGURE
 100
 101 # Libtool setup.
 102 if test "x${with_newlib}" != "xyes" &&
 103     test "x${with_avrlibc}" != "xyes" &&
 104     test "x$with_headers" != "xno"; then
 105   AC_LIBTOOL_DLOPEN
 106 fi
 107 AM_PROG_LIBTOOL
 108 ACX_LT_HOST_FLAGS
 109 AC_SUBST(enable_shared)
 110 AC_SUBST(enable_static)
 111 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
 112
 113 if test "$enable_vtable_verify" = yes; then
 114   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 115   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 116 fi
 117
 118
 119 # libtool variables for C++ shared and position-independent compiles.
 120 #
 121 # Use glibcxx_lt_pic_flag to designate the automake variable
 122 # used to encapsulate the default libtool approach to creating objects
 123 # with position-independent code. Default: -prefer-pic.
 124 #
 125 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 126 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 127 #
 128 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 129 # creating position-independent objects. This varies with the target
 130 # hardware and operating system, but is often: -DPIC -fPIC.
 131 if test "$enable_shared" = yes; then
 132   glibcxx_lt_pic_flag="-prefer-pic"
 133   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 134   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 135
 136 else
 137   glibcxx_lt_pic_flag=
 138   glibcxx_compiler_pic_flag=
 139   glibcxx_compiler_shared_flag=
 140 fi
 141 AC_SUBST(glibcxx_lt_pic_flag)
 142 AC_SUBST(glibcxx_compiler_pic_flag)
 143 AC_SUBST(glibcxx_compiler_shared_flag)
 144
 145 # Override the libtool's pic_flag and pic_mode.
 146 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 147 # NB: this impacts --with-pic and --without-pic.
 148 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 149 pic_mode='default'
 150
 151 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 152 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 153
 154 # Possibly disable most of the library.
 155 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 156 ## than just ignoring the results.  Faster /and/ more correct, win win.
 157 GLIBCXX_ENABLE_HOSTED
 158
 159 # Enable descriptive messages to standard output on termination.
 160 GLIBCXX_ENABLE_VERBOSE
 161
 162 # Enable compiler support that doesn't require linking.
 163 GLIBCXX_ENABLE_PCH($is_hosted)
 164 GLIBCXX_ENABLE_THREADS
 165 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 166 GLIBCXX_ENABLE_LOCK_POLICY
 167 GLIBCXX_ENABLE_DECIMAL_FLOAT
 168 GLIBCXX_ENABLE_FLOAT128
 169 if test "$enable_float128" = yes; then
 170   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 171 fi
 172
 173 # Checks for compiler support that doesn't require linking.
 174 GLIBCXX_CHECK_COMPILER_FEATURES
 175
 176 # Enable all the variable C++ runtime options that don't require linking.
 177 GLIBCXX_ENABLE_CSTDIO
 178 GLIBCXX_ENABLE_CLOCALE
 179 GLIBCXX_ENABLE_ALLOCATOR
 180 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 181 GLIBCXX_ENABLE_LONG_LONG([yes])
 182 GLIBCXX_ENABLE_WCHAR_T([yes])
 183 GLIBCXX_ENABLE_C99([yes])
 184 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 185 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 186 GLIBCXX_ENABLE_DEBUG([no])
 187 GLIBCXX_ENABLE_PARALLEL([yes])
 188 GLIBCXX_ENABLE_CXX_FLAGS
 189 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 190 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 191 GLIBCXX_ENABLE_PYTHON
 192 GLIBCXX_ENABLE_WERROR([no])
 193 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 194
 195 # Checks for operating systems support that doesn't require linking.
 196 GLIBCXX_CHECK_STDIO_PROTO
 197 GLIBCXX_CHECK_MATH11_PROTO
 198 GLIBCXX_CHECK_UCHAR_H
 199
 200 # For LFS support.
 201 GLIBCXX_CHECK_LFS
 202
 203 # For showmanyc_helper().
 204 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 205 GLIBCXX_CHECK_POLL
 206 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 207
 208 # For xsputn_2().
 209 AC_CHECK_HEADERS(sys/uio.h)
 210 GLIBCXX_CHECK_WRITEV
 211
 212 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 213 # so that the check is done with the C compiler (not C++).
 214 # Checking with C++ can break a canadian cross build if either
 215 # file does not exist in C but does in C++.
 216 AC_CHECK_HEADERS(fenv.h complex.h)
 217
 218 # For C99 support to TR1.
 219 GLIBCXX_CHECK_C99_TR1
 220
 221 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 222 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 223
 224 # For gettimeofday support.
 225 GLIBCXX_CHECK_GETTIMEOFDAY
 226
 227 # For clock_gettime, nanosleep and sched_yield support.
 228 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 229
 230 # Check for tmpnam which is obsolescent in POSIX.1-2008
 231 GLIBCXX_CHECK_TMPNAM
 232
 233 # For pthread_cond_clockwait
 234 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 235
 236 # For pthread_mutex_clocklock
 237 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 238
 239 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 240 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 241
 242 AC_LC_MESSAGES
 243
 244 # For hardware_concurrency
 245 AC_CHECK_HEADERS(sys/sysinfo.h)
 246 GLIBCXX_CHECK_GET_NPROCS
 247 AC_CHECK_HEADERS(unistd.h)
 248 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 249 GLIBCXX_CHECK_SC_NPROC_ONLN
 250 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 251 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 252 GLIBCXX_CHECK_SDT_H
 253
 254 # Check for available headers.
 255 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 256 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 257 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 258 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 259 wchar.h wctype.h linux/types.h])
 260
 261 AC_CHECK_HEADERS([linux/random.h], [], [],
 262 [[#ifdef HAVE_LINUX_TYPES_H
 263 # include <linux/types.h>
 264 #endif
 265 ]])
 266
 267 AC_CHECK_HEADERS([xlocale.h])
 268
 269 # Only do link tests if native. Else, hardcode.
 270 if $GLIBCXX_IS_NATIVE; then
 271
 272   # We can do more elaborate tests that assume a working linker.
 273   CANADIAN=no
 274
 275   GLIBCXX_CHECK_LINKER_FEATURES
 276   GLIBCXX_CHECK_MATH_SUPPORT
 277   GLIBCXX_CHECK_STDLIB_SUPPORT
 278
 279   # For /dev/random and /dev/urandom for std::random_device.
 280   GLIBCXX_CHECK_DEV_RANDOM
 281
 282   # For TLS support.
 283   GCC_CHECK_TLS
 284
 285   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 286   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 287   AC_CHECK_FUNCS(_wfopen)
 288   AC_CHECK_FUNCS(secure_getenv)
 289
 290   # C11 functions for C++17 library
 291   AC_CHECK_FUNCS(timespec_get)
 292
 293   # For Networking TS.
 294   AC_CHECK_FUNCS(sockatmark)
 295
 296   # Non-standard functions used by C++17 std::from_chars
 297   AC_CHECK_FUNCS(uselocale)
 298
 299   # For iconv support.
 300   AM_ICONV
 301
 302 else
 303
 304   # This lets us hard-code the functionality we know we'll have in the cross
 305   # target environment.  "Let" is a sugar-coated word placed on an especially
 306   # dull and tedious hack, actually.
 307   #
 308   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 309   # that involve linking, can't be used:
 310   #    "cannot open sim-crt0.o"
 311   #    "cannot open crt0.o"
 312   # etc.  All this is because there currently exists no unified, consistent
 313   # way for top level CC information to be passed down to target directories:
 314   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 315   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 316   # crosses can be removed.
 317
 318   # If Canadian cross, then don't pick up tools from the build directory.
 319   # Used only in GLIBCXX_EXPORT_INCLUDES.
 320   if test -n "$with_cross_host" &&
 321      test x"$build_alias" != x"$with_cross_host" &&
 322      test x"$build" != x"$target";
 323   then
 324     CANADIAN=yes
 325   else
 326     CANADIAN=no
 327   fi
 328
 329   # Construct crosses by hand, eliminating bits that need ld...
 330   # GLIBCXX_CHECK_MATH_SUPPORT
 331
 332   # First, test for "known" system libraries.  We may be using newlib even
 333   # on a hosted environment.
 334   if test "x${with_newlib}" = "xyes"; then
 335     os_include_dir="os/newlib"
 336     AC_DEFINE(HAVE_HYPOT)
 337
 338     # GLIBCXX_CHECK_STDLIB_SUPPORT
 339     AC_DEFINE(HAVE_STRTOF)
 340
 341     AC_DEFINE(HAVE_ACOSF)
 342     AC_DEFINE(HAVE_ASINF)
 343     AC_DEFINE(HAVE_ATAN2F)
 344     AC_DEFINE(HAVE_ATANF)
 345     AC_DEFINE(HAVE_CEILF)
 346     AC_DEFINE(HAVE_COSF)
 347     AC_DEFINE(HAVE_COSHF)
 348     AC_DEFINE(HAVE_EXPF)
 349     AC_DEFINE(HAVE_FABSF)
 350     AC_DEFINE(HAVE_FLOORF)
 351     AC_DEFINE(HAVE_FMODF)
 352     AC_DEFINE(HAVE_FREXPF)
 353     AC_DEFINE(HAVE_HYPOTF)
 354     AC_DEFINE(HAVE_LDEXPF)
 355     AC_DEFINE(HAVE_LOG10F)
 356     AC_DEFINE(HAVE_LOGF)
 357     AC_DEFINE(HAVE_MODFF)
 358     AC_DEFINE(HAVE_POWF)
 359     AC_DEFINE(HAVE_SINF)
 360     AC_DEFINE(HAVE_SINHF)
 361     AC_DEFINE(HAVE_SQRTF)
 362     AC_DEFINE(HAVE_TANF)
 363     AC_DEFINE(HAVE_TANHF)
 364
 365 dnl # Support for the long version of some math libraries depends on
 366 dnl # architecture and newlib version.  So test for their availability
 367 dnl # rather than hardcoding that information.
 368     GLIBCXX_CHECK_MATH_DECLS([
 369       acosl asinl atan2l atanl ceill coshl cosl expl fabsl floorl fmodl
 370       frexpl hypotl ldexpl log10l logl modfl powl sinhl sinl sqrtl
 371       tanhl tanl])
 372
 373     AC_DEFINE(HAVE_ICONV)
 374     AC_DEFINE(HAVE_MEMALIGN)
 375
 376     case "${target}" in
 377       *-rtems*)
 378         case "${target}" in
 379           bfin* | lm32* | mips* | moxie* | or1k* | v850*)
 380             ;;
 381           *)
 382             AC_DEFINE(HAVE_TLS)
 383             ;;
 384         esac
 385         AC_DEFINE(HAVE_ALIGNED_ALLOC)
 386         AC_DEFINE(HAVE_AT_QUICK_EXIT)
 387         AC_DEFINE(HAVE_LINK)
 388         AC_DEFINE(HAVE_QUICK_EXIT)
 389         AC_DEFINE(HAVE_READLINK)
 390         AC_DEFINE(HAVE_SETENV)
 391         AC_DEFINE(HAVE_SLEEP)
 392         AC_DEFINE(HAVE_SOCKATMARK)
 393         AC_DEFINE(HAVE_STRERROR_L)
 394         AC_DEFINE(HAVE_SYMLINK)
 395         AC_DEFINE(HAVE_TRUNCATE)
 396         AC_DEFINE(HAVE_USLEEP)
 397         ;;
 398     esac
 399   elif test "x$with_headers" != "xno"; then
 400     GLIBCXX_CROSSCONFIG
 401   fi
 402
 403   # At some point, we should differentiate between architectures
 404   # like x86, which have long double versions, and alpha/powerpc/etc.,
 405   # which don't. For the time being, punt.
 406   if test x"long_double_math_on_this_cpu" = x"yes"; then
 407     AC_DEFINE(HAVE_ACOSL)
 408     AC_DEFINE(HAVE_ASINL)
 409     AC_DEFINE(HAVE_ATAN2L)
 410     AC_DEFINE(HAVE_ATANL)
 411     AC_DEFINE(HAVE_CEILL)
 412     AC_DEFINE(HAVE_COSL)
 413     AC_DEFINE(HAVE_COSHL)
 414     AC_DEFINE(HAVE_EXPL)
 415     AC_DEFINE(HAVE_FABSL)
 416     AC_DEFINE(HAVE_FLOORL)
 417     AC_DEFINE(HAVE_FMODL)
 418     AC_DEFINE(HAVE_FREXPL)
 419     AC_DEFINE(HAVE_LDEXPL)
 420     AC_DEFINE(HAVE_LOG10L)
 421     AC_DEFINE(HAVE_LOGL)
 422     AC_DEFINE(HAVE_MODFL)
 423     AC_DEFINE(HAVE_POWL)
 424     AC_DEFINE(HAVE_SINCOSL)
 425     AC_DEFINE(HAVE_SINL)
 426     AC_DEFINE(HAVE_SINHL)
 427     AC_DEFINE(HAVE_SQRTL)
 428     AC_DEFINE(HAVE_TANL)
 429     AC_DEFINE(HAVE_TANHL)
 430   fi
 431 fi
 432
 433 # Check for _Unwind_GetIPInfo.
 434 GCC_CHECK_UNWIND_GETIPINFO
 435
 436 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 437
 438 GLIBCXX_ENABLE_SYMVERS([yes])
 439 AC_SUBST(libtool_VERSION)
 440
 441 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 442
 443 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 444 GLIBCXX_DEFAULT_ABI
 445
 446 ac_ldbl_compat=no
 447 ac_ldbl_alt128_compat=no
 448 ac_ldbl_ieee128_default=no
 449 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 450 LONG_DOUBLE_128_FLAGS=
 451 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 452 case "$target" in
 453   powerpc*-*-linux* | \
 454   sparc*-*-linux* | \
 455   s390*-*-linux* | \
 456   alpha*-*-linux*)
 457   AC_TRY_COMPILE(, [
 458 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 459 #error no need for long double compatibility
 460 #endif
 461   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 462   if test "$ac_ldbl_compat" = yes; then
 463     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 464               [Define if compatibility should be provided for -mlong-double-64.])
 465     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 466     case "$target" in
 467       powerpc*-*-linux*)
 468         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 469         # Check for IEEE128 support in libm:
 470         AC_CHECK_LIB(m, __frexpieee128,
 471                      [ac_ldbl_ieee128_in_libc=yes],
 472                      [ac_ldbl_ieee128_in_libc=no])
 473         if test $ac_ldbl_ieee128_in_libc = yes; then
 474           # Determine which long double format is the compiler's default:
 475           AC_TRY_COMPILE(, [
 476             #ifndef __LONG_DOUBLE_IEEE128__
 477             #error compiler defaults to ibm128
 478             #endif
 479           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 480           # Library objects should use default long double format.
 481           if test "$ac_ldbl_ieee128_default" = yes; then
 482             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 483             # Except for the ones that explicitly use these flags:
 484             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 485           else
 486             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 487             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 488           fi
 489           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 490                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 491           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 492           ac_ldbl_alt128_compat=yes
 493         else
 494           ac_ldbl_alt128_compat=no
 495         fi
 496         ;;
 497     esac
 498   fi
 499 esac
 500 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 501 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 502 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 503 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 504 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 505
 506 # Check if assembler supports disabling hardware capability support.
 507 GCC_CHECK_ASSEMBLER_HWCAP
 508
 509 # Check if assembler supports rdrand opcode.
 510 GLIBCXX_CHECK_X86_RDRAND
 511 # Check if assembler supports rdseed opcode.
 512 GLIBCXX_CHECK_X86_RDSEED
 513
 514 # Check for other random number APIs
 515 GLIBCXX_CHECK_GETENTROPY
 516 GLIBCXX_CHECK_ARC4RANDOM
 517
 518 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 519 GLIBCXX_CONFIGURE_TESTSUITE
 520
 521 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 522 GLIBCXX_CHECK_GTHREADS
 523
 524 # For Filesystem TS.
 525 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 526 GLIBCXX_ENABLE_FILESYSTEM_TS
 527 GLIBCXX_CHECK_FILESYSTEM_DEPS
 528
 529 GLIBCXX_ENABLE_BACKTRACE
 530
 531 # For Networking TS.
 532 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 533 AC_CHECK_DECL(F_GETFL,,,[#include <fcntl.h>])
 534 AC_CHECK_DECL(F_SETFL,,,[#include <fcntl.h>])
 535 if test "$ac_cv_have_decl_F_GETFL$ac_cv_have_decl_F_SETFL" = yesyes ; then
 536   AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
 537 fi
 538
 539 # For Transactional Memory TS
 540 GLIBCXX_CHECK_SIZE_T_MANGLING
 541
 542 # Check which release added std::exception_ptr for the target
 543 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 544
 545 # For libsupc++/eh_alloc.cc defaults.
 546 GLIBCXX_EMERGENCY_EH_ALLOC
 547
 548 # For src/c++20/tzdb.cc defaults.
 549 GLIBCXX_ZONEINFO_DIR
 550
 551 # For src/c++11/shared_ptr.cc alignment.
 552 GLIBCXX_CHECK_ALIGNAS_CACHELINE
 553
 554 # For using init_priority in ios_init.cc
 555 GLIBCXX_CHECK_INIT_PRIORITY
 556
 557 # For __basic_file::native_handle()
 558 GLIBCXX_CHECK_FILEBUF_NATIVE_HANDLES
 559
 560 # Define documentation rules conditionally.
 561
 562 # See if makeinfo has been installed and is modern enough
 563 # that we can use it.
 564 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 565                    [GNU texinfo.* \([0-9][0-9.]*\)],
 566                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 567 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 568
 569 # Check for doxygen
 570 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 571 AC_CHECK_PROG([DOT], dot, yes, no)
 572
 573 # Check for docbook
 574 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 575 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 576 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 577 GLIBCXX_CONFIGURE_DOCBOOK
 578
 579 # Check for xml/html dependencies.
 580 AM_CONDITIONAL(BUILD_XML,
 581                test $ac_cv_prog_DOXYGEN = "yes" &&
 582                test $ac_cv_prog_DOT = "yes" &&
 583                test $ac_cv_prog_XSLTPROC = "yes" &&
 584                test $ac_cv_prog_XMLLINT = "yes" &&
 585                test $glibcxx_stylesheets = "yes")
 586
 587 AM_CONDITIONAL(BUILD_HTML,
 588                test $ac_cv_prog_DOXYGEN = "yes" &&
 589                test $ac_cv_prog_DOT = "yes" &&
 590                test $ac_cv_prog_XSLTPROC = "yes" &&
 591                test $ac_cv_prog_XMLLINT = "yes" &&
 592                test $glibcxx_stylesheets = "yes")
 593
 594 # Check for man dependencies.
 595 AM_CONDITIONAL(BUILD_MAN,
 596                test $ac_cv_prog_DOXYGEN = "yes" &&
 597                test $ac_cv_prog_DOT = "yes")
 598
 599 # Check for pdf dependencies.
 600 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 601 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 602 AM_CONDITIONAL(BUILD_PDF,
 603                test $ac_cv_prog_DOXYGEN = "yes" &&
 604                test $ac_cv_prog_DOT = "yes" &&
 605                test $ac_cv_prog_XSLTPROC = "yes" &&
 606                test $ac_cv_prog_XMLLINT = "yes" &&
 607                test $ac_cv_prog_DBLATEX = "yes" &&
 608                test $ac_cv_prog_PDFLATEX = "yes")
 609
 610 case "$build" in
 611  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 612  * ) glibcxx_include_dir_notparallel=no ;;
 613 esac
 614 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 615                test $glibcxx_include_dir_notparallel = "yes")
 616
 617 # Propagate the target-specific source directories through the build chain.
 618 ATOMICITY_SRCDIR=config/${atomicity_dir}
 619 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 620 ATOMIC_FLAGS=${atomic_flags}
 621 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 622 OS_INC_SRCDIR=config/${os_include_dir}
 623 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 624 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 625 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 626 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 627 AC_SUBST(ATOMICITY_SRCDIR)
 628 AC_SUBST(ATOMIC_WORD_SRCDIR)
 629 AC_SUBST(ATOMIC_FLAGS)
 630 AC_SUBST(CPU_DEFINES_SRCDIR)
 631 AC_SUBST(ABI_TWEAKS_SRCDIR)
 632 AC_SUBST(OS_INC_SRCDIR)
 633 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 634 AC_SUBST(CPU_OPT_EXT_RANDOM)
 635 AC_SUBST(CPU_OPT_BITS_RANDOM)
 636
 637 # Conditionalize the makefile for this target machine.
 638 tmake_file_=
 639 for f in ${tmake_file}
 640 do
 641         if test -f ${srcdir}/config/$f
 642         then
 643                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 644         fi
 645 done
 646 tmake_file="${tmake_file_}"
 647 AC_SUBST(tmake_file)
 648
 649 # Add CET specific flags if Intel CET is enabled.
 650 GCC_CET_FLAGS(CET_FLAGS)
 651 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 652 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 653 AC_SUBST(EXTRA_CFLAGS)
 654 AC_SUBST(EXTRA_CXX_FLAGS)
 655
 656 # Determine cross-compile flags and AM_CONDITIONALs.
 657 #AC_SUBST(GLIBCXX_IS_NATIVE)
 658 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 659 GLIBCXX_EVALUATE_CONDITIONALS
 660
 661 AC_CACHE_SAVE
 662
 663 if test ${multilib} = yes; then
 664   multilib_arg="--enable-multilib"
 665 else
 666   multilib_arg=
 667 fi
 668
 669 # Export all the install information.
 670 GLIBCXX_EXPORT_INSTALL_INFO
 671
 672 # Export all the include and flag information to Makefiles.
 673 GLIBCXX_EXPORT_INCLUDES
 674 GLIBCXX_EXPORT_FLAGS
 675
 676 # Determine what GCC version number to use in filesystem paths.
 677 GCC_BASE_VER
 678
 679 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 680 dnl which can all be called multiple times as needed, plus one (different)
 681 dnl AC_OUTPUT macro.  This one lists the files to be created:
 682 AC_CONFIG_FILES(Makefile)
 683 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 684 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 685 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 686 AC_CONFIG_FILES([src/libbacktrace/backtrace-supported.h])
 687
 688 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 689 # that multilib installs will end up installed in the correct place.
 690 # The testsuite needs it for multilib-aware ABI baseline files.
 691 # To work around this not being passed down from config-ml.in ->
 692 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 693 # append it here.  Only modify Makefiles that have just been created.
 694 #
 695 # Also, get rid of this simulated-VPATH thing that automake does.
 696 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 697   [cat > vpsed$$ << \_EOF
 698 s!`test -f '$<' || echo '$(srcdir)/'`!!
 699 _EOF
 700    sed -f vpsed$$ $ac_file > tmp$$
 701    mv tmp$$ $ac_file
 702    rm vpsed$$
 703    echo 'MULTISUBDIR =' >> $ac_file
 704    ml_norecursion=yes
 705    . ${multi_basedir}/config-ml.in
 706    AS_UNSET([ml_norecursion])
 707 ])
 708
 709 AC_CONFIG_COMMANDS([generate-headers],
 710   [(cd include && ${MAKE-make} pch_build= )])
 711
 712 dnl And this actually makes things happen:
 713 AC_OUTPUT