src/lib/Torrus/DevDiscover/Xylan.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id$
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 # Xylan (Alcatel) switch discovery.
  21
  22 # Tested with:
  23 #
  24 # Xylan OmniSwitch 9x
  25 # Xylan OmniStack 5024
  26 # Switch software: X/OS 4.3.3
  27 #
  28 # Virtual ports are not processed yet
  29
  30
  31 package Torrus::DevDiscover::Xylan;
  32
  33 use strict;
  34 use warnings;
  35
  36 use Torrus::Log;
  37
  38 our $VERSION = 1.0;
  39
  40 $Torrus::DevDiscover::registry{'Xylan'} = {
  41     'sequence'     => 500,
  42     'checkdevtype' => \&checkdevtype,
  43     'discover'     => \&discover,
  44     'buildConfig'  => \&buildConfig
  45     };
  46
  47
  48 our %oiddef =
  49     (
  50      # XYLAN-BASE-MIB
  51      'xylanSwitchDevice'           => '1.3.6.1.4.1.800.3.1.1',
  52      # PORT-MIB::phyPortTable
  53      'xylanPhyPortTable'           => '1.3.6.1.4.1.800.2.3.3.1',
  54      # PORT-MIB::phyPortDescription
  55      'xylanPhyPortDescription'     => '1.3.6.1.4.1.800.2.3.3.1.1.4',
  56      # PORT-MIB::phyPortToInterface
  57      'xylanPhyPortToInterface'     => '1.3.6.1.4.1.800.2.3.3.1.1.19'
  58      );
  59
  60 # Not all interfaces are normally needed to monitor.
  61 # You may override the interface filtering in devdiscover-siteconfig.pl:
  62 # redefine $Torrus::DevDiscover::Xylan::interfaceFilter
  63 # or define $Torrus::DevDiscover::Xylan::interfaceFilterOverlay
  64
  65 our $interfaceFilter;
  66 our $interfaceFilterOverlay;
  67 my %xylInterfaceFilter;
  68
  69 if( not defined( $interfaceFilter ) )
  70 {
  71     $interfaceFilter = \%xylInterfaceFilter;
  72 }
  73
  74
  75 # Key is some unique symbolic name, does not mean anything
  76 # ifType is the number to match the interface type
  77 # ifDescr is the regexp to match the interface description
  78 %xylInterfaceFilter =
  79     (
  80      'vnN' => {
  81          'ifType'  => 53                     # propVirtual
  82          },
  83      'loN' => {
  84          'ifType'  => 24                     # softwareLoopback
  85          }
  86      );
  87
  88 sub checkdevtype
  89 {
  90     my $dd = shift;
  91     my $devdetails = shift;
  92
  93     if( not $dd->oidBaseMatch
  94         ( 'xylanSwitchDevice',
  95           $devdetails->snmpVar( $dd->oiddef('sysObjectID') ) ) )
  96     {
  97         return 0;
  98     }
  99
 100     &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
 101         ($devdetails, $interfaceFilter);
 102
 103     if( defined( $interfaceFilterOverlay ) )
 104     {
 105         &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
 106             ($devdetails, $interfaceFilterOverlay);
 107     }
 108
 109     $devdetails->setCap('interfaceIndexingPersistent');
 110
 111     return 1;
 112 }
 113
 114
 115 sub discover
 116 {
 117     my $dd = shift;
 118     my $devdetails = shift;
 119
 120     my $data = $devdetails->data();
 121     my $session = $dd->session();
 122
 123     $data->{'nameref'}{'ifNick'}        = 'xylanInterfaceNick';
 124     $data->{'nameref'}{'ifSubtreeName'} = 'xylanInterfaceNick';
 125     $data->{'nameref'}{'ifComment'}     = 'xylanInterfaceComment';
 126     $data->{'nameref'}{'ifReferenceName'}   = 'xylanInterfaceHumanName';
 127
 128     my $phyPortTable =
 129         $session->get_table( -baseoid => $dd->oiddef('xylanPhyPortTable') );
 130
 131     if( not defined $phyPortTable )
 132     {
 133         Error('Error retrieving PORT-MIB::phyPortTable from Xylan device');
 134         return 0;
 135     }
 136
 137     $devdetails->storeSnmpVars( $phyPortTable );
 138
 139     for my $slotDotPort
 140         ( $devdetails->
 141           getSnmpIndices( $dd->oiddef('xylanPhyPortDescription') ) )
 142     {
 143         my ( $slot, $port ) = split( '\.', $slotDotPort );
 144
 145         my $ifIndex =
 146             $devdetails->snmpVar($dd->oiddef('xylanPhyPortToInterface') .
 147                                  '.' . $slotDotPort);
 148         my $interface = $data->{'interfaces'}{$ifIndex};
 149
 150         if( defined $interface )
 151         {
 152             $interface->{'xylanInterfaceNick'} =
 153                 sprintf( '%d_%d', $slot, $port );
 154
 155             $interface->{'xylanInterfaceHumanName'} =
 156                 sprintf( '%d/%d', $slot, $port );
 157
 158             $interface->{'xylanInterfaceComment'} =
 159                 $devdetails->snmpVar($dd->oiddef('xylanPhyPortDescription') .
 160                                      '.' . $slotDotPort);
 161         }
 162     }
 163
 164     # verify if all interfaces are processed
 165
 166     for my $ifIndex ( keys %{$data->{'interfaces'}} )
 167     {
 168         my $interface = $data->{'interfaces'}{$ifIndex};
 169
 170         if( not defined( $interface->{'xylanInterfaceNick'} ) )
 171         {
 172             Warn('Interface ' . $ifIndex . ' is not in phyPortTable');
 173
 174             my $nick = sprintf( 'PORT%d', $ifIndex );
 175             $interface->{'xylanInterfaceNick'} = $nick;
 176             $interface->{'xylanInterfaceHumanName'} = $nick;
 177
 178             $interface->{'xylanInterfaceComment'} = $interface->{'ifDescr'};
 179         }
 180     }
 181
 182     return 1;
 183 }
 184
 185
 186 sub buildConfig
 187 {
 188     my $devdetails = shift;
 189     my $cb = shift;
 190     my $devNode = shift;
 191     return;
 192 }
 193
 194
 195 1;
 196
 197
 198 # Local Variables:
 199 # mode: perl
 200 # indent-tabs-mode: nil
 201 # perl-indent-level: 4
 202 # End: