?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
NEWS: Document integration of gPXE
[syslinux.git] / pxelinux.asm
blobb3f1cbb861d5c400376fecc34a1f70d3550c219c
1 ; -*- fundamental -*- (asm-mode sucks)
2 ; ****************************************************************************
3 ;
4 ; pxelinux.asm
5 ;
6 ; A program to boot Linux kernels off a TFTP server using the Intel PXE
7 ; network booting API. It is based on the SYSLINUX boot loader for
8 ; MS-DOS floppies.
9 ;
10 ; Copyright 1994-2008 H. Peter Anvin - All Rights Reserved
11 ;
12 ; This program is free software; you can redistribute it and/or modify
13 ; it under the terms of the GNU General Public License as published by
14 ; the Free Software Foundation, Inc., 53 Temple Place Ste 330,
15 ; Boston MA 02111-1307, USA; either version 2 of the License, or
16 ; (at your option) any later version; incorporated herein by reference.
17 ;
18 ; ****************************************************************************
19
20 %define IS_PXELINUX 1
21 %include "head.inc"
22 %include "pxe.inc"
23
24 ; gPXE extensions support
25 %define GPXE 1
26
27 ;
28 ; Some semi-configurable constants... change on your own risk.
29 ;
30 my_id equ pxelinux_id
31 FILENAME_MAX_LG2 equ 7 ; log2(Max filename size Including final null)
32 FILENAME_MAX equ (1 << FILENAME_MAX_LG2)
33 NULLFILE equ 0 ; Zero byte == null file name
34 NULLOFFSET equ 4 ; Position in which to look
35 REBOOT_TIME equ 5*60 ; If failure, time until full reset
36 %assign HIGHMEM_SLOP 128*1024 ; Avoid this much memory near the top
37 MAX_OPEN_LG2 equ 5 ; log2(Max number of open sockets)
38 MAX_OPEN equ (1 << MAX_OPEN_LG2)
39 PKTBUF_SIZE equ (65536/MAX_OPEN) ; Per-socket packet buffer size
40 TFTP_PORT equ htons(69) ; Default TFTP port
41 PKT_RETRY equ 6 ; Packet transmit retry count
42 PKT_TIMEOUT equ 12 ; Initial timeout, timer ticks @ 55 ms
43 ; Desired TFTP block size
44 ; For Ethernet MTU is normally 1500. Unfortunately there seems to
45 ; be a fair number of networks with "substandard" MTUs which break.
46 ; The code assumes TFTP_LARGEBLK <= 2K.
47 TFTP_MTU equ 1440
48 TFTP_LARGEBLK equ (TFTP_MTU-20-8-4) ; MTU - IP hdr - UDP hdr - TFTP hdr
49 ; Standard TFTP block size
50 TFTP_BLOCKSIZE_LG2 equ 9 ; log2(bytes/block)
51 TFTP_BLOCKSIZE equ (1 << TFTP_BLOCKSIZE_LG2)
52 %assign USE_PXE_PROVIDED_STACK 1 ; Use stack provided by PXE?
53
54 SECTOR_SHIFT equ TFTP_BLOCKSIZE_LG2
55 SECTOR_SIZE equ TFTP_BLOCKSIZE
56
57 ;
58 ; This is what we need to do when idle
59 ; *** This is disabled because some PXE stacks wait for unacceptably
60 ; *** long if there are no packets receivable.
61
62 %define HAVE_IDLE 0 ; idle is not a noop
63
64 %if HAVE_IDLE
65 %macro RESET_IDLE 0
66 call reset_idle
67 %endmacro
68 %macro DO_IDLE 0
69 call check_for_arp
70 %endmacro
71 %else
72 %macro RESET_IDLE 0
73 ; Nothing
74 %endmacro
75 %macro DO_IDLE 0
76 ; Nothing
77 %endmacro
78 %endif
79
80 ;
81 ; TFTP operation codes
82 ;
83 TFTP_RRQ equ htons(1) ; Read request
84 TFTP_WRQ equ htons(2) ; Write request
85 TFTP_DATA equ htons(3) ; Data packet
86 TFTP_ACK equ htons(4) ; ACK packet
87 TFTP_ERROR equ htons(5) ; ERROR packet
88 TFTP_OACK equ htons(6) ; OACK packet
89
90 ;
91 ; TFTP error codes
92 ;
93 TFTP_EUNDEF equ htons(0) ; Unspecified error
94 TFTP_ENOTFOUND equ htons(1) ; File not found
95 TFTP_EACCESS equ htons(2) ; Access violation
96 TFTP_ENOSPACE equ htons(3) ; Disk full
97 TFTP_EBADOP equ htons(4) ; Invalid TFTP operation
98 TFTP_EBADID equ htons(5) ; Unknown transfer
99 TFTP_EEXISTS equ htons(6) ; File exists
100 TFTP_ENOUSER equ htons(7) ; No such user
101 TFTP_EOPTNEG equ htons(8) ; Option negotiation failure
102
103 ;
104 ; The following structure is used for "virtual kernels"; i.e. LILO-style
105 ; option labels. The options we permit here are `kernel' and `append
106 ; Since there is no room in the bottom 64K for all of these, we
107 ; stick them in high memory and copy them down before we need them.
108 ;
109 struc vkernel
110 vk_vname: resb FILENAME_MAX ; Virtual name **MUST BE FIRST!**
111 vk_rname: resb FILENAME_MAX ; Real name
112 vk_ipappend: resb 1 ; "IPAPPEND" flag
113 vk_type: resb 1 ; Type of file
114 vk_appendlen: resw 1
115 alignb 4
116 vk_append: resb max_cmd_len+1 ; Command line
117 alignb 4
118 vk_end: equ $ ; Should be <= vk_size
119 endstruc
120
121 ;
122 ; Segment assignments in the bottom 640K
123 ; 0000h - main code/data segment (and BIOS segment)
124 ;
125 real_mode_seg equ 3000h
126 pktbuf_seg equ 2000h ; Packet buffers segments
127 xfer_buf_seg equ 1000h ; Bounce buffer for I/O to high mem
128 comboot_seg equ real_mode_seg ; COMBOOT image loading zone
129
130 ;
131 ; BOOTP/DHCP packet pattern
132 ;
133 struc bootp_t
134 bootp:
135 .opcode resb 1 ; BOOTP/DHCP "opcode"
136 .hardware resb 1 ; ARP hardware type
137 .hardlen resb 1 ; Hardware address length
138 .gatehops resb 1 ; Used by forwarders
139 .ident resd 1 ; Transaction ID
140 .seconds resw 1 ; Seconds elapsed
141 .flags resw 1 ; Broadcast flags
142 .cip resd 1 ; Client IP
143 .yip resd 1 ; "Your" IP
144 .sip resd 1 ; Next server IP
145 .gip resd 1 ; Relay agent IP
146 .macaddr resb 16 ; Client MAC address
147 .sname resb 64 ; Server name (optional)
148 .bootfile resb 128 ; Boot file name
149 .option_magic resd 1 ; Vendor option magic cookie
150 .options resb 1260 ; Vendor options
151 endstruc
152
153 BOOTP_OPTION_MAGIC equ htonl(0x63825363) ; See RFC 2132
154
155 ;
156 ; TFTP connection data structure. Each one of these corresponds to a local
157 ; UDP port. The size of this structure must be a power of 2.
158 ; HBO = host byte order; NBO = network byte order
159 ; (*) = written by options negotiation code, must be dword sized
160 ;
161 ; For a gPXE connection, we set the local port number to -1 and the
162 ; remote port number contains the gPXE file handle.
163 ;
164 struc open_file_t
165 tftp_localport resw 1 ; Local port number (0 = not in use)
166 tftp_remoteport resw 1 ; Remote port number
167 tftp_remoteip resd 1 ; Remote IP address
168 tftp_filepos resd 1 ; Bytes downloaded (including buffer)
169 tftp_filesize resd 1 ; Total file size(*)
170 tftp_blksize resd 1 ; Block size for this connection(*)
171 tftp_bytesleft resw 1 ; Unclaimed data bytes
172 tftp_lastpkt resw 1 ; Sequence number of last packet (NBO)
173 tftp_dataptr resw 1 ; Pointer to available data
174 tftp_goteof resb 1 ; 1 if the EOF packet received
175 resb 3 ; Currently unusued
176 ; At end since it should not be zeroed on socked close
177 tftp_pktbuf resw 1 ; Packet buffer offset
178 endstruc
179 %ifndef DEPEND
180 %if (open_file_t_size & (open_file_t_size-1))
181 %error "open_file_t is not a power of 2"
182 %endif
183 %endif
184
185 ; ---------------------------------------------------------------------------
186 ; BEGIN CODE
187 ; ---------------------------------------------------------------------------
188
189 ;
190 ; Memory below this point is reserved for the BIOS and the MBR
191 ;
192 section .earlybss
193 trackbufsize equ 8192
194 trackbuf resb trackbufsize ; Track buffer goes here
195 ; ends at 2800h
196
197 alignb open_file_t_size
198 Files resb MAX_OPEN*open_file_t_size
199
200 alignb FILENAME_MAX
201 BootFile resb 256 ; Boot file from DHCP packet
202 PathPrefix resb 256 ; Path prefix derived from boot file
203 DotQuadBuf resb 16 ; Buffer for dotted-quad IP address
204 IPOption resb 80 ; ip= option buffer
205 InitStack resd 1 ; Pointer to reset stack (SS:SP)
206 PXEStack resd 1 ; Saved stack during PXE call
207
208 section .bss
209 alignb 4
210 RebootTime resd 1 ; Reboot timeout, if set by option
211 StrucPtr resd 1 ; Pointer to PXENV+ or !PXE structure
212 APIVer resw 1 ; PXE API version found
213 IPOptionLen resw 1 ; Length of IPOption
214 IdleTimer resw 1 ; Time to check for ARP?
215 LocalBootType resw 1 ; Local boot return code
216 PktTimeout resw 1 ; Timeout for current packet
217 RealBaseMem resw 1 ; Amount of DOS memory after freeing
218 OverLoad resb 1 ; Set if DHCP packet uses "overloading"
219 DHCPMagic resb 1 ; PXELINUX magic flags
220
221 ; The relative position of these fields matter!
222 MAC_MAX equ 32 ; Handle hardware addresses this long
223 MACLen resb 1 ; MAC address len
224 MACType resb 1 ; MAC address type
225 MAC resb MAC_MAX+1 ; Actual MAC address
226 BOOTIFStr resb 7 ; Space for "BOOTIF="
227 MACStr resb 3*(MAC_MAX+1) ; MAC address as a string
228
229 ; The relative position of these fields matter!
230 UUIDType resb 1 ; Type byte from DHCP option
231 UUID resb 16 ; UUID, from the PXE stack
232 UUIDNull resb 1 ; dhcp_copyoption zero-terminates
233
234 ;
235 ; PXE packets which don't need static initialization
236 ;
237 alignb 4
238 pxe_unload_stack_pkt:
239 .status: resw 1 ; Status
240 .reserved: resw 10 ; Reserved
241 pxe_unload_stack_pkt_len equ $-pxe_unload_stack_pkt
242
243 alignb 16
244 ; BOOTP/DHCP packet buffer
245
246 section .bss2
247 alignb 16
248 packet_buf resb 2048 ; Transfer packet
249 packet_buf_size equ $-packet_buf
250
251 section .text
252 ;
253 ; PXELINUX needs more BSS than the other derivatives;
254 ; therefore we relocate it from 7C00h on startup.
255 ;
256 StackBuf equ $ ; Base of stack if we use our own
257
258 ;
259 ; Primary entry point.
260 ;
261 bootsec equ $
262 _start:
263 pushfd ; Paranoia... in case of return to PXE
264 pushad ; ... save as much state as possible
265 push ds
266 push es
267 push fs
268 push gs
269
270 xor ax,ax
271 mov ds,ax
272 mov es,ax
273
274 %ifndef DEPEND
275 %if TEXT_START != 0x7c00
276 ; This is uglier than it should be, but works around
277 ; some NASM 0.98.38 bugs.
278 mov di,section..bcopy32.start
279 add di,__bcopy_size-4
280 lea si,[di-(TEXT_START-7C00h)]
281 lea cx,[di-(TEXT_START-4)]
282 shr cx,2
283 std ; Overlapping areas, copy backwards
284 rep movsd
285 %endif
286 %endif
287 jmp 0:_start1 ; Canonicalize address
288 _start1:
289 mov bp,sp
290 les bx,[bp+48] ; ES:BX -> !PXE or PXENV+ structure
291
292 ; That is all pushed onto the PXE stack. Save the pointer
293 ; to it and switch to an internal stack.
294 mov [InitStack],sp
295 mov [InitStack+2],ss
296
297 %if USE_PXE_PROVIDED_STACK
298 ; Apparently some platforms go bonkers if we
299 ; set up our own stack...
300 mov [BaseStack],sp
301 mov [BaseStack+4],ss
302 %endif
303
304 cli ; Paranoia
305 lss esp,[BaseStack]
306
307 sti ; Stack set up and ready
308 cld ; Copy upwards
309
310 ;
311 ; Initialize screen (if we're using one)
312 ;
313 push es ; Save ES -> PXE entry structure
314 push ds
315 pop es ; ES <- DS
316 %include "init.inc"
317 pop es ; Restore ES -> PXE entry structure
318 ;
319 ; Tell the user we got this far
320 ;
321 mov si,syslinux_banner
322 call writestr
323
324 mov si,copyright_str
325 call writestr
326
327 ;
328 ; Assume API version 2.1, in case we find the !PXE structure without
329 ; finding the PXENV+ structure. This should really look at the Base
330 ; Code ROM ID structure in have_pxe, but this is adequate for now --
331 ; if we have !PXE, we have to be 2.1 or higher, and we don't care
332 ; about higher versions than that.
333 ;
334 mov word [APIVer],0201h
335
336 ;
337 ; Now we need to find the !PXE structure. It's *supposed* to be pointed
338 ; to by SS:[SP+4], but support INT 1Ah, AX=5650h method as well.
339 ; FIX: ES:BX should point to the PXENV+ structure on entry as well.
340 ; We should make that the second test, and not trash ES:BX...
341 ;
342 cmp dword [es:bx], '!PXE'
343 je have_pxe
344
345 ; Uh-oh, not there... try plan B
346 mov ax, 5650h
347 %if USE_PXE_PROVIDED_STACK == 0
348 lss sp,[InitStack]
349 %endif
350 int 1Ah ; May trash regs
351 %if USE_PXE_PROVIDED_STACK == 0
352 lss esp,[BaseStack]
353 %endif
354
355 jc no_pxe
356 cmp ax,564Eh
357 jne no_pxe
358
359 ; Okay, that gave us the PXENV+ structure, find !PXE
360 ; structure from that (if available)
361 cmp dword [es:bx], 'PXEN'
362 jne no_pxe
363 cmp word [es:bx+4], 'V+'
364 je have_pxenv
365
366 ; Nothing there either. Last-ditch: scan memory
367 call memory_scan_for_pxe_struct ; !PXE scan
368 jnc have_pxe
369 call memory_scan_for_pxenv_struct ; PXENV+ scan
370 jnc have_pxenv
371
372 no_pxe: mov si,err_nopxe
373 call writestr
374 jmp kaboom
375
376 have_pxenv:
377 mov [StrucPtr],bx
378 mov [StrucPtr+2],es
379
380 mov si,found_pxenv
381 call writestr
382
383 mov si,apiver_str
384 call writestr
385 mov ax,[es:bx+6]
386 mov [APIVer],ax
387 call writehex4
388 call crlf
389
390 cmp ax,0201h ; API version 2.1 or higher
391 jb old_api
392 mov si,bx
393 mov ax,es
394 les bx,[es:bx+28h] ; !PXE structure pointer
395 cmp dword [es:bx],'!PXE'
396 je have_pxe
397
398 ; Nope, !PXE structure missing despite API 2.1+, or at least
399 ; the pointer is missing. Do a last-ditch attempt to find it.
400 call memory_scan_for_pxe_struct
401 jnc have_pxe
402
403 ; Otherwise, no dice, use PXENV+ structure
404 mov bx,si
405 mov es,ax
406
407 old_api: ; Need to use a PXENV+ structure
408 mov si,using_pxenv_msg
409 call writestr
410
411 mov eax,[es:bx+0Ah] ; PXE RM API
412 mov [PXEEntry],eax
413
414 mov si,undi_data_msg
415 call writestr
416 mov ax,[es:bx+20h]
417 call writehex4
418 call crlf
419 mov si,undi_data_len_msg
420 call writestr
421 mov ax,[es:bx+22h]
422 call writehex4
423 call crlf
424 mov si,undi_code_msg
425 call writestr
426 mov ax,[es:bx+24h]
427 call writehex4
428 call crlf
429 mov si,undi_code_len_msg
430 call writestr
431 mov ax,[es:bx+26h]
432 call writehex4
433 call crlf
434
435 ; Compute base memory size from PXENV+ structure
436 xor esi,esi
437 movzx eax,word [es:bx+20h] ; UNDI data seg
438 cmp ax,[es:bx+24h] ; UNDI code seg
439 ja .use_data
440 mov ax,[es:bx+24h]
441 mov si,[es:bx+26h]
442 jmp short .combine
443 .use_data:
444 mov si,[es:bx+22h]
445 .combine:
446 shl eax,4
447 add eax,esi
448 shr eax,10 ; Convert to kilobytes
449 mov [RealBaseMem],ax
450
451 mov si,pxenventry_msg
452 call writestr
453 mov ax,[PXEEntry+2]
454 call writehex4
455 mov al,':'
456 call writechr
457 mov ax,[PXEEntry]
458 call writehex4
459 call crlf
460 jmp have_entrypoint
461
462 have_pxe:
463 mov [StrucPtr],bx
464 mov [StrucPtr+2],es
465
466 mov eax,[es:bx+10h]
467 mov [PXEEntry],eax
468
469 mov si,undi_data_msg
470 call writestr
471 mov eax,[es:bx+2Ah]
472 call writehex8
473 call crlf
474 mov si,undi_data_len_msg
475 call writestr
476 mov ax,[es:bx+2Eh]
477 call writehex4
478 call crlf
479 mov si,undi_code_msg
480 call writestr
481 mov ax,[es:bx+32h]
482 call writehex8
483 call crlf
484 mov si,undi_code_len_msg
485 call writestr
486 mov ax,[es:bx+36h]
487 call writehex4
488 call crlf
489
490 ; Compute base memory size from !PXE structure
491 xor esi,esi
492 mov eax,[es:bx+2Ah]
493 cmp eax,[es:bx+32h]
494 ja .use_data
495 mov eax,[es:bx+32h]
496 mov si,[es:bx+36h]
497 jmp short .combine
498 .use_data:
499 mov si,[es:bx+2Eh]
500 .combine:
501 add eax,esi
502 shr eax,10
503 mov [RealBaseMem],ax
504
505 mov si,pxeentry_msg
506 call writestr
507 mov ax,[PXEEntry+2]
508 call writehex4
509 mov al,':'
510 call writechr
511 mov ax,[PXEEntry]
512 call writehex4
513 call crlf
514
515 have_entrypoint:
516 push cs
517 pop es ; Restore CS == DS == ES
518
519 ;
520 ; Network-specific initialization
521 ;
522 xor ax,ax
523 mov [LocalDomain],al ; No LocalDomain received
524
525 ;
526 ; The DHCP client identifiers are best gotten from the DHCPREQUEST
527 ; packet (query info 1).
528 ;
529 query_bootp_1:
530 mov dl,1
531 call pxe_get_cached_info
532 call parse_dhcp
533
534 ; We don't use flags from the request packet, so
535 ; this is a good time to initialize DHCPMagic...
536 ; Initialize it to 1 meaning we will accept options found;
537 ; in earlier versions of PXELINUX bit 0 was used to indicate
538 ; we have found option 208 with the appropriate magic number;
539 ; we no longer require that, but MAY want to re-introduce
540 ; it in the future for vendor encapsulated options.
541 mov byte [DHCPMagic],1
542
543 ;
544 ; Now attempt to get the BOOTP/DHCP packet that brought us life (and an IP
545 ; address). This lives in the DHCPACK packet (query info 2).
546 ;
547 query_bootp_2:
548 mov dl,2
549 call pxe_get_cached_info
550 call parse_dhcp ; Parse DHCP packet
551 ;
552 ; Save away MAC address (assume this is in query info 2. If this
553 ; turns out to be problematic it might be better getting it from
554 ; the query info 1 packet.)
555 ;
556 .save_mac:
557 movzx cx,byte [trackbuf+bootp.hardlen]
558 cmp cx,16
559 jna .mac_ok
560 xor cx,cx ; Bad hardware address length
561 .mac_ok:
562 mov [MACLen],cl
563 mov al,[trackbuf+bootp.hardware]
564 mov [MACType],al
565 mov si,trackbuf+bootp.macaddr
566 mov di,MAC
567 rep movsb
568
569 ; Enable this if we really need to zero-pad this field...
570 ; mov cx,MAC+MAC_MAX+1
571 ; sub cx,di
572 ; xor ax,ax
573 ; rep stosb
574
575 ;
576 ; Now, get the boot file and other info. This lives in the CACHED_REPLY
577 ; packet (query info 3).
578 ;
579 mov dl,3
580 call pxe_get_cached_info
581 call parse_dhcp ; Parse DHCP packet
582
583 ;
584 ; Generate the bootif string, and the hardware-based config string.
585 ;
586 make_bootif_string:
587 mov si,bootif_str
588 mov di,BOOTIFStr
589 mov cx,bootif_str_len
590 rep movsb
591
592 movzx cx,byte [MACLen]
593 mov si,MACType
594 inc cx
595 .hexify_mac:
596 push cx
597 mov cl,1 ; CH == 0 already
598 call lchexbytes
599 mov al,'-'
600 stosb
601 pop cx
602 loop .hexify_mac
603 mov [di-1],cl ; Null-terminate and strip final dash
604 ;
605 ; Generate ip= option
606 ;
607 call genipopt
608
609 ;
610 ; Print IP address
611 ;
612 mov eax,[MyIP]
613 mov di,DotQuadBuf
614 push di
615 call gendotquad ; This takes network byte order input
616
617 xchg ah,al ; Convert to host byte order
618 ror eax,16 ; (BSWAP doesn't work on 386)
619 xchg ah,al
620
621 mov si,myipaddr_msg
622 call writestr
623 call writehex8
624 mov al,' '
625 call writechr
626 pop si ; DotQuadBuf
627 call writestr
628 call crlf
629
630 mov si,IPOption
631 call writestr
632 call crlf
633
634 ;
635 ; Check to see if we got any PXELINUX-specific DHCP options; in particular,
636 ; if we didn't get the magic enable, do not recognize any other options.
637 ;
638 check_dhcp_magic:
639 test byte [DHCPMagic], 1 ; If we didn't get the magic enable...
640 jnz .got_magic
641 mov byte [DHCPMagic], 0 ; If not, kill all other options
642 .got_magic:
643
644
645 ;
646 ; Initialize UDP stack
647 ;
648 udp_init:
649 mov eax,[MyIP]
650 mov [pxe_udp_open_pkt.sip],eax
651 mov di,pxe_udp_open_pkt
652 mov bx,PXENV_UDP_OPEN
653 call pxenv
654 jc .failed
655 cmp word [pxe_udp_open_pkt.status], byte 0
656 je .success
657 .failed: mov si,err_udpinit
658 call writestr
659 jmp kaboom
660 .success:
661
662 ;
663 ; Common initialization code
664 ;
665 %include "cpuinit.inc"
666
667 ;
668 ; Now we're all set to start with our *real* business. First load the
669 ; configuration file (if any) and parse it.
670 ;
671 ; In previous versions I avoided using 32-bit registers because of a
672 ; rumour some BIOSes clobbered the upper half of 32-bit registers at
673 ; random. I figure, though, that if there are any of those still left
674 ; they probably won't be trying to install Linux on them...
675 ;
676 ; The code is still ripe with 16-bitisms, though. Not worth the hassle
677 ; to take'm out. In fact, we may want to put them back if we're going
678 ; to boot ELKS at some point.
679 ;
680
681 ;
682 ; Store standard filename prefix
683 ;
684 prefix: test byte [DHCPMagic], 04h ; Did we get a path prefix option
685 jnz .got_prefix
686 mov si,BootFile
687 mov di,PathPrefix
688 cld
689 call strcpy
690 mov cx,di
691 sub cx,PathPrefix+1
692 std
693 lea si,[di-2] ; Skip final null!
694 .find_alnum: lodsb
695 or al,20h
696 cmp al,'.' ; Count . or - as alphanum
697 je .alnum
698 cmp al,'-'
699 je .alnum
700 cmp al,'0'
701 jb .notalnum
702 cmp al,'9'
703 jbe .alnum
704 cmp al,'a'
705 jb .notalnum
706 cmp al,'z'
707 ja .notalnum
708 .alnum: loop .find_alnum
709 dec si
710 .notalnum: mov byte [si+2],0 ; Zero-terminate after delimiter
711 cld
712 .got_prefix:
713 mov si,tftpprefix_msg
714 call writestr
715 mov si,PathPrefix
716 call writestr
717 call crlf
718
719 ;
720 ; Load configuration file
721 ;
722 find_config:
723
724 ;
725 ; Begin looking for configuration file
726 ;
727 config_scan:
728 test byte [DHCPMagic], 02h
729 jz .no_option
730
731 ; We got a DHCP option, try it first
732 call .try
733 jnz .success
734
735 .no_option:
736 mov di,ConfigName
737 mov si,cfgprefix
738 mov cx,cfgprefix_len
739 rep movsb
740
741 ; Have to guess config file name...
742
743 ; Try loading by UUID.
744 cmp byte [HaveUUID],0
745 je .no_uuid
746
747 push di
748 mov bx,uuid_dashes
749 mov si,UUID
750 .gen_uuid:
751 movzx cx,byte [bx]
752 jcxz .done_uuid
753 inc bx
754 call lchexbytes
755 mov al,'-'
756 stosb
757 jmp .gen_uuid
758 .done_uuid:
759 mov [di-1],cl ; Remove last dash and zero-terminate
760 pop di
761 call .try
762 jnz .success
763 .no_uuid:
764
765 ; Try loading by MAC address
766 push di
767 mov si,MACStr
768 call strcpy
769 pop di
770 call .try
771 jnz .success
772
773 ; Nope, try hexadecimal IP prefixes...
774 .scan_ip:
775 mov cx,4
776 mov si,MyIP
777 call uchexbytes ; Convert to hex string
778
779 mov cx,8 ; Up to 8 attempts
780 .tryagain:
781 mov byte [di],0 ; Zero-terminate string
782 call .try
783 jnz .success
784 dec di ; Drop one character
785 loop .tryagain
786
787 ; Final attempt: "default" string
788 mov si,default_str ; "default" string
789 call strcpy
790 call .try
791 jnz .success
792
793 mov si,err_noconfig
794 call writestr
795 jmp kaboom
796
797 .try:
798 pusha
799 mov si,trying_msg
800 call writestr
801 mov di,ConfigName
802 mov si,di
803 call writestr
804 call crlf
805 mov si,di
806 mov di,KernelName ; Borrow this buffer for mangled name
807 call mangle_name
808 call open
809 popa
810 ret
811
812
813 .success:
814
815 ;
816 ; Linux kernel loading code is common. However, we need to define
817 ; a couple of helper macros...
818 ;
819
820 ; Handle "ipappend" option
821 %define HAVE_SPECIAL_APPEND
822 %macro SPECIAL_APPEND 0
823 test byte [IPAppend],01h ; ip=
824 jz .noipappend1
825 mov si,IPOption
826 mov cx,[IPOptionLen]
827 rep movsb
828 mov al,' '
829 stosb
830 .noipappend1:
831 test byte [IPAppend],02h
832 jz .noipappend2
833 mov si,BOOTIFStr
834 call strcpy
835 mov byte [es:di-1],' ' ; Replace null with space
836 .noipappend2:
837 %endmacro
838
839 ; Unload PXE stack
840 %define HAVE_UNLOAD_PREP
841 %macro UNLOAD_PREP 0
842 call unload_pxe
843 %endmacro
844
845 ;
846 ; Now we have the config file open. Parse the config file and
847 ; run the user interface.
848 ;
849 %include "ui.inc"
850
851 ;
852 ; Boot to the local disk by returning the appropriate PXE magic.
853 ; AX contains the appropriate return code.
854 ;
855 local_boot:
856 push cs
857 pop ds
858 mov [LocalBootType],ax
859 call vgaclearmode
860 mov si,localboot_msg
861 call writestr
862 ; Restore the environment we were called with
863 lss sp,[InitStack]
864 pop gs
865 pop fs
866 pop es
867 pop ds
868 popad
869 mov ax,[cs:LocalBootType]
870 popfd
871 retf ; Return to PXE
872
873 ;
874 ; kaboom: write a message and bail out. Wait for quite a while,
875 ; or a user keypress, then do a hard reboot.
876 ;
877 kaboom:
878 RESET_STACK_AND_SEGS AX
879 .patch: mov si,bailmsg
880 call writestr ; Returns with AL = 0
881 .drain: call pollchar
882 jz .drained
883 call getchar
884 jmp short .drain
885 .drained:
886 mov edi,[RebootTime]
887 mov al,[DHCPMagic]
888 and al,09h ; Magic+Timeout
889 cmp al,09h
890 je .time_set
891 mov edi,REBOOT_TIME
892 .time_set:
893 mov cx,18
894 .wait1: push cx
895 mov ecx,edi
896 .wait2: mov dx,[BIOS_timer]
897 .wait3: call pollchar
898 jnz .keypress
899 cmp dx,[BIOS_timer]
900 je .wait3
901 loop .wait2,ecx
902 mov al,'.'
903 call writechr
904 pop cx
905 loop .wait1
906 .keypress:
907 call crlf
908 mov word [BIOS_magic],0 ; Cold reboot
909 jmp 0F000h:0FFF0h ; Reset vector address
910
911 ;
912 ; memory_scan_for_pxe_struct:
913 ;
914 ; If none of the standard methods find the !PXE structure, look for it
915 ; by scanning memory.
916 ;
917 ; On exit, if found:
918 ; CF = 0, ES:BX -> !PXE structure
919 ; Otherwise CF = 1, all registers saved
920 ;
921 memory_scan_for_pxe_struct:
922 push ds
923 pusha
924 mov ax,cs
925 mov ds,ax
926 mov si,trymempxe_msg
927 call writestr
928 mov ax,[BIOS_fbm] ; Starting segment
929 shl ax,(10-4) ; Kilobytes -> paragraphs
930 ; mov ax,01000h ; Start to look here
931 dec ax ; To skip inc ax
932 .mismatch:
933 inc ax
934 cmp ax,0A000h ; End of memory
935 jae .not_found
936 call writehex4
937 mov si,fourbs_msg
938 call writestr
939 mov es,ax
940 mov edx,[es:0]
941 cmp edx,'!PXE'
942 jne .mismatch
943 movzx cx,byte [es:4] ; Length of structure
944 cmp cl,08h ; Minimum length
945 jb .mismatch
946 push ax
947 xor ax,ax
948 xor si,si
949 .checksum: es lodsb
950 add ah,al
951 loop .checksum
952 pop ax
953 jnz .mismatch ; Checksum must == 0
954 .found: mov bp,sp
955 xor bx,bx
956 mov [bp+8],bx ; Save BX into stack frame (will be == 0)
957 mov ax,es
958 call writehex4
959 call crlf
960 popa
961 pop ds
962 clc
963 ret
964 .not_found: mov si,notfound_msg
965 call writestr
966 popa
967 pop ds
968 stc
969 ret
970
971 ;
972 ; memory_scan_for_pxenv_struct:
973 ;
974 ; If none of the standard methods find the PXENV+ structure, look for it
975 ; by scanning memory.
976 ;
977 ; On exit, if found:
978 ; CF = 0, ES:BX -> PXENV+ structure
979 ; Otherwise CF = 1, all registers saved
980 ;
981 memory_scan_for_pxenv_struct:
982 pusha
983 mov si,trymempxenv_msg
984 call writestr
985 ; mov ax,[BIOS_fbm] ; Starting segment
986 ; shl ax,(10-4) ; Kilobytes -> paragraphs
987 mov ax,01000h ; Start to look here
988 dec ax ; To skip inc ax
989 .mismatch:
990 inc ax
991 cmp ax,0A000h ; End of memory
992 jae .not_found
993 mov es,ax
994 mov edx,[es:0]
995 cmp edx,'PXEN'
996 jne .mismatch
997 mov dx,[es:4]
998 cmp dx,'V+'
999 jne .mismatch
1000 movzx cx,byte [es:8] ; Length of structure
1001 cmp cl,26h ; Minimum length
1002 jb .mismatch
1003 xor ax,ax
1004 xor si,si
1005 .checksum: es lodsb
1006 add ah,al
1007 loop .checksum
1008 and ah,ah
1009 jnz .mismatch ; Checksum must == 0
1010 .found: mov bp,sp
1011 mov [bp+8],bx ; Save BX into stack frame
1012 mov ax,bx
1013 call writehex4
1014 call crlf
1015 clc
1016 ret
1017 .not_found: mov si,notfound_msg
1018 call writestr
1019 popad
1020 stc
1021 ret
1022
1023 ;
1024 ; close_file:
1025 ; Deallocates a file structure (pointer in SI)
1026 ; Assumes CS == DS.
1027 ;
1028 ; XXX: We should check to see if this file is still open on the server
1029 ; side and send a courtesy ERROR packet to the server.
1030 ;
1031 close_file:
1032 and si,si
1033 jz .closed
1034 mov word [si],0 ; Not in use
1035 .closed: ret
1036
1037 ;
1038 ; searchdir:
1039 ;
1040 ; Open a TFTP connection to the server
1041 ;
1042 ; On entry:
1043 ; DS:DI = mangled filename
1044 ; If successful:
1045 ; ZF clear
1046 ; SI = socket pointer
1047 ; EAX = file length in bytes, or -1 if unknown
1048 ; If unsuccessful
1049 ; ZF set
1050 ;
1051
1052 searchdir:
1053 push es
1054 push bx
1055 push cx
1056 mov ax,ds
1057 mov es,ax
1058 mov si,di
1059 push bp
1060 mov bp,sp
1061
1062 call allocate_socket
1063 jz .ret
1064
1065 mov ax,PKT_RETRY ; Retry counter
1066 mov word [PktTimeout],PKT_TIMEOUT ; Initial timeout
1067
1068 .sendreq: push ax ; [bp-2] - Retry counter
1069 push si ; [bp-4] - File name
1070
1071 mov di,packet_buf
1072 mov [pxe_udp_write_pkt.buffer],di
1073
1074 mov ax,TFTP_RRQ ; TFTP opcode
1075 stosw
1076
1077 lodsd ; EAX <- server override (if any)
1078 and eax,eax
1079 jnz .noprefix ; No prefix, and we have the server
1080
1081 push si ; Add common prefix
1082 mov si,PathPrefix
1083 call strcpy
1084 dec di
1085 pop si
1086
1087 mov eax,[ServerIP] ; Get default server
1088
1089 .noprefix:
1090 call strcpy ; Filename
1091 %if GPXE
1092 mov si,packet_buf+2
1093 call is_gpxe
1094 jnc .gpxe
1095 %endif
1096
1097 mov [bx+tftp_remoteip],eax
1098
1099 push bx ; [bp-6] - TFTP block
1100 mov bx,[bx]
1101 push bx ; [bp-8] - TID (local port no)
1102
1103 mov [pxe_udp_write_pkt.status],byte 0
1104 mov [pxe_udp_write_pkt.sip],eax
1105 ; Now figure out the gateway
1106 xor eax,[MyIP]
1107 and eax,[Netmask]
1108 jz .nogwneeded
1109 mov eax,[Gateway]
1110 .nogwneeded:
1111 mov [pxe_udp_write_pkt.gip],eax
1112 mov [pxe_udp_write_pkt.lport],bx
1113 mov ax,[ServerPort]
1114 mov [pxe_udp_write_pkt.rport],ax
1115 mov si,tftp_tail
1116 mov cx,tftp_tail_len
1117 rep movsb
1118 sub di,packet_buf ; Get packet size
1119 mov [pxe_udp_write_pkt.buffersize],di
1120
1121 mov di,pxe_udp_write_pkt
1122 mov bx,PXENV_UDP_WRITE
1123 call pxenv
1124 jc .failure
1125 cmp word [pxe_udp_write_pkt.status],byte 0
1126 jne .failure
1127
1128 ;
1129 ; Danger, Will Robinson! We need to support timeout
1130 ; and retry lest we just lost a packet...
1131 ;
1132
1133 ; Packet transmitted OK, now we need to receive
1134 .getpacket: push word [PktTimeout] ; [bp-10]
1135 push word [BIOS_timer] ; [bp-12]
1136
1137 .pkt_loop: mov bx,[bp-8] ; TID
1138 mov di,packet_buf
1139 mov word [pxe_udp_read_pkt.status],0
1140 mov [pxe_udp_read_pkt.buffer],di
1141 mov [pxe_udp_read_pkt.buffer+2],ds
1142 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
1143 mov eax,[MyIP]
1144 mov [pxe_udp_read_pkt.dip],eax
1145 mov [pxe_udp_read_pkt.lport],bx
1146 mov di,pxe_udp_read_pkt
1147 mov bx,PXENV_UDP_READ
1148 call pxenv
1149 jnc .got_packet ; Wait for packet
1150 .no_packet:
1151 mov dx,[BIOS_timer]
1152 cmp dx,[bp-12]
1153 je .pkt_loop
1154 mov [bp-12],dx
1155 dec word [bp-10] ; Timeout
1156 jnz .pkt_loop
1157 pop ax ; Adjust stack
1158 pop ax
1159 shl word [PktTimeout],1 ; Exponential backoff
1160 jmp .failure
1161
1162 .got_packet:
1163 mov si,[bp-6] ; TFTP pointer
1164 mov bx,[bp-8] ; TID
1165
1166 ; Make sure the packet actually came from the server
1167 ; This is technically not to the TFTP spec?
1168 mov eax,[si+tftp_remoteip]
1169 cmp [pxe_udp_read_pkt.sip],eax
1170 jne .no_packet
1171
1172 ; Got packet - reset timeout
1173 mov word [PktTimeout],PKT_TIMEOUT
1174
1175 pop ax ; Adjust stack
1176 pop ax
1177
1178 mov ax,[pxe_udp_read_pkt.rport]
1179 mov [si+tftp_remoteport],ax
1180
1181 ; filesize <- -1 == unknown
1182 mov dword [si+tftp_filesize], -1
1183 ; Default blksize unless blksize option negotiated
1184 mov word [si+tftp_blksize], TFTP_BLOCKSIZE
1185
1186 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1187 sub cx,2 ; CX <- bytes after opcode
1188 jb .failure ; Garbled reply
1189
1190 mov si,packet_buf
1191 lodsw
1192
1193 cmp ax, TFTP_ERROR
1194 je .bailnow ; ERROR reply: don't try again
1195
1196 ; If the server doesn't support any options, we'll get
1197 ; a DATA reply instead of OACK. Stash the data in
1198 ; the file buffer and go with the default value for
1199 ; all options...
1200 cmp ax, TFTP_DATA
1201 je .no_oack
1202
1203 cmp ax, TFTP_OACK
1204 jne .err_reply ; Unknown packet type
1205
1206 ; Now we need to parse the OACK packet to get the transfer
1207 ; and packet sizes.
1208 ; SI -> first byte of options; [E]CX -> byte count
1209 .parse_oack:
1210 jcxz .done_pkt ; No options acked
1211 .get_opt_name:
1212 mov di,si
1213 mov bx,si
1214 .opt_name_loop: lodsb
1215 and al,al
1216 jz .got_opt_name
1217 or al,20h ; Convert to lowercase
1218 stosb
1219 loop .opt_name_loop
1220 ; We ran out, and no final null
1221 jmp .err_reply
1222 .got_opt_name: ; si -> option value
1223 dec cx ; bytes left in pkt
1224 jz .err_reply ; Option w/o value
1225
1226 ; Parse option pointed to by bx; guaranteed to be
1227 ; null-terminated.
1228 push cx
1229 push si
1230 mov si,bx ; -> option name
1231 mov bx,tftp_opt_table
1232 mov cx,tftp_opts
1233 .opt_loop:
1234 push cx
1235 push si
1236 mov di,[bx] ; Option pointer
1237 mov cx,[bx+2] ; Option len
1238 repe cmpsb
1239 pop si
1240 pop cx
1241 je .get_value ; OK, known option
1242 add bx,6
1243 loop .opt_loop
1244
1245 pop si
1246 pop cx
1247 jmp .err_reply ; Non-negotiated option returned
1248
1249 .get_value: pop si ; si -> option value
1250 pop cx ; cx -> bytes left in pkt
1251 mov bx,[bx+4] ; Pointer to data target
1252 add bx,[bp-6] ; TFTP socket pointer
1253 xor eax,eax
1254 xor edx,edx
1255 .value_loop: lodsb
1256 and al,al
1257 jz .got_value
1258 sub al,'0'
1259 cmp al, 9
1260 ja .err_reply ; Not a decimal digit
1261 imul edx,10
1262 add edx,eax
1263 mov [bx],edx
1264 loop .value_loop
1265 ; Ran out before final null, accept anyway
1266 jmp short .done_pkt
1267
1268 .got_value:
1269 dec cx
1270 jnz .get_opt_name ; Not end of packet
1271
1272 ; ZF == 1
1273
1274 ; Success, done!
1275 .done_pkt:
1276 pop si ; Junk
1277 pop si ; We want the packet ptr in SI
1278
1279 mov eax,[si+tftp_filesize]
1280 .got_file: ; SI->socket structure, EAX = size
1281 and eax,eax ; Set ZF depending on file size
1282 jz .error_si ; ZF = 1 need to free the socket
1283 .ret:
1284 leave ; SP <- BP, POP BP
1285 pop cx
1286 pop bx
1287 pop es
1288 ret
1289
1290
1291 .no_oack: ; We got a DATA packet, meaning no options are
1292 ; suported. Save the data away and consider the length
1293 ; undefined, *unless* this is the only data packet...
1294 mov bx,[bp-6] ; File pointer
1295 sub cx,2 ; Too short?
1296 jb .failure
1297 lodsw ; Block number
1298 cmp ax,htons(1)
1299 jne .failure
1300 mov [bx+tftp_lastpkt],ax
1301 cmp cx,TFTP_BLOCKSIZE
1302 ja .err_reply ; Corrupt...
1303 je .not_eof
1304 ; This was the final EOF packet, already...
1305 ; We know the filesize, but we also want to ack the
1306 ; packet and set the EOF flag.
1307 mov [bx+tftp_filesize],ecx
1308 mov byte [bx+tftp_goteof],1
1309 push si
1310 mov si,bx
1311 ; AX = htons(1) already
1312 call ack_packet
1313 pop si
1314 .not_eof:
1315 mov [bx+tftp_bytesleft],cx
1316 mov ax,pktbuf_seg
1317 push es
1318 mov es,ax
1319 mov di,tftp_pktbuf
1320 mov [bx+tftp_dataptr],di
1321 add cx,3
1322 shr cx,2
1323 rep movsd
1324 pop es
1325 jmp .done_pkt
1326
1327 .err_reply: ; Option negotiation error. Send ERROR reply.
1328 ; ServerIP and gateway are already programmed in
1329 mov si,[bp-6]
1330 mov ax,[si+tftp_remoteport]
1331 mov word [pxe_udp_write_pkt.rport],ax
1332 mov word [pxe_udp_write_pkt.buffer],tftp_opt_err
1333 mov word [pxe_udp_write_pkt.buffersize],tftp_opt_err_len
1334 mov di,pxe_udp_write_pkt
1335 mov bx,PXENV_UDP_WRITE
1336 call pxenv
1337
1338 ; Write an error message and explode
1339 mov si,err_damage
1340 call writestr
1341 jmp kaboom
1342
1343 .bailnow: mov word [bp-2],1 ; Immediate error - no retry
1344
1345 .failure: pop bx ; Junk
1346 pop bx
1347 pop si
1348 pop ax
1349 dec ax ; Retry counter
1350 jnz .sendreq ; Try again
1351
1352 .error: mov si,bx ; Socket pointer
1353 .error_si: ; Socket pointer already in SI
1354 call free_socket ; ZF <- 1, SI <- 0
1355 jmp .ret
1356
1357
1358 %if GPXE
1359 .gpxe:
1360 push bx ; Socket pointer
1361 mov di,gpxe_file_open
1362 mov word [di],2 ; PXENV_STATUS_BAD_FUNC
1363 mov word [di+4],packet_buf+2 ; Completed URL
1364 mov [di+6],ds
1365 mov bx,PXENV_FILE_OPEN
1366 call pxenv
1367 pop si ; Socket pointer in SI
1368 jc .error_si
1369
1370 mov ax,[di+2]
1371 mov word [si+tftp_localport],-1 ; gPXE URL
1372 mov [si+tftp_remoteport],ax
1373 mov di,gpxe_get_file_size
1374 mov [di+2],ax
1375
1376 %if 0
1377 ; Disable this for now since gPXE doesn't always
1378 ; return valid information in PXENV_GET_FILE_SIZE
1379 mov bx,PXENV_GET_FILE_SIZE
1380 call pxenv
1381 mov eax,[di+4] ; File size
1382 jnc .oksize
1383 %endif
1384 or eax,-1 ; Size unknown
1385 .oksize:
1386 mov [si+tftp_filesize],eax
1387 jmp .got_file
1388 %endif ; GPXE
1389
1390 ;
1391 ; allocate_socket: Allocate a local UDP port structure
1392 ;
1393 ; If successful:
1394 ; ZF set
1395 ; BX = socket pointer
1396 ; If unsuccessful:
1397 ; ZF clear
1398 ;
1399 allocate_socket:
1400 push cx
1401 mov bx,Files
1402 mov cx,MAX_OPEN
1403 .check: cmp word [bx], byte 0
1404 je .found
1405 add bx,open_file_t_size
1406 loop .check
1407 xor cx,cx ; ZF = 1
1408 pop cx
1409 ret
1410 ; Allocate a socket number. Socket numbers are made
1411 ; guaranteed unique by including the socket slot number
1412 ; (inverted, because we use the loop counter cx); add a
1413 ; counter value to keep the numbers from being likely to
1414 ; get immediately reused.
1415 ;
1416 ; The NextSocket variable also contains the top two bits
1417 ; set. This generates a value in the range 49152 to
1418 ; 57343.
1419 .found:
1420 dec cx
1421 push ax
1422 mov ax,[NextSocket]
1423 inc ax
1424 and ax,((1 << (13-MAX_OPEN_LG2))-1) | 0xC000
1425 mov [NextSocket],ax
1426 shl cx,13-MAX_OPEN_LG2
1427 add cx,ax ; ZF = 0
1428 xchg ch,cl ; Convert to network byte order
1429 mov [bx],cx ; Socket in use
1430 pop ax
1431 pop cx
1432 ret
1433
1434 ;
1435 ; Free socket: socket in SI; return SI = 0, ZF = 1 for convenience
1436 ;
1437 free_socket:
1438 push es
1439 pusha
1440 xor ax,ax
1441 mov es,ax
1442 mov di,si
1443 mov cx,tftp_pktbuf >> 1 ; tftp_pktbuf is not cleared
1444 rep stosw
1445 popa
1446 pop es
1447 xor si,si
1448 ret
1449
1450 ;
1451 ; parse_dotquad:
1452 ; Read a dot-quad pathname in DS:SI and output an IP
1453 ; address in EAX, with SI pointing to the first
1454 ; nonmatching character.
1455 ;
1456 ; Return CF=1 on error.
1457 ;
1458 ; No segment assumptions permitted.
1459 ;
1460 parse_dotquad:
1461 push cx
1462 mov cx,4
1463 xor eax,eax
1464 .parseloop:
1465 mov ch,ah
1466 mov ah,al
1467 lodsb
1468 sub al,'0'
1469 jb .notnumeric
1470 cmp al,9
1471 ja .notnumeric
1472 aad ; AL += 10 * AH; AH = 0;
1473 xchg ah,ch
1474 jmp .parseloop
1475 .notnumeric:
1476 cmp al,'.'-'0'
1477 pushf
1478 mov al,ah
1479 mov ah,ch
1480 xor ch,ch
1481 ror eax,8
1482 popf
1483 jne .error
1484 loop .parseloop
1485 jmp .done
1486 .error:
1487 loop .realerror ; If CX := 1 then we're done
1488 clc
1489 jmp .done
1490 .realerror:
1491 stc
1492 .done:
1493 dec si ; CF unchanged!
1494 pop cx
1495 ret
1496
1497 ;
1498 ; is_url: Return CF=0 if and only if the buffer pointed to by
1499 ; DS:SI is a URL (contains ://). No registers modified.
1500 ;
1501 %if GPXE
1502 is_url:
1503 push si
1504 push eax
1505 .loop:
1506 mov eax,[si]
1507 inc si
1508 and al,al
1509 jz .not_url
1510 and eax,0FFFFFFh
1511 cmp eax,'://'
1512 jne .loop
1513 .done:
1514 ; CF=0 here
1515 pop eax
1516 pop si
1517 ret
1518 .not_url:
1519 stc
1520 jmp .done
1521
1522 ;
1523 ; is_gpxe: Return CF=0 if and only if the buffer pointed to by
1524 ; DS:SI is a URL (contains ://) *and* the gPXE extensions
1525 ; API is available. No registers modified.
1526 ;
1527 is_gpxe:
1528 call is_url
1529 jc .ret ; Not a URL, don't bother
1530 .again:
1531 cmp byte [HasGPXE],1
1532 ja .unknown
1533 ; CF=1 if not available (0),
1534 ; CF=0 if known available (1).
1535 .ret: ret
1536
1537 .unknown:
1538 ; If we get here, the gPXE status is unknown.
1539 push es
1540 pushad
1541 push ds
1542 pop es
1543 mov di,gpxe_file_api_check
1544 mov bx,PXENV_FILE_API_CHECK ; BH = 0
1545 call pxenv
1546 jc .nogood
1547 cmp dword [di+4],0xe9c17b20
1548 jne .nogood
1549 mov ax,[di+12] ; Don't care about the upper half...
1550 not ax ; Set bits of *missing* functions...
1551 and ax,01001011b ; The functions we care about
1552 setz bh
1553 jz .done
1554 .nogood:
1555 mov si,gpxe_warning_msg
1556 call writestr
1557 .done:
1558 mov [HasGPXE],bh
1559 popad
1560 pop es
1561 jmp .again
1562
1563 section .data
1564 gpxe_warning_msg
1565 db 'URL syntax, but gPXE extensions not detected, '
1566 db 'trying plain TFTP...', CR, LF, 0
1567 HasGPXE db -1 ; Unknown
1568 section .text
1569
1570 %endif
1571
1572 ;
1573 ; mangle_name: Mangle a filename pointed to by DS:SI into a buffer pointed
1574 ; to by ES:DI; ends on encountering any whitespace.
1575 ; DI is preserved.
1576 ;
1577 ; This verifies that a filename is < FILENAME_MAX characters
1578 ; and doesn't contain whitespace, and zero-pads the output buffer,
1579 ; so "repe cmpsb" can do a compare.
1580 ;
1581 ; The first four bytes of the manged name is the IP address of
1582 ; the download host, 0 for no host, or -1 for a gPXE URL.
1583 ;
1584 ; No segment assumptions permitted.
1585 ;
1586 mangle_name:
1587 push di
1588 %if GPXE
1589 call is_url
1590 jc .not_url
1591 or eax,-1 ; It's a URL
1592 jmp .prefix_done
1593 .not_url:
1594 %endif ; GPXE
1595 push si
1596 mov eax,[cs:ServerIP]
1597 cmp byte [si],0
1598 je .noip ; Null filename?!?!
1599 cmp word [si],'::' ; Leading ::?
1600 je .gotprefix
1601
1602 .more:
1603 inc si
1604 cmp byte [si],0
1605 je .noip
1606 cmp word [si],'::'
1607 jne .more
1608
1609 ; We have a :: prefix of some sort, it could be either
1610 ; a DNS name or a dot-quad IP address. Try the dot-quad
1611 ; first...
1612 .here:
1613 pop si
1614 push si
1615 call parse_dotquad
1616 jc .notdq
1617 cmp word [si],'::'
1618 je .gotprefix
1619 .notdq:
1620 pop si
1621 push si
1622 call dns_resolv
1623 cmp word [si],'::'
1624 jne .noip
1625 and eax,eax
1626 jnz .gotprefix
1627
1628 .noip:
1629 pop si
1630 xor eax,eax
1631 jmp .prefix_done
1632
1633 .gotprefix:
1634 pop cx ; Adjust stack
1635 inc si ; Skip double colon
1636 inc si
1637
1638 .prefix_done:
1639 stosd ; Save IP address prefix
1640 mov cx,FILENAME_MAX-5
1641
1642 .mn_loop:
1643 lodsb
1644 cmp al,' ' ; If control or space, end
1645 jna .mn_end
1646 stosb
1647 loop .mn_loop
1648 .mn_end:
1649 inc cx ; At least one null byte
1650 xor ax,ax ; Zero-fill name
1651 rep stosb ; Doesn't do anything if CX=0
1652 pop di
1653 ret ; Done
1654
1655 ;
1656 ; unmangle_name: Does the opposite of mangle_name; converts a DOS-mangled
1657 ; filename to the conventional representation. This is needed
1658 ; for the BOOT_IMAGE= parameter for the kernel.
1659 ;
1660 ; NOTE: The output buffer needs to be able to hold an
1661 ; expanded IP address.
1662 ;
1663 ; DS:SI -> input mangled file name
1664 ; ES:DI -> output buffer
1665 ;
1666 ; On return, DI points to the first byte after the output name,
1667 ; which is set to a null byte.
1668 ;
1669 unmangle_name:
1670 push eax
1671 lodsd
1672 and eax,eax
1673 jz .noip
1674 cmp eax,-1
1675 jz .noip ; URL
1676 call gendotquad
1677 mov ax,'::'
1678 stosw
1679 .noip:
1680 call strcpy
1681 dec di ; Point to final null byte
1682 pop eax
1683 ret
1684
1685 ;
1686 ; pxenv
1687 ;
1688 ; This is the main PXENV+/!PXE entry point, using the PXENV+
1689 ; calling convention. This is a separate local routine so
1690 ; we can hook special things from it if necessary. In particular,
1691 ; some PXE stacks seem to not like being invoked from anything but
1692 ; the initial stack, so humour it.
1693 ;
1694 ; While we're at it, save and restore all registers.
1695 ;
1696 pxenv:
1697 pushad
1698 %if USE_PXE_PROVIDED_STACK == 0
1699 mov [cs:PXEStack],sp
1700 mov [cs:PXEStack+2],ss
1701 lss sp,[cs:InitStack]
1702 %endif
1703 ; This works either for the PXENV+ or the !PXE calling
1704 ; convention, as long as we ignore CF (which is redundant
1705 ; with AX anyway.)
1706 push es
1707 push di
1708 push bx
1709 .jump: call 0:0
1710 add sp,6
1711 add ax,-1 ; Set CF unless AX was 0
1712
1713 %if USE_PXE_PROVIDED_STACK == 0
1714 lss sp,[cs:PXEStack]
1715 %endif
1716
1717 ; This clobbers the AX return, but we don't use it
1718 ; except for testing it against zero (and setting CF),
1719 ; which we did above. For anything else,
1720 ; use the Status field in the reply.
1721 popad
1722 cld ; Make sure DF <- 0
1723 ret
1724
1725 ; Must be after function def due to NASM bug
1726 PXEEntry equ pxenv.jump+1
1727
1728 ;
1729 ; getfssec: Get multiple clusters from a file, given the starting cluster.
1730 ;
1731 ; In this case, get multiple blocks from a specific TCP connection.
1732 ;
1733 ; On entry:
1734 ; ES:BX -> Buffer
1735 ; SI -> TFTP socket pointer
1736 ; CX -> 512-byte block count; 0FFFFh = until end of file
1737 ; On exit:
1738 ; SI -> TFTP socket pointer (or 0 on EOF)
1739 ; CF = 1 -> Hit EOF
1740 ; ECX -> number of bytes actually read
1741 ;
1742 getfssec:
1743 push eax
1744 push edi
1745 push bx
1746 push si
1747 push fs
1748 mov di,bx
1749 mov ax,pktbuf_seg
1750 mov fs,ax
1751
1752 xor eax,eax
1753 movzx ecx,cx
1754 shl ecx,TFTP_BLOCKSIZE_LG2 ; Convert to bytes
1755 push ecx ; Initial request size
1756 jz .hit_eof ; Nothing to do?
1757
1758 .need_more:
1759 call fill_buffer
1760 movzx eax,word [si+tftp_bytesleft]
1761 and ax,ax
1762 jz .hit_eof
1763
1764 push ecx
1765 cmp ecx,eax
1766 jna .ok_size
1767 mov ecx,eax
1768 .ok_size:
1769 mov ax,cx ; EAX<31:16> == ECX<31:16> == 0
1770 mov bx,[si+tftp_dataptr]
1771 sub [si+tftp_bytesleft],cx
1772 xchg si,bx
1773 fs rep movsb ; Copy from packet buffer
1774 xchg si,bx
1775 mov [si+tftp_dataptr],bx
1776
1777 pop ecx
1778 sub ecx,eax
1779 jnz .need_more
1780
1781 .hit_eof:
1782 call fill_buffer
1783
1784 pop eax ; Initial request amount
1785 xchg eax,ecx
1786 sub ecx,eax ; ... minus anything not gotten
1787
1788 pop fs
1789 pop si
1790
1791 ; Is there anything left of this?
1792 mov eax,[si+tftp_filesize]
1793 sub eax,[si+tftp_filepos]
1794 jnz .bytes_left
1795
1796 cmp [si+tftp_bytesleft],ax ; AX == 0
1797 jne .bytes_left
1798
1799 cmp byte [si+tftp_goteof],0
1800 je .done
1801 ; I'm 99% sure this can't happen, but...
1802 call fill_buffer ; Receive/ACK the EOF packet
1803 .done:
1804 ; The socket is closed and the buffer drained
1805 ; Close socket structure and re-init for next user
1806 call free_socket
1807 stc
1808 jmp .ret
1809 .bytes_left:
1810 clc
1811 .ret:
1812 pop bx
1813 pop edi
1814 pop eax
1815 ret
1816
1817 ;
1818 ; Get a fresh packet if the buffer is drained, and we haven't hit
1819 ; EOF yet. The buffer should be filled immediately after draining!
1820 ;
1821 ; expects fs -> pktbuf_seg and ds:si -> socket structure
1822 ;
1823 fill_buffer:
1824 cmp word [si+tftp_bytesleft],0
1825 je .empty
1826 ret ; Otherwise, nothing to do
1827
1828 .empty:
1829 push es
1830 pushad
1831 mov ax,ds
1832 mov es,ax
1833
1834 ; Note: getting the EOF packet is not the same thing
1835 ; as tftp_filepos == tftp_filesize; if the EOF packet
1836 ; is empty the latter condition can be true without
1837 ; having gotten the official EOF.
1838 cmp byte [si+tftp_goteof],0
1839 jne .ret ; Already EOF
1840
1841 %if GPXE
1842 cmp word [si+tftp_localport], -1
1843 jne .get_packet_tftp
1844 call get_packet_gpxe
1845 jmp .ret
1846 .get_packet_tftp:
1847 %endif ; GPXE
1848
1849 ; TFTP code...
1850 .packet_loop:
1851 ; Start by ACKing the previous packet; this should cause the
1852 ; next packet to be sent.
1853 mov cx,PKT_RETRY
1854 mov word [PktTimeout],PKT_TIMEOUT
1855
1856 .send_ack: push cx ; <D> Retry count
1857
1858 mov ax,[si+tftp_lastpkt]
1859 call ack_packet ; Send ACK
1860
1861 ; We used to test the error code here, but sometimes
1862 ; PXE would return negative status even though we really
1863 ; did send the ACK. Now, just treat a failed send as
1864 ; a normally lost packet, and let it time out in due
1865 ; course of events.
1866
1867 .send_ok: ; Now wait for packet.
1868 mov dx,[BIOS_timer] ; Get current time
1869
1870 mov cx,[PktTimeout]
1871 .wait_data: push cx ; <E> Timeout
1872 push dx ; <F> Old time
1873
1874 mov bx,[si+tftp_pktbuf]
1875 mov [pxe_udp_read_pkt.buffer],bx
1876 mov [pxe_udp_read_pkt.buffer+2],fs
1877 mov [pxe_udp_read_pkt.buffersize],word PKTBUF_SIZE
1878 mov eax,[si+tftp_remoteip]
1879 mov [pxe_udp_read_pkt.sip],eax
1880 mov eax,[MyIP]
1881 mov [pxe_udp_read_pkt.dip],eax
1882 mov ax,[si+tftp_remoteport]
1883 mov [pxe_udp_read_pkt.rport],ax
1884 mov ax,[si+tftp_localport]
1885 mov [pxe_udp_read_pkt.lport],ax
1886 mov di,pxe_udp_read_pkt
1887 mov bx,PXENV_UDP_READ
1888 call pxenv
1889 jnc .recv_ok
1890
1891 ; No packet, or receive failure
1892 mov dx,[BIOS_timer]
1893 pop ax ; <F> Old time
1894 pop cx ; <E> Timeout
1895 cmp ax,dx ; Same time -> don't advance timeout
1896 je .wait_data ; Same clock tick
1897 loop .wait_data ; Decrease timeout
1898
1899 pop cx ; <D> Didn't get any, send another ACK
1900 shl word [PktTimeout],1 ; Exponential backoff
1901 loop .send_ack
1902 jmp kaboom ; Forget it...
1903
1904 .recv_ok: pop dx ; <F>
1905 pop cx ; <E>
1906
1907 cmp word [pxe_udp_read_pkt.buffersize],byte 4
1908 jb .wait_data ; Bad size for a DATA packet
1909
1910 mov bx,[si+tftp_pktbuf]
1911 cmp word [fs:bx],TFTP_DATA ; Not a data packet?
1912 jne .wait_data ; Then wait for something else
1913
1914 mov ax,[si+tftp_lastpkt]
1915 xchg ah,al ; Host byte order
1916 inc ax ; Which packet are we waiting for?
1917 xchg ah,al ; Network byte order
1918 cmp [fs:bx+2],ax
1919 je .right_packet
1920
1921 ; Wrong packet, ACK the packet and then try again
1922 ; This is presumably because the ACK got lost,
1923 ; so the server just resent the previous packet
1924 mov ax,[fs:bx+2]
1925 call ack_packet
1926 jmp .send_ok ; Reset timeout
1927
1928 .right_packet: ; It's the packet we want. We're also EOF if the
1929 ; size < blocksize
1930
1931 pop cx ; <D> Don't need the retry count anymore
1932
1933 mov [si+tftp_lastpkt],ax ; Update last packet number
1934
1935 movzx ecx,word [pxe_udp_read_pkt.buffersize]
1936 sub cx,byte 4 ; Skip TFTP header
1937
1938 ; Set pointer to data block
1939 lea ax,[bx+4] ; Data past TFTP header
1940 mov [si+tftp_dataptr],ax
1941
1942 add [si+tftp_filepos],ecx
1943 mov [si+tftp_bytesleft],cx
1944
1945 cmp cx,[si+tftp_blksize] ; Is it a full block?
1946 jb .last_block ; If not, it's EOF
1947
1948 .ret:
1949 popad
1950 pop es
1951 ret
1952
1953
1954 .last_block: ; Last block - ACK packet immediately
1955 mov ax,[fs:bx+2]
1956 call ack_packet
1957
1958 ; Make sure we know we are at end of file
1959 mov eax,[si+tftp_filepos]
1960 mov [si+tftp_filesize],eax
1961 mov byte [si+tftp_goteof],1
1962
1963 jmp .ret
1964
1965 ;
1966 ; ack_packet:
1967 ;
1968 ; Send ACK packet. This is a common operation and so is worth canning.
1969 ;
1970 ; Entry:
1971 ; SI = TFTP block
1972 ; AX = Packet # to ack (network byte order)
1973 ; Exit:
1974 ; All registers preserved
1975 ;
1976 ; This function uses the pxe_udp_write_pkt but not the packet_buf.
1977 ;
1978 ack_packet:
1979 pushad
1980 mov [ack_packet_buf+2],ax ; Packet number to ack
1981 mov ax,[si]
1982 mov [pxe_udp_write_pkt.lport],ax
1983 mov ax,[si+tftp_remoteport]
1984 mov [pxe_udp_write_pkt.rport],ax
1985 mov eax,[si+tftp_remoteip]
1986 mov [pxe_udp_write_pkt.sip],eax
1987 xor eax,[MyIP]
1988 and eax,[Netmask]
1989 jz .nogw
1990 mov eax,[Gateway]
1991 .nogw:
1992 mov [pxe_udp_write_pkt.gip],eax
1993 mov [pxe_udp_write_pkt.buffer],word ack_packet_buf
1994 mov [pxe_udp_write_pkt.buffersize], word 4
1995 mov di,pxe_udp_write_pkt
1996 mov bx,PXENV_UDP_WRITE
1997 call pxenv
1998 popad
1999 ret
2000
2001 %if GPXE
2002 ;
2003 ; Get a fresh packet from a gPXE socket; expects fs -> pktbuf_seg
2004 ; and ds:si -> socket structure
2005 ;
2006 ; Assumes CS == DS == ES.
2007 ;
2008 get_packet_gpxe:
2009 mov di,gpxe_file_read
2010
2011 mov ax,[si+tftp_remoteport] ; gPXE filehandle
2012 mov [di+2],ax
2013 mov ax,[si+tftp_pktbuf]
2014 mov [di+6],ax
2015 mov [si+tftp_dataptr],ax
2016 mov [di+8],fs
2017
2018 .again:
2019 mov word [di+4],PKTBUF_SIZE
2020 mov bx,PXENV_FILE_READ
2021 call pxenv
2022 jnc .ok ; Got data or EOF
2023 cmp word [di],PXENV_STATUS_TFTP_OPEN ; == EWOULDBLOCK
2024 je .again
2025 jmp kaboom ; Otherwise error...
2026
2027 .ok:
2028 movzx eax,word [di+4] ; Bytes read
2029 mov [si+tftp_bytesleft],ax ; Bytes in buffer
2030 add [si+tftp_filepos],eax ; Position in file
2031
2032 and ax,ax ; EOF?
2033 mov eax,[si+tftp_filepos]
2034
2035 jnz .got_stuff
2036
2037 ; We got EOF here, make sure the upper layers know
2038 mov [si+tftp_filesize],eax
2039
2040 .got_stuff:
2041 ; If we're done here, close the file
2042 cmp [si+tftp_filesize],eax
2043 ja .done ; Not EOF, there is still data...
2044
2045 ; Reuse the previous [es:di] structure since the
2046 ; relevant fields are all the same
2047 mov byte [si+tftp_goteof],1
2048
2049 mov bx,PXENV_FILE_CLOSE
2050 call pxenv
2051 ; Ignore return...
2052 .done:
2053 ret
2054 %endif ; GPXE
2055
2056 ;
2057 ; unload_pxe:
2058 ;
2059 ; This function unloads the PXE and UNDI stacks and unclaims
2060 ; the memory.
2061 ;
2062 unload_pxe:
2063 test byte [KeepPXE],01h ; Should we keep PXE around?
2064 jnz reset_pxe
2065
2066 push ds
2067 push es
2068
2069 mov ax,cs
2070 mov ds,ax
2071 mov es,ax
2072
2073 mov si,new_api_unload
2074 cmp byte [APIVer+1],2 ; Major API version >= 2?
2075 jae .new_api
2076 mov si,old_api_unload
2077 .new_api:
2078
2079 .call_loop: xor ax,ax
2080 lodsb
2081 and ax,ax
2082 jz .call_done
2083 xchg bx,ax
2084 mov di,pxe_unload_stack_pkt
2085 push di
2086 xor ax,ax
2087 mov cx,pxe_unload_stack_pkt_len >> 1
2088 rep stosw
2089 pop di
2090 call pxenv
2091 jc .cant_free
2092 mov ax,word [pxe_unload_stack_pkt.status]
2093 cmp ax,PXENV_STATUS_SUCCESS
2094 jne .cant_free
2095 jmp .call_loop
2096
2097 .call_done:
2098 mov bx,0FF00h
2099
2100 mov dx,[RealBaseMem]
2101 cmp dx,[BIOS_fbm] ; Sanity check
2102 jna .cant_free
2103 inc bx
2104
2105 ; Check that PXE actually unhooked the INT 1Ah chain
2106 movzx eax,word [4*0x1a]
2107 movzx ecx,word [4*0x1a+2]
2108 shl ecx,4
2109 add eax,ecx
2110 shr eax,10
2111 cmp ax,dx ; Not in range
2112 jae .ok
2113 cmp ax,[BIOS_fbm]
2114 jae .cant_free
2115 ; inc bx
2116
2117 .ok:
2118 mov [BIOS_fbm],dx
2119 .pop_ret:
2120 pop es
2121 pop ds
2122 ret
2123
2124 .cant_free:
2125 mov si,cant_free_msg
2126 call writestr
2127 push ax
2128 xchg bx,ax
2129 call writehex4
2130 mov al,'-'
2131 call writechr
2132 pop ax
2133 call writehex4
2134 mov al,'-'
2135 call writechr
2136 mov eax,[4*0x1a]
2137 call writehex8
2138 call crlf
2139 jmp .pop_ret
2140
2141 ; We want to keep PXE around, but still we should reset
2142 ; it to the standard bootup configuration
2143 reset_pxe:
2144 push es
2145 push cs
2146 pop es
2147 mov bx,PXENV_UDP_CLOSE
2148 mov di,pxe_udp_close_pkt
2149 call pxenv
2150 pop es
2151 ret
2152
2153 ;
2154 ; gendotquad
2155 ;
2156 ; Take an IP address (in network byte order) in EAX and
2157 ; output a dotted quad string to ES:DI.
2158 ; DI points to terminal null at end of string on exit.
2159 ;
2160 gendotquad:
2161 push eax
2162 push cx
2163 mov cx,4
2164 .genchar:
2165 push eax
2166 cmp al,10 ; < 10?
2167 jb .lt10 ; If so, skip first 2 digits
2168
2169 cmp al,100 ; < 100
2170 jb .lt100 ; If so, skip first digit
2171
2172 aam 100
2173 ; Now AH = 100-digit; AL = remainder
2174 add ah,'0'
2175 mov [es:di],ah
2176 inc di
2177
2178 .lt100:
2179 aam 10
2180 ; Now AH = 10-digit; AL = remainder
2181 add ah,'0'
2182 mov [es:di],ah
2183 inc di
2184
2185 .lt10:
2186 add al,'0'
2187 stosb
2188 mov al,'.'
2189 stosb
2190 pop eax
2191 ror eax,8 ; Move next char into LSB
2192 loop .genchar
2193 dec di
2194 mov [es:di], byte 0
2195 pop cx
2196 pop eax
2197 ret
2198 ;
2199 ; uchexbytes/lchexbytes
2200 ;
2201 ; Take a number of bytes in memory and convert to upper/lower-case
2202 ; hexadecimal
2203 ;
2204 ; Input:
2205 ; DS:SI = input bytes
2206 ; ES:DI = output buffer
2207 ; CX = number of bytes
2208 ; Output:
2209 ; DS:SI = first byte after
2210 ; ES:DI = first byte after
2211 ; CX = 0
2212 ;
2213 ; Trashes AX, DX
2214 ;
2215
2216 lchexbytes:
2217 mov dl,'a'-'9'-1
2218 jmp xchexbytes
2219 uchexbytes:
2220 mov dl,'A'-'9'-1
2221 xchexbytes:
2222 .loop:
2223 lodsb
2224 mov ah,al
2225 shr al,4
2226 call .outchar
2227 mov al,ah
2228 call .outchar
2229 loop .loop
2230 ret
2231 .outchar:
2232 and al,0Fh
2233 add al,'0'
2234 cmp al,'9'
2235 jna .done
2236 add al,dl
2237 .done:
2238 stosb
2239 ret
2240
2241 ;
2242 ; pxe_get_cached_info
2243 ;
2244 ; Get a DHCP packet from the PXE stack into the trackbuf.
2245 ;
2246 ; Input:
2247 ; DL = packet type
2248 ; Output:
2249 ; CX = buffer size
2250 ;
2251 ; Assumes CS == DS == ES.
2252 ;
2253 pxe_get_cached_info:
2254 pushad
2255 mov si,get_packet_msg
2256 call writestr
2257 mov al,dl
2258 call writehex2
2259 call crlf
2260 mov di,pxe_bootp_query_pkt
2261 push di
2262 xor ax,ax
2263 stosw ; Status
2264 movzx ax,dl
2265 stosw ; Packet type
2266 mov ax,trackbufsize
2267 stosw ; Buffer size
2268 mov ax,trackbuf
2269 stosw ; Buffer offset
2270 xor ax,ax
2271 stosw ; Buffer segment
2272
2273 pop di ; DI -> parameter set
2274 mov bx,PXENV_GET_CACHED_INFO
2275 call pxenv
2276 jc .err
2277 and ax,ax
2278 jnz .err
2279
2280 popad
2281 mov cx,[pxe_bootp_query_pkt.buffersize]
2282 ret
2283
2284 .err:
2285 mov si,err_pxefailed
2286 call writestr
2287 call writehex4
2288 call crlf
2289 jmp kaboom
2290
2291 section .data
2292 get_packet_msg db 'Getting cached packet ', 0
2293
2294 section .text
2295 ;
2296 ; ip_ok
2297 ;
2298 ; Tests an IP address in EAX for validity; return with ZF=1 for bad.
2299 ; We used to refuse class E, but class E addresses are likely to become
2300 ; assignable unicast addresses in the near future.
2301 ;
2302 ip_ok:
2303 push ax
2304 cmp eax,-1 ; Refuse the all-ones address
2305 jz .out
2306 and al,al ; Refuse network zero
2307 jz .out
2308 cmp al,127 ; Refuse loopback
2309 jz .out
2310 and al,0F0h
2311 cmp al,224 ; Refuse class D
2312 .out:
2313 pop ax
2314 ret
2315
2316 ;
2317 ; parse_dhcp
2318 ;
2319 ; Parse a DHCP packet. This includes dealing with "overloaded"
2320 ; option fields (see RFC 2132, section 9.3)
2321 ;
2322 ; This should fill in the following global variables, if the
2323 ; information is present:
2324 ;
2325 ; MyIP - client IP address
2326 ; ServerIP - boot server IP address
2327 ; Netmask - network mask
2328 ; Gateway - default gateway router IP
2329 ; BootFile - boot file name
2330 ; DNSServers - DNS server IPs
2331 ; LocalDomain - Local domain name
2332 ; MACLen, MAC - Client identifier, if MACLen == 0
2333 ;
2334 ; This assumes the DHCP packet is in "trackbuf" and the length
2335 ; of the packet in in CX on entry.
2336 ;
2337
2338 parse_dhcp:
2339 mov byte [OverLoad],0 ; Assume no overload
2340 mov eax, [trackbuf+bootp.yip]
2341 call ip_ok
2342 jz .noyip
2343 mov [MyIP], eax
2344 .noyip:
2345 mov eax, [trackbuf+bootp.sip]
2346 and eax, eax
2347 call ip_ok
2348 jz .nosip
2349 mov [ServerIP], eax
2350 .nosip:
2351 sub cx, bootp.options
2352 jbe .nooptions
2353 mov si, trackbuf+bootp.option_magic
2354 lodsd
2355 cmp eax, BOOTP_OPTION_MAGIC
2356 jne .nooptions
2357 call parse_dhcp_options
2358 .nooptions:
2359 mov si, trackbuf+bootp.bootfile
2360 test byte [OverLoad],1
2361 jz .nofileoverload
2362 mov cx,128
2363 call parse_dhcp_options
2364 jmp short .parsed_file
2365 .nofileoverload:
2366 cmp byte [si], 0
2367 jz .parsed_file ; No bootfile name
2368 mov di,BootFile
2369 mov cx,32
2370 rep movsd
2371 xor al,al
2372 stosb ; Null-terminate
2373 .parsed_file:
2374 mov si, trackbuf+bootp.sname
2375 test byte [OverLoad],2
2376 jz .nosnameoverload
2377 mov cx,64
2378 call parse_dhcp_options
2379 .nosnameoverload:
2380 ret
2381
2382 ;
2383 ; Parse a sequence of DHCP options, pointed to by DS:SI; the field
2384 ; size is CX -- some DHCP servers leave option fields unterminated
2385 ; in violation of the spec.
2386 ;
2387 ; For parse_some_dhcp_options, DH contains the minimum value for
2388 ; the option to recognize -- this is used to restrict parsing to
2389 ; PXELINUX-specific options only.
2390 ;
2391 parse_dhcp_options:
2392 xor dx,dx
2393
2394 parse_some_dhcp_options:
2395 .loop:
2396 and cx,cx
2397 jz .done
2398
2399 lodsb
2400 dec cx
2401 jz .done ; Last byte; must be PAD, END or malformed
2402 cmp al, 0 ; PAD option
2403 je .loop
2404 cmp al,255 ; END option
2405 je .done
2406
2407 ; Anything else will have a length field
2408 mov dl,al ; DL <- option number
2409 xor ax,ax
2410 lodsb ; AX <- option length
2411 dec cx
2412 sub cx,ax ; Decrement bytes left counter
2413 jb .done ; Malformed option: length > field size
2414
2415 cmp dl,dh ; Is the option value valid?
2416 jb .opt_done
2417
2418 mov bx,dhcp_option_list
2419 .find_option:
2420 cmp bx,dhcp_option_list_end
2421 jae .opt_done
2422 cmp dl,[bx]
2423 je .found_option
2424 add bx,3
2425 jmp .find_option
2426 .found_option:
2427 pushad
2428 call [bx+1]
2429 popad
2430
2431 ; Fall through
2432 ; Unknown option. Skip to the next one.
2433 .opt_done:
2434 add si,ax
2435 jmp .loop
2436 .done:
2437 ret
2438
2439 section .data
2440 dhcp_option_list:
2441 section .text
2442
2443 %macro dopt 2
2444 section .data
2445 db %1
2446 dw dopt_%2
2447 section .text
2448 dopt_%2:
2449 %endmacro
2450
2451 ;
2452 ; Parse individual DHCP options. SI points to the option data and
2453 ; AX to the option length. DL contains the option number.
2454 ; All registers are saved around the routine.
2455 ;
2456 dopt 1, subnet_mask
2457 mov ebx,[si]
2458 mov [Netmask],ebx
2459 ret
2460
2461 dopt 3, router
2462 mov ebx,[si]
2463 mov [Gateway],ebx
2464 ret
2465
2466 dopt 6, dns_servers
2467 mov cx,ax
2468 shr cx,2
2469 cmp cl,DNS_MAX_SERVERS
2470 jna .oklen
2471 mov cl,DNS_MAX_SERVERS
2472 .oklen:
2473 mov di,DNSServers
2474 rep movsd
2475 mov [LastDNSServer],di
2476 ret
2477
2478 dopt 16, local_domain
2479 mov bx,si
2480 add bx,ax
2481 xor ax,ax
2482 xchg [bx],al ; Zero-terminate option
2483 mov di,LocalDomain
2484 call dns_mangle ; Convert to DNS label set
2485 mov [bx],al ; Restore ending byte
2486 ret
2487
2488 dopt 43, vendor_encaps
2489 mov dh,208 ; Only recognize PXELINUX options
2490 mov cx,ax ; Length of option = max bytes to parse
2491 call parse_some_dhcp_options ; Parse recursive structure
2492 ret
2493
2494 dopt 52, option_overload
2495 mov bl,[si]
2496 mov [OverLoad],bl
2497 ret
2498
2499 dopt 54, server
2500 mov eax,[si]
2501 cmp dword [ServerIP],0
2502 jne .skip ; Already have a next server IP
2503 call ip_ok
2504 jz .skip
2505 mov [ServerIP],eax
2506 .skip: ret
2507
2508 dopt 61, client_identifier
2509 cmp ax,MAC_MAX ; Too long?
2510 ja .skip
2511 cmp ax,2 ; Too short?
2512 jb .skip
2513 cmp [MACLen],ah ; Only do this if MACLen == 0
2514 jne .skip
2515 push ax
2516 lodsb ; Client identifier type
2517 cmp al,[MACType]
2518 pop ax
2519 jne .skip ; Client identifier is not a MAC
2520 dec ax
2521 mov [MACLen],al
2522 mov di,MAC
2523 jmp dhcp_copyoption
2524 .skip: ret
2525
2526 dopt 67, bootfile_name
2527 mov di,BootFile
2528 jmp dhcp_copyoption
2529
2530 dopt 97, uuid_client_identifier
2531 cmp ax,17 ; type byte + 16 bytes UUID
2532 jne .skip
2533 mov dl,[si] ; Must have type 0 == UUID
2534 or dl,[HaveUUID] ; Capture only the first instance
2535 jnz .skip
2536 mov byte [HaveUUID],1 ; Got UUID
2537 mov di,UUIDType
2538 jmp dhcp_copyoption
2539 .skip: ret
2540
2541 dopt 209, pxelinux_configfile
2542 mov di,ConfigName
2543 or byte [DHCPMagic],2 ; Got config file
2544 jmp dhcp_copyoption
2545
2546 dopt 210, pxelinux_pathprefix
2547 mov di,PathPrefix
2548 or byte [DHCPMagic],4 ; Got path prefix
2549 jmp dhcp_copyoption
2550
2551 dopt 211, pxelinux_reboottime
2552 cmp al,4
2553 jne .done
2554 mov ebx,[si]
2555 xchg bl,bh ; Convert to host byte order
2556 rol ebx,16
2557 xchg bl,bh
2558 mov [RebootTime],ebx
2559 or byte [DHCPMagic],8 ; Got RebootTime
2560 .done: ret
2561
2562 ; Common code for copying an option verbatim
2563 ; Copies the option into ES:DI and null-terminates it.
2564 ; Returns with AX=0 and SI past the option.
2565 dhcp_copyoption:
2566 xchg cx,ax ; CX <- option length
2567 rep movsb
2568 xchg cx,ax ; AX <- 0
2569 stosb ; Null-terminate
2570 ret
2571
2572 section .data
2573 dhcp_option_list_end:
2574 section .text
2575
2576 section .data
2577 HaveUUID db 0
2578 uuid_dashes db 4,2,2,2,6,0 ; Bytes per UUID dashed section
2579 section .text
2580
2581 ;
2582 ; genipopt
2583 ;
2584 ; Generate an ip=<client-ip>:<boot-server-ip>:<gw-ip>:<netmask>
2585 ; option into IPOption based on a DHCP packet in trackbuf.
2586 ; Assumes CS == DS == ES.
2587 ;
2588 genipopt:
2589 pushad
2590 mov di,IPOption
2591 mov eax,'ip='
2592 stosd
2593 dec di
2594 mov eax,[MyIP]
2595 call gendotquad
2596 mov al,':'
2597 stosb
2598 mov eax,[ServerIP]
2599 call gendotquad
2600 mov al,':'
2601 stosb
2602 mov eax,[Gateway]
2603 call gendotquad
2604 mov al,':'
2605 stosb
2606 mov eax,[Netmask]
2607 call gendotquad ; Zero-terminates its output
2608 sub di,IPOption
2609 mov [IPOptionLen],di
2610 popad
2611 ret
2612
2613 ;
2614 ; Call the receive loop while idle. This is done mostly so we can respond to
2615 ; ARP messages, but perhaps in the future this can be used to do network
2616 ; console.
2617 ;
2618 ; hpa sez: people using automatic control on the serial port get very
2619 ; unhappy if we poll for ARP too often (the PXE stack is pretty slow,
2620 ; typically.) Therefore, only poll if at least 4 BIOS timer ticks have
2621 ; passed since the last poll, and reset this when a character is
2622 ; received (RESET_IDLE).
2623 ;
2624 %if HAVE_IDLE
2625
2626 reset_idle:
2627 push ax
2628 mov ax,[cs:BIOS_timer]
2629 mov [cs:IdleTimer],ax
2630 pop ax
2631 ret
2632
2633 check_for_arp:
2634 push ax
2635 mov ax,[cs:BIOS_timer]
2636 sub ax,[cs:IdleTimer]
2637 cmp ax,4
2638 pop ax
2639 jae .need_poll
2640 ret
2641 .need_poll: pushad
2642 push ds
2643 push es
2644 mov ax,cs
2645 mov ds,ax
2646 mov es,ax
2647 mov di,packet_buf
2648 mov [pxe_udp_read_pkt.status],al ; 0
2649 mov [pxe_udp_read_pkt.buffer],di
2650 mov [pxe_udp_read_pkt.buffer+2],ds
2651 mov word [pxe_udp_read_pkt.buffersize],packet_buf_size
2652 mov eax,[MyIP]
2653 mov [pxe_udp_read_pkt.dip],eax
2654 mov word [pxe_udp_read_pkt.lport],htons(9) ; discard port
2655 mov di,pxe_udp_read_pkt
2656 mov bx,PXENV_UDP_READ
2657 call pxenv
2658 ; Ignore result...
2659 pop es
2660 pop ds
2661 popad
2662 RESET_IDLE
2663 ret
2664
2665 %endif ; HAVE_IDLE
2666
2667 ; -----------------------------------------------------------------------------
2668 ; Common modules
2669 ; -----------------------------------------------------------------------------
2670
2671 %include "getc.inc" ; getc et al
2672 %include "conio.inc" ; Console I/O
2673 %include "writestr.inc" ; String output
2674 writestr equ cwritestr
2675 %include "writehex.inc" ; Hexadecimal output
2676 %include "configinit.inc" ; Initialize configuration
2677 %include "parseconfig.inc" ; High-level config file handling
2678 %include "parsecmd.inc" ; Low-level config file handling
2679 %include "bcopy32.inc" ; 32-bit bcopy
2680 %include "loadhigh.inc" ; Load a file into high memory
2681 %include "font.inc" ; VGA font stuff
2682 %include "graphics.inc" ; VGA graphics
2683 %include "highmem.inc" ; High memory sizing
2684 %include "strcpy.inc" ; strcpy()
2685 %include "rawcon.inc" ; Console I/O w/o using the console functions
2686 %include "dnsresolv.inc" ; DNS resolver
2687 %include "adv.inc" ; Auxillary Data Vector
2688
2689 ; -----------------------------------------------------------------------------
2690 ; Begin data section
2691 ; -----------------------------------------------------------------------------
2692
2693 section .data
2694
2695 copyright_str db ' Copyright (C) 1994-', year, ' H. Peter Anvin'
2696 db CR, LF, 0
2697 err_bootfailed db CR, LF, 'Boot failed: press a key to retry, or wait for reset...', CR, LF, 0
2698 bailmsg equ err_bootfailed
2699 err_nopxe db "No !PXE or PXENV+ API found; we're dead...", CR, LF, 0
2700 err_pxefailed db 'PXE API call failed, error ', 0
2701 err_udpinit db 'Failed to initialize UDP stack', CR, LF, 0
2702 err_noconfig db 'Unable to locate configuration file', CR, LF, 0
2703 err_damage db 'TFTP server sent an incomprehesible reply', CR, LF, 0
2704 found_pxenv db 'Found PXENV+ structure', CR, LF, 0
2705 using_pxenv_msg db 'Old PXE API detected, using PXENV+ structure', CR, LF, 0
2706 apiver_str db 'PXE API version is ',0
2707 pxeentry_msg db 'PXE entry point found (we hope) at ', 0
2708 pxenventry_msg db 'PXENV entry point found (we hope) at ', 0
2709 trymempxe_msg db 'Scanning memory for !PXE structure... ', 0
2710 trymempxenv_msg db 'Scanning memory for PXENV+ structure... ', 0
2711 undi_data_msg db 'UNDI data segment at: ',0
2712 undi_data_len_msg db 'UNDI data segment size: ',0
2713 undi_code_msg db 'UNDI code segment at: ',0
2714 undi_code_len_msg db 'UNDI code segment size: ',0
2715 cant_free_msg db 'Failed to free base memory, error ', 0
2716 notfound_msg db 'not found', CR, LF, 0
2717 myipaddr_msg db 'My IP address seems to be ',0
2718 tftpprefix_msg db 'TFTP prefix: ', 0
2719 localboot_msg db 'Booting from local disk...', CR, LF, 0
2720 trying_msg db 'Trying to load: ', 0
2721 fourbs_msg db BS, BS, BS, BS, 0
2722 default_str db 'default', 0
2723 syslinux_banner db CR, LF, 'PXELINUX ', version_str, ' ', date, ' ', 0
2724 cfgprefix db 'pxelinux.cfg/' ; No final null!
2725 cfgprefix_len equ ($-cfgprefix)
2726
2727 ;
2728 ; Command line options we'd like to take a look at
2729 ;
2730 ; mem= and vga= are handled as normal 32-bit integer values
2731 initrd_cmd db 'initrd='
2732 initrd_cmd_len equ $-initrd_cmd
2733
2734 ; This one we make ourselves
2735 bootif_str db 'BOOTIF='
2736 bootif_str_len equ $-bootif_str
2737 ;
2738 ; Config file keyword table
2739 ;
2740 %include "keywords.inc"
2741
2742 ;
2743 ; Extensions to search for (in *forward* order).
2744 ; (.bs and .bss are disabled for PXELINUX, since they are not supported)
2745 ;
2746 align 4, db 0
2747 exten_table: db '.cbt' ; COMBOOT (specific)
2748 db '.0', 0, 0 ; PXE bootstrap program
2749 db '.com' ; COMBOOT (same as DOS)
2750 db '.c32' ; COM32
2751 exten_table_end:
2752 dd 0, 0 ; Need 8 null bytes here
2753
2754 ;
2755 ; PXE unload sequences
2756 ;
2757 new_api_unload:
2758 db PXENV_UDP_CLOSE
2759 db PXENV_UNDI_SHUTDOWN
2760 db PXENV_UNLOAD_STACK
2761 db PXENV_STOP_UNDI
2762 db 0
2763 old_api_unload:
2764 db PXENV_UDP_CLOSE
2765 db PXENV_UNDI_SHUTDOWN
2766 db PXENV_UNLOAD_STACK
2767 db PXENV_UNDI_CLEANUP
2768 db 0
2769
2770 ;
2771 ; PXE query packets partially filled in
2772 ;
2773 section .bss
2774 pxe_bootp_query_pkt:
2775 .status: resw 1 ; Status
2776 .packettype: resw 1 ; Boot server packet type
2777 .buffersize: resw 1 ; Packet size
2778 .buffer: resw 2 ; seg:off of buffer
2779 .bufferlimit: resw 1 ; Unused
2780
2781 section .data
2782 pxe_udp_open_pkt:
2783 .status: dw 0 ; Status
2784 .sip: dd 0 ; Source (our) IP
2785
2786 pxe_udp_close_pkt:
2787 .status: dw 0 ; Status
2788
2789 pxe_udp_write_pkt:
2790 .status: dw 0 ; Status
2791 .sip: dd 0 ; Server IP
2792 .gip: dd 0 ; Gateway IP
2793 .lport: dw 0 ; Local port
2794 .rport: dw 0 ; Remote port
2795 .buffersize: dw 0 ; Size of packet
2796 .buffer: dw 0, 0 ; seg:off of buffer
2797
2798 pxe_udp_read_pkt:
2799 .status: dw 0 ; Status
2800 .sip: dd 0 ; Source IP
2801 .dip: dd 0 ; Destination (our) IP
2802 .rport: dw 0 ; Remote port
2803 .lport: dw 0 ; Local port
2804 .buffersize: dw 0 ; Max packet size
2805 .buffer: dw 0, 0 ; seg:off of buffer
2806
2807 %if GPXE
2808
2809 gpxe_file_api_check:
2810 .status: dw 0 ; Status
2811 .size: dw 20 ; Size in bytes
2812 .magic: dd 0x91d447b2 ; Magic number
2813 .provider: dd 0
2814 .apimask: dd 0
2815 .flags: dd 0
2816
2817 gpxe_file_open:
2818 .status: dw 0 ; Status
2819 .filehandle: dw 0 ; FileHandle
2820 .filename: dd 0 ; seg:off of FileName
2821 .reserved: dd 0
2822
2823 gpxe_get_file_size:
2824 .status: dw 0 ; Status
2825 .filehandle: dw 0 ; FileHandle
2826 .filesize: dd 0 ; FileSize
2827
2828 gpxe_file_read:
2829 .status: dw 0 ; Status
2830 .filehandle: dw 0 ; FileHandle
2831 .buffersize: dw 0 ; BufferSize
2832 .buffer: dd 0 ; seg:off of buffer
2833
2834 %endif ; GPXE
2835
2836 ;
2837 ; Misc initialized (data) variables
2838 ;
2839 alignb 4, db 0
2840 BaseStack dd StackBuf ; ESP of base stack
2841 dw 0 ; SS of base stack
2842 NextSocket dw 49152 ; Counter for allocating socket numbers
2843 KeepPXE db 0 ; Should PXE be kept around?
2844
2845 ;
2846 ; TFTP commands
2847 ;
2848 tftp_tail db 'octet', 0 ; Octet mode
2849 tsize_str db 'tsize' ,0 ; Request size
2850 tsize_len equ ($-tsize_str)
2851 db '0', 0
2852 blksize_str db 'blksize', 0 ; Request large blocks
2853 blksize_len equ ($-blksize_str)
2854 asciidec TFTP_LARGEBLK
2855 db 0
2856 tftp_tail_len equ ($-tftp_tail)
2857
2858 alignb 2, db 0
2859 ;
2860 ; Options negotiation parsing table (string pointer, string len, offset
2861 ; into socket structure)
2862 ;
2863 tftp_opt_table:
2864 dw tsize_str, tsize_len, tftp_filesize
2865 dw blksize_str, blksize_len, tftp_blksize
2866 tftp_opts equ ($-tftp_opt_table)/6
2867
2868 ;
2869 ; Error packet to return on options negotiation error
2870 ;
2871 tftp_opt_err dw TFTP_ERROR ; ERROR packet
2872 dw TFTP_EOPTNEG ; ERROR 8: bad options
2873 db 'tsize option required', 0 ; Error message
2874 tftp_opt_err_len equ ($-tftp_opt_err)
2875
2876 alignb 4, db 0
2877 ack_packet_buf: dw TFTP_ACK, 0 ; TFTP ACK packet
2878
2879 ;
2880 ; IP information (initialized to "unknown" values)
2881 MyIP dd 0 ; My IP address
2882 ServerIP dd 0 ; IP address of boot server
2883 Netmask dd 0 ; Netmask of this subnet
2884 Gateway dd 0 ; Default router
2885 ServerPort dw TFTP_PORT ; TFTP server port
2886
2887 ;
2888 ; Variables that are uninitialized in SYSLINUX but initialized here
2889 ;
2890 alignb 4, db 0
2891 BufSafe dw trackbufsize/TFTP_BLOCKSIZE ; Clusters we can load into trackbuf
2892 BufSafeBytes dw trackbufsize ; = how many bytes?
2893 %ifndef DEPEND
2894 %if ( trackbufsize % TFTP_BLOCKSIZE ) != 0
2895 %error trackbufsize must be a multiple of TFTP_BLOCKSIZE
2896 %endif
2897 %endif
The Syslinux boot loader collection