libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos || test $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # In the case that we're building without headers, we won't have <stdio.h>
  62 # available. In these cases, we have to instruct autotools to never include
  63 # <stdio.h> as a part of default headers.
  64 m4_version_prereq([2.70], [], [
  65 if test "x$with_headers" = "xno"; then
  66   ac_includes_default=`echo "$ac_includes_default" | sed '/^#include <stdio.h>$/d'`
  67 fi
  68 ])
  69
  70 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  71 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  72 #  1.x:  minimum required version
  73 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  74 #              of other PACKAGE_* variables will, however, and there's nothing
  75 #              we can do about that; they come from AC_INIT).
  76 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  77 #            file in the top srcdir, etc, etc), so stop complaining.
  78 #  no-dependencies:  turns off auto dependency generation (just for now)
  79 #  no-dist:  we don't want 'dist' and related rules.
  80 #  -Wall:  turns on all automake warnings...
  81 #  -Wno-portability:  ...except this one, since GNU make is now required.
  82 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  83 AH_TEMPLATE(PACKAGE, [Name of package])
  84 AH_TEMPLATE(VERSION, [Version number of package])
  85
  86 # -fno-builtin must be present here so that a non-conflicting form of
  87 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  88
  89 save_CXXFLAGS="$CXXFLAGS"
  90 CXXFLAGS="$CXXFLAGS -fno-builtin"
  91 AC_PROG_CC
  92 AC_PROG_CXX
  93 CXXFLAGS="$save_CXXFLAGS"
  94
  95 AC_SYS_LARGEFILE
  96
  97 # Runs configure.host, and assorted other critical bits.  Sets
  98 # up critical shell variables.
  99 GLIBCXX_CONFIGURE
 100
 101 # Libtool setup.
 102 if test "x${with_newlib}" != "xyes" &&
 103     test "x${with_avrlibc}" != "xyes" &&
 104     test "x$with_headers" != "xno"; then
 105   AC_LIBTOOL_DLOPEN
 106 fi
 107 AM_PROG_LIBTOOL
 108 ACX_LT_HOST_FLAGS
 109 AC_SUBST(enable_shared)
 110 AC_SUBST(enable_static)
 111 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
 112 os_is_darwin=no
 113 case ${host_os} in
 114   darwin*) os_is_darwin=yes ;;
 115   *) ;;
 116 esac
 117 AM_CONDITIONAL([OS_IS_DARWIN], [test x${os_is_darwin} = xyes])
 118
 119 if test "$enable_vtable_verify" = yes; then
 120   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 121   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 122 fi
 123
 124
 125 # libtool variables for C++ shared and position-independent compiles.
 126 #
 127 # Use glibcxx_lt_pic_flag to designate the automake variable
 128 # used to encapsulate the default libtool approach to creating objects
 129 # with position-independent code. Default: -prefer-pic.
 130 #
 131 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 132 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 133 #
 134 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 135 # creating position-independent objects. This varies with the target
 136 # hardware and operating system, but is often: -DPIC -fPIC.
 137 if test "$enable_shared" = yes; then
 138   glibcxx_lt_pic_flag="-prefer-pic"
 139   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 140   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 141
 142 else
 143   glibcxx_lt_pic_flag=
 144   glibcxx_compiler_pic_flag=
 145   glibcxx_compiler_shared_flag=
 146 fi
 147 AC_SUBST(glibcxx_lt_pic_flag)
 148 AC_SUBST(glibcxx_compiler_pic_flag)
 149 AC_SUBST(glibcxx_compiler_shared_flag)
 150
 151 # Override the libtool's pic_flag and pic_mode.
 152 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 153 # NB: this impacts --with-pic and --without-pic.
 154 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 155 pic_mode='default'
 156
 157 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 158 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 159
 160 # Possibly disable most of the library.
 161 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 162 ## than just ignoring the results.  Faster /and/ more correct, win win.
 163 GLIBCXX_ENABLE_HOSTED
 164
 165 # Enable descriptive messages to standard output on termination.
 166 GLIBCXX_ENABLE_VERBOSE
 167
 168 # Enable compiler support that doesn't require linking.
 169 GLIBCXX_ENABLE_PCH($is_hosted)
 170 GLIBCXX_ENABLE_THREADS
 171 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 172 GLIBCXX_ENABLE_LOCK_POLICY
 173 GLIBCXX_ENABLE_DECIMAL_FLOAT
 174 GLIBCXX_ENABLE_FLOAT128
 175 if test "$enable_float128" = yes; then
 176   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 177 fi
 178
 179 # Checks for compiler support that doesn't require linking.
 180 GLIBCXX_CHECK_COMPILER_FEATURES
 181
 182 # Enable all the variable C++ runtime options that don't require linking.
 183 GLIBCXX_ENABLE_CSTDIO
 184 GLIBCXX_ENABLE_CLOCALE
 185 GLIBCXX_ENABLE_ALLOCATOR
 186 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 187 GLIBCXX_ENABLE_LONG_LONG([yes])
 188 GLIBCXX_ENABLE_WCHAR_T([yes])
 189 GLIBCXX_ENABLE_C99([yes])
 190 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 191 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 192 GLIBCXX_ENABLE_DEBUG([no])
 193 GLIBCXX_ENABLE_PARALLEL([yes])
 194 GLIBCXX_ENABLE_CXX_FLAGS
 195 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 196 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 197 GLIBCXX_ENABLE_PYTHON
 198 GLIBCXX_ENABLE_WERROR([no])
 199 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 200
 201 # Checks for operating systems support that doesn't require linking.
 202 GLIBCXX_CHECK_STDIO_PROTO
 203 GLIBCXX_CHECK_MATH11_PROTO
 204 GLIBCXX_CHECK_UCHAR_H
 205
 206 # For LFS support.
 207 GLIBCXX_CHECK_LFS
 208
 209 # For showmanyc_helper().
 210 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 211 GLIBCXX_CHECK_POLL
 212 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 213
 214 # For xsputn_2().
 215 AC_CHECK_HEADERS(sys/uio.h)
 216 GLIBCXX_CHECK_WRITEV
 217
 218 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 219 # so that the check is done with the C compiler (not C++).
 220 # Checking with C++ can break a canadian cross build if either
 221 # file does not exist in C but does in C++.
 222 AC_CHECK_HEADERS(fenv.h complex.h)
 223
 224 # For C99 support to TR1.
 225 GLIBCXX_CHECK_C99_TR1
 226
 227 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 228 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 229
 230 # For gettimeofday support.
 231 GLIBCXX_CHECK_GETTIMEOFDAY
 232
 233 # For clock_gettime, nanosleep and sched_yield support.
 234 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 235
 236 # Check for tmpnam which is obsolescent in POSIX.1-2008
 237 GLIBCXX_CHECK_TMPNAM
 238
 239 # For pthread_cond_clockwait
 240 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 241
 242 # For pthread_mutex_clocklock
 243 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 244
 245 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 246 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 247
 248 AC_LC_MESSAGES
 249
 250 # For hardware_concurrency
 251 AC_CHECK_HEADERS(sys/sysinfo.h)
 252 GLIBCXX_CHECK_GET_NPROCS
 253 AC_CHECK_HEADERS(unistd.h)
 254 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 255 GLIBCXX_CHECK_SC_NPROC_ONLN
 256 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 257 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 258 GLIBCXX_CHECK_SDT_H
 259
 260 # Check for available headers.
 261 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 262 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 263 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 264 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 265 wchar.h wctype.h linux/types.h])
 266
 267 AC_CHECK_HEADERS([linux/random.h], [], [],
 268 [[#ifdef HAVE_LINUX_TYPES_H
 269 # include <linux/types.h>
 270 #endif
 271 ]])
 272
 273 AC_CHECK_HEADERS([xlocale.h])
 274
 275 # Only do link tests if native. Else, hardcode.
 276 if $GLIBCXX_IS_NATIVE; then
 277
 278   # We can do more elaborate tests that assume a working linker.
 279   CANADIAN=no
 280
 281   GLIBCXX_CHECK_LINKER_FEATURES
 282   GLIBCXX_CHECK_MATH_SUPPORT
 283   GLIBCXX_CHECK_STDLIB_SUPPORT
 284
 285   # For /dev/random and /dev/urandom for std::random_device.
 286   GLIBCXX_CHECK_DEV_RANDOM
 287
 288   # For TLS support.
 289   GCC_CHECK_TLS
 290
 291   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 292   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 293   AC_CHECK_FUNCS(_wfopen)
 294   AC_CHECK_FUNCS(secure_getenv)
 295
 296   # C11 functions for C++17 library
 297   AC_CHECK_FUNCS(timespec_get)
 298
 299   # For Networking TS.
 300   AC_CHECK_FUNCS(sockatmark)
 301
 302   # Non-standard functions used by C++17 std::from_chars
 303   AC_CHECK_FUNCS(uselocale)
 304
 305   # For iconv support.
 306   AM_ICONV
 307
 308 else
 309
 310   # This lets us hard-code the functionality we know we'll have in the cross
 311   # target environment.  "Let" is a sugar-coated word placed on an especially
 312   # dull and tedious hack, actually.
 313   #
 314   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 315   # that involve linking, can't be used:
 316   #    "cannot open sim-crt0.o"
 317   #    "cannot open crt0.o"
 318   # etc.  All this is because there currently exists no unified, consistent
 319   # way for top level CC information to be passed down to target directories:
 320   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 321   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 322   # crosses can be removed.
 323
 324   # If Canadian cross, then don't pick up tools from the build directory.
 325   # Used only in GLIBCXX_EXPORT_INCLUDES.
 326   if test -n "$with_cross_host" &&
 327      test x"$build_alias" != x"$with_cross_host" &&
 328      test x"$build" != x"$target";
 329   then
 330     CANADIAN=yes
 331   else
 332     CANADIAN=no
 333   fi
 334
 335   # Construct crosses by hand, eliminating bits that need ld...
 336   # GLIBCXX_CHECK_MATH_SUPPORT
 337
 338   # First, test for "known" system libraries.  We may be using newlib even
 339   # on a hosted environment.
 340   if test "x${with_newlib}" = "xyes"; then
 341     os_include_dir="os/newlib"
 342     AC_DEFINE(HAVE_HYPOT)
 343
 344     # GLIBCXX_CHECK_STDLIB_SUPPORT
 345     AC_DEFINE(HAVE_STRTOF)
 346
 347     AC_DEFINE(HAVE_ACOSF)
 348     AC_DEFINE(HAVE_ASINF)
 349     AC_DEFINE(HAVE_ATAN2F)
 350     AC_DEFINE(HAVE_ATANF)
 351     AC_DEFINE(HAVE_CEILF)
 352     AC_DEFINE(HAVE_COSF)
 353     AC_DEFINE(HAVE_COSHF)
 354     AC_DEFINE(HAVE_EXPF)
 355     AC_DEFINE(HAVE_FABSF)
 356     AC_DEFINE(HAVE_FLOORF)
 357     AC_DEFINE(HAVE_FMODF)
 358     AC_DEFINE(HAVE_FREXPF)
 359     AC_DEFINE(HAVE_HYPOTF)
 360     AC_DEFINE(HAVE_LDEXPF)
 361     AC_DEFINE(HAVE_LOG10F)
 362     AC_DEFINE(HAVE_LOGF)
 363     AC_DEFINE(HAVE_MODFF)
 364     AC_DEFINE(HAVE_POWF)
 365     AC_DEFINE(HAVE_SINF)
 366     AC_DEFINE(HAVE_SINHF)
 367     AC_DEFINE(HAVE_SQRTF)
 368     AC_DEFINE(HAVE_TANF)
 369     AC_DEFINE(HAVE_TANHF)
 370
 371 dnl # Support for the long version of some math libraries depends on
 372 dnl # architecture and newlib version.  So test for their availability
 373 dnl # rather than hardcoding that information.
 374     GLIBCXX_CHECK_MATH_DECLS([
 375       acosl asinl atan2l atanl ceill coshl cosl expl fabsl floorl fmodl
 376       frexpl hypotl ldexpl log10l logl modfl powl sinhl sinl sqrtl
 377       tanhl tanl])
 378
 379     AC_DEFINE(HAVE_ICONV)
 380     AC_DEFINE(HAVE_MEMALIGN)
 381
 382     case "${target}" in
 383       *-rtems*)
 384         case "${target}" in
 385           bfin* | lm32* | mips* | moxie* | or1k* | v850*)
 386             ;;
 387           *)
 388             AC_DEFINE(HAVE_TLS)
 389             ;;
 390         esac
 391         AC_DEFINE(HAVE_ALIGNED_ALLOC)
 392         AC_DEFINE(HAVE_AT_QUICK_EXIT)
 393         AC_DEFINE(HAVE_LINK)
 394         AC_DEFINE(HAVE_QUICK_EXIT)
 395         AC_DEFINE(HAVE_READLINK)
 396         AC_DEFINE(HAVE_SETENV)
 397         AC_DEFINE(HAVE_SLEEP)
 398         AC_DEFINE(HAVE_SOCKATMARK)
 399         AC_DEFINE(HAVE_STRERROR_L)
 400         AC_DEFINE(HAVE_SYMLINK)
 401         AC_DEFINE(HAVE_TRUNCATE)
 402         AC_DEFINE(HAVE_USLEEP)
 403         ;;
 404     esac
 405   elif test "x$with_headers" != "xno"; then
 406     GLIBCXX_CROSSCONFIG
 407   fi
 408
 409   # At some point, we should differentiate between architectures
 410   # like x86, which have long double versions, and alpha/powerpc/etc.,
 411   # which don't. For the time being, punt.
 412   if test x"long_double_math_on_this_cpu" = x"yes"; then
 413     AC_DEFINE(HAVE_ACOSL)
 414     AC_DEFINE(HAVE_ASINL)
 415     AC_DEFINE(HAVE_ATAN2L)
 416     AC_DEFINE(HAVE_ATANL)
 417     AC_DEFINE(HAVE_CEILL)
 418     AC_DEFINE(HAVE_COSL)
 419     AC_DEFINE(HAVE_COSHL)
 420     AC_DEFINE(HAVE_EXPL)
 421     AC_DEFINE(HAVE_FABSL)
 422     AC_DEFINE(HAVE_FLOORL)
 423     AC_DEFINE(HAVE_FMODL)
 424     AC_DEFINE(HAVE_FREXPL)
 425     AC_DEFINE(HAVE_LDEXPL)
 426     AC_DEFINE(HAVE_LOG10L)
 427     AC_DEFINE(HAVE_LOGL)
 428     AC_DEFINE(HAVE_MODFL)
 429     AC_DEFINE(HAVE_POWL)
 430     AC_DEFINE(HAVE_SINCOSL)
 431     AC_DEFINE(HAVE_SINL)
 432     AC_DEFINE(HAVE_SINHL)
 433     AC_DEFINE(HAVE_SQRTL)
 434     AC_DEFINE(HAVE_TANL)
 435     AC_DEFINE(HAVE_TANHL)
 436   fi
 437 fi
 438
 439 # Check for _Unwind_GetIPInfo.
 440 GCC_CHECK_UNWIND_GETIPINFO
 441
 442 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 443
 444 GLIBCXX_ENABLE_SYMVERS([yes])
 445 AC_SUBST(libtool_VERSION)
 446
 447 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 448
 449 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 450 GLIBCXX_DEFAULT_ABI
 451
 452 ac_ldbl_compat=no
 453 ac_ldbl_alt128_compat=no
 454 ac_ldbl_ieee128_default=no
 455 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 456 LONG_DOUBLE_128_FLAGS=
 457 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 458 case "$target" in
 459   powerpc*-*-linux* | \
 460   sparc*-*-linux* | \
 461   s390*-*-linux* | \
 462   alpha*-*-linux*)
 463   AC_TRY_COMPILE(, [
 464 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 465 #error no need for long double compatibility
 466 #endif
 467   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 468   if test "$ac_ldbl_compat" = yes; then
 469     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 470               [Define if compatibility should be provided for -mlong-double-64.])
 471     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 472     case "$target" in
 473       powerpc*-*-linux*)
 474         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 475         # Check for IEEE128 support in libm:
 476         AC_CHECK_LIB(m, __frexpieee128,
 477                      [ac_ldbl_ieee128_in_libc=yes],
 478                      [ac_ldbl_ieee128_in_libc=no])
 479         if test $ac_ldbl_ieee128_in_libc = yes; then
 480           # Determine which long double format is the compiler's default:
 481           AC_TRY_COMPILE(, [
 482             #ifndef __LONG_DOUBLE_IEEE128__
 483             #error compiler defaults to ibm128
 484             #endif
 485           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 486           # Library objects should use default long double format.
 487           if test "$ac_ldbl_ieee128_default" = yes; then
 488             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 489             # Except for the ones that explicitly use these flags:
 490             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 491           else
 492             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 493             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 494           fi
 495           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 496                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 497           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 498           ac_ldbl_alt128_compat=yes
 499         else
 500           ac_ldbl_alt128_compat=no
 501         fi
 502         ;;
 503     esac
 504   fi
 505 esac
 506 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 507 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 508 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 509 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 510 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 511
 512 # Check if assembler supports disabling hardware capability support.
 513 GCC_CHECK_ASSEMBLER_HWCAP
 514
 515 # Check if assembler supports rdrand opcode.
 516 GLIBCXX_CHECK_X86_RDRAND
 517 # Check if assembler supports rdseed opcode.
 518 GLIBCXX_CHECK_X86_RDSEED
 519
 520 # Check for other random number APIs
 521 GLIBCXX_CHECK_GETENTROPY
 522 GLIBCXX_CHECK_ARC4RANDOM
 523
 524 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 525 GLIBCXX_CONFIGURE_TESTSUITE
 526
 527 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 528 GLIBCXX_CHECK_GTHREADS
 529
 530 # For Filesystem TS.
 531 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 532 GLIBCXX_ENABLE_FILESYSTEM_TS
 533 GLIBCXX_CHECK_FILESYSTEM_DEPS
 534
 535 GLIBCXX_ENABLE_BACKTRACE
 536
 537 # For Networking TS.
 538 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 539 AC_CHECK_DECL(F_GETFL,,,[#include <fcntl.h>])
 540 AC_CHECK_DECL(F_SETFL,,,[#include <fcntl.h>])
 541 if test "$ac_cv_have_decl_F_GETFL$ac_cv_have_decl_F_SETFL" = yesyes ; then
 542   AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
 543 fi
 544
 545 # For Transactional Memory TS
 546 GLIBCXX_CHECK_SIZE_T_MANGLING
 547
 548 # Check which release added std::exception_ptr for the target
 549 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 550
 551 # For libsupc++/eh_alloc.cc defaults.
 552 GLIBCXX_EMERGENCY_EH_ALLOC
 553
 554 # For src/c++20/tzdb.cc defaults.
 555 GLIBCXX_ZONEINFO_DIR
 556
 557 # For src/c++11/shared_ptr.cc alignment.
 558 GLIBCXX_CHECK_ALIGNAS_CACHELINE
 559
 560 # For using init_priority in ios_init.cc
 561 GLIBCXX_CHECK_INIT_PRIORITY
 562
 563 # For __basic_file::native_handle()
 564 GLIBCXX_CHECK_FILEBUF_NATIVE_HANDLES
 565
 566 # For std::text_encoding
 567 GLIBCXX_CHECK_TEXT_ENCODING
 568
 569 # Define documentation rules conditionally.
 570
 571 # See if makeinfo has been installed and is modern enough
 572 # that we can use it.
 573 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 574                    [GNU texinfo.* \([0-9][0-9.]*\)],
 575                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 576 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 577
 578 # Check for doxygen
 579 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 580 AC_CHECK_PROG([DOT], dot, yes, no)
 581
 582 # Check for docbook
 583 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 584 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 585 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 586 GLIBCXX_CONFIGURE_DOCBOOK
 587
 588 # Check for xml/html dependencies.
 589 AM_CONDITIONAL(BUILD_XML,
 590                test $ac_cv_prog_DOXYGEN = "yes" &&
 591                test $ac_cv_prog_DOT = "yes" &&
 592                test $ac_cv_prog_XSLTPROC = "yes" &&
 593                test $ac_cv_prog_XMLLINT = "yes" &&
 594                test $glibcxx_stylesheets = "yes")
 595
 596 AM_CONDITIONAL(BUILD_HTML,
 597                test $ac_cv_prog_DOXYGEN = "yes" &&
 598                test $ac_cv_prog_DOT = "yes" &&
 599                test $ac_cv_prog_XSLTPROC = "yes" &&
 600                test $ac_cv_prog_XMLLINT = "yes" &&
 601                test $glibcxx_stylesheets = "yes")
 602
 603 # Check for man dependencies.
 604 AM_CONDITIONAL(BUILD_MAN,
 605                test $ac_cv_prog_DOXYGEN = "yes" &&
 606                test $ac_cv_prog_DOT = "yes")
 607
 608 # Check for pdf dependencies.
 609 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 610 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 611 AM_CONDITIONAL(BUILD_PDF,
 612                test $ac_cv_prog_DOXYGEN = "yes" &&
 613                test $ac_cv_prog_DOT = "yes" &&
 614                test $ac_cv_prog_XSLTPROC = "yes" &&
 615                test $ac_cv_prog_XMLLINT = "yes" &&
 616                test $ac_cv_prog_DBLATEX = "yes" &&
 617                test $ac_cv_prog_PDFLATEX = "yes")
 618
 619 case "$build" in
 620  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 621  * ) glibcxx_include_dir_notparallel=no ;;
 622 esac
 623 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 624                test $glibcxx_include_dir_notparallel = "yes")
 625
 626 # Propagate the target-specific source directories through the build chain.
 627 ATOMICITY_SRCDIR=config/${atomicity_dir}
 628 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 629 ATOMIC_FLAGS=${atomic_flags}
 630 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 631 OS_INC_SRCDIR=config/${os_include_dir}
 632 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 633 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 634 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 635 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 636 AC_SUBST(ATOMICITY_SRCDIR)
 637 AC_SUBST(ATOMIC_WORD_SRCDIR)
 638 AC_SUBST(ATOMIC_FLAGS)
 639 AC_SUBST(CPU_DEFINES_SRCDIR)
 640 AC_SUBST(ABI_TWEAKS_SRCDIR)
 641 AC_SUBST(OS_INC_SRCDIR)
 642 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 643 AC_SUBST(CPU_OPT_EXT_RANDOM)
 644 AC_SUBST(CPU_OPT_BITS_RANDOM)
 645
 646 # Conditionalize the makefile for this target machine.
 647 tmake_file_=
 648 for f in ${tmake_file}
 649 do
 650         if test -f ${srcdir}/config/$f
 651         then
 652                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 653         fi
 654 done
 655 tmake_file="${tmake_file_}"
 656 AC_SUBST(tmake_file)
 657
 658 # Add CET specific flags if Intel CET is enabled.
 659 GCC_CET_FLAGS(CET_FLAGS)
 660 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 661 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 662 AC_SUBST(EXTRA_CFLAGS)
 663 AC_SUBST(EXTRA_CXX_FLAGS)
 664
 665 # Determine cross-compile flags and AM_CONDITIONALs.
 666 #AC_SUBST(GLIBCXX_IS_NATIVE)
 667 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 668 GLIBCXX_EVALUATE_CONDITIONALS
 669
 670 AC_CACHE_SAVE
 671
 672 if test ${multilib} = yes; then
 673   multilib_arg="--enable-multilib"
 674 else
 675   multilib_arg=
 676 fi
 677
 678 # Export all the install information.
 679 GLIBCXX_EXPORT_INSTALL_INFO
 680
 681 # Export all the include and flag information to Makefiles.
 682 GLIBCXX_EXPORT_INCLUDES
 683 GLIBCXX_EXPORT_FLAGS
 684
 685 # Determine what GCC version number to use in filesystem paths.
 686 GCC_BASE_VER
 687
 688 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 689 dnl which can all be called multiple times as needed, plus one (different)
 690 dnl AC_OUTPUT macro.  This one lists the files to be created:
 691 AC_CONFIG_FILES(Makefile)
 692 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 693 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 694 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 695 AC_CONFIG_FILES([src/libbacktrace/backtrace-supported.h])
 696
 697 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 698 # that multilib installs will end up installed in the correct place.
 699 # The testsuite needs it for multilib-aware ABI baseline files.
 700 # To work around this not being passed down from config-ml.in ->
 701 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 702 # append it here.  Only modify Makefiles that have just been created.
 703 #
 704 # Also, get rid of this simulated-VPATH thing that automake does.
 705 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 706   [cat > vpsed$$ << \_EOF
 707 s!`test -f '$<' || echo '$(srcdir)/'`!!
 708 _EOF
 709    sed -f vpsed$$ $ac_file > tmp$$
 710    mv tmp$$ $ac_file
 711    rm vpsed$$
 712    echo 'MULTISUBDIR =' >> $ac_file
 713    ml_norecursion=yes
 714    . ${multi_basedir}/config-ml.in
 715    AS_UNSET([ml_norecursion])
 716 ])
 717
 718 AC_CONFIG_COMMANDS([generate-headers],
 719   [(cd include && ${MAKE-make} pch_build= )])
 720
 721 dnl And this actually makes things happen:
 722 AC_OUTPUT