libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 GCC_WITH_TOOLEXECLIBDIR
  68
  69 # Calculate toolexeclibdir
  70 # Also toolexecdir, though it's only used in toolexeclibdir
  71 case ${enable_version_specific_runtime_libs} in
  72   yes)
  73     # Need the gcc compiler version to know where to install libraries
  74     # and header files if --enable-version-specific-runtime-libs option
  75     # is selected.
  76     toolexecdir='$(libdir)/gcc/$(target_alias)'
  77     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  78     ;;
  79   no)
  80     if test -n "$with_cross_host" &&
  81        test x"$with_cross_host" != x"no"; then
  82       # Install a library built with a cross compiler in tooldir, not libdir.
  83       toolexecdir='$(exec_prefix)/$(target_alias)'
  84       case ${with_toolexeclibdir} in
  85         no)
  86           toolexeclibdir='$(toolexecdir)/lib'
  87           ;;
  88         *)
  89           toolexeclibdir=${with_toolexeclibdir}
  90           ;;
  91       esac
  92     else
  93       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  94       toolexeclibdir='$(libdir)'
  95     fi
  96     multi_os_directory=`$CC -print-multi-os-directory`
  97     case $multi_os_directory in
  98       .) ;; # Avoid trailing /.
  99       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 100     esac
 101     ;;
 102 esac
 103 AC_SUBST(toolexecdir)
 104 AC_SUBST(toolexeclibdir)
 105
 106 # Check the compiler.
 107 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 108 # We must force CC to /not/ be precious variables; otherwise
 109 # the wrong, non-multilib-adjusted value will be used in multilibs.
 110 # As a side effect, we have to subst CFLAGS ourselves.
 111
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 AC_PROG_CC
 115 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 116
 117 AC_SUBST(CFLAGS)
 118
 119 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 120 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 121 # in both places for now and restore CFLAGS at the end of config.
 122 save_CFLAGS="$CFLAGS"
 123
 124 AC_ARG_ENABLE([werror],
 125   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 126 # Add -Wall -Werror if we are using GCC.
 127 AS_IF([test "x$GCC" = "xyes"],
 128   [XCFLAGS="$XCFLAGS -Wall"])
 129 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 130   [XCFLAGS="$XCFLAGS -Werror"])
 131
 132 # Find other programs we need.
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 135 AC_PROG_MAKE_SET
 136 AC_PROG_INSTALL
 137
 138 # See if makeinfo has been installed and is modern enough
 139 # that we can use it.
 140 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 141                    [GNU texinfo.* \([0-9][0-9.]*\)],
 142                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 143 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 144
 145
 146 # Configure libtool
 147 AM_PROG_LIBTOOL
 148 ACX_LT_HOST_FLAGS
 149 AC_SUBST(enable_shared)
 150 AC_SUBST(enable_static)
 151 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
 152
 153 AM_MAINTAINER_MODE
 154
 155 # Create a spec file, so that compile/link tests don't fail
 156 test -f libgfortran.spec || touch libgfortran.spec
 157 FCFLAGS="$FCFLAGS -L."
 158
 159 # We need gfortran to compile parts of the library
 160 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 161 #AC_PROG_FC(gfortran)
 162 case `echo $GFORTRAN` in
 163   -* | no* )
 164     FC=no ;;
 165   *)
 166     set dummy $GFORTRAN; ac_word=$2
 167     if test -x "$ac_word"; then
 168       FC="$GFORTRAN"
 169     else
 170       FC=no
 171     fi ;;
 172 esac
 173 AC_PROG_FC(gfortran)
 174 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 175
 176 # For libtool versioning info, format is CURRENT:REVISION:AGE
 177 libtool_VERSION=1:0:0
 178 AC_SUBST(libtool_VERSION)
 179
 180 # Check header files.
 181 AC_STDC_HEADERS
 182 AC_HEADER_TIME
 183 ACX_HEADER_STRING
 184 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 185
 186 XPCFLAGS=""
 187 case "$host" in
 188   *-*-rtems*)
 189     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 190     ;;
 191   nvptx*-*-* | amdgcn*-*-*)
 192     # NVPTX does not support Pthreads, has its own code replacement.
 193     libgomp_use_pthreads=no
 194     # NVPTX is an accelerator-only target
 195     libgomp_offloaded_only=yes
 196     ;;
 197   *)
 198     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 199     # In case the pthread.h system header is not found, this test will fail.
 200     CFLAGS="$CFLAGS -pthread"
 201     AC_LINK_IFELSE(
 202      [AC_LANG_PROGRAM(
 203       [#include <pthread.h>
 204        void *g(void *d) { return NULL; }],
 205       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 206      [XPCFLAGS=" -Wc,-pthread"],
 207      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 208       AC_LINK_IFELSE(
 209        [AC_LANG_PROGRAM(
 210         [#include <pthread.h>
 211          void *g(void *d) { return NULL; }],
 212         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 213        [],
 214        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 215 esac
 216
 217 if test x$libgomp_use_pthreads != xno; then
 218   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 219             [Define to 1 if libgomp should use POSIX threads.])
 220 fi
 221
 222 if test x$libgomp_offloaded_only = xyes; then
 223   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 224             [Define to 1 if building libgomp for an accelerator-only target.])
 225 fi
 226
 227 if test "x$enable_offload_defaulted" = xyes; then
 228   AC_DEFINE(OFFLOAD_DEFAULTED, 1,
 229     [Define to 1 to if -foffload is defaulted])
 230 fi
 231
 232 AC_CHECK_SIZEOF([void *])
 233
 234 m4_include([plugin/configfrag.ac])
 235
 236 # Check for functions needed.
 237 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 238 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 239
 240 # Check for broken semaphore implementation on darwin.
 241 # sem_init returns: sem_init error: Function not implemented.
 242 case "$host" in
 243   *-darwin*)
 244     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 245         Define if the POSIX Semaphores do not work on your system.)
 246     ;;
 247 esac
 248
 249 # RTEMS specific checks
 250 case "$host" in
 251   *-*-rtems*)
 252     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 253     ;;
 254 esac
 255
 256 GCC_LINUX_FUTEX(:)
 257
 258 # Check for pthread_{,attr_}[sg]etaffinity_np.
 259 AC_LINK_IFELSE(
 260  [AC_LANG_PROGRAM(
 261   [#define _GNU_SOURCE
 262    #include <pthread.h>],
 263   [cpu_set_t cpuset;
 264    pthread_attr_t attr;
 265    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 266    if (CPU_ISSET (0, &cpuset))
 267      CPU_SET (1, &cpuset);
 268    else
 269      CPU_ZERO (&cpuset);
 270    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 271    pthread_attr_init (&attr);
 272    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 273    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 274   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 275 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 276
 277 # At least for glibc, clock_gettime is in librt.  But don't pull that
 278 # in if it still doesn't give us the function we want.
 279 if test $ac_cv_func_clock_gettime = no; then
 280   AC_CHECK_LIB(rt, clock_gettime,
 281     [LIBS="-lrt $LIBS"
 282      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 283                [Define to 1 if you have the `clock_gettime' function.])])
 284 fi
 285
 286 # Check for uname.
 287 AC_COMPILE_IFELSE(
 288  [AC_LANG_PROGRAM(
 289   [#include <string.h>
 290    #include <stdlib.h>
 291    #include <sys/utsname.h>],
 292   [struct utsname buf;
 293    volatile size_t len = 0;
 294    if (!uname (buf))
 295      len = strlen (buf.nodename);])],
 296   AC_DEFINE(HAVE_UNAME, 1,
 297 [       Define if uname is supported and struct utsname has nodename field.]))
 298
 299 # Check for gethostname.
 300 AC_COMPILE_IFELSE(
 301  [AC_LANG_PROGRAM(
 302   [#include <unistd.h>],
 303   [
 304 changequote(,)dnl
 305    char buf[256];
 306    if (gethostname (buf, sizeof (buf) - 1) == 0)
 307      buf[255] = '\0';
 308 changequote([,])dnl
 309   ])],
 310   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 311 [       Define if gethostname is supported.]))
 312
 313 # Check for getpid.
 314 AC_COMPILE_IFELSE(
 315  [AC_LANG_PROGRAM(
 316   [#include <unistd.h>],
 317   [int pid = getpid ();])],
 318   AC_DEFINE(HAVE_GETPID, 1,
 319 [       Define if getpid is supported.]))
 320
 321 # See if we support thread-local storage.
 322 GCC_CHECK_TLS
 323
 324 # See if we have emulated thread-local storage.
 325 GCC_CHECK_EMUTLS
 326
 327 # See what sort of export controls are available.
 328 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 329 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 330 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 331 LIBGOMP_ENABLE_SYMVERS
 332
 333 if test $enable_symvers = gnu; then
 334   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 335             [Define to 1 if GNU symbol versioning is used for libgomp.])
 336 fi
 337
 338 # Determine cpu count to limit testsuite parallelism.
 339 AX_COUNT_CPUS
 340 AC_SUBST(CPU_COUNT)
 341
 342 AC_MSG_NOTICE([checking for flock implementation])
 343 AC_CHECK_PROGS(FLOCK, flock)
 344 # Fallback if 'perl' is available.
 345 if test -z "$FLOCK"; then
 346   # These need to be absolute paths, yet at the same time need to
 347   # canonicalize only relative paths, because then amd will not unmount
 348   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 349   case $srcdir in
 350 changequote(,)dnl
 351     [\\/$]* | ?:[\\/]*) libgomp_abs_srcdir=${srcdir} ;;
 352 changequote([,])dnl
 353     *) libgomp_abs_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 354   esac
 355   AC_CHECK_PROG(FLOCK, perl, $libgomp_abs_srcdir/testsuite/flock)
 356 fi
 357
 358 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 359
 360 # Get target configury.
 361 . ${srcdir}/configure.tgt
 362 CFLAGS="$save_CFLAGS $XCFLAGS"
 363
 364 # Check for __sync_val_compare_and_swap, but only after the target has
 365 # had a chance to set XCFLAGS.
 366 LIBGOMP_CHECK_SYNC_BUILTINS
 367
 368 XCFLAGS="$XCFLAGS$XPCFLAGS"
 369
 370 # Add CET specific flags if CET is enabled
 371 GCC_CET_FLAGS(CET_FLAGS)
 372 XCFLAGS="$XCFLAGS $CET_FLAGS"
 373 FCFLAGS="$FCFLAGS $CET_FLAGS"
 374
 375 AC_SUBST(config_path)
 376 AC_SUBST(XCFLAGS)
 377 AC_SUBST(XLDFLAGS)
 378
 379 # Conditionalize the makefile for this target machine.
 380 tmake_file_=
 381 for f in ${tmake_file}
 382 do
 383         if test -f ${srcdir}/config/$f
 384         then
 385                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 386         fi
 387 done
 388 tmake_file="${tmake_file_}"
 389 AC_SUBST(tmake_file)
 390
 391 # Cleanup and exit.
 392 CFLAGS="$save_CFLAGS"
 393 AC_CACHE_SAVE
 394
 395 if test ${multilib} = yes; then
 396   multilib_arg="--enable-multilib"
 397 else
 398   multilib_arg=
 399 fi
 400
 401 # Set up the set of libraries that we need to link against for libgomp.
 402 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 403 # which will force linkage against -lpthread (or equivalent for the system).
 404 # That's not 100% ideal, but about the best we can do easily.
 405 if test $enable_shared = yes; then
 406   link_gomp="-lgomp %{static: $LIBS${DL_LIBS:+ $DL_LIBS}}"
 407 else
 408   link_gomp="-lgomp $LIBS${DL_LIBS:+ $DL_LIBS}"
 409 fi
 410 AC_SUBST(link_gomp)
 411
 412 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 413
 414 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 415 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 416 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 417 # need to copy this macro to our acinclude.m4.
 418 save_CFLAGS="$CFLAGS"
 419 for i in $config_path; do
 420   if test -f $srcdir/config/$i/omp-lock.h; then
 421     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 422     break
 423   fi
 424 done
 425
 426 _AC_COMPUTE_INT([sizeof (__INTPTR_TYPE__)], [INTPTR_T_KIND])
 427 _AC_COMPUTE_INT([sizeof (__int128)], [OMP_INT128_SIZE],,[OMP_INT128_SIZE=0])
 428 _AC_COMPUTE_INT([2*sizeof (__INTPTR_TYPE__)], [OMP_DEPEND_KIND],,
 429                 [OMP_DEPEND_KIND=0])
 430 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 431   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 432 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 433 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 434 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 435 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 436   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 437 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 438 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 439 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 440
 441 # If the lock fits in an integer, then arrange for Fortran to use that
 442 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 443 # Except that we don't have a way at present to multi-lib the installed
 444 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 445 # actual target.
 446 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 447 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 448 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 449   OMP_LOCK_KIND=8
 450 fi
 451 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 452   OMP_NEST_LOCK_KIND=8
 453 fi
 454 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 455 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 456 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 457   OMP_LOCK_25_KIND=8
 458 fi
 459 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 460   OMP_NEST_LOCK_25_KIND=8
 461 fi
 462 if test "$ac_cv_fc_compiler_gnu" = yes; then
 463   if test $OMP_DEPEND_KIND -eq 16; then
 464     if test $OMP_INT128_SIZE -ne 16; then
 465       AC_MSG_ERROR([unsupported system, cannot find Fortran int kind=16, needed for omp_depend_kind])
 466     fi
 467   else
 468     if test $OMP_DEPEND_KIND -ne 8; then
 469       AC_MSG_ERROR([unsupported system, cannot find Fortran integer kind for omp_depend_kind])
 470     fi
 471   fi
 472 fi
 473
 474 AC_SUBST(INTPTR_T_KIND)
 475 AC_SUBST(OMP_LOCK_SIZE)
 476 AC_SUBST(OMP_LOCK_ALIGN)
 477 AC_SUBST(OMP_NEST_LOCK_SIZE)
 478 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 479 AC_SUBST(OMP_LOCK_KIND)
 480 AC_SUBST(OMP_NEST_LOCK_KIND)
 481 AC_SUBST(OMP_LOCK_25_SIZE)
 482 AC_SUBST(OMP_LOCK_25_ALIGN)
 483 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 484 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 485 AC_SUBST(OMP_LOCK_25_KIND)
 486 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 487 AC_SUBST(OMP_DEPEND_KIND)
 488 CFLAGS="$save_CFLAGS"
 489
 490 # Determine what GCC version number to use in filesystem paths.
 491 GCC_BASE_VER
 492
 493 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 494 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 495 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 496 AC_CONFIG_FILES([testsuite/libgomp-site-extra.exp])
 497 AC_OUTPUT