libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 AC_SYS_LARGEFILE
  87
  88 # Runs configure.host, and assorted other critical bits.  Sets
  89 # up critical shell variables.
  90 GLIBCXX_CONFIGURE
  91
  92 # Libtool setup.
  93 if test "x${with_newlib}" != "xyes" && test "x${with_avrlibc}" != "xyes"; then
  94   AC_LIBTOOL_DLOPEN
  95 fi
  96 AM_PROG_LIBTOOL
  97 ACX_LT_HOST_FLAGS
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 if test "$enable_vtable_verify" = yes; then
 102   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 103   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 104 fi
 105
 106
 107 # libtool variables for C++ shared and position-independent compiles.
 108 #
 109 # Use glibcxx_lt_pic_flag to designate the automake variable
 110 # used to encapsulate the default libtool approach to creating objects
 111 # with position-independent code. Default: -prefer-pic.
 112 #
 113 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 114 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 115 #
 116 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 117 # creating position-independent objects. This varies with the target
 118 # hardware and operating system, but is often: -DPIC -fPIC.
 119 if test "$enable_shared" = yes; then
 120   glibcxx_lt_pic_flag="-prefer-pic"
 121   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 122   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 123
 124 else
 125   glibcxx_lt_pic_flag=
 126   glibcxx_compiler_pic_flag=
 127   glibcxx_compiler_shared_flag=
 128 fi
 129 AC_SUBST(glibcxx_lt_pic_flag)
 130 AC_SUBST(glibcxx_compiler_pic_flag)
 131 AC_SUBST(glibcxx_compiler_shared_flag)
 132
 133 # Override the libtool's pic_flag and pic_mode.
 134 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 135 # NB: this impacts --with-pic and --without-pic.
 136 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 137 pic_mode='default'
 138
 139 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 140 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 141
 142 # Possibly disable most of the library.
 143 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 144 ## than just ignoring the results.  Faster /and/ more correct, win win.
 145 GLIBCXX_ENABLE_HOSTED
 146
 147 # Enable descriptive messages to standard output on termination.
 148 GLIBCXX_ENABLE_VERBOSE
 149
 150 # Enable compiler support that doesn't require linking.
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_LOCK_POLICY
 155 GLIBCXX_ENABLE_DECIMAL_FLOAT
 156 GLIBCXX_ENABLE_FLOAT128
 157 if test "$enable_float128" = yes; then
 158   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 159 fi
 160
 161 # Checks for compiler support that doesn't require linking.
 162 GLIBCXX_CHECK_COMPILER_FEATURES
 163
 164 # Enable all the variable C++ runtime options that don't require linking.
 165 GLIBCXX_ENABLE_CSTDIO
 166 GLIBCXX_ENABLE_CLOCALE
 167 GLIBCXX_ENABLE_ALLOCATOR
 168 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 169 GLIBCXX_ENABLE_LONG_LONG([yes])
 170 GLIBCXX_ENABLE_WCHAR_T([yes])
 171 GLIBCXX_ENABLE_C99([yes])
 172 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 173 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 174 GLIBCXX_ENABLE_DEBUG([no])
 175 GLIBCXX_ENABLE_PARALLEL([yes])
 176 GLIBCXX_ENABLE_CXX_FLAGS
 177 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 178 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 179 GLIBCXX_ENABLE_PYTHON
 180 GLIBCXX_ENABLE_WERROR([no])
 181 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 182
 183 # Checks for operating systems support that doesn't require linking.
 184 GLIBCXX_CHECK_STDIO_PROTO
 185 GLIBCXX_CHECK_MATH11_PROTO
 186 GLIBCXX_CHECK_UCHAR_H
 187
 188 # For LFS support.
 189 GLIBCXX_CHECK_LFS
 190
 191 # For showmanyc_helper().
 192 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 193 GLIBCXX_CHECK_POLL
 194 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 195
 196 # For xsputn_2().
 197 AC_CHECK_HEADERS(sys/uio.h)
 198 GLIBCXX_CHECK_WRITEV
 199
 200 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 201 # so that the check is done with the C compiler (not C++).
 202 # Checking with C++ can break a canadian cross build if either
 203 # file does not exist in C but does in C++.
 204 AC_CHECK_HEADERS(fenv.h complex.h)
 205
 206 # For C99 support to TR1.
 207 GLIBCXX_CHECK_C99_TR1
 208
 209 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 210 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 211
 212 # For gettimeofday support.
 213 GLIBCXX_CHECK_GETTIMEOFDAY
 214
 215 # For clock_gettime, nanosleep and sched_yield support.
 216 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 217
 218 # Check for tmpnam which is obsolescent in POSIX.1-2008
 219 GLIBCXX_CHECK_TMPNAM
 220
 221 # For pthread_cond_clockwait
 222 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 223
 224 # For pthread_mutex_clocklock
 225 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 226
 227 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 228 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 229
 230 AC_LC_MESSAGES
 231
 232 # For hardware_concurrency
 233 AC_CHECK_HEADERS(sys/sysinfo.h)
 234 GLIBCXX_CHECK_GET_NPROCS
 235 AC_CHECK_HEADERS(unistd.h)
 236 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 237 GLIBCXX_CHECK_SC_NPROC_ONLN
 238 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 239 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 240 GLIBCXX_CHECK_SDT_H
 241
 242 # Check for available headers.
 243 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 244 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 245 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 246 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 247 wchar.h wctype.h linux/types.h])
 248
 249 AC_CHECK_HEADERS([linux/random.h], [], [],
 250 [[#ifdef HAVE_LINUX_TYPES_H
 251 # include <linux/types.h>
 252 #endif
 253 ]])
 254
 255 AC_CHECK_HEADERS([xlocale.h])
 256
 257 # Only do link tests if native. Else, hardcode.
 258 if $GLIBCXX_IS_NATIVE; then
 259
 260   # We can do more elaborate tests that assume a working linker.
 261   CANADIAN=no
 262
 263   GLIBCXX_CHECK_LINKER_FEATURES
 264   GLIBCXX_CHECK_MATH_SUPPORT
 265   GLIBCXX_CHECK_STDLIB_SUPPORT
 266
 267   # For /dev/random and /dev/urandom for std::random_device.
 268   GLIBCXX_CHECK_DEV_RANDOM
 269
 270   # For TLS support.
 271   GCC_CHECK_TLS
 272
 273   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 274   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 275   AC_CHECK_FUNCS(_wfopen)
 276
 277   # C11 functions for C++17 library
 278   AC_CHECK_FUNCS(timespec_get)
 279
 280   # For Networking TS.
 281   AC_CHECK_FUNCS(sockatmark)
 282
 283   # Non-standard functions used by C++17 std::from_chars
 284   AC_CHECK_FUNCS(uselocale)
 285
 286   # For iconv support.
 287   AM_ICONV
 288
 289 else
 290
 291   # This lets us hard-code the functionality we know we'll have in the cross
 292   # target environment.  "Let" is a sugar-coated word placed on an especially
 293   # dull and tedious hack, actually.
 294   #
 295   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 296   # that involve linking, can't be used:
 297   #    "cannot open sim-crt0.o"
 298   #    "cannot open crt0.o"
 299   # etc.  All this is because there currently exists no unified, consistent
 300   # way for top level CC information to be passed down to target directories:
 301   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 302   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 303   # crosses can be removed.
 304
 305   # If Canadian cross, then don't pick up tools from the build directory.
 306   # Used only in GLIBCXX_EXPORT_INCLUDES.
 307   if test -n "$with_cross_host" &&
 308      test x"$build_alias" != x"$with_cross_host" &&
 309      test x"$build" != x"$target";
 310   then
 311     CANADIAN=yes
 312   else
 313     CANADIAN=no
 314   fi
 315
 316   # Construct crosses by hand, eliminating bits that need ld...
 317   # GLIBCXX_CHECK_MATH_SUPPORT
 318
 319   # First, test for "known" system libraries.  We may be using newlib even
 320   # on a hosted environment.
 321   if test "x${with_newlib}" = "xyes"; then
 322     os_include_dir="os/newlib"
 323     AC_DEFINE(HAVE_HYPOT)
 324
 325     # GLIBCXX_CHECK_STDLIB_SUPPORT
 326     AC_DEFINE(HAVE_STRTOF)
 327
 328     AC_DEFINE(HAVE_ACOSF)
 329     AC_DEFINE(HAVE_ASINF)
 330     AC_DEFINE(HAVE_ATAN2F)
 331     AC_DEFINE(HAVE_ATANF)
 332     AC_DEFINE(HAVE_CEILF)
 333     AC_DEFINE(HAVE_COSF)
 334     AC_DEFINE(HAVE_COSHF)
 335     AC_DEFINE(HAVE_EXPF)
 336     AC_DEFINE(HAVE_FABSF)
 337     AC_DEFINE(HAVE_FLOORF)
 338     AC_DEFINE(HAVE_FMODF)
 339     AC_DEFINE(HAVE_FREXPF)
 340     AC_DEFINE(HAVE_LDEXPF)
 341     AC_DEFINE(HAVE_LOG10F)
 342     AC_DEFINE(HAVE_LOGF)
 343     AC_DEFINE(HAVE_MODFF)
 344     AC_DEFINE(HAVE_POWF)
 345     AC_DEFINE(HAVE_SINF)
 346     AC_DEFINE(HAVE_SINHF)
 347     AC_DEFINE(HAVE_SQRTF)
 348     AC_DEFINE(HAVE_TANF)
 349     AC_DEFINE(HAVE_TANHF)
 350
 351     AC_DEFINE(HAVE_ICONV)
 352     AC_DEFINE(HAVE_MEMALIGN)
 353   else
 354     GLIBCXX_CROSSCONFIG
 355   fi
 356
 357   # At some point, we should differentiate between architectures
 358   # like x86, which have long double versions, and alpha/powerpc/etc.,
 359   # which don't. For the time being, punt.
 360   if test x"long_double_math_on_this_cpu" = x"yes"; then
 361     AC_DEFINE(HAVE_ACOSL)
 362     AC_DEFINE(HAVE_ASINL)
 363     AC_DEFINE(HAVE_ATAN2L)
 364     AC_DEFINE(HAVE_ATANL)
 365     AC_DEFINE(HAVE_CEILL)
 366     AC_DEFINE(HAVE_COSL)
 367     AC_DEFINE(HAVE_COSHL)
 368     AC_DEFINE(HAVE_EXPL)
 369     AC_DEFINE(HAVE_FABSL)
 370     AC_DEFINE(HAVE_FLOORL)
 371     AC_DEFINE(HAVE_FMODL)
 372     AC_DEFINE(HAVE_FREXPL)
 373     AC_DEFINE(HAVE_LDEXPL)
 374     AC_DEFINE(HAVE_LOG10L)
 375     AC_DEFINE(HAVE_LOGL)
 376     AC_DEFINE(HAVE_MODFL)
 377     AC_DEFINE(HAVE_POWL)
 378     AC_DEFINE(HAVE_SINCOSL)
 379     AC_DEFINE(HAVE_SINL)
 380     AC_DEFINE(HAVE_SINHL)
 381     AC_DEFINE(HAVE_SQRTL)
 382     AC_DEFINE(HAVE_TANL)
 383     AC_DEFINE(HAVE_TANHL)
 384   fi
 385 fi
 386
 387 # Check for _Unwind_GetIPInfo.
 388 GCC_CHECK_UNWIND_GETIPINFO
 389
 390 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 391
 392 GCC_HEADER_STDINT(include/gstdint.h)
 393
 394 GLIBCXX_ENABLE_SYMVERS([yes])
 395 AC_SUBST(libtool_VERSION)
 396
 397 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 398
 399 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 400 GLIBCXX_DEFAULT_ABI
 401
 402 ac_ldbl_compat=no
 403 ac_ldbl_alt128_compat=no
 404 ac_ldbl_ieee128_default=no
 405 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 406 LONG_DOUBLE_128_FLAGS=
 407 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 408 case "$target" in
 409   powerpc*-*-linux* | \
 410   sparc*-*-linux* | \
 411   s390*-*-linux* | \
 412   alpha*-*-linux*)
 413   AC_TRY_COMPILE(, [
 414 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 415 #error no need for long double compatibility
 416 #endif
 417   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 418   if test "$ac_ldbl_compat" = yes; then
 419     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 420               [Define if compatibility should be provided for -mlong-double-64.])
 421     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 422     case "$target" in
 423       powerpc*-*-linux*)
 424         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 425         # Check for IEEE128 support in libm:
 426         AC_CHECK_LIB(m, __frexpieee128,
 427                      [ac_ldbl_ieee128_in_libc=yes],
 428                      [ac_ldbl_ieee128_in_libc=no])
 429         if test $ac_ldbl_ieee128_in_libc = yes; then
 430           # Determine which long double format is the compiler's default:
 431           AC_TRY_COMPILE(, [
 432             #ifndef __LONG_DOUBLE_IEEE128__
 433             #error compiler defaults to ibm128
 434             #endif
 435           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 436           # Library objects should use default long double format.
 437           if test "$ac_ldbl_ieee128_default" = yes; then
 438             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 439             # Except for the ones that explicitly use these flags:
 440             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 441           else
 442             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 443             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 444           fi
 445           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 446                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 447           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 448           ac_ldbl_alt128_compat=yes
 449         else
 450           ac_ldbl_alt128_compat=no
 451         fi
 452         ;;
 453     esac
 454   fi
 455 esac
 456 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 457 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 458 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 459 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 460 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 461
 462 # Check if assembler supports disabling hardware capability support.
 463 GCC_CHECK_ASSEMBLER_HWCAP
 464
 465 # Check if assembler supports rdrand opcode.
 466 GLIBCXX_CHECK_X86_RDRAND
 467 # Check if assembler supports rdseed opcode.
 468 GLIBCXX_CHECK_X86_RDSEED
 469
 470 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 471 GLIBCXX_CONFIGURE_TESTSUITE
 472
 473 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 474 GLIBCXX_CHECK_GTHREADS
 475
 476 # For Filesystem TS.
 477 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 478 GLIBCXX_ENABLE_FILESYSTEM_TS
 479 GLIBCXX_CHECK_FILESYSTEM_DEPS
 480
 481 # For Networking TS.
 482 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 483
 484 # For Transactional Memory TS
 485 GLIBCXX_CHECK_SIZE_T_MANGLING
 486
 487 # Check which release added std::exception_ptr for the target
 488 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 489
 490 # Define documentation rules conditionally.
 491
 492 # See if makeinfo has been installed and is modern enough
 493 # that we can use it.
 494 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 495                    [GNU texinfo.* \([0-9][0-9.]*\)],
 496                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 497 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 498
 499 # Check for doxygen
 500 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 501 AC_CHECK_PROG([DOT], dot, yes, no)
 502
 503 # Check for docbook
 504 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 505 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 506 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 507 GLIBCXX_CONFIGURE_DOCBOOK
 508
 509 # Check for xml/html dependencies.
 510 AM_CONDITIONAL(BUILD_XML,
 511                test $ac_cv_prog_DOXYGEN = "yes" &&
 512                test $ac_cv_prog_DOT = "yes" &&
 513                test $ac_cv_prog_XSLTPROC = "yes" &&
 514                test $ac_cv_prog_XMLLINT = "yes" &&
 515                test $glibcxx_stylesheets = "yes")
 516
 517 AM_CONDITIONAL(BUILD_HTML,
 518                test $ac_cv_prog_DOXYGEN = "yes" &&
 519                test $ac_cv_prog_DOT = "yes" &&
 520                test $ac_cv_prog_XSLTPROC = "yes" &&
 521                test $ac_cv_prog_XMLLINT = "yes" &&
 522                test $glibcxx_stylesheets = "yes")
 523
 524 # Check for man dependencies.
 525 AM_CONDITIONAL(BUILD_MAN,
 526                test $ac_cv_prog_DOXYGEN = "yes" &&
 527                test $ac_cv_prog_DOT = "yes")
 528
 529 # Check for pdf dependencies.
 530 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 531 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 532 AM_CONDITIONAL(BUILD_PDF,
 533                test $ac_cv_prog_DOXYGEN = "yes" &&
 534                test $ac_cv_prog_DOT = "yes" &&
 535                test $ac_cv_prog_XSLTPROC = "yes" &&
 536                test $ac_cv_prog_XMLLINT = "yes" &&
 537                test $ac_cv_prog_DBLATEX = "yes" &&
 538                test $ac_cv_prog_PDFLATEX = "yes")
 539
 540 case "$build" in
 541  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 542  * ) glibcxx_include_dir_notparallel=no ;;
 543 esac
 544 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 545                test $glibcxx_include_dir_notparallel = "yes")
 546
 547 # Propagate the target-specific source directories through the build chain.
 548 ATOMICITY_SRCDIR=config/${atomicity_dir}
 549 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 550 ATOMIC_FLAGS=${atomic_flags}
 551 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 552 OS_INC_SRCDIR=config/${os_include_dir}
 553 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 554 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 555 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 556 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 557 AC_SUBST(ATOMICITY_SRCDIR)
 558 AC_SUBST(ATOMIC_WORD_SRCDIR)
 559 AC_SUBST(ATOMIC_FLAGS)
 560 AC_SUBST(CPU_DEFINES_SRCDIR)
 561 AC_SUBST(ABI_TWEAKS_SRCDIR)
 562 AC_SUBST(OS_INC_SRCDIR)
 563 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 564 AC_SUBST(CPU_OPT_EXT_RANDOM)
 565 AC_SUBST(CPU_OPT_BITS_RANDOM)
 566
 567 # Conditionalize the makefile for this target machine.
 568 tmake_file_=
 569 for f in ${tmake_file}
 570 do
 571         if test -f ${srcdir}/config/$f
 572         then
 573                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 574         fi
 575 done
 576 tmake_file="${tmake_file_}"
 577 AC_SUBST(tmake_file)
 578
 579 # Add CET specific flags if Intel CET is enabled.
 580 GCC_CET_FLAGS(CET_FLAGS)
 581 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 582 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 583 AC_SUBST(EXTRA_CFLAGS)
 584 AC_SUBST(EXTRA_CXX_FLAGS)
 585
 586 # Determine cross-compile flags and AM_CONDITIONALs.
 587 #AC_SUBST(GLIBCXX_IS_NATIVE)
 588 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 589 GLIBCXX_EVALUATE_CONDITIONALS
 590
 591 AC_CACHE_SAVE
 592
 593 if test ${multilib} = yes; then
 594   multilib_arg="--enable-multilib"
 595 else
 596   multilib_arg=
 597 fi
 598
 599 # Export all the install information.
 600 GLIBCXX_EXPORT_INSTALL_INFO
 601
 602 # Export all the include and flag information to Makefiles.
 603 GLIBCXX_EXPORT_INCLUDES
 604 GLIBCXX_EXPORT_FLAGS
 605
 606 # Determine what GCC version number to use in filesystem paths.
 607 GCC_BASE_VER
 608
 609 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 610 dnl which can all be called multiple times as needed, plus one (different)
 611 dnl AC_OUTPUT macro.  This one lists the files to be created:
 612 AC_CONFIG_FILES(Makefile)
 613 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 614 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 615 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 616
 617 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 618 # that multilib installs will end up installed in the correct place.
 619 # The testsuite needs it for multilib-aware ABI baseline files.
 620 # To work around this not being passed down from config-ml.in ->
 621 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 622 # append it here.  Only modify Makefiles that have just been created.
 623 #
 624 # Also, get rid of this simulated-VPATH thing that automake does.
 625 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 626   [cat > vpsed$$ << \_EOF
 627 s!`test -f '$<' || echo '$(srcdir)/'`!!
 628 _EOF
 629    sed -f vpsed$$ $ac_file > tmp$$
 630    mv tmp$$ $ac_file
 631    rm vpsed$$
 632    echo 'MULTISUBDIR =' >> $ac_file
 633    ml_norecursion=yes
 634    . ${multi_basedir}/config-ml.in
 635    AS_UNSET([ml_norecursion])
 636 ])
 637
 638 AC_CONFIG_COMMANDS([generate-headers],
 639   [(cd include && ${MAKE-make} pch_build= )])
 640
 641 dnl And this actually makes things happen:
 642 AC_OUTPUT