core/comboot.inc

   1 ;; -----------------------------------------------------------------------
   2 ;;
   3 ;;   Copyright 1994-2009 H. Peter Anvin - All Rights Reserved
   4 ;;   Copyright 2009-2010 Intel Corporation; author: H. Peter Anvin
   5 ;;
   6 ;;   This program is free software; you can redistribute it and/or modify
   7 ;;   it under the terms of the GNU General Public License as published by
   8 ;;   the Free Software Foundation, Inc., 53 Temple Place Ste 330,
   9 ;;   Boston MA 02111-1307, USA; either version 2 of the License, or
  10 ;;   (at your option) any later version; incorporated herein by reference.
  11 ;;
  12 ;; -----------------------------------------------------------------------
  13
  14 ;;
  15 ;; comboot.inc
  16 ;;
  17 ;; Common code for running a COMBOOT image
  18 ;;
  19                 section .text16
  20
  21 ; Parameter registers definition; this is the definition
  22 ; of the stack frame used by INT 21h and INT 22h.
  23 %define         P_FLAGS         word [bp+44]
  24 %define         P_FLAGSL        byte [bp+44]
  25 %define         P_FLAGSH        byte [bp+45]
  26 %define         P_CS            word [bp+42]
  27 %define         P_IP            word [bp+40]
  28 %define         P_CSIP          dword [bp+40]
  29 %define         P_DS            word [bp+38]
  30 %define         P_ES            word [bp+36]
  31 %define         P_FS            word [bp+34]
  32 %define         P_GS            word [bp+32]
  33 %define         P_EAX           dword [bp+28]
  34 %define         P_AX            word [bp+28]
  35 %define         P_HAX           word [bp+30]
  36 %define         P_AL            byte [bp+28]
  37 %define         P_AH            byte [bp+29]
  38 %define         P_ECX           dword [bp+24]
  39 %define         P_CX            word [bp+24]
  40 %define         P_HCX           word [bp+26]
  41 %define         P_CL            byte [bp+24]
  42 %define         P_CH            byte [bp+25]
  43 %define         P_EDX           dword [bp+20]
  44 %define         P_DX            word [bp+20]
  45 %define         P_HDX           word [bp+22]
  46 %define         P_DL            byte [bp+20]
  47 %define         P_DH            byte [bp+21]
  48 %define         P_EBX           dword [bp+16]
  49 %define         P_BX            word [bp+16]
  50 %define         P_HBX           word [bp+18]
  51 %define         P_BL            byte [bp+16]
  52 %define         P_BH            byte [bp+17]
  53 %define         P_EBP           dword [bp+8]
  54 %define         P_BP            word [bp+8]
  55 %define         P_HBP           word [bp+10]
  56 %define         P_ESI           dword [bp+4]
  57 %define         P_SI            word [bp+4]
  58 %define         P_HSI           word [bp+6]
  59 %define         P_EDI           dword [bp]
  60 %define         P_DI            word [bp]
  61 %define         P_HDI           word [bp+2]
  62
  63 ;
  64 ; Set up the COMBOOT API interrupt vectors.  This is now done at
  65 ; initialization time.
  66 ;
  67 comboot_setup_api:
  68                 mov di,DOSErrTramp      ; Error trampolines
  69                 mov cx,32
  70                 push cx
  71                 mov eax,02EB206Ah       ; push 20h; jmp $+4
  72 .loop1:         stosd
  73                 inc ah
  74                 loop .loop1
  75                 dec di
  76                 mov byte [di-1],0E9h
  77                 mov ax,comboot_bogus-2
  78                 sub ax,di
  79                 stosw
  80
  81                 pop cx                  ; CX <- 32
  82                 mov si,4*20h            ; DOS interrupt vectors
  83                 mov bx,comboot_vectors
  84                 mov di,DOSSaveVectors
  85 .loop2:
  86                 movsd
  87                 movzx eax,word [bx]
  88                 inc bx
  89                 inc bx
  90                 mov [si-4],eax
  91                 loop .loop2
  92                 ret
  93
  94 ;
  95 ; Restore the original state of the COMBOOT API vectors, and free
  96 ; any low memory allocated by the comboot module.
  97 ;
  98                 global comboot_cleanup_api
  99 comboot_cleanup_api:
 100                 pusha
 101                 mov si,DOSSaveVectors
 102                 mov di,4*20h
 103                 mov cx,20h
 104                 rep movsd               ; Restore DOS-range vectors
 105                 popa
 106                 ret
 107
 108                 section .bss16
 109                 alignb 4
 110 DOSSaveVectors  resd 32
 111
 112                 section .data16
 113 %define comboot_err(x) (DOSErrTramp+4*((x)-20h))
 114
 115 comboot_vectors:
 116                 dw comboot_return       ; INT 20 = exit
 117                 dw comboot_int21        ; INT 21 = DOS-compatible system calls
 118                 dw comboot_int22        ; INT 22 = native system calls
 119                 dw comboot_err(23h)     ; INT 23 = DOS Ctrl-C handler
 120                 dw comboot_err(24h)     ; INT 24 = DOS critical error handler
 121                 dw comboot_err(25h)     ; INT 25 = DOS absolute disk read
 122                 dw comboot_err(26h)     ; INT 26 = DOS absolute disk write
 123                 dw comboot_err(27h)     ; INT 27 = DOS TSR
 124                 dw comboot_int28        ; INT 28 = DOS idle interrupt
 125                 dw comboot_int29        ; INT 29 = DOS fast console output
 126                 dw comboot_err(2Ah)     ; INT 2A = DOS network API (NetBIOS)
 127                 dw comboot_err(2Bh)     ; INT 2B = DOS reserved
 128                 dw comboot_err(2Ch)     ; INT 2C = DOS reserved
 129                 dw comboot_iret         ; INT 2D = DOS reserved, AMIS
 130                 dw comboot_err(2Eh)     ; INT 2E = DOS run command
 131                 dw comboot_iret         ; INT 2F = DOS multiplex interrupt
 132                 dw comboot_err(30h)     ; INT 30 = DOS CP/M system calls
 133                 dw comboot_err(31h)     ; INT 31 = DPMI
 134                 dw comboot_err(32h)     ; INT 32 = DOS reserved
 135                 dw comboot_iret         ; INT 33 = DOS mouse API
 136                 dw comboot_err(34h)     ; INT 34 = DOS FPU emulation
 137                 dw comboot_err(35h)     ; INT 35 = DOS FPU emulation
 138                 dw comboot_err(36h)     ; INT 36 = DOS FPU emulation
 139                 dw comboot_err(37h)     ; INT 37 = DOS FPU emulation
 140                 dw comboot_err(38h)     ; INT 38 = DOS FPU emulation
 141                 dw comboot_err(39h)     ; INT 39 = DOS FPU emulation
 142                 dw comboot_err(3Ah)     ; INT 3A = DOS FPU emulation
 143                 dw comboot_err(3Bh)     ; INT 3B = DOS FPU emulation
 144                 dw comboot_err(3Ch)     ; INT 3C = DOS FPU emulation
 145                 dw comboot_err(3Dh)     ; INT 3D = DOS FPU emulation
 146                 dw comboot_err(3Eh)     ; INT 3E = DOS FPU emulation
 147                 dw comboot_err(3Fh)     ; INT 3F = DOS overlay manager
 148
 149                 section .text16
 150
 151 ; INT 21h: generic DOS system call
 152 comboot_int21:  sti
 153                 push ds
 154                 push es
 155                 push fs
 156                 push gs
 157                 pushad
 158                 cld
 159                 mov bp,cs
 160                 mov ds,bp
 161                 mov es,bp
 162                 mov bp,sp                       ; Set up stack frame
 163
 164                 pm_call pm_adjust_screen        ; The COMBOOT program might hav changed the screen
 165
 166                 mov cx,int21_count
 167                 mov si,int21_table
 168 .again:         lodsb
 169                 cmp al,P_AH
 170                 lodsw
 171                 loopne .again
 172                 ; The last function in the list is the
 173                 ; "no such function" function
 174                 clc
 175                 call ax                 ; Call the invoked function
 176 comboot_resume:
 177                 mov bp,sp               ; In case the function clobbers BP
 178                 setc P_FLAGSL           ; Propagate CF->error
 179                 popad
 180                 pop gs
 181                 pop fs
 182                 pop es
 183                 pop ds
 184 comboot_iret:
 185                 iret
 186
 187 comboot_bad_int21:
 188                 mov ax,P_AX
 189                 push P_CSIP
 190                 push 21h
 191                 ; Fall through
 192
 193 ; Attempted to execute invalid DOS system call
 194 ; The interrupt number is on the stack.
 195 comboot_bogus:  pop dx                  ; Interrupt number
 196                 pop edi                 ; CS:IP
 197                 mov cx,err_notdos
 198                 push comboot_bogus_tail
 199                 jmp comboot_exit_msg
 200 comboot_bogus_tail:
 201                 xchg ax,dx
 202                 pm_call pm_writehex2            ; Interrupt number
 203                 mov al,' '
 204                 pm_call pm_writechr
 205                 xchg ax,dx
 206                 pm_call pm_writehex4            ; Function number (AX)
 207                 mov al,' '
 208                 pm_call pm_writechr
 209                 mov eax,edi
 210                 pm_call pm_writehex8            ; CS:IP of the origin
 211                 pm_call crlf
 212                 jmp kaboom
 213
 214 ; Proper return vector
 215 ; Note: this gets invoked both via INT 21h and directly via INT 20h.
 216 ; We don't need to cld explicitly here, because comboot_exit does that
 217 ; when invoking RESET_STACK_AND_SEGS.
 218 comboot_return:
 219                 cli                     ; May not have a safe stack
 220                 push enter_command      ; Normal return to command prompt
 221                 ; jmp comboot_exit
 222
 223 ;
 224 ; Generic COMBOOT return to command line code
 225 ;  stack -> where to go next
 226 ;     CX -> message (for _msg version)
 227 ;
 228                 extern comboot_cleanup_lowmem
 229 comboot_exit:
 230                 xor cx,cx
 231 comboot_exit_msg:
 232                 pop bx                  ; Return address
 233                 RESET_STACK_AND_SEGS si ; Contains sti, cld
 234                 pm_call comboot_cleanup_lowmem
 235                 pm_call pm_adjust_screen; The COMBOOT program might have change the screen
 236                 jcxz .nomsg
 237                 mov si,KernelName
 238                 pm_call pm_writestr
 239                 mov si,cx
 240                 pm_call pm_writestr
 241 .nomsg:
 242                 jmp bx
 243
 244 ;
 245 ; INT 21h system calls
 246 ;
 247 comboot_getkey:                         ; 01 = get key with echo
 248                 pm_call vgashowcursor
 249                 call comboot_getchar
 250                 pm_call vgahidecursor
 251                 pm_call pm_writechr
 252                 clc
 253                 ret
 254
 255 comboot_writechr:                       ; 02 = writechr
 256                 mov al,P_DL
 257                 pm_call pm_writechr
 258                 clc
 259                 ret
 260
 261 comboot_writeserial:                    ; 04 = write serial port
 262                 mov al,P_DL
 263                 pm_call pm_write_serial
 264                 clc
 265                 ret
 266
 267 comboot_getkeynoecho:                   ; 08 = get key w/o echo
 268                 call comboot_getchar
 269                 clc
 270                 ret
 271
 272 comboot_writestr:                       ; 09 = write DOS string
 273                 mov es,P_DS
 274                 mov si,P_DX
 275 .loop:          es lodsb
 276                 cmp al,'$'              ; End string with $ - bizarre
 277                 je .done
 278                 pm_call pm_writechr
 279                 jmp short .loop
 280 .done:          clc
 281                 ret
 282
 283 comboot_checkkey:                       ; 0B = check keyboard status
 284                 cmp byte [APIKeyFlag],00h
 285                 jnz .waiting
 286                 pm_call pm_pollchar
 287 .waiting:       setz al
 288                 dec al                  ; AL = 0FFh if present, 0 if not
 289                 mov P_AL,al
 290                 clc
 291                 ret
 292
 293 comboot_checkver:                       ; 30 = check DOS version
 294                 ; We return 0 in all DOS-compatible version registers,
 295                 ; but the high part of eax-ebx-ecx-edx spell "SYSLINUX"
 296                 mov P_EAX,'SY' << 16
 297                 mov P_EBX,'SL' << 16
 298                 mov P_ECX,'IN' << 16
 299                 mov P_EDX,'UX' << 16
 300                 ret
 301
 302 comboot_getchar:
 303                 cmp byte [APIKeyFlag],00h
 304                 jne .queued
 305                 pm_call pm_getchar      ; If not queued get input
 306                 and al,al               ; Function key?  (CF <- 0)
 307                 jnz .done
 308                 mov [APIKeyWait],ah     ; High part of key
 309                 inc byte [APIKeyFlag]   ; Set flag
 310 .done:          mov P_AL,al
 311                 ret
 312 .queued:        mov al,[APIKeyWait]
 313                 dec byte [APIKeyFlag]
 314                 jmp .done
 315
 316 ;
 317 ; INT 28h - DOS idle
 318 ;
 319 comboot_int28:
 320                 sti
 321                 cld
 322                 call do_idle
 323                 iret
 324
 325 ;
 326 ; INT 29h - DOS fast write character
 327 ;
 328 comboot_int29:
 329                 sti
 330                 cld
 331                 pm_call pm_writechr
 332                 iret
 333
 334 ;
 335 ; INT 22h - SYSLINUX-specific system calls
 336 ;           System call number in ax
 337 ;
 338 comboot_int22:
 339                 sti
 340                 push ds
 341                 push es
 342                 push fs
 343                 push gs
 344                 pushad
 345                 cld
 346                 mov bp,cs
 347                 mov ds,bp
 348                 mov es,bp
 349                 mov bp,sp                       ; Set up stack frame
 350
 351                 pm_call pm_adjust_screen        ; The COMBOOT program might hav changed the screen
 352
 353                 cmp ax,int22_count
 354                 jb .ok
 355                 xor ax,ax                       ; Function 0 -> unimplemented
 356 .ok:
 357                 xchg ax,bx
 358                 add bx,bx                       ; CF <- 0
 359                 call [bx+int22_table]
 360                 jmp comboot_resume              ; On return
 361
 362 ;
 363 ; INT 22h AX=0000h      Unimplemented call
 364 ;
 365 comapi_err:
 366                 stc
 367                 ret
 368
 369 ;
 370 ; INT 22h AX=000Ah      Get Derivative-Specific Info
 371 ;
 372 comapi_derinfo:
 373                 mov P_AL,my_id
 374 %if IS_PXELINUX
 375                 mov ax,[APIVer]
 376                 mov P_DX,ax
 377                 mov ax,[StrucPtr]
 378                 mov P_BX,ax
 379                 mov ax,[StrucPtr+2]
 380                 mov P_ES,ax
 381                 mov ax,[InitStack]
 382                 mov P_SI,ax
 383                 mov ax,[InitStack+2]
 384                 mov P_FS,ax
 385                 mov eax,[IPInfo.MyIP]
 386                 mov P_ECX,eax
 387                 mov P_GS,0
 388                 mov P_DI,IPInfo
 389 %else
 390                 ; Physical medium...
 391
 392                 mov al,[SectorShift]
 393                 mov P_CL,al
 394                 mov al,[DriveNumber]
 395                 mov P_DL,al
 396                 mov P_FS,cs
 397                 mov P_SI,OrigESDI
 398                 mov P_GS,cs
 399                 mov P_DI,Hidden
 400 %if IS_SYSLINUX || IS_EXTLINUX
 401                 mov P_ES,cs
 402                 mov P_BX,PartInfo
 403 %elif IS_ISOLINUX
 404                 mov P_ES,cs
 405                 mov P_BX,spec_packet
 406                 mov ax,[BIOSType]
 407                 sub ax,bios_cdrom
 408                 shr ax,2
 409                 mov P_CH,al             ; Mode (el torito/cbios/ebios)
 410 %endif
 411 %endif
 412                 clc
 413                 ret
 414
 415 ;
 416 ; INT 22h AX=001Ch      Get pointer to auxillary data vector
 417 ;
 418 comapi_getadv:
 419                 mov P_ES,ds
 420                 mov P_BX,adv0.data
 421                 mov P_CX,ADV_LEN
 422                 ret
 423
 424 ;
 425 ; INT 22h AX=001Dh      Write auxillary data vector
 426 ;
 427 comapi_writeadv equ adv_write
 428
 429 ;
 430 ; INT 22h AX=0024h      Cleanup, shuffle and boot raw
 431 ;
 432 comapi_shufraw:
 433 %if IS_PXELINUX
 434                 ; Unload PXE if requested
 435                 test dl,3
 436                 setnz [KeepPXE]
 437                 sub bp,sp               ; unload_pxe may move the stack around
 438                 pm_call unload_pxe
 439                 add bp,sp               ; restore frame pointer...
 440 %elif IS_SYSLINUX || IS_EXTLINUX
 441                 ; Restore original FDC table
 442                 mov eax,[OrigFDCTabPtr]
 443                 mov [fdctab],eax
 444 %endif
 445                 pm_call cleanup_hardware
 446                 mov edi,P_EDI
 447                 mov esi,P_ESI
 448                 mov ecx,P_ECX
 449                 jmp shuffle_and_boot_raw
 450
 451 ;
 452 ; INT 22h AX=0025h      Initialize the ADV structure
 453 ;
 454 comapi_initadv:
 455                 call adv_init
 456                 ret
 457
 458                 section .data16
 459
 460 %macro          int21 2
 461                 db %1
 462                 dw %2
 463 %endmacro
 464
 465 int21_table:
 466                 int21   00h, comboot_return
 467                 int21   01h, comboot_getkey
 468                 int21   02h, comboot_writechr
 469                 int21   04h, comboot_writeserial
 470                 int21   08h, comboot_getkeynoecho
 471                 int21   09h, comboot_writestr
 472                 int21   0Bh, comboot_checkkey
 473                 int21   30h, comboot_checkver
 474                 int21   4Ch, comboot_return
 475                 int21    -1, comboot_bad_int21
 476 int21_count     equ ($-int21_table)/3
 477
 478                 alignz 2
 479 int22_table:
 480                 dw comapi_err           ; 0000 unimplemented syscall
 481                 dw comapi_err           ; 0001 get SYSLINUX version
 482                 dw comapi_err           ; 0002 write string
 483                 dw comapi_err           ; 0003 run specified command
 484                 dw comapi_err           ; 0004 run default command
 485                 dw comapi_err           ; 0005 force text mode
 486                 dw comapi_err           ; 0006 open file
 487                 dw comapi_err           ; 0007 read file
 488                 dw comapi_err           ; 0008 close file
 489                 dw comapi_err           ; 0009 call PXE stack
 490                 dw comapi_derinfo       ; 000A derivative-specific info
 491                 dw comapi_err           ; 000B get serial port config
 492                 dw comapi_err           ; 000C perform final cleanup
 493                 dw comapi_err           ; 000D clean up then bootstrap
 494                 dw comapi_err           ; 000E get name of config file
 495                 dw comapi_err           ; 000F get ipappend strings
 496                 dw comapi_err           ; 0010 resolve hostname
 497                 dw comapi_err           ; 0011 maximum shuffle descriptors
 498                 dw comapi_err           ; 0012 cleanup, shuffle and boot
 499                 dw comapi_err           ; 0013 idle call
 500                 dw comapi_err           ; 0014 local boot
 501                 dw comapi_err           ; 0015 feature flags
 502                 dw comapi_err           ; 0016 run kernel image
 503                 dw comapi_err           ; 0017 report video mode change
 504                 dw comapi_err           ; 0018 query custom font
 505                 dw comapi_err           ; 0019 read disk
 506                 dw comapi_err           ; 001A cleanup, shuffle and boot to pm
 507                 dw comapi_err           ; 001B cleanup, shuffle and boot to rm
 508                 dw comapi_getadv        ; 001C get pointer to ADV
 509                 dw comapi_writeadv      ; 001D write ADV to disk
 510                 dw comapi_err           ; 001E keyboard remapping table
 511                 dw comapi_err           ; 001F get current working directory
 512                 dw comapi_err           ; 0020 open directory
 513                 dw comapi_err           ; 0021 read directory
 514                 dw comapi_err           ; 0022 close directory
 515                 dw comapi_err           ; 0023 query shuffler size
 516                 dw comapi_shufraw       ; 0024 cleanup, shuffle and boot raw
 517                 dw comapi_initadv       ; 0025 initialize adv structure
 518 int22_count     equ ($-int22_table)/2
 519
 520 APIKeyWait      db 0
 521 APIKeyFlag      db 0
 522
 523 zero_string     db 0                    ; Empty, null-terminated string
 524
 525 err_notdos      db ': attempted DOS system call INT ',0
 526 err_comlarge    db 'COMBOOT image too large.', CR, LF, 0
 527
 528                 section .bss16
 529                 alignb 4
 530 DOSErrTramp     resd    33              ; Error trampolines
 531
 532 %ifndef HAVE_CURRENTDIRNAME
 533                 global CurrentDirName
 534 CurrentDirName  resb    FILENAME_MAX
 535 %endif