libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, yes,
  20   [Use the Linux futex system call],
  21   permit yes|no)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # -------
  25 # -------
  26
  27 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  28 #
  29 # You will slowly go insane if you do not grok the following fact:  when
  30 # building this library, the top-level /target/ becomes the library's /host/.
  31 #
  32 # configure then causes --target to default to --host, exactly like any
  33 # other package using autoconf.  Therefore, 'target' and 'host' will
  34 # always be the same.  This makes sense both for native and cross compilers
  35 # just think about it for a little while.  :-)
  36 #
  37 # Also, if this library is being configured as part of a cross compiler, the
  38 # top-level configure script will pass the "real" host as $with_cross_host.
  39 #
  40 # Do not delete or change the following two lines.  For why, see
  41 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  42 AC_CANONICAL_SYSTEM
  43 target_alias=${target_alias-$host_alias}
  44
  45 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  46 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  47 #  1.9.0:  minimum required version
  48 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  49 #              of other PACKAGE_* variables will, however, and there's nothing
  50 #              we can do about that; they come from AC_INIT).
  51 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  52 #            file in the top srcdir, etc, etc), so stop complaining.
  53 #  no-dependencies:  turns off auto dependency generation (just for now)
  54 #  -Wall:  turns on all automake warnings...
  55 #  -Wno-portability:  ...except this one, since GNU make is required.
  56 #  -Wno-override: ... and this one, since we do want this in testsuite.
  57 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  58 AM_ENABLE_MULTILIB(, ..)
  59
  60 # Calculate toolexeclibdir
  61 # Also toolexecdir, though it's only used in toolexeclibdir
  62 case ${enable_version_specific_runtime_libs} in
  63   yes)
  64     # Need the gcc compiler version to know where to install libraries
  65     # and header files if --enable-version-specific-runtime-libs option
  66     # is selected.
  67     toolexecdir='$(libdir)/gcc/$(target_alias)'
  68     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  69     ;;
  70   no)
  71     if test -n "$with_cross_host" &&
  72        test x"$with_cross_host" != x"no"; then
  73       # Install a library built with a cross compiler in tooldir, not libdir.
  74       toolexecdir='$(exec_prefix)/$(target_alias)'
  75       toolexeclibdir='$(toolexecdir)/lib'
  76     else
  77       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  78       toolexeclibdir='$(libdir)'
  79     fi
  80     multi_os_directory=`$CC -print-multi-os-directory`
  81     case $multi_os_directory in
  82       .) ;; # Avoid trailing /.
  83       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  84     esac
  85     ;;
  86 esac
  87 AC_SUBST(toolexecdir)
  88 AC_SUBST(toolexeclibdir)
  89
  90 # Check the compiler.
  91 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  92 # We must force CC to /not/ be precious variables; otherwise
  93 # the wrong, non-multilib-adjusted value will be used in multilibs.
  94 # As a side effect, we have to subst CFLAGS ourselves.
  95
  96 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  97 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  98 AC_PROG_CC
  99 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 100
 101 AC_SUBST(CFLAGS)
 102
 103 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 104 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 105 # in both places for now and restore CFLAGS at the end of config.
 106 save_CFLAGS="$CFLAGS"
 107
 108 # Add -Wall -Werror if we are using GCC.
 109 if test "x$GCC" = "xyes"; then
 110   XCFLAGS="$XCFLAGS -Wall -Werror"
 111 fi
 112
 113 # Find other programs we need.
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 116 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 117 AC_PROG_MAKE_SET
 118 AC_PROG_INSTALL
 119
 120 # Configure libtool
 121 AM_PROG_LIBTOOL
 122 AC_SUBST(enable_shared)
 123 AC_SUBST(enable_static)
 124
 125 AM_MAINTAINER_MODE
 126
 127 # We need gfortran to compile parts of the library
 128 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 129 #AC_PROG_FC(gfortran)
 130 FC="$GFORTRAN"
 131 AC_PROG_FC(gfortran)
 132 FCFLAGS="$FCFLAGS -Wall"
 133
 134 # For libtool versioning info, format is CURRENT:REVISION:AGE
 135 libtool_VERSION=1:0:0
 136 AC_SUBST(libtool_VERSION)
 137
 138 # Check header files.
 139 AC_STDC_HEADERS
 140 AC_HEADER_TIME
 141 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 142 AC_CHECK_HEADER([pthread.h],[],
 143   [AC_MSG_ERROR([Pthreads are required to build libgomp])])
 144
 145 GCC_HEADER_STDINT(gstdint.h)
 146
 147 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 148 XPCFLAGS=""
 149 CFLAGS="$CFLAGS -pthread"
 150 AC_LINK_IFELSE(
 151  [AC_LANG_PROGRAM(
 152   [#include <pthread.h>
 153    void *g(void *d) { return NULL; }],
 154   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 155  [XPCFLAGS=" -Wc,-pthread"],
 156  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 157   AC_LINK_IFELSE(
 158    [AC_LANG_PROGRAM(
 159     [#include <pthread.h>
 160      void *g(void *d) { return NULL; }],
 161     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 162    [],
 163    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 164
 165 # Check for functions needed.
 166 AC_CHECK_FUNCS(getloadavg clock_gettime)
 167
 168 # At least for glibc, clock_gettime is in librt.  But don't pull that
 169 # in if it still doesn't give us the function we want.
 170 if test $ac_cv_func_clock_gettime = no; then
 171   AC_CHECK_LIB(rt, clock_gettime,
 172     [LIBS="-lrt $LIBS"
 173      AC_DEFINE(HAVE_CLOCK_GETTIME,
 174                [Define to 1 if you have the `clock_gettime' function.])])
 175 fi
 176
 177 # See if we support thread-local storage.
 178 LIBGOMP_CHECK_TLS
 179
 180 # See what sort of export controls are availible.
 181 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 182 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 183 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 184 LIBGOMP_ENABLE_SYMVERS
 185
 186 # Get target configury.
 187 . ${srcdir}/configure.tgt
 188 CFLAGS="$save_CFLAGS $XCFLAGS"
 189
 190 # Check for __sync_val_compare_and_swap, but only after the target has
 191 # had a chance to set XCFLAGS.
 192 LIBGOMP_CHECK_SYNC_BUILTINS
 193
 194 XCFLAGS="$XCFLAGS$XPCFLAGS"
 195
 196 AC_SUBST(config_path)
 197 AC_SUBST(XCFLAGS)
 198 AC_SUBST(XLDFLAGS)
 199
 200 # Cleanup and exit.
 201 CFLAGS="$save_CFLAGS"
 202 AC_CACHE_SAVE
 203
 204 if test ${multilib} = yes; then
 205   multilib_arg="--enable-multilib"
 206 else
 207   multilib_arg=
 208 fi
 209
 210 # Set up the set of libraries that we need to link against for libgomp.
 211 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 212 # which will force linkage against -lpthread (or equivalent for the system).
 213 # That's not 100% ideal, but about the best we can do easily.
 214 if test $enable_shared = yes; then
 215   link_gomp="-lgomp %{static: $LIBS}"
 216 else
 217   link_gomp="-lgomp $LIBS"
 218 fi
 219 AC_SUBST(link_gomp)
 220
 221 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 222
 223 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 224 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 225 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 226 # need to copy this macro to our acinclude.m4.
 227 save_CFLAGS="$CFLAGS"
 228 for i in $config_path; do
 229   if test -f $srcdir/config/$i/omp-lock.h; then
 230     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 231     break
 232   fi
 233 done
 234
 235 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 236   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 237 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 238 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 239 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 240
 241 # If the lock fits in an integer, then arrange for Fortran to use that
 242 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 243 # Except that we don't have a way at present to multi-lib the installed
 244 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 245 # actual target.
 246 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 247 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 248 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 249   OMP_LOCK_KIND=8
 250 fi
 251 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 252   OMP_NEST_LOCK_KIND=8
 253 fi
 254
 255 AC_SUBST(OMP_LOCK_SIZE)
 256 AC_SUBST(OMP_LOCK_ALIGN)
 257 AC_SUBST(OMP_NEST_LOCK_SIZE)
 258 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 259 AC_SUBST(OMP_LOCK_KIND)
 260 AC_SUBST(OMP_NEST_LOCK_KIND)
 261 CFLAGS="$save_CFLAGS"
 262
 263 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 264 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 265 AC_OUTPUT