cgcc

   1 #!/usr/bin/perl -w
   2 # -----------------------------------------------------------------------------
   3
   4 my $cc = $ENV{'REAL_CC'} || 'cc';
   5 my $check = $ENV{'CHECK'} || 'sparse';
   6
   7 my $m32 = 0;
   8 my $m64 = 0;
   9 my $has_specs = 0;
  10 my $gendeps = 0;
  11 my $do_check = 0;
  12 my $do_compile = 1;
  13 my $gcc_base_dir;
  14 my $verbose = 0;
  15
  16 while (@ARGV) {
  17     $_ = shift(@ARGV);
  18     # Look for a .c file.  We don't want to run the checker on .o or .so files
  19     # in the link run.  (This simplistic check knows nothing about options
  20     # with arguments, but it seems to do the job.)
  21     $do_check = 1 if /^[^-].*\.c$/;
  22
  23     # Ditto for stdin.
  24     $do_check = 1 if $_ eq '-';
  25
  26     $m32 = 1 if /^-m32$/;
  27     $m64 = 1 if /^-m64$/;
  28     $gendeps = 1 if /^-M$/;
  29
  30     if (/^-target=(.*)$/) {
  31         $check .= &add_specs ($1);
  32         $has_specs = 1;
  33         next;
  34     }
  35
  36     if ($_ eq '-no-compile') {
  37         $do_compile = 0;
  38         next;
  39     }
  40
  41     if (/^-gcc-base-dir$/) {
  42         $gcc_base_dir = shift @ARGV;
  43         die ("$0: missing argument for -gcc-base-dir option") if !$gcc_base_dir;
  44         next;
  45     }
  46
  47     # If someone adds "-E", don't pre-process twice.
  48     $do_compile = 0 if $_ eq '-E';
  49
  50     $verbose = 1 if $_ eq '-v';
  51
  52     my $this_arg = ' ' . &quote_arg ($_);
  53     $cc .= $this_arg unless &check_only_option ($_);
  54     $check .= $this_arg;
  55 }
  56
  57 if ($gendeps) {
  58     $do_compile = 1;
  59     $do_check = 0;
  60 }
  61
  62 if ($do_check) {
  63     if (!$has_specs) {
  64         $check .= &add_specs ('host_arch_specs');
  65         $check .= &add_specs ('host_os_specs');
  66     }
  67
  68     $gcc_base_dir = qx($cc -print-file-name=) if !$gcc_base_dir;
  69     $check .= " -gcc-base-dir " . $gcc_base_dir if $gcc_base_dir;
  70
  71     print "$check\n" if $verbose;
  72     if ($do_compile) {
  73         system ($check);
  74     } else {
  75         exec ($check);
  76     }
  77 }
  78
  79 if ($do_compile) {
  80     print "$cc\n" if $verbose;
  81     exec ($cc);
  82 }
  83
  84 exit 0;
  85
  86 # -----------------------------------------------------------------------------
  87 # Check if an option is for "check" only.
  88
  89 sub check_only_option {
  90     my ($arg) = @_;
  91     return 1 if $arg =~ /^-W(no-?)?(default-bitfield-sign|one-bit-signed-bitfield|cast-truncate|bitwise|typesign|context|undef|ptr-subtraction-blows|cast-to-as|decl|transparent-union|address-space|enum-mismatch|do-while|old-initializer|non-pointer-null|paren-string|return-void|designated-init|sparse-all)$/;
  92     return 1 if $arg =~ /^-v(no-?)?(entry|dead)$/;
  93     return 0;
  94 }
  95
  96 # -----------------------------------------------------------------------------
  97 # Simple arg-quoting function.  Just adds backslashes when needed.
  98
  99 sub quote_arg {
 100     my ($arg) = @_;
 101     return "''" if $arg eq '';
 102     return join ('',
 103                  map {
 104                      m|^[-a-zA-Z0-9._/,=]+$| ? $_ : "\\" . $_;
 105                  } (split (//, $arg)));
 106 }
 107
 108 # -----------------------------------------------------------------------------
 109
 110 sub integer_types {
 111     my ($char,@dummy) = @_;
 112
 113     my %pow2m1 =
 114         (8 => '127',
 115          16 => '32767',
 116          32 => '2147483647',
 117          64 => '9223372036854775807',
 118          128 => '170141183460469231731687303715884105727',
 119          );
 120     my @types = (['SCHAR',''], ['SHRT',''], ['INT',''], ['LONG','L'], ['LONG_LONG','LL'], ['LONG_LONG_LONG','LLL']);
 121
 122     my $result = " -D__CHAR_BIT__=$char";
 123     while (@types && @_) {
 124         my $bits = shift @_;
 125         my ($name,$suffix) = @{ shift @types };
 126         die "$0: weird number of bits." unless exists $pow2m1{$bits};
 127         $result .= " -D__${name}_MAX__=" . $pow2m1{$bits} . $suffix;
 128     }
 129     return $result;
 130 }
 131
 132 # -----------------------------------------------------------------------------
 133
 134 sub float_types {
 135     my ($has_inf,$has_qnan,$dec_dig,@bitsizes) = @_;
 136     my $result = " -D__FLT_RADIX__=2";
 137     $result .= " -D__FINITE_MATH_ONLY__=" . ($has_inf || $has_qnan ? '0' : '1');
 138     $result .= " -D__DECIMAL_DIG__=$dec_dig";
 139
 140     my %constants =
 141         (24 =>
 142          {
 143              'MIN' => '1.17549435e-38',
 144              'MAX' => '3.40282347e+38',
 145              'EPSILON' => '1.19209290e-7',
 146              'DENORM_MIN' => '1.40129846e-45',
 147          },
 148          53 =>
 149          {
 150              'MIN' => '2.2250738585072014e-308',
 151              'MAX' => '1.7976931348623157e+308',
 152              'EPSILON' => '2.2204460492503131e-16',
 153              'DENORM_MIN' => '4.9406564584124654e-324',
 154          },
 155          64 =>
 156          {
 157              'MIN' => '3.36210314311209350626e-4932',
 158              'MAX' => '1.18973149535723176502e+4932',
 159              'EPSILON' => '1.08420217248550443401e-19',
 160              'DENORM_MIN' => '3.64519953188247460253e-4951',
 161          },
 162          113 =>
 163          {
 164              'MIN' => '3.36210314311209350626267781732175260e-4932',
 165              'MAX' => '1.18973149535723176508575932662800702e+4932',
 166              'EPSILON' => '1.92592994438723585305597794258492732e-34',
 167              'DENORM_MIN' => '6.47517511943802511092443895822764655e-4966',
 168          },
 169          );
 170
 171     my @types = (['FLT','F'], ['DBL',''], ['LDBL','L']);
 172     while (@types) {
 173         my ($mant_bits,$exp_bits) = @{ shift @bitsizes };
 174         my ($name,$suffix) = @{ shift @types };
 175
 176         my $h = $constants{$mant_bits};
 177         die "$0: weird number of mantissa bits." unless $h;
 178
 179         my $mant_dig = int (($mant_bits - 1) * log (2) / log (10));
 180         my $max_exp = 1 << ($exp_bits - 1);
 181         my $min_exp = 3 - $max_exp;
 182         my $max_10_exp = int ($max_exp * log (2) / log (10));
 183         my $min_10_exp = -int (-$min_exp * log (2) / log (10));
 184
 185         $result .= " -D__${name}_MANT_DIG__=$mant_bits";
 186         $result .= " -D__${name}_DIG__=$mant_dig";
 187         $result .= " -D__${name}_MIN_EXP__='($min_exp)'";
 188         $result .= " -D__${name}_MAX_EXP__=$max_exp";
 189         $result .= " -D__${name}_MIN_10_EXP__='($min_10_exp)'";
 190         $result .= " -D__${name}_MAX_10_EXP__=$max_10_exp";
 191         $result .= " -D__${name}_HAS_INFINITY__=" . ($has_inf ? '1' : '0');
 192         $result .= " -D__${name}_HAS_QUIET_NAN__=" . ($has_qnan ? '1' : '0');;
 193
 194         foreach my $inf (sort keys %$h) {
 195             $result .= " -D__${name}_${inf}__=" . $h->{$inf} . $suffix;
 196         }
 197     }
 198     return $result;
 199 }
 200
 201 # -----------------------------------------------------------------------------
 202
 203 sub define_size_t {
 204     my ($text) = @_;
 205     # We have to undef in order to override check's internal definition.
 206     return ' -U__SIZE_TYPE__ ' . &quote_arg ("-D__SIZE_TYPE__=$text");
 207 }
 208
 209 # -----------------------------------------------------------------------------
 210
 211 sub add_specs {
 212     my ($spec) = @_;
 213     if ($spec eq 'sunos') {
 214         return &add_specs ('unix') .
 215             ' -D__sun__=1 -D__sun=1 -Dsun=1' .
 216             ' -D__svr4__=1 -DSVR4=1' .
 217             ' -D__STDC__=0' .
 218             ' -D_REENTRANT' .
 219             ' -D_SOLARIS_THREADS' .
 220             ' -DNULL="((void *)0)"';
 221     } elsif ($spec eq 'linux') {
 222         return &add_specs ('unix') .
 223             ' -D__linux__=1 -D__linux=1 -Dlinux=linux';
 224     } elsif ($spec eq 'openbsd') {
 225         return &add_specs ('unix') .
 226             ' -D__OpenBSD__=1';
 227     } elsif ($spec eq 'unix') {
 228         return ' -Dunix=1 -D__unix=1 -D__unix__=1';
 229     } elsif ( $spec =~ /^cygwin/) {
 230         return &add_specs ('unix') .
 231             ' -D__CYGWIN__=1 -D__CYGWIN32__=1' .
 232             " -D'_cdecl=__attribute__((__cdecl__))'" .
 233             " -D'__cdecl=__attribute__((__cdecl__))'" .
 234             " -D'_stdcall=__attribute__((__stdcall__))'" .
 235             " -D'__stdcall=__attribute__((__stdcall__))'" .
 236             " -D'_fastcall=__attribute__((__fastcall__))'" .
 237             " -D'__fastcall=__attribute__((__fastcall__))'" .
 238             " -D'__declspec(x)=__attribute__((x))'";
 239     } elsif ($spec eq 'i86') {
 240         return (' -Di386=1 -D__i386=1 -D__i386__=1' .
 241                 &integer_types (8, 16, 32, $m64 ? 64 : 32, 64) .
 242                 &float_types (1, 1, 21, [24,8], [53,11], [64,15]) .
 243                 &define_size_t ($m64 ? "long unsigned int" : "unsigned int") .
 244                 ' -D__SIZEOF_POINTER__=' . ($m64 ? '8' : '4'));
 245     } elsif ($spec eq 'sparc') {
 246         return (' -Dsparc=1 -D__sparc=1 -D__sparc__=1' .
 247                 &integer_types (8, 16, 32, $m64 ? 64 : 32, 64) .
 248                 &float_types (1, 1, 33, [24,8], [53,11], [113,15]) .
 249                 &define_size_t ($m64 ? "long unsigned int" : "unsigned int") .
 250                 ' -D__SIZEOF_POINTER__=' . ($m64 ? '8' : '4'));
 251     } elsif ($spec eq 'sparc64') {
 252         return (' -Dsparc=1 -D__sparc=1 -D__sparc__=1 -D__sparcv9__=1 -D__sparc64__=1 -D__arch64__=1 -D__LP64__=1' .
 253                 &integer_types (8, 16, 32, 64, 64, 128) .
 254                 &float_types (1, 1, 33, [24,8], [53,11], [113,15]) .
 255                 &define_size_t ("long unsigned int") .
 256                 ' -D__SIZEOF_POINTER__=8');
 257     } elsif ($spec eq 'x86_64') {
 258         return (' -Dx86_64=1 -D__x86_64=1 -D__x86_64__=1' . ($m32 ? '' : ' -D__LP64__=1') .
 259                 &integer_types (8, 16, 32, $m32 ? 32 : 64, 64, 128) .
 260                 &float_types (1, 1, 33, [24,8], [53,11], [113,15]) .
 261                 &define_size_t ($m32 ? "unsigned int" : "long unsigned int") .
 262                 ' -D__SIZEOF_POINTER__=' . ($m32 ? '4' : '8'));
 263     } elsif ($spec eq 'ppc') {
 264         return (' -D__powerpc__=1 -D_BIG_ENDIAN -D_STRING_ARCH_unaligned=1' .
 265                 &integer_types (8, 16, 32, $m64 ? 64 : 32, 64) .
 266                 &float_types (1, 1, 21, [24,8], [53,11], [113,15]) .
 267                 &define_size_t ($m64 ? "long unsigned int" : "unsigned int") .
 268                 ' -D__SIZEOF_POINTER__=' . ($m64 ? '8' : '4'));
 269     } elsif ($spec eq 'host_os_specs') {
 270         my $os = `uname -s`;
 271         chomp $os;
 272         return &add_specs (lc $os);
 273     } elsif ($spec eq 'host_arch_specs') {
 274         my $arch = `uname -m`;
 275         chomp $arch;
 276         if ($arch =~ /^(i.?86|athlon)$/i) {
 277             return &add_specs ('i86');
 278         } elsif ($arch =~ /^(sun4u)$/i) {
 279             return &add_specs ('sparc');
 280         } elsif ($arch =~ /^(x86_64)$/i) {
 281             return &add_specs ('x86_64');
 282         } elsif ($arch =~ /^(ppc)$/i) {
 283             return &add_specs ('ppc');
 284         } elsif ($arch =~ /^(sparc64)$/i) {
 285             return &add_specs ('sparc64');
 286         }
 287     } else {
 288         die "$0: invalid specs: $spec\n";
 289     }
 290 }
 291
 292 # -----------------------------------------------------------------------------