src/lib/Torrus/DevDiscover/Xylan.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  18
  19 # Xylan (Alcatel) switch discovery.
  20
  21 # Tested with:
  22 #
  23 # Xylan OmniSwitch 9x
  24 # Xylan OmniStack 5024
  25 # Switch software: X/OS 4.3.3
  26 #
  27 # Virtual ports are not processed yet
  28
  29
  30 package Torrus::DevDiscover::Xylan;
  31
  32 use strict;
  33 use warnings;
  34
  35 use Torrus::Log;
  36
  37 our $VERSION = 1.0;
  38
  39 $Torrus::DevDiscover::registry{'Xylan'} = {
  40     'sequence'     => 500,
  41     'checkdevtype' => \&checkdevtype,
  42     'discover'     => \&discover,
  43     'buildConfig'  => \&buildConfig
  44     };
  45
  46
  47 our %oiddef =
  48     (
  49      # XYLAN-BASE-MIB
  50      'xylanSwitchDevice'           => '1.3.6.1.4.1.800.3.1.1',
  51      # PORT-MIB::phyPortTable
  52      'xylanPhyPortTable'           => '1.3.6.1.4.1.800.2.3.3.1',
  53      # PORT-MIB::phyPortDescription
  54      'xylanPhyPortDescription'     => '1.3.6.1.4.1.800.2.3.3.1.1.4',
  55      # PORT-MIB::phyPortToInterface
  56      'xylanPhyPortToInterface'     => '1.3.6.1.4.1.800.2.3.3.1.1.19'
  57      );
  58
  59 # Not all interfaces are normally needed to monitor.
  60 # You may override the interface filtering in devdiscover-siteconfig.pl:
  61 # redefine $Torrus::DevDiscover::Xylan::interfaceFilter
  62 # or define $Torrus::DevDiscover::Xylan::interfaceFilterOverlay
  63
  64 our $interfaceFilter;
  65 our $interfaceFilterOverlay;
  66 my %xylInterfaceFilter;
  67
  68 if( not defined( $interfaceFilter ) )
  69 {
  70     $interfaceFilter = \%xylInterfaceFilter;
  71 }
  72
  73
  74 # Key is some unique symbolic name, does not mean anything
  75 # ifType is the number to match the interface type
  76 # ifDescr is the regexp to match the interface description
  77 %xylInterfaceFilter =
  78     (
  79      'vnN' => {
  80          'ifType'  => 53                     # propVirtual
  81          },
  82      'loN' => {
  83          'ifType'  => 24                     # softwareLoopback
  84          }
  85      );
  86
  87 sub checkdevtype
  88 {
  89     my $dd = shift;
  90     my $devdetails = shift;
  91
  92     if( not $dd->oidBaseMatch
  93         ( 'xylanSwitchDevice',
  94           $devdetails->snmpVar( $dd->oiddef('sysObjectID') ) ) )
  95     {
  96         return 0;
  97     }
  98
  99     &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
 100         ($devdetails, $interfaceFilter);
 101
 102     if( defined( $interfaceFilterOverlay ) )
 103     {
 104         &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
 105             ($devdetails, $interfaceFilterOverlay);
 106     }
 107
 108     $devdetails->setCap('interfaceIndexingPersistent');
 109
 110     return 1;
 111 }
 112
 113
 114 sub discover
 115 {
 116     my $dd = shift;
 117     my $devdetails = shift;
 118
 119     my $data = $devdetails->data();
 120     my $session = $dd->session();
 121
 122     $data->{'nameref'}{'ifNick'}        = 'xylanInterfaceNick';
 123     $data->{'nameref'}{'ifSubtreeName'} = 'xylanInterfaceNick';
 124     $data->{'nameref'}{'ifComment'}     = 'xylanInterfaceComment';
 125     $data->{'nameref'}{'ifReferenceName'}   = 'xylanInterfaceHumanName';
 126
 127     my $phyPortTable =
 128         $session->get_table( -baseoid => $dd->oiddef('xylanPhyPortTable') );
 129
 130     if( not defined $phyPortTable )
 131     {
 132         Error('Error retrieving PORT-MIB::phyPortTable from Xylan device');
 133         return 0;
 134     }
 135
 136     $devdetails->storeSnmpVars( $phyPortTable );
 137
 138     for my $slotDotPort
 139         ( $devdetails->
 140           getSnmpIndices( $dd->oiddef('xylanPhyPortDescription') ) )
 141     {
 142         my ( $slot, $port ) = split( '\.', $slotDotPort );
 143
 144         my $ifIndex =
 145             $devdetails->snmpVar($dd->oiddef('xylanPhyPortToInterface') .
 146                                  '.' . $slotDotPort);
 147         my $interface = $data->{'interfaces'}{$ifIndex};
 148
 149         if( defined $interface )
 150         {
 151             $interface->{'xylanInterfaceNick'} =
 152                 sprintf( '%d_%d', $slot, $port );
 153
 154             $interface->{'xylanInterfaceHumanName'} =
 155                 sprintf( '%d/%d', $slot, $port );
 156
 157             $interface->{'xylanInterfaceComment'} =
 158                 $devdetails->snmpVar($dd->oiddef('xylanPhyPortDescription') .
 159                                      '.' . $slotDotPort);
 160         }
 161     }
 162
 163     # verify if all interfaces are processed
 164
 165     for my $ifIndex ( keys %{$data->{'interfaces'}} )
 166     {
 167         my $interface = $data->{'interfaces'}{$ifIndex};
 168
 169         if( not defined( $interface->{'xylanInterfaceNick'} ) )
 170         {
 171             Warn('Interface ' . $ifIndex . ' is not in phyPortTable');
 172
 173             my $nick = sprintf( 'PORT%d', $ifIndex );
 174             $interface->{'xylanInterfaceNick'} = $nick;
 175             $interface->{'xylanInterfaceHumanName'} = $nick;
 176
 177             $interface->{'xylanInterfaceComment'} = $interface->{'ifDescr'};
 178         }
 179     }
 180
 181     return 1;
 182 }
 183
 184
 185 sub buildConfig
 186 {
 187     my $devdetails = shift;
 188     my $cb = shift;
 189     my $devNode = shift;
 190     return;
 191 }
 192
 193
 194 1;
 195
 196
 197 # Local Variables:
 198 # mode: perl
 199 # indent-tabs-mode: nil
 200 # perl-indent-level: 4
 201 # End: