| blob | 8e8e3bc1be96de6edf2ca5686bbe5d57e5d504c8 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Original author: Michael Patra
3 dnl See ChangeLog file for detailed change history.
5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
7 AC_PREREQ(2.53)
8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
9 AC_CONFIG_SRCDIR(server/atom.c)
10 AC_CONFIG_HEADERS(include/config.h)
11 AC_CONFIG_AUX_DIR(tools)
13 dnl **** Command-line arguments ****
15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
20 AC_ARG_WITH(opengl, AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
21 AC_ARG_WITH(curses, AC_HELP_STRING([--without-curses],[do not use curses]))
22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
24 AC_SUBST(DLLDEFS,"")
25 if test "x$enable_debug" = "xno"
26 then
27 DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
28 fi
29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
30 then
31 DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
32 fi
34 AC_CANONICAL_HOST
35 case $host in
36 x86_64*linux*)
37 if test "x$enable_win64" != "xyes"
38 then
39 test -n "$CC" || CC="gcc -m32"
40 test -n "$LD" || LD="ld -m elf_i386"
41 test -n "$AS" || AS="as --32"
42 host_cpu="i386"
43 fi
44 ;;
45 esac
47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
48 case $host_cpu in
49 *i[[3456789]]86*)
50 if test "x$enable_win16" != "xno"
51 then
52 enable_win16="yes"
53 fi
54 ;;
55 esac
57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
59 if test "x$enable_win16" != "xyes"
60 then
61 WIN16_FILES=""
62 WIN16_INSTALL=""
63 fi
65 dnl **** Check for some programs ****
67 AC_PROG_MAKE_SET
68 AC_PROG_CC
69 AC_PROG_CXX
70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
74 [if test -z "$with_wine_tools"; then
75 if test "$cross_compiling" = "yes"; then
76 AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
77 else
78 wine_cv_toolsdir="\$(TOPOBJDIR)"
79 fi
80 elif test -d "$with_wine_tools/tools/winebuild"; then
81 case $with_wine_tools in
82 /*) wine_cv_toolsdir="$with_wine_tools" ;;
83 *) wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
84 esac
85 else
86 AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
87 fi])
88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
90 AC_PATH_XTRA
91 AC_PROG_LEX
93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
94 dnl **** without one present.
95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
96 if test "$XLEX" = "none"
97 then
98 AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
99 fi
101 dnl Check for bison
102 AC_CHECK_PROGS(BISON,bison,none)
103 if test "$BISON" = "none"
104 then
105 AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
106 fi
108 AC_CHECK_TOOLS(AS,[gas as],as)
109 AC_CHECK_TOOL(LD,ld,ld)
110 AC_CHECK_TOOL(AR,ar,ar)
111 AC_PROG_RANLIB
112 AC_CHECK_TOOL(STRIP,strip,strip)
113 AC_CHECK_TOOL(WINDRES,windres,false)
114 AC_PROG_LN_S
115 WINE_PROG_LN
116 AC_PROG_EGREP
117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
118 AC_PROG_INSTALL
119 dnl Prepend src dir to install path dir if it's a relative path
120 case "$INSTALL" in
121 [[\\/$]]* | ?:[[\\/]]* ) ;;
122 *) INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
123 esac
125 dnl Check for lint
126 AC_CHECK_PROGS(LINT, lclint lint)
127 if test "$LINT" = "lint"
128 then
129 LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
130 dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
131 fi
132 AC_SUBST(LINT)
133 AC_SUBST(LINTFLAGS)
135 dnl Check for various programs
136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
139 case $host_cpu in
140 *i[[3456789]]86*)
141 AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
142 ;;
143 esac
145 dnl **** Check for some libraries ****
147 dnl Check for -li386 for NetBSD and OpenBSD
148 AC_CHECK_LIB(i386,i386_set_ldt)
149 dnl Check for -lossaudio for NetBSD
150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
151 dnl Check for -lnsl for Solaris
152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
153 dnl Check for -lsocket for Solaris
154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
155 dnl Check for -lresolv for Solaris
156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
157 dnl Check for -lxpg4 for FreeBSD
158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
159 dnl Check for -lpoll for Mac OS X/Darwin
160 AC_CHECK_LIB(poll,poll)
161 dnl Check for -lresolv for Mac OS X/Darwin
162 AC_CHECK_LIB(resolv,res_9_init)
163 dnl Check for -lpthread
164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
166 AC_SUBST(XLIB,"")
167 AC_SUBST(XFILES,"")
168 AC_SUBST(OPENGLFILES,"")
169 AC_SUBST(GLU32FILES,"")
170 AC_SUBST(OPENGL_LIBS,"")
172 dnl **** Check for header files ****
174 AC_CHECK_HEADERS(\
175 IOKit/IOKitLib.h \
176 alsa/asoundlib.h \
177 arpa/inet.h \
178 arpa/nameser.h \
179 asm/types.h \
180 capi20.h \
181 cups/cups.h \
182 curses.h \
183 direct.h \
184 dlfcn.h \
185 elf.h \
186 float.h \
187 fontconfig/fontconfig.h \
188 getopt.h \
189 gif_lib.h \
190 ieeefp.h \
191 io.h \
192 jack/jack.h \
193 jpeglib.h \
194 lber.h \
195 lcms.h \
196 lcms/lcms.h \
197 ldap.h \
198 libaudioio.h \
199 link.h \
200 linux/capi.h \
201 linux/cdrom.h \
202 linux/compiler.h \
203 linux/hdreg.h \
204 linux/input.h \
205 linux/ioctl.h \
206 linux/joystick.h \
207 linux/major.h \
208 linux/param.h \
209 linux/serial.h \
210 linux/ucdrom.h \
211 mach/machine.h \
212 machine/cpu.h \
213 machine/limits.h \
214 machine/soundcard.h \
215 mntent.h \
216 ncurses.h \
217 netdb.h \
218 netinet/in.h \
219 netinet/in_systm.h \
220 netinet/tcp.h \
221 netinet/tcp_fsm.h \
222 openssl/ssl.h \
223 poll.h \
224 process.h \
225 pthread.h \
226 pwd.h \
227 regex.h \
228 sched.h \
229 scsi/scsi.h \
230 scsi/scsi_ioctl.h \
231 scsi/sg.h \
232 soundcard.h \
233 stdint.h \
234 strings.h \
235 sys/asoundlib.h \
236 sys/cdio.h \
237 sys/elf32.h \
238 sys/epoll.h \
239 sys/errno.h \
240 sys/exec_elf.h \
241 sys/filio.h \
242 sys/ioctl.h \
243 sys/ipc.h \
244 sys/link.h \
245 sys/lwp.h \
246 sys/mman.h \
247 sys/modem.h \
248 sys/msg.h \
249 sys/param.h \
250 sys/poll.h \
251 sys/ptrace.h \
252 sys/reg.h \
253 sys/scsiio.h \
254 sys/shm.h \
255 sys/signal.h \
256 sys/socket.h \
257 sys/sockio.h \
258 sys/soundcard.h \
259 sys/statvfs.h \
260 sys/strtio.h \
261 sys/syscall.h \
262 sys/sysctl.h \
263 sys/time.h \
264 sys/times.h \
265 sys/uio.h \
266 sys/un.h \
267 sys/vm86.h \
268 sys/wait.h \
269 syscall.h \
270 termios.h \
271 unicode/ubidi.h \
272 unistd.h \
273 utime.h \
274 valgrind/memcheck.h
275 )
276 AC_HEADER_STAT()
278 dnl **** Check for X11 ****
280 if test "$have_x" = "yes"
281 then
282 XLIB="-lXext -lX11"
283 ac_save_CPPFLAGS="$CPPFLAGS"
284 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
286 dnl *** All of the following tests require X11/Xlib.h
287 AC_CHECK_HEADERS([X11/Xlib.h \
288 X11/XKBlib.h \
289 X11/Xutil.h \
290 X11/extensions/shape.h \
291 X11/extensions/XInput.h \
292 X11/extensions/XShm.h \
293 X11/extensions/Xrandr.h \
294 X11/extensions/Xrender.h \
295 X11/extensions/xf86dga.h \
296 X11/extensions/xf86vmode.h],,,
297 [#ifdef HAVE_X11_XLIB_H
298 # include <X11/Xlib.h>
299 #endif
300 #ifdef HAVE_X11_XUTIL_H
301 # include <X11/Xutil.h>
302 #endif])
304 dnl *** Check for X keyboard extension
305 if test "$ac_cv_header_X11_XKBlib_h" = "yes"
306 then
307 AC_CHECK_LIB(X11, XkbQueryExtension,
308 AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
309 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
310 fi
312 dnl *** Check for X Shm extension
313 if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
314 then
315 AC_CHECK_LIB(Xext, XShmQueryExtension,
316 AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
317 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
318 fi
320 dnl *** Check for X shape extension
321 if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
322 then
323 AC_CHECK_LIB(Xext,XShapeQueryExtension,
324 AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
325 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
326 fi
328 dnl *** Check for XFree86 DGA / DGA 2.0 extension
329 if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
330 then
331 AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
332 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
333 [Define if you have the Xxf86dga library version 2])
334 X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
335 ],,
336 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
337 fi
339 dnl *** Check for XFree86 VMODE extension
340 if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
341 then
342 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
343 [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
344 X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
345 ],,
346 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
347 fi
349 dnl *** Check for X RandR extension
350 if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
351 then
352 AC_TRY_COMPILE([#include <X11/Xlib.h>
353 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
354 [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
355 fi
357 dnl *** Check for Transform functions in Xrender
358 if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
359 then
360 AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
361 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
362 [Define if Xrender has the XRenderSetPictureTransform function])],,
363 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
364 fi
365 dnl *** End of X11/Xlib.h check
367 dnl Check for the presence of OpenGL
368 if test "x$with_opengl" != "xno"
369 then
370 AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h,,,
371 [#ifdef HAVE_GL_GLX_H
372 # include <GL/glx.h>
373 #endif])
374 if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
375 then
376 dnl Check for some problems due to old Mesa versions
377 AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
378 AC_TRY_COMPILE(
379 [#include <GL/gl.h>],
380 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
381 [wine_cv_opengl_version_OK="yes"],
382 [wine_cv_opengl_version_OK="no"]
383 )
384 )
386 if test "$wine_cv_opengl_version_OK" = "yes"
387 then
388 dnl Check for the presence of the library
389 AC_CHECK_LIB(GL,glXCreateContext,
390 OPENGL_LIBS="-lGL"
391 ,,
392 $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
394 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
395 then
396 OPENGLFILES='$(OPENGLFILES)'
397 AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
398 else
399 if test -f /usr/X11R6/lib/libGL.a
400 then
401 AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
402 This prevents linking to OpenGL. Delete the file and restart configure.])
403 fi
404 fi
406 dnl Check for GLU32 library.
407 AC_CHECK_LIB(GLU,gluLookAt,
408 [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
409 GLU32FILES='$(GLU32FILES)']
410 ,,
411 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
412 )
413 fi
415 dnl Check for glut32 library.
416 AC_CHECK_LIB(glut,glutMainLoop,
417 [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
418 AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
419 $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
420 fi
421 fi
423 dnl **** Check for NAS ****
424 AC_SUBST(NASLIBS,"")
425 AC_CHECK_HEADERS(audio/audiolib.h,
426 [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
427 AC_CHECK_LIB(audio,AuCreateFlow,
428 [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
429 NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
430 [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
432 CPPFLAGS="$ac_save_CPPFLAGS"
433 XFILES='$(XFILES)'
434 else
435 XLIB=""
436 X_CFLAGS=""
437 X_LIBS=""
438 fi
440 dnl **** Check for libxml2 ****
442 AC_SUBST(XML2LIBS,"")
443 AC_SUBST(XML2INCL,"")
444 if test "$PKG_CONFIG" != "false"
445 then
446 ac_save_CPPFLAGS="$CPPFLAGS"
447 ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
448 ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
449 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
450 AC_CHECK_HEADERS(libxml/parser.h,
451 [AC_CHECK_LIB(xml2, xmlParseMemory,
452 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
453 XML2LIBS="$ac_xml_libs"
454 XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
455 AC_CHECK_LIB(xml2, xmlReadMemory,
456 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])])
457 ])
458 CPPFLAGS="$ac_save_CPPFLAGS"
459 fi
461 dnl **** Check which curses lib to use ***
462 CURSESLIBS=""
463 if test "x$with_curses" != "xno"
464 then
465 if test "$ac_cv_header_ncurses_h" = "yes"
466 then
467 AC_CHECK_LIB(ncurses,waddch,
468 [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
469 CURSESLIBS="-lncurses"])
470 elif test "$ac_cv_header_curses_h" = "yes"
471 then
472 AC_CHECK_LIB(curses,waddch,
473 [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
474 CURSESLIBS="-lcurses"])
475 fi
476 fi
477 AC_SUBST(CURSESLIBS)
479 dnl **** Check for SANE ****
480 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
481 AC_SUBST(SANELIBS,"")
482 AC_SUBST(SANEINCL,"")
483 if test "$sane_devel" != "no"
484 then
485 SANELIBS="`$sane_devel --libs`"
486 SANEINCL="`$sane_devel --cflags`"
487 ac_save_CPPFLAGS="$CPPFLAGS"
488 ac_save_LIBS="$LIBS"
489 CPPFLAGS="$CPPFLAGS $SANEINCL"
490 LIBS="$LIBS $SANELIBS"
491 AC_CHECK_HEADER(sane/sane.h,
492 [AC_CHECK_LIB(sane,sane_open,
493 [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
494 [SANELIBS=""
495 SANEINCL=""])],
496 [SANELIBS=""
497 SANEINCL=""])
498 LIBS="$ac_save_LIBS"
499 CPPFLAGS="$ac_save_CPPFLAGS"
500 fi
502 dnl **** Check for the ICU library ****
503 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
504 then
505 saved_libs="$LIBS"
506 ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
507 ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
508 ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
509 AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
510 LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
511 AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
512 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
513 AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
514 AC_MSG_RESULT(yes)],
515 [AC_MSG_RESULT(no)])
516 LIBS="$saved_libs"
517 fi
519 dnl **** Check for LittleCMS ***
520 AC_SUBST(LCMSLIBS,"")
521 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
522 then
523 AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
524 [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
525 LCMSLIBS="-llcms"])
526 fi
528 dnl **** Check for OpenLDAP ***
529 AC_SUBST(LDAPLIBS,"")
530 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
531 then
532 AC_CHECK_LIB(ldap, ldap_init,
533 [AC_CHECK_LIB(lber, ber_init,
534 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
535 LDAPLIBS="-lldap -llber"])])
536 fi
538 dnl **** Check for FreeType 2 ****
539 AC_SUBST(FREETYPELIBS,"")
540 AC_SUBST(FREETYPEINCL,"")
541 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
542 if test "$ft_lib" = "no"
543 then
544 wine_cv_msg_freetype=no
545 else
546 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
547 if test "$ft_devel" = "no"
548 then
549 AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
550 if test "$ft_devel2" = "freetype2-config"
551 then
552 ft_devel=$ft_devel2
553 fi
554 fi
555 if test "$ft_devel" = "no"
556 then
557 wine_cv_msg_freetype=yes
558 else
559 FREETYPELIBS=`$ft_devel --libs`
560 FREETYPEINCL=`$ft_devel --cflags`
561 ac_save_CPPFLAGS="$CPPFLAGS"
562 CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
563 AC_CHECK_HEADERS(ft2build.h \
564 freetype/freetype.h \
565 freetype/ftglyph.h \
566 freetype/tttables.h \
567 freetype/ftnames.h \
568 freetype/ftsnames.h \
569 freetype/ttnameid.h \
570 freetype/ftoutln.h \
571 freetype/ftwinfnt.h \
572 freetype/internal/sfnt.h,,,
573 [#if HAVE_FT2BUILD_H
574 #include <ft2build.h>
575 #endif])
576 AC_TRY_CPP([#include <ft2build.h>
577 #include <freetype/fttrigon.h>],
578 [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
579 [Define if you have the <freetype/fttrigon.h> header file.])
580 wine_cv_fttrigon=yes],
581 wine_cv_fttrigon=no)
582 CPPFLAGS="$ac_save_CPPFLAGS"
583 dnl Check that we have at least freetype/freetype.h
584 if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
585 then
586 AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
587 wine_cv_msg_freetype=no
588 else
589 FREETYPELIBS=""
590 FREETYPEINCL=""
591 wine_cv_msg_freetype=yes
592 fi
593 fi
594 fi
596 dnl Only build the fonts dir if we have both freetype and fontforge
597 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
598 then
599 AC_SUBST(FONTSSUBDIRS,"fonts")
600 fi
602 dnl **** Check for parport (currently Linux only) ****
603 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
604 AC_TRY_COMPILE(
605 [#include <linux/ppdev.h>],
606 [ioctl (1,PPCLAIM,0)],
607 [ac_cv_c_ppdev="yes"],
608 [ac_cv_c_ppdev="no"])
609 )
610 if test "$ac_cv_c_ppdev" = "yes"
611 then
612 AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
613 fi
615 dnl **** Check for va_copy ****
616 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
617 AC_TRY_LINK(
618 [#include <stdarg.h>],
619 [va_list ap1, ap2;
620 va_copy(ap1,ap2);
621 ],
622 [ac_cv_c_va_copy="yes"],
623 [ac_cv_c_va_copy="no"])
624 )
625 if test "$ac_cv_c_va_copy" = "yes"
626 then
627 AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
628 fi
629 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
630 AC_TRY_LINK(
631 [#include <stdarg.h>],
632 [va_list ap1, ap2;
633 __va_copy(ap1,ap2);
634 ],
635 [ac_cv_c___va_copy="yes"],
636 [ac_cv_c___va_copy="no"])
637 )
638 if test "$ac_cv_c___va_copy" = "yes"
639 then
640 AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
641 fi
643 dnl **** Check for sigsetjmp ****
644 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
645 AC_TRY_LINK(
646 [#include <setjmp.h>],
647 [sigjmp_buf buf;
648 sigsetjmp( buf, 1 );
649 siglongjmp( buf, 1 );],
650 [ac_cv_c_sigsetjmp="yes"],
651 [ac_cv_c_sigsetjmp="no"])
652 )
653 if test "$ac_cv_c_sigsetjmp" = "yes"
654 then
655 AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
656 fi
658 dnl **** Check for pthread_rwlock_t ****
659 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
660 #include <pthread.h>])
662 dnl **** Check for pthread functions ****
663 ac_save_LIBS="$LIBS"
664 LIBS="$LIBS $LIBPTHREAD"
665 AC_CHECK_FUNCS(\
666 pthread_getattr_np \
667 pthread_get_stackaddr_np \
668 pthread_get_stacksize_np \
669 )
670 LIBS="$ac_save_LIBS"
672 dnl **** Check for aRts Sound Server ****
673 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
674 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
675 then
676 ARTSC_CFLAGS=""
677 for i in `$ARTSCCONFIG --cflags`
678 do
679 case "$i" in
680 -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
681 esac
682 done
683 ARTSC_LIBS=`$ARTSCCONFIG --libs`
684 save_CFLAGS="$CFLAGS"
685 CFLAGS="$CFLAGS $ARTSC_CFLAGS"
686 AC_CHECK_LIB(artsc,arts_init,
687 [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
688 [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
689 AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
690 AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
691 $ARTSC_LIBS)
692 CFLAGS="$save_CFLAGS"
693 fi
695 dnl **** Check for EsounD ****
696 AC_PATH_PROG(ESDCONFIG, esd-config)
697 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
698 then
699 ESD_CFLAGS=""
700 for i in `$ESDCONFIG --cflags`
701 do
702 case "$i" in
703 -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
704 esac
705 done
706 ESD_LIBS=`$ESDCONFIG --libs`
707 save_CFLAGS="$CFLAGS"
708 CFLAGS="$CFLAGS $ESD_CFLAGS"
709 AC_CHECK_LIB(esd,esd_open_sound,
710 [AC_SUBST(ESDLIBS, $ESD_LIBS)
711 AC_SUBST(ESDINCL, $ESD_CFLAGS)
712 AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
713 CFLAGS="$save_CFLAGS"
714 fi
716 dnl **** Check for ALSA 1.x ****
717 AC_SUBST(ALSALIBS,"")
718 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
719 then
720 AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
721 [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
722 #include <alsa/asoundlib.h>
723 #elif defined(HAVE_SYS_ASOUNDLIB_H)
724 #include <sys/asoundlib.h>
725 #endif],
726 [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
727 [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
728 ALSALIBS="-lasound"])])
729 fi
731 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
733 AC_SUBST(AUDIOIOLIBS,"")
734 if test "$ac_cv_header_libaudioio_h" = "yes"
735 then
736 AC_CHECK_LIB(audioio,AudioIOGetVersion,
737 [AUDIOIOLIBS="-laudioio"
738 AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
739 fi
741 dnl **** Check for capi4linux ****
743 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
744 then
745 AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
746 fi
748 dnl **** Check for gcc specific options ****
750 AC_SUBST(EXTRACFLAGS,"")
751 if test "x${GCC}" = "xyes"
752 then
753 EXTRACFLAGS="-Wall -pipe"
755 dnl Check for strength-reduce bug
756 AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
757 AC_TRY_RUN([
758 int L[[4]] = {0,1,2,3};
759 int main(void) {
760 static int Array[[3]];
761 unsigned int B = 3;
762 int i;
763 for(i=0; i<B; i++) Array[[i]] = i - 3;
764 for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
765 L[[i]] = 4;
767 exit( Array[[1]] != -2 || L[[2]] != 3);
768 }],
769 ac_cv_c_gcc_strength_bug="no",
770 ac_cv_c_gcc_strength_bug="yes",
771 ac_cv_c_gcc_strength_bug="yes") )
772 if test "$ac_cv_c_gcc_strength_bug" = "yes"
773 then
774 EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
775 fi
777 dnl Check for -fshort-wchar
778 AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
779 [WINE_TRY_CFLAGS([-fshort-wchar],
780 ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
781 if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
782 then
783 AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
784 fi
786 dnl Check for -mpreferred-stack-boundary
787 AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
788 [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
789 ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
790 if test "$ac_cv_c_gcc_stack_boundary" = "yes"
791 then
792 EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
793 fi
795 dnl Check for -fno-strict-aliasing
796 AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
797 [WINE_TRY_CFLAGS([-fno-strict-aliasing],
798 ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
799 if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
800 then
801 EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
802 fi
804 dnl Check for -gstabs+ option
805 AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
806 [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
807 if test "$ac_cv_c_gcc_gstabs" = "yes"
808 then
809 EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
810 fi
812 dnl Check for noisy string.h
813 saved_CFLAGS="$CFLAGS"
814 CFLAGS="$CFLAGS -Wpointer-arith -Werror"
815 AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
816 AC_TRY_COMPILE([#include <string.h>],[],
817 [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
818 CFLAGS="$saved_CFLAGS"
819 if test "$ac_cv_c_string_h_warnings" = "no"
820 then
821 EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
822 fi
824 AC_SUBST(BUILTINFLAG,"")
825 saved_CFLAGS="$CFLAGS"
826 CFLAGS="$CFLAGS -Werror"
827 AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
828 AC_TRY_COMPILE([],
829 [int iswlower(unsigned short);],
830 [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
831 CFLAGS="$saved_CFLAGS"
832 if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
833 then
834 BUILTINFLAG=""
835 for builtin in \
836 iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
837 iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
838 do
839 BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
840 done
841 fi
842 fi
844 dnl **** Check how to define a function in assembly code ****
846 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
847 WINE_TRY_ASM_LINK(
848 ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
849 ac_cv_asm_func_def=".def",
850 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
851 ac_cv_asm_func_def=".type @function",
852 [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
853 ac_cv_asm_func_def=".type 2",
854 ac_cv_asm_func_def="unknown")])]))
856 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
857 case "$ac_cv_asm_func_def" in
858 ".def")
859 AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
860 ".type @function")
861 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
862 ".type 2")
863 AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
864 *)
865 AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
866 esac
868 dnl **** Check for underscore on external symbols ****
870 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
871 WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
872 [extern int ac_test;],
873 [if (ac_test) return 1],
874 ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
876 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
877 if test "$ac_cv_c_extern_prefix" = "yes"
878 then
879 AC_DEFINE([__ASM_NAME(name)], ["_" name])
880 else
881 AC_DEFINE([__ASM_NAME(name)], [name])
882 fi
884 dnl **** Check for working dll ****
886 AC_SUBST(DLLEXT,"")
887 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
888 AC_SUBST(DLLIBS,"")
889 AC_SUBST(LDSHARED,"")
890 AC_SUBST(LDDLLFLAGS,"")
891 AC_SUBST(LIBEXT,"so")
892 AC_SUBST(IMPLIBEXT,"def")
894 case $host_os in
895 cygwin*|mingw32*)
896 AC_CHECK_TOOL(DLLTOOL,dlltool,false)
897 AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
898 if test "$DLLWRAP" = "false"; then
899 LIBEXT="a"
900 else
901 dnl FIXME - check whether dllwrap works correctly...
902 LIBEXT="dll"
903 fi
904 IMPLIBEXT="a"
905 dnl We can't build 16-bit NE dlls
906 WIN16_FILES=""
907 WIN16_INSTALL=""
908 ;;
909 *)
910 if test "$ac_cv_header_dlfcn_h" = "yes"
911 then
912 AC_CHECK_FUNCS(dlopen,,
913 [AC_CHECK_LIB(dl,dlopen,
914 [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
915 DLLIBS="-ldl"],
916 [LIBEXT="a"])])
917 else
918 LIBEXT="a"
919 fi
921 if test "$LIBEXT" = "so"
922 then
923 DLLFLAGS="$DLLFLAGS -fPIC"
924 DLLEXT=".so"
925 AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
926 [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
927 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
928 if test "$ac_cv_c_dll_gnuelf" = "yes"
929 then
930 LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
931 LDDLLFLAGS="-shared -Wl,-Bsymbolic"
932 AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
933 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
934 ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
935 if test "$ac_cv_c_dll_zdefs" = "yes"
936 then
937 LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
938 fi
940 AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
941 [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
942 ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
943 if test "$ac_cv_c_dll_init_fini" = "yes"
944 then
945 LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
946 fi
948 AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
949 [echo '{ global: *; };' >conftest.map
950 WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
951 ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
952 rm -f conftest.map])
953 if test "$ac_cv_c_ld_version_scripts" = "yes"
954 then
955 LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
956 fi
958 AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
959 [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
960 ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
961 if test "$ac_cv_c_export_dynamic" = "yes"
962 then
963 AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
964 fi
966 case $host_cpu in
967 *i[[3456789]]86*)
968 AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
969 [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
970 ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
971 if test "$ac_cv_ld_reloc_exec" = "yes"
972 then
973 LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
974 fi
975 ;;
976 esac
978 else
979 AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
980 [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
981 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
982 if test "$ac_cv_c_dll_unixware" = "yes"
983 then
984 LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
985 LDDLLFLAGS="-Wl,-G,-B,symbolic"
987 else
988 AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
989 [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
990 if test "$ac_cv_c_dll_macho" = "yes"
991 then
992 LIBEXT="dylib"
993 LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
994 LDSHARED="\$(CC) -dynamiclib"
995 CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
996 STRIP="$STRIP -u -r"
997 dnl Relocate wine executable
998 AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
999 dnl Relocate libwine.dyld too
1000 AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1001 dnl declare needed frameworks
1002 AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1003 AC_SUBST(IOKITLIB,"-framework IOKit")
1004 dnl using IOKit imply we use CoreFoundation too
1005 IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1006 else
1007 AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1008 [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1009 if test "$ac_cv_c_dll_hpux" = "yes"
1010 then
1011 LIBEXT="sl"
1012 DLLEXT=".sl"
1013 LDDLLFLAGS="-shared -fPIC"
1014 LDSHARED="\$(CC) -shared"
1015 fi
1016 fi
1017 fi
1018 fi
1019 fi
1021 dnl Check for cross compiler to build test programs
1022 AC_SUBST(CROSSTEST,"")
1023 if test "$cross_compiling" = "no"
1024 then
1025 AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1026 AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1027 AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1028 if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1029 fi
1030 ;;
1031 esac
1033 if test "$LIBEXT" = "a"; then
1034 AC_MSG_ERROR(
1035 [could not find a way to build shared libraries.
1036 It is currently not possible to build Wine without shared library
1037 (.so) support to allow transparent switch between .so and .dll files.
1038 If you are using Linux, you will need a newer binutils.]
1039 )
1040 fi
1042 case $build_os in
1043 cygwin*|mingw32*)
1044 AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1045 darwin*|macosx*)
1046 AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1047 *)
1048 AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1049 esac
1051 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1052 case $host_os in
1053 mingw32*)
1054 AC_SUBST(CRTLIBS,"-lmsvcrt")
1055 AC_SUBST(SOCKETLIBS,"-lws2_32")
1056 ;;
1057 esac
1059 case $host_os in
1060 linux*)
1061 case $host_cpu in
1062 *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1063 *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1064 esac
1065 AC_SUBST(MAIN_BINARY,"wine-glibc")
1066 ;;
1067 darwin*)
1068 AC_SUBST(WINE_BINARIES,"wine-pthread")
1069 AC_SUBST(MAIN_BINARY,"wine-pthread")
1070 ;;
1071 *)
1072 AC_SUBST(WINE_BINARIES,"wine-kthread")
1073 AC_SUBST(MAIN_BINARY,"wine-kthread")
1074 ;;
1075 esac
1077 dnl **** Get the soname for libraries that we load dynamically ****
1079 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1080 then
1081 WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1082 WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1083 WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1084 WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1085 WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1086 WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1087 WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1088 WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1089 WINE_GET_SONAME(cups,cupsGetDefault)
1090 WINE_GET_SONAME(jack,jack_client_new)
1091 WINE_GET_SONAME(fontconfig,FcInit)
1092 WINE_GET_SONAME(ssl,SSL_library_init)
1093 WINE_GET_SONAME(crypto,BIO_new_socket)
1094 WINE_GET_SONAME(ncurses,waddch)
1095 WINE_GET_SONAME(curses,waddch)
1096 WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1097 WINE_GET_SONAME(ungif,DGifOpen)
1098 WINE_GET_SONAME(gif,DGifOpen)
1099 WINE_GET_SONAME(capi20,capi20_isinstalled)
1100 fi
1103 dnl **** Check for functions ****
1105 AC_CHECK_FUNCS(\
1106 _lwp_create \
1107 _lwp_self \
1108 _pclose \
1109 _popen \
1110 _snprintf \
1111 _spawnvp \
1112 _stricmp \
1113 _strnicmp \
1114 _vsnprintf \
1115 chsize \
1116 clone \
1117 epoll_create \
1118 ffs \
1119 finite \
1120 fork \
1121 fpclass \
1122 fstatfs \
1123 fstatvfs \
1124 ftruncate \
1125 futimes \
1126 futimesat \
1127 getnetbyname \
1128 getopt_long \
1129 getpagesize \
1130 getprotobyname \
1131 getprotobynumber \
1132 getpwuid \
1133 getservbyport \
1134 gettid \
1135 gettimeofday \
1136 getuid \
1137 inet_network \
1138 lstat \
1139 memmove \
1140 mmap \
1141 pclose \
1142 popen \
1143 pread \
1144 pwrite \
1145 readlink \
1146 rfork \
1147 sched_yield \
1148 select \
1149 sendmsg \
1150 settimeofday \
1151 sigaltstack \
1152 sigprocmask \
1153 snprintf \
1154 spawnvp \
1155 statfs \
1156 statvfs \
1157 strcasecmp \
1158 strerror \
1159 strncasecmp \
1160 tcgetattr \
1161 timegm \
1162 usleep \
1163 vsnprintf \
1164 wait4 \
1165 waitpid \
1166 )
1168 dnl **** Checks for headers that depend on other ones ****
1170 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1171 [#include <sys/types.h>
1172 #if HAVE_SYS_PARAM_H
1173 # include <sys/param.h>
1174 #endif])
1176 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1177 [#include <sys/types.h>
1178 #if HAVE_SYS_SOCKET_H
1179 # include <sys/socket.h>
1180 #endif])
1182 AC_CHECK_HEADERS([resolv.h],,,
1183 [#include <sys/types.h>
1184 #if HAVE_SYS_SOCKET_H
1185 # include <sys/socket.h>
1186 #endif
1187 #if HAVE_NETINET_IN_H
1188 # include <netinet/in.h>
1189 #endif
1190 #if HAVE_ARPA_NAMESER_H
1191 # include <arpa/nameser.h>
1192 #endif])
1194 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1196 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1197 [#ifdef HAVE_SYS_TIME_H
1198 #include <sys/time.h>
1199 #endif
1200 #include <sys/types.h>
1201 #ifdef HAVE_ASM_TYPES_H
1202 #include <asm/types.h>
1203 #endif])
1205 dnl **** Check for types ****
1207 AC_C_CONST
1208 AC_C_INLINE
1209 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1210 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1211 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1213 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1214 [#ifdef HAVE_LINUX_INPUT_H
1215 #include <linux/input.h>
1216 #endif])
1218 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1219 AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1220 wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1221 if test "$wine_cv_have_sigaddset" = "yes"
1222 then
1223 AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1224 fi
1227 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1228 wine_cv_linux_gethostbyname_r_6,
1229 AC_TRY_LINK([
1230 #include <netdb.h>
1231 ], [
1232 char *name=NULL;
1233 struct hostent he;
1234 struct hostent *result;
1235 char *buf=NULL;
1236 int bufsize=0;
1237 int res,errnr;
1238 char *addr=NULL;
1239 int addrlen=0;
1240 int addrtype=0;
1241 res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1242 res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1243 ],
1244 wine_cv_linux_gethostbyname_r_6=yes,
1245 wine_cv_linux_gethostbyname_r_6=no
1246 )
1247 )
1248 if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1249 then
1250 AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1251 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1252 fi
1254 if test "$ac_cv_header_linux_joystick_h" = "yes"
1255 then
1256 AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1257 wine_cv_linux_joystick_22_api,
1258 AC_TRY_COMPILE([
1259 #include <sys/ioctl.h>
1260 #include <linux/joystick.h>
1262 struct js_event blub;
1263 #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1264 #error "no 2.2 header"
1265 #endif
1266 ],/*empty*/,
1267 wine_cv_linux_joystick_22_api=yes,
1268 wine_cv_linux_joystick_22_api=no,
1269 wine_cv_linux_joystick_22_api=no
1270 )
1271 )
1272 if test "$wine_cv_linux_joystick_22_api" = "yes"
1273 then
1274 AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1275 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1276 fi
1277 fi
1279 dnl **** statfs checks ****
1281 if test "$ac_cv_header_sys_vfs_h" = "yes"
1282 then
1283 AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1284 wine_cv_sys_vfs_has_statfs,
1285 AC_TRY_COMPILE([
1286 #include <sys/types.h>
1287 #ifdef HAVE_SYS_PARAM_H
1288 # include <sys/param.h>
1289 #endif
1290 #include <sys/vfs.h>
1291 ],[
1292 struct statfs stfs;
1294 memset(&stfs,0,sizeof(stfs));
1295 ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1296 )
1297 )
1298 if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1299 then
1300 AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1301 [Define if the struct statfs is defined by <sys/vfs.h>])
1302 fi
1303 fi
1305 if test "$ac_cv_header_sys_statfs_h" = "yes"
1306 then
1307 AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1308 wine_cv_sys_statfs_has_statfs,
1309 AC_TRY_COMPILE([
1310 #include <sys/types.h>
1311 #ifdef HAVE_SYS_PARAM_H
1312 # include <sys/param.h>
1313 #endif
1314 #include <sys/statfs.h>
1315 ],[
1316 struct statfs stfs;
1317 ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1318 )
1319 )
1320 if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1321 then
1322 AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1323 [Define if the struct statfs is defined by <sys/statfs.h>])
1324 fi
1325 fi
1327 if test "$ac_cv_header_sys_mount_h" = "yes"
1328 then
1329 AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1330 wine_cv_sys_mount_has_statfs,
1331 AC_TRY_COMPILE([
1332 #include <sys/types.h>
1333 #ifdef HAVE_SYS_PARAM_H
1334 # include <sys/param.h>
1335 #endif
1336 #include <sys/mount.h>
1337 ],[
1338 struct statfs stfs;
1339 ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1340 )
1341 )
1342 if test "$wine_cv_sys_mount_has_statfs" = "yes"
1343 then
1344 AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1345 [Define if the struct statfs is defined by <sys/mount.h>])
1346 fi
1347 fi
1349 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1351 dnl Check for statfs members
1352 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1353 [#include <sys/types.h>
1354 #ifdef HAVE_SYS_PARAM_H
1355 # include <sys/param.h>
1356 #endif
1357 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1358 # include <sys/mount.h>
1359 #else
1360 # ifdef STATFS_DEFINED_BY_SYS_VFS
1361 # include <sys/vfs.h>
1362 # else
1363 # ifdef STATFS_DEFINED_BY_SYS_STATFS
1364 # include <sys/statfs.h>
1365 # endif
1366 # endif
1367 #endif])
1369 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1370 [#ifdef HAVE_SYS_STATVFS_H
1371 #include <sys/statvfs.h>
1372 #endif])
1374 dnl Check for socket structure members
1375 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1376 [#include <sys/types.h>
1377 #ifdef HAVE_SYS_SOCKET_H
1378 # include <sys/socket.h>
1379 #endif
1380 #ifdef HAVE_SYS_UN_H
1381 # include <sys/un.h>
1382 #endif])
1384 dnl Check for scsireq_t and sg_io_hdr_t members
1385 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1386 [#include <sys/types.h>
1387 #ifdef HAVE_SCSI_SG_H
1388 #include <scsi/sg.h>
1389 #endif])
1391 dnl Check for siginfo_t members
1392 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1394 dnl Check for struct option
1395 AC_CHECK_MEMBERS([struct option.name],,,
1396 [#ifdef HAVE_GETOPT_H
1397 #include <getopt.h>
1398 #endif])
1400 dnl Check for stat.st_blocks
1401 AC_CHECK_MEMBERS([struct stat.st_blocks])
1403 dnl Check for the external timezone variables timezone and daylight
1404 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1405 AC_TRY_LINK([#include <time.h>],[timezone;],
1406 ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1407 if test "$ac_cv_have_timezone" = "yes"
1408 then
1409 AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1410 fi
1411 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1412 AC_TRY_LINK([#include <time.h>],[daylight;],
1413 ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1414 if test "$ac_cv_have_daylight" = "yes"
1415 then
1416 AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1417 fi
1419 dnl *** check for the need to define platform-specific symbols
1421 case $host_cpu in
1422 *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1423 *alpha*) WINE_CHECK_DEFINE([__ALPHA__]) ;;
1424 *sparc*) WINE_CHECK_DEFINE([__sparc__]) ;;
1425 *powerpc*) WINE_CHECK_DEFINE([__powerpc__]) ;;
1426 esac
1428 case $host_vendor in
1429 *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1430 esac
1432 dnl **** Generate output files ****
1434 AH_TOP([#define __WINE_CONFIG_H])
1436 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1437 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1438 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1439 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1440 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1441 WINE_CONFIG_EXTRA_DIR(include/wine)
1443 MAKE_RULES=Make.rules
1444 AC_SUBST_FILE(MAKE_RULES)
1446 MAKE_DLL_RULES=dlls/Makedll.rules
1447 AC_SUBST_FILE(MAKE_DLL_RULES)
1449 MAKE_TEST_RULES=dlls/Maketest.rules
1450 AC_SUBST_FILE(MAKE_TEST_RULES)
1452 MAKE_LIB_RULES=libs/Makelib.rules
1453 AC_SUBST_FILE(MAKE_LIB_RULES)
1455 MAKE_PROG_RULES=programs/Makeprog.rules
1456 AC_SUBST_FILE(MAKE_PROG_RULES)
1458 AC_CONFIG_FILES([
1459 Make.rules
1460 dlls/Makedll.rules
1461 dlls/Maketest.rules
1462 libs/Makelib.rules
1463 programs/Makeprog.rules
1464 Makefile
1465 dlls/Makefile
1466 dlls/activeds/Makefile
1467 dlls/advapi32/Makefile
1468 dlls/advapi32/tests/Makefile
1469 dlls/advpack/Makefile
1470 dlls/advpack/tests/Makefile
1471 dlls/amstream/Makefile
1472 dlls/atl/Makefile
1473 dlls/avicap32/Makefile
1474 dlls/avifil32/Makefile
1475 dlls/cabinet/Makefile
1476 dlls/capi2032/Makefile
1477 dlls/cards/Makefile
1478 dlls/cfgmgr32/Makefile
1479 dlls/comcat/Makefile
1480 dlls/comctl32/Makefile
1481 dlls/comctl32/tests/Makefile
1482 dlls/commdlg/Makefile
1483 dlls/crtdll/Makefile
1484 dlls/crypt32/Makefile
1485 dlls/crypt32/tests/Makefile
1486 dlls/cryptdll/Makefile
1487 dlls/ctl3d/Makefile
1488 dlls/d3d8/Makefile
1489 dlls/d3d9/Makefile
1490 dlls/d3dim/Makefile
1491 dlls/d3drm/Makefile
1492 dlls/d3dx8/Makefile
1493 dlls/d3dxof/Makefile
1494 dlls/dbghelp/Makefile
1495 dlls/dciman32/Makefile
1496 dlls/ddraw/Makefile
1497 dlls/ddraw/tests/Makefile
1498 dlls/devenum/Makefile
1499 dlls/dinput/Makefile
1500 dlls/dinput/tests/Makefile
1501 dlls/dinput8/Makefile
1502 dlls/dmband/Makefile
1503 dlls/dmcompos/Makefile
1504 dlls/dmime/Makefile
1505 dlls/dmloader/Makefile
1506 dlls/dmscript/Makefile
1507 dlls/dmstyle/Makefile
1508 dlls/dmsynth/Makefile
1509 dlls/dmusic/Makefile
1510 dlls/dmusic32/Makefile
1511 dlls/dplay/Makefile
1512 dlls/dplayx/Makefile
1513 dlls/dpnet/Makefile
1514 dlls/dpnhpast/Makefile
1515 dlls/dsound/Makefile
1516 dlls/dsound/tests/Makefile
1517 dlls/dswave/Makefile
1518 dlls/dxdiagn/Makefile
1519 dlls/dxerr8/Makefile
1520 dlls/dxerr9/Makefile
1521 dlls/dxguid/Makefile
1522 dlls/gdi/Makefile
1523 dlls/gdi/tests/Makefile
1524 dlls/glu32/Makefile
1525 dlls/glut32/Makefile
1526 dlls/hhctrl.ocx/Makefile
1527 dlls/iccvid/Makefile
1528 dlls/icmp/Makefile
1529 dlls/ifsmgr.vxd/Makefile
1530 dlls/imagehlp/Makefile
1531 dlls/imm32/Makefile
1532 dlls/iphlpapi/Makefile
1533 dlls/iphlpapi/tests/Makefile
1534 dlls/itss/Makefile
1535 dlls/kernel/Makefile
1536 dlls/kernel/tests/Makefile
1537 dlls/lzexpand/Makefile
1538 dlls/lzexpand/tests/Makefile
1539 dlls/mapi32/Makefile
1540 dlls/mapi32/tests/Makefile
1541 dlls/mcicda/Makefile
1542 dlls/mciseq/Makefile
1543 dlls/midimap/Makefile
1544 dlls/mlang/Makefile
1545 dlls/mlang/tests/Makefile
1546 dlls/mmdevldr.vxd/Makefile
1547 dlls/monodebg.vxd/Makefile
1548 dlls/mpr/Makefile
1549 dlls/msacm/Makefile
1550 dlls/msacm/imaadp32/Makefile
1551 dlls/msacm/msadp32/Makefile
1552 dlls/msacm/msg711/Makefile
1553 dlls/msacm/tests/Makefile
1554 dlls/msacm/winemp3/Makefile
1555 dlls/mscms/Makefile
1556 dlls/mscms/tests/Makefile
1557 dlls/msdmo/Makefile
1558 dlls/mshtml/Makefile
1559 dlls/mshtml/tests/Makefile
1560 dlls/msi/Makefile
1561 dlls/msi/tests/Makefile
1562 dlls/msimg32/Makefile
1563 dlls/msisys/Makefile
1564 dlls/msnet32/Makefile
1565 dlls/msrle32/Makefile
1566 dlls/msvcrt/Makefile
1567 dlls/msvcrt/tests/Makefile
1568 dlls/msvcrt20/Makefile
1569 dlls/msvcrt40/Makefile
1570 dlls/msvcrtd/Makefile
1571 dlls/msvcrtd/tests/Makefile
1572 dlls/msvidc32/Makefile
1573 dlls/msvideo/Makefile
1574 dlls/mswsock/Makefile
1575 dlls/msxml3/Makefile
1576 dlls/msxml3/tests/Makefile
1577 dlls/netapi32/Makefile
1578 dlls/netapi32/tests/Makefile
1579 dlls/newdev/Makefile
1580 dlls/ntdll/Makefile
1581 dlls/ntdll/tests/Makefile
1582 dlls/objsel/Makefile
1583 dlls/odbc32/Makefile
1584 dlls/odbccp32/Makefile
1585 dlls/ole32/Makefile
1586 dlls/ole32/tests/Makefile
1587 dlls/oleacc/Makefile
1588 dlls/oleaut32/Makefile
1589 dlls/oleaut32/tests/Makefile
1590 dlls/olecli/Makefile
1591 dlls/oledlg/Makefile
1592 dlls/olepro32/Makefile
1593 dlls/olesvr/Makefile
1594 dlls/opengl32/Makefile
1595 dlls/powrprof/Makefile
1596 dlls/psapi/Makefile
1597 dlls/psapi/tests/Makefile
1598 dlls/qcap/Makefile
1599 dlls/quartz/Makefile
1600 dlls/quartz/tests/Makefile
1601 dlls/rasapi32/Makefile
1602 dlls/riched20/Makefile
1603 dlls/richedit/Makefile
1604 dlls/rpcrt4/Makefile
1605 dlls/rpcrt4/tests/Makefile
1606 dlls/rsabase/Makefile
1607 dlls/rsabase/tests/Makefile
1608 dlls/rsaenh/Makefile
1609 dlls/rsaenh/tests/Makefile
1610 dlls/secur32/Makefile
1611 dlls/secur32/tests/Makefile
1612 dlls/sensapi/Makefile
1613 dlls/serialui/Makefile
1614 dlls/setupapi/Makefile
1615 dlls/shdocvw/Makefile
1616 dlls/shell32/Makefile
1617 dlls/shell32/tests/Makefile
1618 dlls/shfolder/Makefile
1619 dlls/shlwapi/Makefile
1620 dlls/shlwapi/tests/Makefile
1621 dlls/snmpapi/Makefile
1622 dlls/stdole2.tlb/Makefile
1623 dlls/stdole32.tlb/Makefile
1624 dlls/sti/Makefile
1625 dlls/strmiids/Makefile
1626 dlls/tapi32/Makefile
1627 dlls/ttydrv/Makefile
1628 dlls/twain/Makefile
1629 dlls/unicows/Makefile
1630 dlls/url/Makefile
1631 dlls/urlmon/Makefile
1632 dlls/urlmon/tests/Makefile
1633 dlls/user/Makefile
1634 dlls/user/tests/Makefile
1635 dlls/usp10/Makefile
1636 dlls/uuid/Makefile
1637 dlls/uxtheme/Makefile
1638 dlls/vdhcp.vxd/Makefile
1639 dlls/vdmdbg/Makefile
1640 dlls/version/Makefile
1641 dlls/version/tests/Makefile
1642 dlls/vmm.vxd/Makefile
1643 dlls/vnbt.vxd/Makefile
1644 dlls/vnetbios.vxd/Makefile
1645 dlls/vtdapi.vxd/Makefile
1646 dlls/vwin32.vxd/Makefile
1647 dlls/win32s/Makefile
1648 dlls/winaspi/Makefile
1649 dlls/wined3d/Makefile
1650 dlls/winedos/Makefile
1651 dlls/wineps/Makefile
1652 dlls/wininet/Makefile
1653 dlls/wininet/tests/Makefile
1654 dlls/winmm/Makefile
1655 dlls/winmm/joystick/Makefile
1656 dlls/winmm/mcianim/Makefile
1657 dlls/winmm/mciavi/Makefile
1658 dlls/winmm/mciwave/Makefile
1659 dlls/winmm/tests/Makefile
1660 dlls/winmm/wavemap/Makefile
1661 dlls/winmm/winealsa/Makefile
1662 dlls/winmm/winearts/Makefile
1663 dlls/winmm/wineaudioio/Makefile
1664 dlls/winmm/wineesd/Makefile
1665 dlls/winmm/winejack/Makefile
1666 dlls/winmm/winenas/Makefile
1667 dlls/winmm/wineoss/Makefile
1668 dlls/winnls/Makefile
1669 dlls/winsock/Makefile
1670 dlls/winsock/tests/Makefile
1671 dlls/winspool/Makefile
1672 dlls/winspool/tests/Makefile
1673 dlls/wintab32/Makefile
1674 dlls/wintrust/Makefile
1675 dlls/wldap32/Makefile
1676 dlls/wow32/Makefile
1677 dlls/wsock32/Makefile
1678 dlls/wtsapi32/Makefile
1679 dlls/x11drv/Makefile
1680 documentation/Makefile
1681 fonts/Makefile
1682 include/Makefile
1683 libs/Makefile
1684 libs/port/Makefile
1685 libs/unicode/Makefile
1686 libs/wine/Makefile
1687 libs/wpp/Makefile
1688 loader/Makefile
1689 programs/Makefile
1690 programs/avitools/Makefile
1691 programs/clock/Makefile
1692 programs/cmdlgtst/Makefile
1693 programs/control/Makefile
1694 programs/expand/Makefile
1695 programs/hh/Makefile
1696 programs/msiexec/Makefile
1697 programs/notepad/Makefile
1698 programs/progman/Makefile
1699 programs/regedit/Makefile
1700 programs/regsvr32/Makefile
1701 programs/rpcss/Makefile
1702 programs/rundll32/Makefile
1703 programs/start/Makefile
1704 programs/taskmgr/Makefile
1705 programs/uninstaller/Makefile
1706 programs/view/Makefile
1707 programs/wcmd/Makefile
1708 programs/wineboot/Makefile
1709 programs/winebrowser/Makefile
1710 programs/winecfg/Makefile
1711 programs/wineconsole/Makefile
1712 programs/winedbg/Makefile
1713 programs/winefile/Makefile
1714 programs/winemenubuilder/Makefile
1715 programs/winemine/Makefile
1716 programs/winepath/Makefile
1717 programs/winetest/Makefile
1718 programs/winevdm/Makefile
1719 programs/winhelp/Makefile
1720 programs/winver/Makefile
1721 server/Makefile
1722 tools/Makefile
1723 tools/widl/Makefile
1724 tools/winapi/Makefile
1725 tools/winebuild/Makefile
1726 tools/winedump/Makefile
1727 tools/winegcc/Makefile
1728 tools/wmc/Makefile
1729 tools/wrc/Makefile])
1731 AC_OUTPUT
1733 if test "$have_x" = "no"
1734 then
1735 echo
1736 echo "*** Warning: X development files not found. Wine will be built without"
1737 echo "*** X support, which currently does not work, and would probably not be"
1738 echo "*** what you want anyway. You will need to install devel packages of"
1739 echo "*** Xlib/Xfree86 at the very least."
1740 fi
1742 if test "$wine_cv_opengl_version_OK" = "no"
1743 then
1744 echo
1745 echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1746 echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1747 fi
1749 if test "$wine_cv_msg_freetype" = "yes"
1750 then
1751 echo
1752 echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1753 echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1754 echo "*** freetype-devel package (or its equivalent on your distribution) to"
1755 echo "*** enable Wine to use TrueType fonts."
1756 fi
1758 if test -z "$ALSALIBS" -a \
1759 -z "$ARTSC_LIBS" -a \
1760 -z "$AUDIOIOLIBS" -a \
1761 -z "$NASLIBS" -a \
1762 -z "$ESD_LIBS" -a \
1763 -z "$ac_cv_lib_soname_jack" -a \
1764 "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1765 "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1766 "$ac_cv_header_soundcard_h" != "yes"
1767 then
1768 echo "*** No sound system was found. Windows applications will be silent."
1769 echo "*** The currently supported sound systems are:"
1770 echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1771 fi
1773 echo
1774 echo "Configure finished. Do '${ac_make} depend && ${ac_make}' to compile Wine."
1775 echo
1777 dnl Local Variables:
1778 dnl comment-start: "dnl "
1779 dnl comment-end: ""
1780 dnl comment-start-skip: "\\bdnl\\b\\s *"
1781 dnl compile-command: "autoconf"
1782 dnl End: