com32/lib/sys/entry.S

   1 /* -----------------------------------------------------------------------
   2  *
   3  *   Copyright 2003-2008 H. Peter Anvin - All Rights Reserved
   4  *
   5  *   Permission is hereby granted, free of charge, to any person
   6  *   obtaining a copy of this software and associated documentation
   7  *   files (the "Software"), to deal in the Software without
   8  *   restriction, including without limitation the rights to use,
   9  *   copy, modify, merge, publish, distribute, sublicense, and/or
  10  *   sell copies of the Software, and to permit persons to whom
  11  *   the Software is furnished to do so, subject to the following
  12  *   conditions:
  13  *
  14  *   The above copyright notice and this permission notice shall
  15  *   be included in all copies or substantial portions of the Software.
  16  *
  17  *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18  *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19  *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20  *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21  *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22  *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23  *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24  *   OTHER DEALINGS IN THE SOFTWARE.
  25  *
  26  * ----------------------------------------------------------------------- */
  27
  28 /*
  29  * COM32 start up code - must be linked first in the binary
  30  */
  31
  32 /* Number of arguments in our version of the entry structure */
  33 #define COM32_ARGS 9
  34
  35                 .section ".init","ax"
  36                 .globl _start
  37                 .type _start, @function
  38 _start:
  39                 /* This first instruction acts as COM32R magic number */
  40                 movl $0x21cd4cfe,%eax
  41
  42                 /* Upwards string operations */
  43                 cld
  44
  45                 /* Find our own location */
  46                 call 1f
  47 1:              popl %ebx
  48                 addl $_GLOBAL_OFFSET_TABLE_ + (. - 1b), %ebx
  49
  50                 /* Process relocations (which overlay the .bss segment) */
  51                 leal _edata@GOTOFF(%ebx),%esi
  52                 leal _start@GOTOFF(%ebx),%edx
  53 2:              lodsl
  54                 andl %eax,%eax
  55                 jz 3f
  56                 addl %edx,(%eax,%edx)
  57                 jmp 2b
  58 3:
  59                 /* Relocate the GOT (is this right?) */
  60                 leal __got_start@GOTOFF(%ebx),%esi
  61                 leal __got_end@GOTOFF(%ebx),%edi
  62 4:
  63                 addl %edx,(%esi)
  64                 addl $4,%esi
  65                 cmpl %edi,%esi
  66                 jb 4b
  67
  68                 /* Zero the .bss segment */
  69                 xorl %eax,%eax
  70                 leal __bss_start@GOTOFF(%ebx),%edi
  71                 leal _end+3@GOTOFF(%ebx),%ecx
  72                 subl %edi,%ecx
  73                 shrl $2,%ecx
  74                 rep ; stosl
  75
  76                 /* Copy COM32 invocation parameters */
  77                 leal 4(%esp),%esi               # Argument list
  78                 leal __com32@GOTOFF(%ebx),%edi
  79                 movl $(COM32_ARGS),%ecx
  80                 movl %esp,-4(%edi)              # Save the initial stack ptr
  81                 cmpl (%esi),%ecx
  82                 jbe 5f
  83                 movl (%esi),%ecx
  84 5:              inc %ecx                        # Copy the argument count, too
  85                 rep ; movsl
  86
  87                 /* Parse the command line (assumes REGPARM) */
  88                 movl __com32+4@GOTOFF(%ebx),%edx        # Command line
  89                 pushl %edx                              # Make space for argv
  90                 movl %esp,%eax
  91                 call __parse_argv
  92                 pushl %eax                              # Save argc
  93
  94                 /* Look for library initialization functions */
  95                 leal __ctors_start@GOTOFF(%ebx),%esi
  96                 leal __ctors_end@GOTOFF(%ebx),%edi
  97 6:
  98                 cmpl %edi,%esi
  99                 jae 7f
 100                 call *(%esi)
 101                 addl $4,%esi
 102                 jmp 6b
 103 /*
 104  * Actually run main.  This assumes REGPARM is used!!!!
 105  */
 106 7:
 107                 popl %eax                       # argc
 108                 popl %edx                       # argv
 109                 call main
 110                 call *__exit_handler@GOTOFF(%ebx)
 111                 hlt
 112                 .size _start, .-_start
 113
 114                 .bss
 115                 .globl __entry_esp
 116 __entry_esp:    .space 4
 117                 .globl __com32
 118 __com32:        .space 4*(COM32_ARGS+1)