?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
runkernel: remove debugging code
[syslinux.git] / pxelinux.asm
blob7a5391e984d5132de18554667e008e2d315b11c6
1 ; -*- fundamental -*- (asm-mode sucks)
2 ; ****************************************************************************
3 ;
4 ; pxelinux.asm
5 ;
6 ; A program to boot Linux kernels off a TFTP server using the Intel PXE
7 ; network booting API. It is based on the SYSLINUX boot loader for
8 ; MS-DOS floppies.
9 ;
10 ; Copyright 1994-2008 H. Peter Anvin - All Rights Reserved
11 ;
12 ; This program is free software; you can redistribute it and/or modify
13 ; it under the terms of the GNU General Public License as published by
14 ; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
15 ; Boston MA 02111-1307, USA; either version 2 of the License, or
16 ; (at your option) any later version; incorporated herein by reference.
17 ;
18 ; ****************************************************************************
19
20 %define IS_PXELINUX 1
21 %include "head.inc"
22 %include "pxe.inc"
23
24 ; gPXE extensions support
25 %define GPXE 1
26
27 ;
28 ; Some semi-configurable constants... change on your own risk.
29 ;
30 my_id equ pxelinux_id
31 FILENAME_MAX_LG2 equ 7 ; log2(Max filename size Including final null)
32 FILENAME_MAX equ (1 << FILENAME_MAX_LG2)
33 NULLFILE equ 0 ; Zero byte == null file name
34 NULLOFFSET equ 4 ; Position in which to look
35 REBOOT_TIME equ 5*60 ; If failure, time until full reset
36 %assign HIGHMEM_SLOP 128*1024 ; Avoid this much memory near the top
37 MAX_OPEN_LG2 equ 5 ; log2(Max number of open sockets)
38 MAX_OPEN equ (1 << MAX_OPEN_LG2)
39 PKTBUF_SIZE equ (65536/MAX_OPEN) ; Per-socket packet buffer size
40 TFTP_PORT equ htons(69) ; Default TFTP port
41 PKT_RETRY equ 6 ; Packet transmit retry count
42 PKT_TIMEOUT equ 12 ; Initial timeout, timer ticks @ 55 ms
43 ; Desired TFTP block size
44 ; For Ethernet MTU is normally 1500. Unfortunately there seems to
45 ; be a fair number of networks with "substandard" MTUs which break.
46 ; The code assumes TFTP_LARGEBLK <= 2K.
47 TFTP_MTU equ 1440
48 TFTP_LARGEBLK equ (TFTP_MTU-20-8-4) ; MTU - IP hdr - UDP hdr - TFTP hdr
49 ; Standard TFTP block size
50 TFTP_BLOCKSIZE_LG2 equ 9 ; log2(bytes/block)
51 TFTP_BLOCKSIZE equ (1 << TFTP_BLOCKSIZE_LG2)
52 %assign USE_PXE_PROVIDED_STACK 1 ; Use stack provided by PXE?
53
54 SECTOR_SHIFT equ TFTP_BLOCKSIZE_LG2
55 SECTOR_SIZE equ TFTP_BLOCKSIZE
56
57 ;
58 ; This is what we need to do when idle
59 ; *** This is disabled because some PXE stacks wait for unacceptably
60 ; *** long if there are no packets receivable.
61
62 %define HAVE_IDLE 0 ; idle is not a noop
63
64 %if HAVE_IDLE
65 %macro RESET_IDLE 0
66 call reset_idle
67 %endmacro
68 %macro DO_IDLE 0
69 call check_for_arp
70 %endmacro
71 %else
72 %macro RESET_IDLE 0
73 ; Nothing
74 %endmacro
75 %macro DO_IDLE 0
76 ; Nothing
77 %endmacro
78 %endif
79
80 ;
81 ; TFTP operation codes
82 ;
83 TFTP_RRQ equ htons(1) ; Read request
84 TFTP_WRQ equ htons(2) ; Write request
85 TFTP_DATA equ htons(3) ; Data packet
86 TFTP_ACK equ htons(4) ; ACK packet
87 TFTP_ERROR equ htons(5) ; ERROR packet
88 TFTP_OACK equ htons(6) ; OACK packet
89
90 ;
91 ; TFTP error codes
92 ;
93 TFTP_EUNDEF equ htons(0) ; Unspecified error
94 TFTP_ENOTFOUND equ htons(1) ; File not found
95 TFTP_EACCESS equ htons(2) ; Access violation
96 TFTP_ENOSPACE equ htons(3) ; Disk full
97 TFTP_EBADOP equ htons(4) ; Invalid TFTP operation
98 TFTP_EBADID equ htons(5) ; Unknown transfer
99 TFTP_EEXISTS equ htons(6) ; File exists
100 TFTP_ENOUSER equ htons(7) ; No such user
101 TFTP_EOPTNEG equ htons(8) ; Option negotiation failure
102
103 ;
104 ; The following structure is used for "virtual kernels"; i.e. LILO-style
105 ; option labels. The options we permit here are `kernel' and `append
106 ; Since there is no room in the bottom 64K for all of these, we
107 ; stick them in high memory and copy them down before we need them.
108 ;
109 struc vkernel
110 vk_vname: resb FILENAME_MAX ; Virtual name **MUST BE FIRST!**
111 vk_rname: resb FILENAME_MAX ; Real name
112 vk_ipappend: resb 1 ; "IPAPPEND" flag
113 vk_type: resb 1 ; Type of file
114 vk_appendlen: resw 1
115 alignb 4
116 vk_append: resb max_cmd_len+1 ; Command line
117 alignb 4
118 vk_end: equ $ ; Should be <= vk_size
119 endstruc
120
121 ;
122 ; Segment assignments in the bottom 640K
123 ; 0000h - main code/data segment (and BIOS segment)
124 ;
125 real_mode_seg equ 3000h
126 pktbuf_seg equ 2000h ; Packet buffers segments
127 xfer_buf_seg equ 1000h ; Bounce buffer for I/O to high mem
128 comboot_seg equ real_mode_seg ; COMBOOT image loading zone
129
130 ;
131 ; BOOTP/DHCP packet pattern
132 ;
133 struc bootp_t
134 bootp:
135 .opcode resb 1 ; BOOTP/DHCP "opcode"
136 .hardware resb 1 ; ARP hardware type
137 .hardlen resb 1 ; Hardware address length
138 .gatehops resb 1 ; Used by forwarders
139 .ident resd 1 ; Transaction ID
140 .seconds resw 1 ; Seconds elapsed
141 .flags resw 1 ; Broadcast flags
142 .cip resd 1 ; Client IP
143 .yip resd 1 ; "Your" IP
144 .sip resd 1 ; Next server IP
145 .gip resd 1 ; Relay agent IP
146 .macaddr resb 16 ; Client MAC address
147 .sname resb 64 ; Server name (optional)
148 .bootfile resb 128 ; Boot file name
149 .option_magic resd 1 ; Vendor option magic cookie
150 .options resb 1260 ; Vendor options
151 endstruc
152
153 BOOTP_OPTION_MAGIC equ htonl(0x63825363) ; See RFC 2132
154
155 ;
156 ; TFTP connection data structure. Each one of these corresponds to a local
157 ; UDP port. The size of this structure must be a power of 2.
158 ; HBO = host byte order; NBO = network byte order
159 ; (*) = written by options negotiation code, must be dword sized
160 ;
161 ; For a gPXE connection, we set the local port number to -1 and the
162 ; remote port number contains the gPXE file handle.
163 ;
164 struc open_file_t
165 tftp_localport resw 1 ; Local port number (0 = not in use)
166 tftp_remoteport resw 1 ; Remote port number
167 tftp_remoteip resd 1 ; Remote IP address
168 tftp_filepos resd 1 ; Bytes downloaded (including buffer)
169 tftp_filesize resd 1 ; Total file size(*)
170 tftp_blksize resd 1 ; Block size for this connection(*)
171 tftp_bytesleft resw 1 ; Unclaimed data bytes
172 tftp_lastpkt resw 1 ; Sequence number of last packet (NBO)
173 tftp_dataptr resw 1 ; Pointer to available data
174 tftp_goteof resb 1 ; 1 if the EOF packet received
175 resb 3 ; Currently unusued
176 ; At end since it should not be zeroed on socked close
177 tftp_pktbuf resw 1 ; Packet buffer offset
178 endstruc
179 %ifndef DEPEND
180 %if (open_file_t_size & (open_file_t_size-1))
181 %error "open_file_t is not a power of 2"
182 %endif
183 %endif
184
185 ; ---------------------------------------------------------------------------
186 ; BEGIN CODE
187 ; ---------------------------------------------------------------------------
188
189 ;
190 ; Memory below this point is reserved for the BIOS and the MBR
191 ;
192 section .earlybss
193 trackbufsize equ 8192
194 trackbuf resb trackbufsize ; Track buffer goes here
195 ; ends at 2800h
196
197 alignb open_file_t_size
198 Files resb MAX_OPEN*open_file_t_size
199
200 alignb FILENAME_MAX
201 BootFile resb 256 ; Boot file from DHCP packet
202 PathPrefix resb 256 ; Path prefix derived from boot file
203 DotQuadBuf resb 16 ; Buffer for dotted-quad IP address
204 IPOption resb 80 ; ip= option buffer
205 InitStack resd 1 ; Pointer to reset stack (SS:SP)
206 PXEStack resd 1 ; Saved stack during PXE call
207
208 section .bss
209 alignb 4
210 RebootTime resd 1 ; Reboot timeout, if set by option
211 StrucPtr resd 1 ; Pointer to PXENV+ or !PXE structure
212 APIVer resw 1 ; PXE API version found
213 IPOptionLen resw 1 ; Length of IPOption
214 IdleTimer resw 1 ; Time to check for ARP?
215 LocalBootType resw 1 ; Local boot return code
216 PktTimeout resw 1 ; Timeout for current packet
217 RealBaseMem resw 1 ; Amount of DOS memory after freeing
218 OverLoad resb 1 ; Set if DHCP packet uses "overloading"
219 DHCPMagic resb 1 ; PXELINUX magic flags
220
221 ; The relative position of these fields matter!
222 MAC_MAX equ 32 ; Handle hardware addresses this long
223 MACLen resb 1 ; MAC address len
224 MACType resb 1 ; MAC address type
225 MAC resb MAC_MAX+1 ; Actual MAC address
226 BOOTIFStr resb 7 ; Space for "BOOTIF="
227 MACStr resb 3*(MAC_MAX+1) ; MAC address as a string
228
229 ; The relative position of these fields matter!
230 UUIDType resb 1 ; Type byte from DHCP option
231 UUID resb 16 ; UUID, from the PXE stack
232 UUIDNull resb 1 ; dhcp_copyoption zero-terminates
233
234 ;
235 ; PXE packets which don't need static initialization
236 ;
237 alignb 4
238 pxe_unload_stack_pkt:
239 .status: resw 1 ; Status
240 .reserved: resw 10 ; Reserved
241 pxe_unload_stack_pkt_len equ $-pxe_unload_stack_pkt
242
243 alignb 16
244 ; BOOTP/DHCP packet buffer
245
246 section .bss2
247 alignb 16
248 packet_buf resb 2048 ; Transfer packet
249 packet_buf_size equ $-packet_buf
250
251 section .text
252 ;
253 ; PXELINUX needs more BSS than the other derivatives;
254 ; therefore we relocate it from 7C00h on startup.
255 ;
256 StackBuf equ $ ; Base of stack if we use our own
257
258 ;
259 ; Primary entry point.
260 ;
261 bootsec equ $
262 _start:
263 pushfd ; Paranoia... in case of return to PXE
264 pushad ; ... save as much state as possible
265 push ds
266 push es
267 push fs
268 push gs
269
270 xor ax,ax
271 mov ds,ax
272 mov es,ax
273
274 %ifndef DEPEND
275 %if TEXT_START != 0x7c00
276 ; This is uglier than it should be, but works around
277 ; some NASM 0.98.38 bugs.
278 mov di,section..bcopy32.start
279 add di,__bcopy_size-4
280 lea si,[di-(TEXT_START-7C00h)]
281 lea cx,[di-(TEXT_START-4)]
282 shr cx,2
283 std ; Overlapping areas, copy backwards
284 rep movsd
285 %endif
286 %endif
287 jmp 0:_start1 ; Canonicalize address
288 _start1:
289 mov bp,sp
290 les bx,[bp+48] ; ES:BX -> !PXE or PXENV+ structure
291
292 ; That is all pushed onto the PXE stack. Save the pointer
293 ; to it and switch to an internal stack.
294 mov [InitStack],sp
295 mov [InitStack+2],ss
296
297 %if USE_PXE_PROVIDED_STACK
298 ; Apparently some platforms go bonkers if we
299 ; set up our own stack...
300 mov [BaseStack],sp
301 mov [BaseStack+4],ss
302 %endif
303
304 cli ; Paranoia
305 lss esp,[BaseStack]
306
307 sti ; Stack set up and ready
308 cld ; Copy upwards
309
310 ;
311 ; Initialize screen (if we're using one)
312 ;
313 push es ; Save ES -> PXE entry structure
314 push ds
315 pop es ; ES <- DS
316 %include "init.inc"
317 pop es ; Restore ES -> PXE entry structure
318 ;
319 ; Tell the user we got this far
320 ;
321 mov si,syslinux_banner
322 call writestr
323
324 mov si,copyright_str
325 call writestr
326
327 ;
328 ; Assume API version 2.1, in case we find the !PXE structure without
329 ; finding the PXENV+ structure. This should really look at the Base
330 ; Code ROM ID structure in have_pxe, but this is adequate for now --
331 ; if we have !PXE, we have to be 2.1 or higher, and we don't care
332 ; about higher versions than that.
333 ;
334 mov word [APIVer],0201h
335
336 ;
337 ; Now we need to find the !PXE structure. It's *supposed* to be pointed
338 ; to by SS:[SP+4], but support INT 1Ah, AX=5650h method as well.
339 ; FIX: ES:BX should point to the PXENV+ structure on entry as well.
340 ; We should make that the second test, and not trash ES:BX...
341 ;
342 cmp dword [es:bx], '!PXE'
343 je have_pxe
344
345 ; Uh-oh, not there... try plan B
346 mov ax, 5650h
347 %if USE_PXE_PROVIDED_STACK == 0
348 lss sp,[InitStack]
349 %endif
350 int 1Ah ; May trash regs
351 %if USE_PXE_PROVIDED_STACK == 0
352 lss esp,[BaseStack]
353 %endif
354
355 jc no_pxe
356 cmp ax,564Eh
357 jne no_pxe
358
359 ; Okay, that gave us the PXENV+ structure, find !PXE
360 ; structure from that (if available)
361 cmp dword [es:bx], 'PXEN'
362 jne no_pxe
363 cmp word [es:bx+4], 'V+'
364 je have_pxenv
365
366 ; Nothing there either. Last-ditch: scan memory
367 call memory_scan_for_pxe_struct ; !PXE scan
368 jnc have_pxe
369 call memory_scan_for_pxenv_struct ; PXENV+ scan
370 jnc have_pxenv
371
372 no_pxe: mov si,err_nopxe
373 call writestr
374 jmp kaboom
375
376 have_pxenv:
377 mov [StrucPtr],bx
378 mov [StrucPtr+2],es
379
380 mov si,found_pxenv
381 call writestr
382
383 mov si,apiver_str
384 call writestr
385 mov ax,[es:bx+6]
386 mov [APIVer],ax
387 call writehex4
388 call crlf
389
390 cmp ax,0201h ; API version 2.1 or higher
391 jb old_api
392 mov si,bx
393 mov ax,es
394 les bx,[es:bx+28h] ; !PXE structure pointer
395 cmp dword [es:bx],'!PXE'
396 je have_pxe
397
398 ; Nope, !PXE structure missing despite API 2.1+, or at least
399 ; the pointer is missing. Do a last-ditch attempt to find it.
400 call memory_scan_for_pxe_struct
401 jnc have_pxe
402
403 ; Otherwise, no dice, use PXENV+ structure
404 mov bx,si
405 mov es,ax
406
407 old_api: ; Need to use a PXENV+ structure
408 mov si,using_pxenv_msg
409 call writestr
410
411 mov eax,[es:bx+0Ah] ; PXE RM API
412 mov [PXENVEntry],eax
413
414 mov si,undi_data_msg
415 call writestr
416 mov ax,[es:bx+20h]
417 call writehex4
418 call crlf
419 mov si,undi_data_len_msg
420 call writestr
421 mov ax,[es:bx+22h]
422 call writehex4
423 call crlf
424 mov si,undi_code_msg
425 call writestr
426 mov ax,[es:bx+24h]
427 call writehex4
428 call crlf
429 mov si,undi_code_len_msg
430 call writestr
431 mov ax,[es:bx+26h]
432 call writehex4
433 call crlf
434
435 ; Compute base memory size from PXENV+ structure
436 xor esi,esi
437 movzx eax,word [es:bx+20h] ; UNDI data seg
438 cmp ax,[es:bx+24h] ; UNDI code seg
439 ja .use_data
440 mov ax,[es:bx+24h]
441 mov si,[es:bx+26h]
442 jmp short .combine
443 .use_data:
444 mov si,[es:bx+22h]
445 .combine:
446 shl eax,4
447 add eax,esi
448 shr eax,10 ; Convert to kilobytes
449 mov [RealBaseMem],ax
450
451 mov si,pxenventry_msg
452 call writestr
453 mov ax,[PXENVEntry+2]
454 call writehex4
455 mov al,':'
456 call writechr
457 mov ax,[PXENVEntry]
458 call writehex4
459 call crlf
460 jmp have_entrypoint
461
462 have_pxe:
463 mov [StrucPtr],bx
464 mov [StrucPtr+2],es
465
466 mov eax,[es:bx+10h]
467 mov [PXEEntry],eax
468
469 mov si,undi_data_msg
470 call writestr
471 mov eax,[es:bx+2Ah]
472 call writehex8
473 call crlf
474 mov si,undi_data_len_msg
475 call writestr
476 mov ax,[es:bx+2Eh]
477 call writehex4
478 call crlf
479 mov si,undi_code_msg
480 call writestr
481 mov ax,[es:bx+32h]
482 call writehex8
483 call crlf
484 mov si,undi_code_len_msg
485 call writestr
486 mov ax,[es:bx+36h]
487 call writehex4
488 call crlf
489
490 ; Compute base memory size from !PXE structure
491 xor esi,esi
492 mov eax,[es:bx+2Ah]
493 cmp eax,[es:bx+32h]
494 ja .use_data
495 mov eax,[es:bx+32h]
496 mov si,[es:bx+36h]
497 jmp short .combine
498 .use_data:
499 mov si,[es:bx+2Eh]
500 .combine:
501 add eax,esi
502 shr eax,10
503 mov [RealBaseMem],ax
504
505 mov si,pxeentry_msg
506 call writestr
507 mov ax,[PXEEntry+2]
508 call writehex4
509 mov al,':'
510 call writechr
511 mov ax,[PXEEntry]
512 call writehex4
513 call crlf
514
515 have_entrypoint:
516 push cs
517 pop es ; Restore CS == DS == ES
518
519 ;
520 ; Network-specific initialization
521 ;
522 xor ax,ax
523 mov [LocalDomain],al ; No LocalDomain received
524
525 ;
526 ; The DHCP client identifiers are best gotten from the DHCPREQUEST
527 ; packet (query info 1).
528 ;
529 query_bootp_1:
530 mov dl,1
531 call pxe_get_cached_info
532 call parse_dhcp
533
534 ; We don't use flags from the request packet, so
535 ; this is a good time to initialize DHCPMagic...
536 ; Initialize it to 1 meaning we will accept options found;
537 ; in earlier versions of PXELINUX bit 0 was used to indicate
538 ; we have found option 208 with the appropriate magic number;
539 ; we no longer require that, but MAY want to re-introduce
540 ; it in the future for vendor encapsulated options.
541 mov byte [DHCPMagic],1
542
543 ;
544 ; Now attempt to get the BOOTP/DHCP packet that brought us life (and an IP
545 ; address). This lives in the DHCPACK packet (query info 2).
546 ;
547 query_bootp_2:
548 mov dl,2
549 call pxe_get_cached_info
550 call parse_dhcp ; Parse DHCP packet
551 ;
552 ; Save away MAC address (assume this is in query info 2. If this
553 ; turns out to be problematic it might be better getting it from
554 ; the query info 1 packet.)
555 ;
556 .save_mac:
557 movzx cx,byte [trackbuf+bootp.hardlen]
558 cmp cx,16
559 jna .mac_ok
560 xor cx,cx ; Bad hardware address length
561 .mac_ok:
562 mov [MACLen],cl
563 mov al,[trackbuf+bootp.hardware]
564 mov [MACType],al
565 mov si,trackbuf+bootp.macaddr
566 mov di,MAC
567 rep movsb
568
569 ; Enable this if we really need to zero-pad this field...
570 ; mov cx,MAC+MAC_MAX+1
571 ; sub cx,di
572 ; xor ax,ax
573 ; rep stosb
574
575 ;
576 ; Now, get the boot file and other info. This lives in the CACHED_REPLY
577 ; packet (query info 3).
578 ;
579 mov dl,3
580 call pxe_get_cached_info
581 call parse_dhcp ; Parse DHCP packet
582
583 ;
584 ; Generate the bootif string, and the hardware-based config string.
585 ;
586 make_bootif_string:
587 mov si,bootif_str
588 mov di,BOOTIFStr
589 mov cx,bootif_str_len
590 rep movsb
591
592 movzx cx,byte [MACLen]
593 mov si,MACType
594 inc cx
595 .hexify_mac:
596 push cx
597 mov cl,1 ; CH == 0 already
598 call lchexbytes
599 mov al,'-'
600 stosb
601 pop cx
602 loop .hexify_mac
603 mov [di-1],cl ; Null-terminate and strip final dash
604 ;
605 ; Generate ip= option
606 ;
607 call genipopt
608
609 ;
610 ; Print IP address
611 ;
612 mov eax,[MyIP]
613 mov di,DotQuadBuf
614 push di
615 call gendotquad ; This takes network byte order input
616
617 xchg ah,al ; Convert to host byte order
618 ror eax,16 ; (BSWAP doesn't work on 386)
619 xchg ah,al
620
621 mov si,myipaddr_msg
622 call writestr
623 call writehex8
624 mov al,' '
625 call writechr
626 pop si ; DotQuadBuf
627 call writestr
628 call crlf
629
630 mov si,IPOption
631 call writestr
632 call crlf
633
634 ;
635 ; Check to see if we got any PXELINUX-specific DHCP options; in particular,
636 ; if we didn't get the magic enable, do not recognize any other options.
637 ;
638 check_dhcp_magic:
639 test byte [DHCPMagic], 1 ; If we didn't get the magic enable...
640 jnz .got_magic
641 mov byte [DHCPMagic], 0 ; If not, kill all other options
642 .got_magic:
643
644
645 ;
646 ; Initialize UDP stack
647 ;
648 udp_init:
649 mov eax,[MyIP]
650 mov [pxe_udp_open_pkt.sip],eax
651 mov di,pxe_udp_open_pkt
652 mov bx,PXENV_UDP_OPEN
653 call pxenv
654 jc .failed
655 cmp word [pxe_udp_open_pkt.status], byte 0
656 je .success
657 .failed: mov si,err_udpinit
658 call writestr
659 jmp kaboom
660 .success:
661
662 ;
663 ; Common initialization code
664 ;
665 %include "cpuinit.inc"
666
667 ;
668 ; Now we're all set to start with our *real* business. First load the
669 ; configuration file (if any) and parse it.
670 ;
671 ; In previous versions I avoided using 32-bit registers because of a
672 ; rumour some BIOSes clobbered the upper half of 32-bit registers at
673 ; random. I figure, though, that if there are any of those still left
674 ; they probably won't be trying to install Linux on them...
675 ;
676 ; The code is still ripe with 16-bitisms, though. Not worth the hassle
677 ; to take'm out. In fact, we may want to put them back if we're going
678 ; to boot ELKS at some point.
679 ;
680
681 ;
682 ; Store standard filename prefix
683 ;
684 prefix: test byte [DHCPMagic], 04h ; Did we get a path prefix option
685 jnz .got_prefix
686 mov si,BootFile
687 mov di,PathPrefix
688 cld
689 call strcpy
690 mov cx,di
691 sub cx,PathPrefix+1
692 std
693 lea si,[di-2] ; Skip final null!
694 .find_alnum: lodsb
695 or al,20h
696 cmp al,'.' ; Count . or - as alphanum
697 je .alnum
698 cmp al,'-'
699 je .alnum
700 cmp al,'0'
701 jb .notalnum
702 cmp al,'9'
703 jbe .alnum
704 cmp al,'a'
705 jb .notalnum
706 cmp al,'z'
707 ja .notalnum
708 .alnum: loop .find_alnum
709 dec si
710 .notalnum: mov byte [si+2],0 ; Zero-terminate after delimiter
711 cld
712 .got_prefix:
713 mov si,tftpprefix_msg
714 call writestr
715 mov si,PathPrefix
716 call writestr
717 call crlf
718
719 ;
720 ; Load configuration file
721 ;
722 find_config:
723
724 ;
725 ; Begin looking for configuration file
726 ;
727 config_scan:
728 test byte [DHCPMagic], 02h
729 jz .no_option
730
731 ; We got a DHCP option, try it first
732 call .try
733 jnz .success
734
735 .no_option:
736 mov di,ConfigName
737 mov si,cfgprefix
738 mov cx,cfgprefix_len
739 rep movsb
740
741 ; Have to guess config file name...
742
743 ; Try loading by UUID.
744 cmp byte [HaveUUID],0
745 je .no_uuid
746
747 push di
748 mov bx,uuid_dashes
749 mov si,UUID
750 .gen_uuid:
751 movzx cx,byte [bx]
752 jcxz .done_uuid
753 inc bx
754 call lchexbytes
755 mov al,'-'
756 stosb
757 jmp .gen_uuid
758 .done_uuid:
759 mov [di-1],cl ; Remove last dash and zero-terminate
760 pop di
761 call .try
762 jnz .success
763 .no_uuid:
764
765 ; Try loading by MAC address
766 push di
767 mov si,MACStr
768 call strcpy
769 pop di
770 call .try
771 jnz .success
772
773 ; Nope, try hexadecimal IP prefixes...
774 .scan_ip:
775 mov cx,4
776 mov si,MyIP
777 call uchexbytes ; Convert to hex string
778
779 mov cx,8 ; Up to 8 attempts
780 .tryagain:
781 mov byte [di],0 ; Zero-terminate string
782 call .try
783 jnz .success
784 dec di ; Drop one character
785 loop .tryagain
786
787 ; Final attempt: "default" string
788 mov si,default_str ; "default" string
789 call strcpy
790 call .try
791 jnz .success
792
793 mov si,err_noconfig
794 call writestr
795 jmp kaboom
796
797 .try:
798 pusha
799 mov si,trying_msg
800 call writestr
801 mov di,ConfigName
802 mov si,di
803 call writestr
804 call crlf
805 mov si,di
806 mov di,KernelName ; Borrow this buffer for mangled name
807 call mangle_name
808 call open
809 popa
810 ret
811
812
813 .success:
814
815 ;
816 ; Linux kernel loading code is common. However, we need to define
817 ; a couple of helper macros...
818 ;
819
820 ; Handle "ipappend" option
821 %define HAVE_SPECIAL_APPEND
822 %macro SPECIAL_APPEND 0
823 test byte [IPAppend],01h ; ip=
824 jz .noipappend1
825 mov si,IPOption
826 mov cx,[IPOptionLen]
827 rep movsb
828 mov al,' '
829 stosb
830 .noipappend1:
831 test byte [IPAppend],02h
832 jz .noipappend2
833 mov si,BOOTIFStr
834 call strcpy
835 mov byte [es:di-1],' ' ; Replace null with space
836 .noipappend2:
837 %endmacro
838
839 ; Unload PXE stack
840 %define HAVE_UNLOAD_PREP
841 %macro UNLOAD_PREP 0
842 call unload_pxe
843 %endmacro
844
845 ;
846 ; Now we have the config file open. Parse the config file and
847 ; run the user interface.
848 ;
849 %include "ui.inc"
850
851 ;
852 ; Boot to the local disk by returning the appropriate PXE magic.
853 ; AX contains the appropriate return code.
854 ;
855 local_boot:
856 push cs
857 pop ds
858 mov [LocalBootType],ax
859 call vgaclearmode
860 mov si,localboot_msg
861 call writestr
862 ; Restore the environment we were called with
863 lss sp,[InitStack]
864 pop gs
865 pop fs
866 pop es
867 pop ds
868 popad
869 mov ax,[cs:LocalBootType]
870 popfd
871 retf ; Return to PXE
872
873 ;
874 ; kaboom: write a message and bail out. Wait for quite a while,
875 ; or a user keypress, then do a hard reboot.
876 ;
877 kaboom:
878 RESET_STACK_AND_SEGS AX
879 .patch: mov si,bailmsg
880 call writestr ; Returns with AL = 0
881 .drain: call pollchar
882 jz .drained
883 call getchar
884 jmp short .drain
885 .drained:
886 mov edi,[RebootTime]
887 mov al,[DHCPMagic]
888 and al,09h ; Magic+Timeout
889 cmp al,09h
890 je .time_set
891 mov edi,REBOOT_TIME
892 .time_set:
893 mov cx,18
894 .wait1: push cx
895 mov ecx,edi
896 .wait2: mov dx,[BIOS_timer]
897 .wait3: call pollchar
898 jnz .keypress
899 cmp dx,[BIOS_timer]
900 je .wait3
901 loop .wait2,ecx
902 mov al,'.'
903 call writechr
904 pop cx
905 loop .wait1
906 .keypress:
907 call crlf
908 mov word [BIOS_magic],0 ; Cold reboot
909 jmp 0F000h:0FFF0h ; Reset vector address
910
911 ;
912 ; memory_scan_for_pxe_struct:
913 ;
914 ; If none of the standard methods find the !PXE structure, look for it
915 ; by scanning memory.
916 ;
917 ; On exit, if found:
918 ; CF = 0, ES:BX -> !PXE structure
919 ; Otherwise CF = 1, all registers saved
920 ;
921 memory_scan_for_pxe_struct:
922 push ds
923 pusha
924 mov ax,cs
925 mov ds,ax
926 mov si,trymempxe_msg
927 call writestr
928 mov ax,[BIOS_fbm] ; Starting segment
929 shl ax,(10-4) ; Kilobytes -> paragraphs
930 ; mov ax,01000h ; Start to look here
931 dec ax ; To skip inc ax
932 .mismatch:
933 inc ax
934 cmp ax,0A000h ; End of memory
935 jae .not_found
936 call writehex4
937 mov si,fourbs_msg
938 call writestr
939 mov es,ax
940 mov edx,[es:0]
941 cmp edx,'!PXE'
942 jne .mismatch
943 movzx cx,byte [es:4] ; Length of structure
944 cmp cl,08h ; Minimum length
945 jb .mismatch
946 push ax
947 xor ax,ax
948 xor si,si
949 .checksum: es lodsb
950 add ah,al
951 loop .checksum
952 pop ax
953 jnz .mismatch ; Checksum must == 0
954 .found: mov bp,sp
955 xor bx,bx
956 mov [bp+8],bx ; Save BX into stack frame (will be == 0)
957 mov ax,es
958 call writehex4
959 call crlf
960 popa
961 pop ds
962 clc
963 ret
964 .not_found: mov si,notfound_msg
965 call writestr
966 popa
967 pop ds
968 stc
969 ret
970
971 ;
972 ; memory_scan_for_pxenv_struct:
973 ;
974 ; If none of the standard methods find the PXENV+ structure, look for it
975 ; by scanning memory.
976 ;
977 ; On exit, if found:
978 ; CF = 0, ES:BX -> PXENV+ structure
979 ; Otherwise CF = 1, all registers saved
980 ;
981 memory_scan_for_pxenv_struct:
982 pusha
983 mov si,trymempxenv_msg
984 call writestr
985 ; mov ax,[BIOS_fbm] ; Starting segment
986 ; shl ax,(10-4) ; Kilobytes -> paragraphs
987 mov ax,01000h ; Start to look here
988 dec ax ; To skip inc ax
989 .mismatch:
990 inc ax
991 cmp ax,0A000h ; End of memory
992 jae .not_found
993 mov es,ax
994 mov edx,[es:0]
995 cmp edx,'PXEN'
996 jne .mismatch
997 mov dx,[es:4]
998 cmp dx,'V+'
999 jne .mismatch
1000 movzx cx,byte [es:8] ; Length of structure
1001 cmp cl,26h ; Minimum length
1002 jb .mismatch
1003 xor ax,ax
1004 xor si,si
1005 .checksum: es lodsb
1006 add ah,al
1007 loop .checksum
1008 and ah,ah
1009 jnz .mismatch ; Checksum must == 0
1010 .found: mov bp,sp
1011 mov [bp+8],bx ; Save BX into stack frame
1012 mov ax,bx
1013 call writehex4
1014 call crlf
1015 clc
1016 ret
1017 .not_found: mov si,notfound_msg
1018 call writestr
1019 popad
1020 stc
1021 ret
1022
1023 ;
1024 ; close_file:
1025 ; Deallocates a file structure (pointer in SI)
1026 ; Assumes CS == DS.
1027 ;
1028 ; XXX: We should check to see if this file is still open on the server
1029 ; side and send a courtesy ERROR packet to the server.
1030 ;
1031 close_file:
1032 and si,si
1033 jz .closed
1034 mov word [si],0 ; Not in use
1035 .closed: ret
1036
1037 ;
1038 ; searchdir:
1039 ;
1040 ; Open a TFTP connection to the server
1041 ;
1042 ; On entry:
1043 ; DS:DI = mangled filename
1044 ; If successful:
1045 ; ZF clear
1046 ; SI = socket pointer
1047 ; EAX = file length in bytes, or -1 if unknown
1048 ; If unsuccessful
1049 ; ZF set
1050 ;
1051
1052 searchdir:
1053 push es
1054 push bx
1055 push cx
1056 mov ax,ds
1057 mov es,ax
1058 mov si,di
1059 push bp
1060 mov bp,sp
1061
1062 call allocate_socket
1063 jz .ret
1064
1065 mov ax,PKT_RETRY ; Retry counter
1066 mov word [PktTimeout],PKT_TIMEOUT ; Initial timeout
1067
1068 .sendreq: push ax ; [bp-2] - Retry counter
1069 push si ; [bp-4] - File name
1070
1071 mov di,packet_buf
1072 mov [pxe_udp_write_pkt.buffer],di
1073
1074 mov ax,TFTP_RRQ ; TFTP opcode
1075 stosw
1076
1077 lodsd ; EAX <- server override (if any)
1078 and eax,eax
1079 jnz .noprefix ; No prefix, and we have the server
1080
1081 push si ; Add common prefix
1082 mov si,PathPrefix
1083 call strcpy
1084 dec di
1085 pop si
1086
1087 mov eax,[ServerIP] ; Get default server
1088
1089 .noprefix:
1090 call strcpy ; Filename
1091 %if GPXE
1092 mov si,packet_buf+2
1093 call is_url
1094 jnc .gpxe
1095 %endif
1096
1097 mov [bx+tftp_remoteip],eax
1098
1099 push bx ; [bp-6] - TFTP block
1100 mov bx,[bx]
1101 push bx ; [bp-8] - TID (local port no)
1102
1103 mov [pxe_udp_write_pkt.status],byte 0
1104 mov [pxe_udp_write_pkt.sip],eax
1105 ; Now figure out the gateway
1106 xor eax,[MyIP]
1107 and eax,[Netmask]
1108 jz .nogwneeded
1109 mov eax,[Gateway]
1110 .nogwneeded:
1111 mov [pxe_udp_write_pkt.gip],eax
1112 mov [pxe_udp_write_pkt.lport],bx
1113 mov ax,[ServerPort]
1114 mov [pxe_udp_write_pkt.rport],ax
1115 mov si,tftp_tail
1116 mov cx,tftp_tail_len
1117 rep movsb
1118 sub di,packet_buf ; Get packet size
1119 mov [pxe_udp_write_pkt.buffersize],di
1120
1121 mov di,pxe_udp_write_pkt
1122 mov bx,PXENV_UDP_WRITE
1123 call pxenv
1124 jc .failure
1125 cmp word [pxe_udp_write_pkt.status],byte 0
1126 jne .failure
1127
1128 ;
1129 ; Danger, Will Robinson! We need to support timeout
1130 ; and retry lest we just lost a packet...
1131 ;
1132
1133 ; Packet transmitted OK, now we need to receive
1134 .getpacket: push word [PktTimeout] ; [bp-10]
1135 push word [BIOS_timer] ; [bp-12]
1136
1137 .pkt_loop: mov bx,[bp-8] ; TID
1138 mov di,packet_buf
1139 mov word [pxe_udp_read_pkt.status],0
1140 mov [pxe_udp_read_pkt.buffer],di
1141 mov [pxe_udp_read_pkt.buffer+2],ds
1142 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
1143 mov eax,[MyIP]
1144 mov [pxe_udp_read_pkt.dip],eax
1145 mov [pxe_udp_read_pkt.lport],bx
1146 mov di,pxe_udp_read_pkt
1147 mov bx,PXENV_UDP_READ
1148 call pxenv
1149 and ax,ax
1150 jz .got_packet ; Wait for packet
1151 .no_packet:
1152 mov dx,[BIOS_timer]
1153 cmp dx,[bp-12]
1154 je .pkt_loop
1155 mov [bp-12],dx
1156 dec word [bp-10] ; Timeout
1157 jnz .pkt_loop
1158 pop ax ; Adjust stack
1159 pop ax
1160 shl word [PktTimeout],1 ; Exponential backoff
1161 jmp .failure
1162
1163 .got_packet:
1164 mov si,[bp-6] ; TFTP pointer
1165 mov bx,[bp-8] ; TID
1166
1167 ; Make sure the packet actually came from the server
1168 ; This is technically not to the TFTP spec?
1169 mov eax,[si+tftp_remoteip]
1170 cmp [pxe_udp_read_pkt.sip],eax
1171 jne .no_packet
1172
1173 ; Got packet - reset timeout
1174 mov word [PktTimeout],PKT_TIMEOUT
1175
1176 pop ax ; Adjust stack
1177 pop ax
1178
1179 mov ax,[pxe_udp_read_pkt.rport]
1180 mov [si+tftp_remoteport],ax
1181
1182 ; filesize <- -1 == unknown
1183 mov dword [si+tftp_filesize], -1
1184 ; Default blksize unless blksize option negotiated
1185 mov word [si+tftp_blksize], TFTP_BLOCKSIZE
1186
1187 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1188 sub cx,2 ; CX <- bytes after opcode
1189 jb .failure ; Garbled reply
1190
1191 mov si,packet_buf
1192 lodsw
1193
1194 cmp ax, TFTP_ERROR
1195 je .bailnow ; ERROR reply: don't try again
1196
1197 ; If the server doesn't support any options, we'll get
1198 ; a DATA reply instead of OACK. Stash the data in
1199 ; the file buffer and go with the default value for
1200 ; all options...
1201 cmp ax, TFTP_DATA
1202 je .no_oack
1203
1204 cmp ax, TFTP_OACK
1205 jne .err_reply ; Unknown packet type
1206
1207 ; Now we need to parse the OACK packet to get the transfer
1208 ; and packet sizes.
1209 ; SI -> first byte of options; [E]CX -> byte count
1210 .parse_oack:
1211 jcxz .done_pkt ; No options acked
1212 .get_opt_name:
1213 mov di,si
1214 mov bx,si
1215 .opt_name_loop: lodsb
1216 and al,al
1217 jz .got_opt_name
1218 or al,20h ; Convert to lowercase
1219 stosb
1220 loop .opt_name_loop
1221 ; We ran out, and no final null
1222 jmp .err_reply
1223 .got_opt_name: ; si -> option value
1224 dec cx ; bytes left in pkt
1225 jz .err_reply ; Option w/o value
1226
1227 ; Parse option pointed to by bx; guaranteed to be
1228 ; null-terminated.
1229 push cx
1230 push si
1231 mov si,bx ; -> option name
1232 mov bx,tftp_opt_table
1233 mov cx,tftp_opts
1234 .opt_loop:
1235 push cx
1236 push si
1237 mov di,[bx] ; Option pointer
1238 mov cx,[bx+2] ; Option len
1239 repe cmpsb
1240 pop si
1241 pop cx
1242 je .get_value ; OK, known option
1243 add bx,6
1244 loop .opt_loop
1245
1246 pop si
1247 pop cx
1248 jmp .err_reply ; Non-negotiated option returned
1249
1250 .get_value: pop si ; si -> option value
1251 pop cx ; cx -> bytes left in pkt
1252 mov bx,[bx+4] ; Pointer to data target
1253 add bx,[bp-6] ; TFTP socket pointer
1254 xor eax,eax
1255 xor edx,edx
1256 .value_loop: lodsb
1257 and al,al
1258 jz .got_value
1259 sub al,'0'
1260 cmp al, 9
1261 ja .err_reply ; Not a decimal digit
1262 imul edx,10
1263 add edx,eax
1264 mov [bx],edx
1265 loop .value_loop
1266 ; Ran out before final null, accept anyway
1267 jmp short .done_pkt
1268
1269 .got_value:
1270 dec cx
1271 jnz .get_opt_name ; Not end of packet
1272
1273 ; ZF == 1
1274
1275 ; Success, done!
1276 .done_pkt:
1277 pop si ; Junk
1278 pop si ; We want the packet ptr in SI
1279
1280 mov eax,[si+tftp_filesize]
1281 .got_file: ; SI->socket structure, EAX = size
1282 and eax,eax ; Set ZF depending on file size
1283 pop bp ; Junk
1284 pop bp ; Junk (retry counter)
1285 jz .error_si ; ZF = 1 need to free the socket
1286 .ret:
1287 pop bp
1288 pop cx
1289 pop bx
1290 pop es
1291 ret
1292
1293
1294 .no_oack: ; We got a DATA packet, meaning no options are
1295 ; suported. Save the data away and consider the length
1296 ; undefined, *unless* this is the only data packet...
1297 mov bx,[bp-6] ; File pointer
1298 sub cx,2 ; Too short?
1299 jb .failure
1300 lodsw ; Block number
1301 cmp ax,htons(1)
1302 jne .failure
1303 mov [bx+tftp_lastpkt],ax
1304 cmp cx,TFTP_BLOCKSIZE
1305 ja .err_reply ; Corrupt...
1306 je .not_eof
1307 ; This was the final EOF packet, already...
1308 ; We know the filesize, but we also want to ack the
1309 ; packet and set the EOF flag.
1310 mov [bx+tftp_filesize],ecx
1311 mov byte [bx+tftp_goteof],1
1312 push si
1313 mov si,bx
1314 ; AX = htons(1) already
1315 call ack_packet
1316 pop si
1317 .not_eof:
1318 mov [bx+tftp_bytesleft],cx
1319 mov ax,pktbuf_seg
1320 push es
1321 mov es,ax
1322 mov di,tftp_pktbuf
1323 mov [bx+tftp_dataptr],di
1324 add cx,3
1325 shr cx,2
1326 rep movsd
1327 pop es
1328 jmp .done_pkt
1329
1330 .err_reply: ; Option negotiation error. Send ERROR reply.
1331 ; ServerIP and gateway are already programmed in
1332 mov si,[bp-6]
1333 mov ax,[si+tftp_remoteport]
1334 mov word [pxe_udp_write_pkt.rport],ax
1335 mov word [pxe_udp_write_pkt.buffer],tftp_opt_err
1336 mov word [pxe_udp_write_pkt.buffersize],tftp_opt_err_len
1337 mov di,pxe_udp_write_pkt
1338 mov bx,PXENV_UDP_WRITE
1339 call pxenv
1340
1341 ; Write an error message and explode
1342 mov si,err_damage
1343 call writestr
1344 jmp kaboom
1345
1346 .bailnow: mov word [bp-2],1 ; Immediate error - no retry
1347
1348 .failure: pop bx ; Junk
1349 pop bx
1350 pop si
1351 pop ax
1352 dec ax ; Retry counter
1353 jnz .sendreq ; Try again
1354
1355 .error: mov si,bx ; Socket pointer
1356 .error_si: ; Socket pointer already in SI
1357 call free_socket ; ZF <- 1, SI <- 0
1358 jmp .ret
1359
1360
1361 %if GPXE
1362 .gpxe:
1363 pop si
1364 pop si
1365
1366 push bx
1367 mov si,packet_buf+2 ; Completed URL
1368 mov di,gpxe_file_open
1369 mov [di+4],si
1370 mov [di+6],ds
1371 mov bx,PXENV_FILE_OPEN
1372 call pxenv
1373 pop si ; Packet pointer in SI
1374 jc .error_si
1375
1376 mov ax,[di+2]
1377 mov word [si+tftp_localport],-1 ; gPXE URL
1378 mov [si+tftp_remoteport],ax
1379 mov di,gpxe_get_file_size
1380 mov [di+2],ax
1381
1382 mov bx,PXENV_GET_FILE_SIZE
1383 call pxenv
1384 jc .error
1385
1386 mov eax,[di+4]
1387 mov [si+tftp_filesize],eax
1388 jmp .got_file
1389 %endif ; GPXE
1390
1391 ;
1392 ; allocate_socket: Allocate a local UDP port structure
1393 ;
1394 ; If successful:
1395 ; ZF set
1396 ; BX = socket pointer
1397 ; If unsuccessful:
1398 ; ZF clear
1399 ;
1400 allocate_socket:
1401 push cx
1402 mov bx,Files
1403 mov cx,MAX_OPEN
1404 .check: cmp word [bx], byte 0
1405 je .found
1406 add bx,open_file_t_size
1407 loop .check
1408 xor cx,cx ; ZF = 1
1409 pop cx
1410 ret
1411 ; Allocate a socket number. Socket numbers are made
1412 ; guaranteed unique by including the socket slot number
1413 ; (inverted, because we use the loop counter cx); add a
1414 ; counter value to keep the numbers from being likely to
1415 ; get immediately reused.
1416 ;
1417 ; The NextSocket variable also contains the top two bits
1418 ; set. This generates a value in the range 49152 to
1419 ; 57343.
1420 .found:
1421 dec cx
1422 push ax
1423 mov ax,[NextSocket]
1424 inc ax
1425 and ax,((1 << (13-MAX_OPEN_LG2))-1) | 0xC000
1426 mov [NextSocket],ax
1427 shl cx,13-MAX_OPEN_LG2
1428 add cx,ax ; ZF = 0
1429 xchg ch,cl ; Convert to network byte order
1430 mov [bx],cx ; Socket in use
1431 pop ax
1432 pop cx
1433 ret
1434
1435 ;
1436 ; Free socket: socket in SI; return SI = 0, ZF = 1 for convenience
1437 ;
1438 free_socket:
1439 push es
1440 pusha
1441 xor ax,ax
1442 mov es,ax
1443 mov di,si
1444 mov cx,tftp_pktbuf >> 1 ; tftp_pktbuf is not cleared
1445 rep stosw
1446 popa
1447 pop es
1448 xor si,si
1449 ret
1450
1451 ;
1452 ; parse_dotquad:
1453 ; Read a dot-quad pathname in DS:SI and output an IP
1454 ; address in EAX, with SI pointing to the first
1455 ; nonmatching character.
1456 ;
1457 ; Return CF=1 on error.
1458 ;
1459 ; No segment assumptions permitted.
1460 ;
1461 parse_dotquad:
1462 push cx
1463 mov cx,4
1464 xor eax,eax
1465 .parseloop:
1466 mov ch,ah
1467 mov ah,al
1468 lodsb
1469 sub al,'0'
1470 jb .notnumeric
1471 cmp al,9
1472 ja .notnumeric
1473 aad ; AL += 10 * AH; AH = 0;
1474 xchg ah,ch
1475 jmp .parseloop
1476 .notnumeric:
1477 cmp al,'.'-'0'
1478 pushf
1479 mov al,ah
1480 mov ah,ch
1481 xor ch,ch
1482 ror eax,8
1483 popf
1484 jne .error
1485 loop .parseloop
1486 jmp .done
1487 .error:
1488 loop .realerror ; If CX := 1 then we're done
1489 clc
1490 jmp .done
1491 .realerror:
1492 stc
1493 .done:
1494 dec si ; CF unchanged!
1495 pop cx
1496 ret
1497
1498 ;
1499 ; is_url: Return CF=0 if and only if the buffer pointed to by
1500 ; DS:SI is a URL (contains ://). No registers modified.
1501 ;
1502 %if GPXE
1503 is_url:
1504 push si
1505 push eax
1506 .loop:
1507 mov eax,[si]
1508 inc si
1509 and al,al
1510 jz .not_url
1511 and eax,0FFFFFFh
1512 cmp eax,'://'
1513 jne .loop
1514 .done:
1515 ; CF=0 here
1516 pop eax
1517 pop si
1518 ret
1519 .not_url:
1520 stc
1521 jmp .done
1522 %endif
1523
1524 ;
1525 ; mangle_name: Mangle a filename pointed to by DS:SI into a buffer pointed
1526 ; to by ES:DI; ends on encountering any whitespace.
1527 ; DI is preserved.
1528 ;
1529 ; This verifies that a filename is < FILENAME_MAX characters
1530 ; and doesn't contain whitespace, and zero-pads the output buffer,
1531 ; so "repe cmpsb" can do a compare.
1532 ;
1533 ; The first four bytes of the manged name is the IP address of
1534 ; the download host, 0 for no host, or -1 for a gPXE URL.
1535 ;
1536 ; No segment assumptions permitted.
1537 ;
1538 mangle_name:
1539 push di
1540 %if GPXE
1541 call is_url
1542 jc .not_url
1543 or eax,-1 ; It's a URL
1544 jmp .prefix_done
1545 .not_url:
1546 %endif ; GPXE
1547 push si
1548 mov eax,[cs:ServerIP]
1549 cmp byte [si],0
1550 je .noip ; Null filename?!?!
1551 cmp word [si],'::' ; Leading ::?
1552 je .gotprefix
1553
1554 .more:
1555 inc si
1556 cmp byte [si],0
1557 je .noip
1558 cmp word [si],'::'
1559 jne .more
1560
1561 ; We have a :: prefix of some sort, it could be either
1562 ; a DNS name or a dot-quad IP address. Try the dot-quad
1563 ; first...
1564 .here:
1565 pop si
1566 push si
1567 call parse_dotquad
1568 jc .notdq
1569 cmp word [si],'::'
1570 je .gotprefix
1571 .notdq:
1572 pop si
1573 push si
1574 call dns_resolv
1575 cmp word [si],'::'
1576 jne .noip
1577 and eax,eax
1578 jnz .gotprefix
1579
1580 .noip:
1581 pop si
1582 xor eax,eax
1583 jmp .prefix_done
1584
1585 .gotprefix:
1586 pop cx ; Adjust stack
1587 inc si ; Skip double colon
1588 inc si
1589
1590 .prefix_done:
1591 stosd ; Save IP address prefix
1592 mov cx,FILENAME_MAX-5
1593
1594 .mn_loop:
1595 lodsb
1596 cmp al,' ' ; If control or space, end
1597 jna .mn_end
1598 stosb
1599 loop .mn_loop
1600 .mn_end:
1601 inc cx ; At least one null byte
1602 xor ax,ax ; Zero-fill name
1603 rep stosb ; Doesn't do anything if CX=0
1604 pop di
1605 ret ; Done
1606
1607 ;
1608 ; unmangle_name: Does the opposite of mangle_name; converts a DOS-mangled
1609 ; filename to the conventional representation. This is needed
1610 ; for the BOOT_IMAGE= parameter for the kernel.
1611 ;
1612 ; NOTE: The output buffer needs to be able to hold an
1613 ; expanded IP address.
1614 ;
1615 ; DS:SI -> input mangled file name
1616 ; ES:DI -> output buffer
1617 ;
1618 ; On return, DI points to the first byte after the output name,
1619 ; which is set to a null byte.
1620 ;
1621 unmangle_name:
1622 push eax
1623 lodsd
1624 and eax,eax
1625 jz .noip
1626 cmp eax,-1
1627 jz .noip ; URL
1628 call gendotquad
1629 mov ax,'::'
1630 stosw
1631 .noip:
1632 call strcpy
1633 dec di ; Point to final null byte
1634 pop eax
1635 ret
1636
1637 ;
1638 ; pxenv
1639 ;
1640 ; This is the main PXENV+/!PXE entry point, using the PXENV+
1641 ; calling convention. This is a separate local routine so
1642 ; we can hook special things from it if necessary. In particular,
1643 ; some PXE stacks seem to not like being invoked from anything but
1644 ; the initial stack, so humour it.
1645 ;
1646
1647 pxenv:
1648 %if USE_PXE_PROVIDED_STACK == 0
1649 mov [cs:PXEStack],sp
1650 mov [cs:PXEStack+2],ss
1651 lss sp,[cs:InitStack]
1652 %endif
1653 .jump: call 0:pxe_thunk ; Default to calling the thunk
1654 %if USE_PXE_PROVIDED_STACK == 0
1655 lss sp,[cs:PXEStack]
1656 %endif
1657 cld ; Make sure DF <- 0
1658 ret
1659
1660 ; Must be after function def due to NASM bug
1661 PXENVEntry equ pxenv.jump+1
1662
1663 ;
1664 ; pxe_thunk
1665 ;
1666 ; Convert from the PXENV+ calling convention (BX, ES, DI) to the !PXE
1667 ; calling convention (using the stack.)
1668 ;
1669 ; This is called as a far routine so that we can just stick it into
1670 ; the PXENVEntry variable.
1671 ;
1672 pxe_thunk: push es
1673 push di
1674 push bx
1675 .jump: call 0:0
1676 add sp,byte 6
1677 cmp ax,byte 1
1678 cmc ; Set CF unless ax == 0
1679 retf
1680
1681 ; Must be after function def due to NASM bug
1682 PXEEntry equ pxe_thunk.jump+1
1683
1684 ;
1685 ; getfssec: Get multiple clusters from a file, given the starting cluster.
1686 ;
1687 ; In this case, get multiple blocks from a specific TCP connection.
1688 ;
1689 ; On entry:
1690 ; ES:BX -> Buffer
1691 ; SI -> TFTP socket pointer
1692 ; CX -> 512-byte block count; 0FFFFh = until end of file
1693 ; On exit:
1694 ; SI -> TFTP socket pointer (or 0 on EOF)
1695 ; CF = 1 -> Hit EOF
1696 ; ECX -> number of bytes actually read
1697 ;
1698 getfssec:
1699 push eax
1700 push edi
1701 push bx
1702 push si
1703 push fs
1704 mov di,bx
1705 mov ax,pktbuf_seg
1706 mov fs,ax
1707
1708 xor eax,eax
1709 movzx ecx,cx
1710 shl ecx,TFTP_BLOCKSIZE_LG2 ; Convert to bytes
1711 push ecx ; Initial request size
1712 jz .hit_eof ; Nothing to do?
1713
1714 .need_more:
1715 call fill_buffer
1716 movzx eax,word [si+tftp_bytesleft]
1717 and ax,ax
1718 jz .hit_eof
1719
1720 push ecx
1721 cmp ecx,eax
1722 jna .ok_size
1723 mov ecx,eax
1724 .ok_size:
1725 mov ax,cx ; EAX<31:16> == ECX<31:16> == 0
1726 mov bx,[si+tftp_dataptr]
1727 sub [si+tftp_bytesleft],cx
1728 xchg si,bx
1729 fs rep movsb ; Copy from packet buffer
1730 xchg si,bx
1731 mov [si+tftp_dataptr],bx
1732
1733 pop ecx
1734 sub ecx,eax
1735 jnz .need_more
1736
1737 .hit_eof:
1738 call fill_buffer
1739
1740 pop eax ; Initial request amount
1741 xchg eax,ecx
1742 sub ecx,eax ; ... minus anything not gotten
1743
1744 pop fs
1745 pop si
1746
1747 ; Is there anything left of this?
1748 mov eax,[si+tftp_filesize]
1749 sub eax,[si+tftp_filepos]
1750 jnz .bytes_left
1751
1752 cmp [si+tftp_bytesleft],ax ; AX == 0
1753 jne .bytes_left
1754
1755 cmp byte [si+tftp_goteof],0
1756 je .done
1757 ; I'm 99% sure this can't happen, but...
1758 call fill_buffer ; Receive/ACK the EOF packet
1759 .done:
1760 ; The socket is closed and the buffer drained
1761 ; Close socket structure and re-init for next user
1762 call free_socket
1763 stc
1764 jmp .ret
1765 .bytes_left:
1766 clc
1767 .ret:
1768 pop bx
1769 pop edi
1770 pop eax
1771 ret
1772
1773 ;
1774 ; Get a fresh packet if the buffer is drained, and we haven't hit
1775 ; EOF yet. The buffer should be filled immediately after draining!
1776 ;
1777 ; expects fs -> pktbuf_seg and ds:si -> socket structure
1778 ;
1779 fill_buffer:
1780 cmp word [si+tftp_bytesleft],0
1781 je .empty
1782 ret ; Otherwise, nothing to do
1783
1784 .empty:
1785 push es
1786 pushad
1787 mov ax,ds
1788 mov es,ax
1789
1790 ; Note: getting the EOF packet is not the same thing
1791 ; as tftp_filepos == tftp_filesize; if the EOF packet
1792 ; is empty the latter condition can be true without
1793 ; having gotten the official EOF.
1794 cmp byte [si+tftp_goteof],0
1795 jne .ret ; Already EOF
1796
1797 %if GPXE
1798 cmp word [si+tftp_localport], -1
1799 jne .get_packet_tftp
1800 call get_packet_gpxe
1801 jmp .gotten
1802 .get_packet_tftp:
1803 %endif ; GPXE
1804 .gotten:
1805
1806 ; TFTP code...
1807 .packet_loop:
1808 ; Start by ACKing the previous packet; this should cause the
1809 ; next packet to be sent.
1810 mov cx,PKT_RETRY
1811 mov word [PktTimeout],PKT_TIMEOUT
1812
1813 .send_ack: push cx ; <D> Retry count
1814
1815 mov ax,[si+tftp_lastpkt]
1816 call ack_packet ; Send ACK
1817
1818 ; We used to test the error code here, but sometimes
1819 ; PXE would return negative status even though we really
1820 ; did send the ACK. Now, just treat a failed send as
1821 ; a normally lost packet, and let it time out in due
1822 ; course of events.
1823
1824 .send_ok: ; Now wait for packet.
1825 mov dx,[BIOS_timer] ; Get current time
1826
1827 mov cx,[PktTimeout]
1828 .wait_data: push cx ; <E> Timeout
1829 push dx ; <F> Old time
1830
1831 mov bx,[si+tftp_pktbuf]
1832 mov [pxe_udp_read_pkt.buffer],bx
1833 mov [pxe_udp_read_pkt.buffer+2],fs
1834 mov [pxe_udp_read_pkt.buffersize],word PKTBUF_SIZE
1835 mov eax,[si+tftp_remoteip]
1836 mov [pxe_udp_read_pkt.sip],eax
1837 mov eax,[MyIP]
1838 mov [pxe_udp_read_pkt.dip],eax
1839 mov ax,[si+tftp_remoteport]
1840 mov [pxe_udp_read_pkt.rport],ax
1841 mov ax,[si+tftp_localport]
1842 mov [pxe_udp_read_pkt.lport],ax
1843 mov di,pxe_udp_read_pkt
1844 mov bx,PXENV_UDP_READ
1845 push si ; <G>
1846 call pxenv
1847 pop si ; <G>
1848 and ax,ax
1849 jz .recv_ok
1850
1851 ; No packet, or receive failure
1852 mov dx,[BIOS_timer]
1853 pop ax ; <F> Old time
1854 pop cx ; <E> Timeout
1855 cmp ax,dx ; Same time -> don't advance timeout
1856 je .wait_data ; Same clock tick
1857 loop .wait_data ; Decrease timeout
1858
1859 pop cx ; <D> Didn't get any, send another ACK
1860 shl word [PktTimeout],1 ; Exponential backoff
1861 loop .send_ack
1862 jmp kaboom ; Forget it...
1863
1864 .recv_ok: pop dx ; <F>
1865 pop cx ; <E>
1866
1867 cmp word [pxe_udp_read_pkt.buffersize],byte 4
1868 jb .wait_data ; Bad size for a DATA packet
1869
1870 mov bx,[si+tftp_pktbuf]
1871 cmp word [fs:bx],TFTP_DATA ; Not a data packet?
1872 jne .wait_data ; Then wait for something else
1873
1874 mov ax,[si+tftp_lastpkt]
1875 xchg ah,al ; Host byte order
1876 inc ax ; Which packet are we waiting for?
1877 xchg ah,al ; Network byte order
1878 cmp [fs:bx+2],ax
1879 je .right_packet
1880
1881 ; Wrong packet, ACK the packet and then try again
1882 ; This is presumably because the ACK got lost,
1883 ; so the server just resent the previous packet
1884 mov ax,[fs:bx+2]
1885 call ack_packet
1886 jmp .send_ok ; Reset timeout
1887
1888 .right_packet: ; It's the packet we want. We're also EOF if the
1889 ; size < blocksize
1890
1891 pop cx ; <D> Don't need the retry count anymore
1892
1893 mov [si+tftp_lastpkt],ax ; Update last packet number
1894
1895 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1896 sub cx,byte 4 ; Skip TFTP header
1897
1898 ; Set pointer to data block
1899 lea ax,[bx+4] ; Data past TFTP header
1900 mov [si+tftp_dataptr],ax
1901
1902 add [si+tftp_filepos],ecx
1903 mov [si+tftp_bytesleft],cx
1904
1905 cmp cx,[si+tftp_blksize] ; Is it a full block?
1906 jb .last_block ; If not, it's EOF
1907
1908 .ret:
1909 popad
1910 pop es
1911 ret
1912
1913
1914 .last_block: ; Last block - ACK packet immediately
1915 TRACER 'L'
1916 mov ax,[fs:bx+2]
1917 call ack_packet
1918
1919 ; Make sure we know we are at end of file
1920 mov eax,[si+tftp_filepos]
1921 mov [si+tftp_filesize],eax
1922 mov byte [si+tftp_goteof],1
1923
1924 jmp .ret
1925
1926 ;
1927 ; ack_packet:
1928 ;
1929 ; Send ACK packet. This is a common operation and so is worth canning.
1930 ;
1931 ; Entry:
1932 ; SI = TFTP block
1933 ; AX = Packet # to ack (network byte order)
1934 ; Exit:
1935 ; ZF = 0 -> Error
1936 ; All registers preserved
1937 ;
1938 ; This function uses the pxe_udp_write_pkt but not the packet_buf.
1939 ;
1940 ack_packet:
1941 pushad
1942 mov [ack_packet_buf+2],ax ; Packet number to ack
1943 mov ax,[si]
1944 mov [pxe_udp_write_pkt.lport],ax
1945 mov ax,[si+tftp_remoteport]
1946 mov [pxe_udp_write_pkt.rport],ax
1947 mov eax,[si+tftp_remoteip]
1948 mov [pxe_udp_write_pkt.sip],eax
1949 xor eax,[MyIP]
1950 and eax,[Netmask]
1951 jz .nogw
1952 mov eax,[Gateway]
1953 .nogw:
1954 mov [pxe_udp_write_pkt.gip],eax
1955 mov [pxe_udp_write_pkt.buffer],word ack_packet_buf
1956 mov [pxe_udp_write_pkt.buffersize], word 4
1957 mov di,pxe_udp_write_pkt
1958 mov bx,PXENV_UDP_WRITE
1959 call pxenv
1960 cmp ax,byte 0 ; ZF = 1 if write OK
1961 popad
1962 ret
1963
1964 %if GPXE
1965 ;
1966 ; Get a fresh packet from a gPXE socket; expects fs -> pktbuf_seg
1967 ; and ds:si -> socket structure
1968 ;
1969 ; Assumes CS == DS == ES.
1970 ;
1971 get_packet_gpxe:
1972 TRACER 'g'
1973
1974 mov ax,[si+tftp_remoteport] ; gPXE filehandle
1975 mov [di+2],ax
1976 mov word [di+4],PKTBUF_SIZE
1977 mov ax,[si+tftp_pktbuf]
1978 mov [di+6],ax
1979 mov [si+tftp_dataptr],ax
1980 mov [di+8],fs
1981
1982 .again:
1983 mov bx,PXENV_FILE_READ
1984 call pxenv
1985 ; XXX: FIX THIS: Need to be able to distinguish
1986 ; error, EOF, and no data
1987 jc .again
1988
1989 movzx eax,word [di+4] ; Bytes read
1990 mov [si+tftp_bytesleft],ax ; Bytes in buffer
1991 add [si+tftp_filepos],eax ; Position in file
1992
1993 and ax,ax
1994 jnz .got_stuff
1995
1996 ; We got EOF here, make sure the upper layers know
1997 mov eax,[si+tftp_filepos]
1998 mov [si+tftp_filesize],eax
1999
2000 .got_stuff:
2001 ; If we're done here, close the file
2002 mov eax,[si+tftp_filepos]
2003 cmp [si+tftp_filesize],eax
2004 ja .done ; Not EOF, there is still data...
2005
2006 ; Reuse the previous [es:di] structure since the
2007 ; relevant fields are all the same
2008 mov byte [si+tftp_goteof],1
2009
2010 mov bx,PXENV_FILE_CLOSE
2011 call pxenv
2012 ; Ignore return...
2013 .done:
2014 ret
2015 %endif ; GPXE
2016
2017 ;
2018 ; unload_pxe:
2019 ;
2020 ; This function unloads the PXE and UNDI stacks and unclaims
2021 ; the memory.
2022 ;
2023 unload_pxe:
2024 test byte [KeepPXE],01h ; Should we keep PXE around?
2025 jnz reset_pxe
2026
2027 push ds
2028 push es
2029
2030 mov ax,cs
2031 mov ds,ax
2032 mov es,ax
2033
2034 mov si,new_api_unload
2035 cmp byte [APIVer+1],2 ; Major API version >= 2?
2036 jae .new_api
2037 mov si,old_api_unload
2038 .new_api:
2039
2040 .call_loop: xor ax,ax
2041 lodsb
2042 and ax,ax
2043 jz .call_done
2044 xchg bx,ax
2045 mov di,pxe_unload_stack_pkt
2046 push di
2047 xor ax,ax
2048 mov cx,pxe_unload_stack_pkt_len >> 1
2049 rep stosw
2050 pop di
2051 call pxenv
2052 jc .cant_free
2053 mov ax,word [pxe_unload_stack_pkt.status]
2054 cmp ax,PXENV_STATUS_SUCCESS
2055 jne .cant_free
2056 jmp .call_loop
2057
2058 .call_done:
2059 mov bx,0FF00h
2060
2061 mov dx,[RealBaseMem]
2062 cmp dx,[BIOS_fbm] ; Sanity check
2063 jna .cant_free
2064 inc bx
2065
2066 ; Check that PXE actually unhooked the INT 1Ah chain
2067 movzx eax,word [4*0x1a]
2068 movzx ecx,word [4*0x1a+2]
2069 shl ecx,4
2070 add eax,ecx
2071 shr eax,10
2072 cmp ax,dx ; Not in range
2073 jae .ok
2074 cmp ax,[BIOS_fbm]
2075 jae .cant_free
2076 ; inc bx
2077
2078 .ok:
2079 mov [BIOS_fbm],dx
2080 .pop_ret:
2081 pop es
2082 pop ds
2083 ret
2084
2085 .cant_free:
2086 mov si,cant_free_msg
2087 call writestr
2088 push ax
2089 xchg bx,ax
2090 call writehex4
2091 mov al,'-'
2092 call writechr
2093 pop ax
2094 call writehex4
2095 mov al,'-'
2096 call writechr
2097 mov eax,[4*0x1a]
2098 call writehex8
2099 call crlf
2100 jmp .pop_ret
2101
2102 ; We want to keep PXE around, but still we should reset
2103 ; it to the standard bootup configuration
2104 reset_pxe:
2105 push es
2106 push cs
2107 pop es
2108 mov bx,PXENV_UDP_CLOSE
2109 mov di,pxe_udp_close_pkt
2110 call pxenv
2111 pop es
2112 ret
2113
2114 ;
2115 ; gendotquad
2116 ;
2117 ; Take an IP address (in network byte order) in EAX and
2118 ; output a dotted quad string to ES:DI.
2119 ; DI points to terminal null at end of string on exit.
2120 ;
2121 gendotquad:
2122 push eax
2123 push cx
2124 mov cx,4
2125 .genchar:
2126 push eax
2127 cmp al,10 ; < 10?
2128 jb .lt10 ; If so, skip first 2 digits
2129
2130 cmp al,100 ; < 100
2131 jb .lt100 ; If so, skip first digit
2132
2133 aam 100
2134 ; Now AH = 100-digit; AL = remainder
2135 add ah,'0'
2136 mov [es:di],ah
2137 inc di
2138
2139 .lt100:
2140 aam 10
2141 ; Now AH = 10-digit; AL = remainder
2142 add ah,'0'
2143 mov [es:di],ah
2144 inc di
2145
2146 .lt10:
2147 add al,'0'
2148 stosb
2149 mov al,'.'
2150 stosb
2151 pop eax
2152 ror eax,8 ; Move next char into LSB
2153 loop .genchar
2154 dec di
2155 mov [es:di], byte 0
2156 pop cx
2157 pop eax
2158 ret
2159 ;
2160 ; uchexbytes/lchexbytes
2161 ;
2162 ; Take a number of bytes in memory and convert to upper/lower-case
2163 ; hexadecimal
2164 ;
2165 ; Input:
2166 ; DS:SI = input bytes
2167 ; ES:DI = output buffer
2168 ; CX = number of bytes
2169 ; Output:
2170 ; DS:SI = first byte after
2171 ; ES:DI = first byte after
2172 ; CX = 0
2173 ;
2174 ; Trashes AX, DX
2175 ;
2176
2177 lchexbytes:
2178 mov dl,'a'-'9'-1
2179 jmp xchexbytes
2180 uchexbytes:
2181 mov dl,'A'-'9'-1
2182 xchexbytes:
2183 .loop:
2184 lodsb
2185 mov ah,al
2186 shr al,4
2187 call .outchar
2188 mov al,ah
2189 call .outchar
2190 loop .loop
2191 ret
2192 .outchar:
2193 and al,0Fh
2194 add al,'0'
2195 cmp al,'9'
2196 jna .done
2197 add al,dl
2198 .done:
2199 stosb
2200 ret
2201
2202 ;
2203 ; pxe_get_cached_info
2204 ;
2205 ; Get a DHCP packet from the PXE stack into the trackbuf.
2206 ;
2207 ; Input:
2208 ; DL = packet type
2209 ; Output:
2210 ; CX = buffer size
2211 ;
2212 ; Assumes CS == DS == ES.
2213 ;
2214 pxe_get_cached_info:
2215 pushad
2216 mov di,pxe_bootp_query_pkt
2217 push di
2218 xor ax,ax
2219 stosw ; Status
2220 movzx ax,dl
2221 stosw ; Packet type
2222 mov ax,trackbufsize
2223 stosw ; Buffer size
2224 mov ax,trackbuf
2225 stosw ; Buffer offset
2226 xor ax,ax
2227 stosw ; Buffer segment
2228
2229 pop di ; DI -> parameter set
2230 mov bx,PXENV_GET_CACHED_INFO
2231 call pxenv
2232 jc .err
2233 and ax,ax
2234 jnz .err
2235
2236 popad
2237 mov cx,[pxe_bootp_query_pkt.buffersize]
2238 ret
2239
2240 .err:
2241 mov si,err_pxefailed
2242 jmp kaboom
2243
2244 ;
2245 ; ip_ok
2246 ;
2247 ; Tests an IP address in EAX for validity; return with ZF=1 for bad.
2248 ; We used to refuse class E, but class E addresses are likely to become
2249 ; assignable unicast addresses in the near future.
2250 ;
2251 ip_ok:
2252 push ax
2253 cmp eax,-1 ; Refuse the all-ones address
2254 jz .out
2255 and al,al ; Refuse network zero
2256 jz .out
2257 cmp al,127 ; Refuse loopback
2258 jz .out
2259 and al,0F0h
2260 cmp al,224 ; Refuse class D
2261 .out:
2262 pop ax
2263 ret
2264
2265 ;
2266 ; parse_dhcp
2267 ;
2268 ; Parse a DHCP packet. This includes dealing with "overloaded"
2269 ; option fields (see RFC 2132, section 9.3)
2270 ;
2271 ; This should fill in the following global variables, if the
2272 ; information is present:
2273 ;
2274 ; MyIP - client IP address
2275 ; ServerIP - boot server IP address
2276 ; Netmask - network mask
2277 ; Gateway - default gateway router IP
2278 ; BootFile - boot file name
2279 ; DNSServers - DNS server IPs
2280 ; LocalDomain - Local domain name
2281 ; MACLen, MAC - Client identifier, if MACLen == 0
2282 ;
2283 ; This assumes the DHCP packet is in "trackbuf" and the length
2284 ; of the packet in in CX on entry.
2285 ;
2286
2287 parse_dhcp:
2288 mov byte [OverLoad],0 ; Assume no overload
2289 mov eax, [trackbuf+bootp.yip]
2290 call ip_ok
2291 jz .noyip
2292 mov [MyIP], eax
2293 .noyip:
2294 mov eax, [trackbuf+bootp.sip]
2295 and eax, eax
2296 call ip_ok
2297 jz .nosip
2298 mov [ServerIP], eax
2299 .nosip:
2300 sub cx, bootp.options
2301 jbe .nooptions
2302 mov si, trackbuf+bootp.option_magic
2303 lodsd
2304 cmp eax, BOOTP_OPTION_MAGIC
2305 jne .nooptions
2306 call parse_dhcp_options
2307 .nooptions:
2308 mov si, trackbuf+bootp.bootfile
2309 test byte [OverLoad],1
2310 jz .nofileoverload
2311 mov cx,128
2312 call parse_dhcp_options
2313 jmp short .parsed_file
2314 .nofileoverload:
2315 cmp byte [si], 0
2316 jz .parsed_file ; No bootfile name
2317 mov di,BootFile
2318 mov cx,32
2319 rep movsd
2320 xor al,al
2321 stosb ; Null-terminate
2322 .parsed_file:
2323 mov si, trackbuf+bootp.sname
2324 test byte [OverLoad],2
2325 jz .nosnameoverload
2326 mov cx,64
2327 call parse_dhcp_options
2328 .nosnameoverload:
2329 ret
2330
2331 ;
2332 ; Parse a sequence of DHCP options, pointed to by DS:SI; the field
2333 ; size is CX -- some DHCP servers leave option fields unterminated
2334 ; in violation of the spec.
2335 ;
2336 ; For parse_some_dhcp_options, DH contains the minimum value for
2337 ; the option to recognize -- this is used to restrict parsing to
2338 ; PXELINUX-specific options only.
2339 ;
2340 parse_dhcp_options:
2341 xor dx,dx
2342
2343 parse_some_dhcp_options:
2344 .loop:
2345 and cx,cx
2346 jz .done
2347
2348 lodsb
2349 dec cx
2350 jz .done ; Last byte; must be PAD, END or malformed
2351 cmp al, 0 ; PAD option
2352 je .loop
2353 cmp al,255 ; END option
2354 je .done
2355
2356 ; Anything else will have a length field
2357 mov dl,al ; DL <- option number
2358 xor ax,ax
2359 lodsb ; AX <- option length
2360 dec cx
2361 sub cx,ax ; Decrement bytes left counter
2362 jb .done ; Malformed option: length > field size
2363
2364 cmp dl,dh ; Is the option value valid?
2365 jb .opt_done
2366
2367 mov bx,dhcp_option_list
2368 .find_option:
2369 cmp bx,dhcp_option_list_end
2370 jae .opt_done
2371 cmp dl,[bx]
2372 je .found_option
2373 add bx,3
2374 jmp .find_option
2375 .found_option:
2376 pushad
2377 call [bx+1]
2378 popad
2379
2380 ; Fall through
2381 ; Unknown option. Skip to the next one.
2382 .opt_done:
2383 add si,ax
2384 jmp .loop
2385 .done:
2386 ret
2387
2388 section .data
2389 dhcp_option_list:
2390 section .text
2391
2392 %macro dopt 2
2393 section .data
2394 db %1
2395 dw dopt_%2
2396 section .text
2397 dopt_%2:
2398 %endmacro
2399
2400 ;
2401 ; Parse individual DHCP options. SI points to the option data and
2402 ; AX to the option length. DL contains the option number.
2403 ; All registers are saved around the routine.
2404 ;
2405 dopt 1, subnet_mask
2406 mov ebx,[si]
2407 mov [Netmask],ebx
2408 ret
2409
2410 dopt 3, router
2411 mov ebx,[si]
2412 mov [Gateway],ebx
2413 ret
2414
2415 dopt 6, dns_servers
2416 mov cx,ax
2417 shr cx,2
2418 cmp cl,DNS_MAX_SERVERS
2419 jna .oklen
2420 mov cl,DNS_MAX_SERVERS
2421 .oklen:
2422 mov di,DNSServers
2423 rep movsd
2424 mov [LastDNSServer],di
2425 ret
2426
2427 dopt 16, local_domain
2428 mov bx,si
2429 add bx,ax
2430 xor ax,ax
2431 xchg [bx],al ; Zero-terminate option
2432 mov di,LocalDomain
2433 call dns_mangle ; Convert to DNS label set
2434 mov [bx],al ; Restore ending byte
2435 ret
2436
2437 dopt 43, vendor_encaps
2438 mov dh,208 ; Only recognize PXELINUX options
2439 mov cx,ax ; Length of option = max bytes to parse
2440 call parse_some_dhcp_options ; Parse recursive structure
2441 ret
2442
2443 dopt 52, option_overload
2444 mov bl,[si]
2445 mov [OverLoad],bl
2446 ret
2447
2448 dopt 54, server
2449 mov eax,[si]
2450 cmp dword [ServerIP],0
2451 jne .skip ; Already have a next server IP
2452 call ip_ok
2453 jz .skip
2454 mov [ServerIP],eax
2455 .skip: ret
2456
2457 dopt 61, client_identifier
2458 cmp ax,MAC_MAX ; Too long?
2459 ja .skip
2460 cmp ax,2 ; Too short?
2461 jb .skip
2462 cmp [MACLen],ah ; Only do this if MACLen == 0
2463 jne .skip
2464 push ax
2465 lodsb ; Client identifier type
2466 cmp al,[MACType]
2467 pop ax
2468 jne .skip ; Client identifier is not a MAC
2469 dec ax
2470 mov [MACLen],al
2471 mov di,MAC
2472 jmp dhcp_copyoption
2473 .skip: ret
2474
2475 dopt 67, bootfile_name
2476 mov di,BootFile
2477 jmp dhcp_copyoption
2478
2479 dopt 97, uuid_client_identifier
2480 cmp ax,17 ; type byte + 16 bytes UUID
2481 jne .skip
2482 mov dl,[si] ; Must have type 0 == UUID
2483 or dl,[HaveUUID] ; Capture only the first instance
2484 jnz .skip
2485 mov byte [HaveUUID],1 ; Got UUID
2486 mov di,UUIDType
2487 jmp dhcp_copyoption
2488 .skip: ret
2489
2490 dopt 209, pxelinux_configfile
2491 mov di,ConfigName
2492 or byte [DHCPMagic],2 ; Got config file
2493 jmp dhcp_copyoption
2494
2495 dopt 210, pxelinux_pathprefix
2496 mov di,PathPrefix
2497 or byte [DHCPMagic],4 ; Got path prefix
2498 jmp dhcp_copyoption
2499
2500 dopt 211, pxelinux_reboottime
2501 cmp al,4
2502 jne .done
2503 mov ebx,[si]
2504 xchg bl,bh ; Convert to host byte order
2505 rol ebx,16
2506 xchg bl,bh
2507 mov [RebootTime],ebx
2508 or byte [DHCPMagic],8 ; Got RebootTime
2509 .done: ret
2510
2511 ; Common code for copying an option verbatim
2512 ; Copies the option into ES:DI and null-terminates it.
2513 ; Returns with AX=0 and SI past the option.
2514 dhcp_copyoption:
2515 xchg cx,ax ; CX <- option length
2516 rep movsb
2517 xchg cx,ax ; AX <- 0
2518 stosb ; Null-terminate
2519 ret
2520
2521 section .data
2522 dhcp_option_list_end:
2523 section .text
2524
2525 section .data
2526 HaveUUID db 0
2527 uuid_dashes db 4,2,2,2,6,0 ; Bytes per UUID dashed section
2528 section .text
2529
2530 ;
2531 ; genipopt
2532 ;
2533 ; Generate an ip=<client-ip>:<boot-server-ip>:<gw-ip>:<netmask>
2534 ; option into IPOption based on a DHCP packet in trackbuf.
2535 ; Assumes CS == DS == ES.
2536 ;
2537 genipopt:
2538 pushad
2539 mov di,IPOption
2540 mov eax,'ip='
2541 stosd
2542 dec di
2543 mov eax,[MyIP]
2544 call gendotquad
2545 mov al,':'
2546 stosb
2547 mov eax,[ServerIP]
2548 call gendotquad
2549 mov al,':'
2550 stosb
2551 mov eax,[Gateway]
2552 call gendotquad
2553 mov al,':'
2554 stosb
2555 mov eax,[Netmask]
2556 call gendotquad ; Zero-terminates its output
2557 sub di,IPOption
2558 mov [IPOptionLen],di
2559 popad
2560 ret
2561
2562 ;
2563 ; Call the receive loop while idle. This is done mostly so we can respond to
2564 ; ARP messages, but perhaps in the future this can be used to do network
2565 ; console.
2566 ;
2567 ; hpa sez: people using automatic control on the serial port get very
2568 ; unhappy if we poll for ARP too often (the PXE stack is pretty slow,
2569 ; typically.) Therefore, only poll if at least 4 BIOS timer ticks have
2570 ; passed since the last poll, and reset this when a character is
2571 ; received (RESET_IDLE).
2572 ;
2573 %if HAVE_IDLE
2574
2575 reset_idle:
2576 push ax
2577 mov ax,[cs:BIOS_timer]
2578 mov [cs:IdleTimer],ax
2579 pop ax
2580 ret
2581
2582 check_for_arp:
2583 push ax
2584 mov ax,[cs:BIOS_timer]
2585 sub ax,[cs:IdleTimer]
2586 cmp ax,4
2587 pop ax
2588 jae .need_poll
2589 ret
2590 .need_poll: pushad
2591 push ds
2592 push es
2593 mov ax,cs
2594 mov ds,ax
2595 mov es,ax
2596 mov di,packet_buf
2597 mov [pxe_udp_read_pkt.status],al ; 0
2598 mov [pxe_udp_read_pkt.buffer],di
2599 mov [pxe_udp_read_pkt.buffer+2],ds
2600 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
2601 mov eax,[MyIP]
2602 mov [pxe_udp_read_pkt.dip],eax
2603 mov word [pxe_udp_read_pkt.lport],htons(9) ; discard port
2604 mov di,pxe_udp_read_pkt
2605 mov bx,PXENV_UDP_READ
2606 call pxenv
2607 ; Ignore result...
2608 pop es
2609 pop ds
2610 popad
2611 RESET_IDLE
2612 ret
2613
2614 %endif ; HAVE_IDLE
2615
2616 ; -----------------------------------------------------------------------------
2617 ; Common modules
2618 ; -----------------------------------------------------------------------------
2619
2620 %include "getc.inc" ; getc et al
2621 %include "conio.inc" ; Console I/O
2622 %include "writestr.inc" ; String output
2623 writestr equ cwritestr
2624 %include "writehex.inc" ; Hexadecimal output
2625 %include "configinit.inc" ; Initialize configuration
2626 %include "parseconfig.inc" ; High-level config file handling
2627 %include "parsecmd.inc" ; Low-level config file handling
2628 %include "bcopy32.inc" ; 32-bit bcopy
2629 %include "loadhigh.inc" ; Load a file into high memory
2630 %include "font.inc" ; VGA font stuff
2631 %include "graphics.inc" ; VGA graphics
2632 %include "highmem.inc" ; High memory sizing
2633 %include "strcpy.inc" ; strcpy()
2634 %include "rawcon.inc" ; Console I/O w/o using the console functions
2635 %include "dnsresolv.inc" ; DNS resolver
2636 %include "adv.inc" ; Auxillary Data Vector
2637
2638 ; -----------------------------------------------------------------------------
2639 ; Begin data section
2640 ; -----------------------------------------------------------------------------
2641
2642 section .data
2643
2644 copyright_str db ' Copyright (C) 1994-', year, ' H. Peter Anvin'
2645 db CR, LF, 0
2646 err_bootfailed db CR, LF, 'Boot failed: press a key to retry, or wait for reset...', CR, LF, 0
2647 bailmsg equ err_bootfailed
2648 err_nopxe db "No !PXE or PXENV+ API found; we're dead...", CR, LF, 0
2649 err_pxefailed db 'PXE API call failed, error ', 0
2650 err_udpinit db 'Failed to initialize UDP stack', CR, LF, 0
2651 err_noconfig db 'Unable to locate configuration file', CR, LF, 0
2652 err_damage db 'TFTP server sent an incomprehesible reply', CR, LF, 0
2653 found_pxenv db 'Found PXENV+ structure', CR, LF, 0
2654 using_pxenv_msg db 'Old PXE API detected, using PXENV+ structure', CR, LF, 0
2655 apiver_str db 'PXE API version is ',0
2656 pxeentry_msg db 'PXE entry point found (we hope) at ', 0
2657 pxenventry_msg db 'PXENV entry point found (we hope) at ', 0
2658 trymempxe_msg db 'Scanning memory for !PXE structure... ', 0
2659 trymempxenv_msg db 'Scanning memory for PXENV+ structure... ', 0
2660 undi_data_msg db 'UNDI data segment at: ',0
2661 undi_data_len_msg db 'UNDI data segment size: ',0
2662 undi_code_msg db 'UNDI code segment at: ',0
2663 undi_code_len_msg db 'UNDI code segment size: ',0
2664 cant_free_msg db 'Failed to free base memory, error ', 0
2665 notfound_msg db 'not found', CR, LF, 0
2666 myipaddr_msg db 'My IP address seems to be ',0
2667 tftpprefix_msg db 'TFTP prefix: ', 0
2668 localboot_msg db 'Booting from local disk...', CR, LF, 0
2669 trying_msg db 'Trying to load: ', 0
2670 fourbs_msg db BS, BS, BS, BS, 0
2671 default_str db 'default', 0
2672 syslinux_banner db CR, LF, 'PXELINUX ', version_str, ' ', date, ' ', 0
2673 cfgprefix db 'pxelinux.cfg/' ; No final null!
2674 cfgprefix_len equ ($-cfgprefix)
2675
2676 ;
2677 ; Command line options we'd like to take a look at
2678 ;
2679 ; mem= and vga= are handled as normal 32-bit integer values
2680 initrd_cmd db 'initrd='
2681 initrd_cmd_len equ $-initrd_cmd
2682
2683 ; This one we make ourselves
2684 bootif_str db 'BOOTIF='
2685 bootif_str_len equ $-bootif_str
2686 ;
2687 ; Config file keyword table
2688 ;
2689 %include "keywords.inc"
2690
2691 ;
2692 ; Extensions to search for (in *forward* order).
2693 ; (.bs and .bss are disabled for PXELINUX, since they are not supported)
2694 ;
2695 align 4, db 0
2696 exten_table: db '.cbt' ; COMBOOT (specific)
2697 db '.0', 0, 0 ; PXE bootstrap program
2698 db '.com' ; COMBOOT (same as DOS)
2699 db '.c32' ; COM32
2700 exten_table_end:
2701 dd 0, 0 ; Need 8 null bytes here
2702
2703 ;
2704 ; PXE unload sequences
2705 ;
2706 new_api_unload:
2707 db PXENV_UDP_CLOSE
2708 db PXENV_UNDI_SHUTDOWN
2709 db PXENV_UNLOAD_STACK
2710 db PXENV_STOP_UNDI
2711 db 0
2712 old_api_unload:
2713 db PXENV_UDP_CLOSE
2714 db PXENV_UNDI_SHUTDOWN
2715 db PXENV_UNLOAD_STACK
2716 db PXENV_UNDI_CLEANUP
2717 db 0
2718
2719 ;
2720 ; PXE query packets partially filled in
2721 ;
2722 section .bss
2723 pxe_bootp_query_pkt:
2724 .status: resw 1 ; Status
2725 .packettype: resw 1 ; Boot server packet type
2726 .buffersize: resw 1 ; Packet size
2727 .buffer: resw 2 ; seg:off of buffer
2728 .bufferlimit: resw 1 ; Unused
2729
2730 section .data
2731 pxe_udp_open_pkt:
2732 .status: dw 0 ; Status
2733 .sip: dd 0 ; Source (our) IP
2734
2735 pxe_udp_close_pkt:
2736 .status: dw 0 ; Status
2737
2738 pxe_udp_write_pkt:
2739 .status: dw 0 ; Status
2740 .sip: dd 0 ; Server IP
2741 .gip: dd 0 ; Gateway IP
2742 .lport: dw 0 ; Local port
2743 .rport: dw 0 ; Remote port
2744 .buffersize: dw 0 ; Size of packet
2745 .buffer: dw 0, 0 ; seg:off of buffer
2746
2747 pxe_udp_read_pkt:
2748 .status: dw 0 ; Status
2749 .sip: dd 0 ; Source IP
2750 .dip: dd 0 ; Destination (our) IP
2751 .rport: dw 0 ; Remote port
2752 .lport: dw 0 ; Local port
2753 .buffersize: dw 0 ; Max packet size
2754 .buffer: dw 0, 0 ; seg:off of buffer
2755
2756 %if GPXE
2757
2758 gpxe_file_open:
2759 .status: dw 0 ; Status
2760 .filehandle: dw 0 ; FileHandle
2761 .filename: dd 0 ; seg:off of FileName
2762 .reserved: dd 0
2763
2764 gpxe_get_file_size:
2765 .status: dw 0 ; Status
2766 .filehandle: dw 0 ; FileHandle
2767 .filesize: dd 0 ; FileSize
2768
2769 gpxe_file_read:
2770 .status: dw 0 ; Status
2771 .filehandle: dw 0 ; FileHandle
2772 .buffersize: dw 0 ; BufferSize
2773 .buffer: dd 0 ; seg:off of buffer
2774
2775 %endif ; GPXE
2776
2777 ;
2778 ; Misc initialized (data) variables
2779 ;
2780 alignb 4, db 0
2781 BaseStack dd StackBuf ; ESP of base stack
2782 dw 0 ; SS of base stack
2783 NextSocket dw 49152 ; Counter for allocating socket numbers
2784 KeepPXE db 0 ; Should PXE be kept around?
2785
2786 ;
2787 ; TFTP commands
2788 ;
2789 tftp_tail db 'octet', 0 ; Octet mode
2790 tsize_str db 'tsize' ,0 ; Request size
2791 tsize_len equ ($-tsize_str)
2792 db '0', 0
2793 blksize_str db 'blksize', 0 ; Request large blocks
2794 blksize_len equ ($-blksize_str)
2795 asciidec TFTP_LARGEBLK
2796 db 0
2797 tftp_tail_len equ ($-tftp_tail)
2798
2799 alignb 2, db 0
2800 ;
2801 ; Options negotiation parsing table (string pointer, string len, offset
2802 ; into socket structure)
2803 ;
2804 tftp_opt_table:
2805 dw tsize_str, tsize_len, tftp_filesize
2806 dw blksize_str, blksize_len, tftp_blksize
2807 tftp_opts equ ($-tftp_opt_table)/6
2808
2809 ;
2810 ; Error packet to return on options negotiation error
2811 ;
2812 tftp_opt_err dw TFTP_ERROR ; ERROR packet
2813 dw TFTP_EOPTNEG ; ERROR 8: bad options
2814 db 'tsize option required', 0 ; Error message
2815 tftp_opt_err_len equ ($-tftp_opt_err)
2816
2817 alignb 4, db 0
2818 ack_packet_buf: dw TFTP_ACK, 0 ; TFTP ACK packet
2819
2820 ;
2821 ; IP information (initialized to "unknown" values)
2822 MyIP dd 0 ; My IP address
2823 ServerIP dd 0 ; IP address of boot server
2824 Netmask dd 0 ; Netmask of this subnet
2825 Gateway dd 0 ; Default router
2826 ServerPort dw TFTP_PORT ; TFTP server port
2827
2828 ;
2829 ; Variables that are uninitialized in SYSLINUX but initialized here
2830 ;
2831 alignb 4, db 0
2832 BufSafe dw trackbufsize/TFTP_BLOCKSIZE ; Clusters we can load into trackbuf
2833 BufSafeBytes dw trackbufsize ; = how many bytes?
2834 %ifndef DEPEND
2835 %if ( trackbufsize % TFTP_BLOCKSIZE ) != 0
2836 %error trackbufsize must be a multiple of TFTP_BLOCKSIZE
2837 %endif
2838 %endif
The Syslinux boot loader collection