| blob | 53e09ae71ebb3dac7028bf735ac5817e9eaf02d8 |
1 dnl Autoconf macros for groff.
2 dnl Copyright (C) 1989-1995, 2001 Free Software Foundation, Inc.
3 dnl
4 dnl This file is part of groff.
5 dnl
6 dnl groff is free software; you can redistribute it and/or modify it under
7 dnl the terms of the GNU General Public License as published by the Free
8 dnl Software Foundation; either version 2, or (at your option) any later
9 dnl version.
10 dnl
11 dnl groff is distributed in the hope that it will be useful, but WITHOUT ANY
12 dnl WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 dnl FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 dnl for more details.
15 dnl
16 dnl You should have received a copy of the GNU General Public License along
17 dnl with groff; see the file COPYING. If not, write to the Free Software
18 dnl Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19 dnl
20 dnl
21 AC_DEFUN(GROFF_PRINT,
22 [if test -z "$PSPRINT"; then
23 AC_CHECK_PROGS(LPR,lpr)
24 AC_CHECK_PROGS(LP,lp)
25 if test -n "$LPR" && test -n "$LP"; then
26 # HP-UX provides an lpr command that emulates lpr using lp,
27 # but it doesn't have lpq; in this case we want to use lp
28 # rather than lpr.
29 AC_CHECK_PROGS(LPQ,lpq)
30 test -n "$LPQ" || LPR=
31 fi
32 if test -n "$LPR"; then
33 PSPRINT="$LPR"
34 elif test -n "$LP"; then
35 PSPRINT="$LP"
36 fi
37 fi
38 AC_SUBST(PSPRINT)
39 AC_MSG_CHECKING([for command to use for printing PostScript files])
40 AC_MSG_RESULT($PSPRINT)
41 # Figure out DVIPRINT from PSPRINT.
42 AC_MSG_CHECKING([for command to use for printing dvi files])
43 if test -n "$PSPRINT" && test -z "$DVIPRINT"; then
44 if test "X$PSPRINT" = "Xlpr"; then
45 DVIPRINT="lpr -d"
46 else
47 DVIPRINT="$PSPRINT"
48 fi
49 fi
50 AC_SUBST(DVIPRINT)
51 AC_MSG_RESULT($DVIPRINT)])dnl
52 dnl
53 dnl
54 dnl Bison generated parsers have problems with C++ compilers other than g++.
55 dnl So byacc is preferred over bison.
56 dnl
57 AC_DEFUN(GROFF_PROG_YACC,
58 [AC_CHECK_PROGS(YACC, byacc 'bison -y', yacc)])dnl
59 dnl
60 dnl
61 dnl GROFF_CSH_HACK(if hack present, if not present)
62 dnl
63 AC_DEFUN(GROFF_CSH_HACK,
64 [AC_MSG_CHECKING([for csh hash hack])
65 cat <<EOF >conftest.sh
66 #!/bin/sh
67 true || exit 0
68 export PATH || exit 0
69 exit 1
70 EOF
71 chmod +x conftest.sh
72 if echo ./conftest.sh | (csh >/dev/null 2>&1) >/dev/null 2>&1; then
73 AC_MSG_RESULT(yes); $1
74 else
75 AC_MSG_RESULT(no); $2
76 fi
77 rm -f conftest.sh])dnl
78 dnl
79 dnl
80 dnl From udodo!hans@relay.NL.net (Hans Zuidam)
81 dnl
82 AC_DEFUN(GROFF_ISC_SYSV3,
83 [AC_MSG_CHECKING([for ISC 3.x or 4.x])
84 changequote(,)dnl
85 if grep '[34]\.' /usr/options/cb.name >/dev/null 2>&1
86 changequote([,])dnl
87 then
88 AC_MSG_RESULT(yes)
89 AC_DEFINE(_SYSV3)
90 else
91 AC_MSG_RESULT(no)
92 fi])dnl
93 dnl
94 dnl
95 AC_DEFUN(GROFF_POSIX,
96 [AC_MSG_CHECKING([whether -D_POSIX_SOURCE is necessary])
97 AC_LANG_SAVE
98 AC_LANG_CPLUSPLUS
99 AC_TRY_COMPILE([#include <stdio.h>
100 extern "C" { void fileno(int); }],,
101 AC_MSG_RESULT(yes);AC_DEFINE(_POSIX_SOURCE),
102 AC_MSG_RESULT(no))
103 AC_LANG_RESTORE])dnl
104 dnl
105 dnl
106 dnl srand() of SunOS 4.1.3 has return type int instead of void
107 dnl
108 AC_DEFUN(GROFF_SRAND,
109 [AC_LANG_SAVE
110 AC_LANG_CPLUSPLUS
111 AC_MSG_CHECKING([for return type of srand])
112 AC_TRY_COMPILE([#include <stdlib.h>
113 extern "C" { void srand(unsigned int); }],,
114 AC_MSG_RESULT(void);AC_DEFINE(RET_TYPE_SRAND_IS_VOID),
115 AC_MSG_RESULT(int))
116 AC_LANG_RESTORE])dnl
117 dnl
118 dnl
119 AC_DEFUN(GROFF_SYS_NERR,
120 [AC_LANG_SAVE
121 AC_LANG_CPLUSPLUS
122 AC_MSG_CHECKING([for sys_nerr in <errno.h> or <stdio.h>])
123 AC_TRY_COMPILE([#include <errno.h>
124 #include <stdio.h>],
125 [int k; k = sys_nerr;],
126 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_SYS_NERR),
127 AC_MSG_RESULT(no))
128 AC_LANG_RESTORE])dnl
129 dnl
130 dnl
131 AC_DEFUN(GROFF_SYS_ERRLIST,
132 [AC_MSG_CHECKING([for sys_errlist[] in <errno.h> or <stdio.h>])
133 AC_TRY_COMPILE([#include <errno.h>
134 #include <stdio.h>],
135 [int k; k = (int)sys_errlist[0];],
136 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_SYS_ERRLIST),
137 AC_MSG_RESULT(no))])dnl
138 dnl
139 dnl
140 AC_DEFUN(GROFF_OSFCN_H,
141 [AC_LANG_SAVE
142 AC_LANG_CPLUSPLUS
143 AC_MSG_CHECKING([C++ <osfcn.h>])
144 AC_TRY_COMPILE([#include <osfcn.h>],
145 [read(0, 0, 0); open(0, 0);],
146 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_CC_OSFCN_H),
147 AC_MSG_RESULT(no))
148 AC_LANG_RESTORE])dnl
149 dnl
150 dnl
151 AC_DEFUN(GROFF_LIMITS_H,
152 [AC_LANG_SAVE
153 AC_LANG_CPLUSPLUS
154 AC_MSG_CHECKING([C++ <limits.h>])
155 AC_TRY_COMPILE([#include <limits.h>],
156 [int x = INT_MIN; int y = INT_MAX; int z = UCHAR_MAX;],
157 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_CC_LIMITS_H),
158 AC_MSG_RESULT(no))
159 AC_LANG_RESTORE])dnl
160 dnl
161 dnl
162 AC_DEFUN(GROFF_TIME_T,
163 [AC_LANG_SAVE
164 AC_LANG_CPLUSPLUS
165 AC_MSG_CHECKING([for declaration of time_t])
166 AC_TRY_COMPILE([#include <time.h>],
167 [time_t t = time(0); struct tm *p = localtime(&t);],
168 AC_MSG_RESULT(yes),
169 AC_MSG_RESULT(no);AC_DEFINE(LONG_FOR_TIME_T))
170 AC_LANG_RESTORE])dnl
171 dnl
172 dnl
173 AC_DEFUN(GROFF_STRUCT_EXCEPTION,
174 [AC_MSG_CHECKING([struct exception])
175 AC_TRY_COMPILE([#include <math.h>],
176 [struct exception e;],
177 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_STRUCT_EXCEPTION),
178 AC_MSG_RESULT(no))])dnl
179 dnl
180 dnl
181 AC_DEFUN(GROFF_ARRAY_DELETE,
182 [AC_LANG_SAVE
183 AC_LANG_CPLUSPLUS
184 AC_MSG_CHECKING([whether ANSI array delete syntax supported])
185 AC_TRY_COMPILE(,
186 changequote(,)dnl
187 char *p = new char[5]; delete [] p;changequote([,]),
188 AC_MSG_RESULT(yes),
189 AC_MSG_RESULT(no);AC_DEFINE(ARRAY_DELETE_NEEDS_SIZE))
190 AC_LANG_RESTORE])dnl
191 dnl
192 dnl
193 dnl
194 AC_DEFUN(GROFF_TRADITIONAL_CPP,
195 [AC_LANG_SAVE
196 AC_LANG_CPLUSPLUS
197 AC_MSG_CHECKING([traditional preprocessor])
198 AC_TRY_COMPILE([#define name2(a,b) a/**/b],[int name2(foo,bar);],
199 AC_MSG_RESULT(yes);AC_DEFINE(TRADITIONAL_CPP),
200 AC_MSG_RESULT(no))
201 AC_LANG_RESTORE])dnl
202 dnl
203 dnl
204 AC_DEFUN(GROFF_WCOREFLAG,
205 [AC_MSG_CHECKING([w_coredump])
206 AC_TRY_RUN([#include <sys/types.h>
207 #include <sys/wait.h>
208 main()
209 {
210 #ifdef WCOREFLAG
211 exit(1);
212 #else
213 int i = 0;
214 ((union wait *)&i)->w_coredump = 1;
215 exit(i != 0200);
216 #endif
217 }],
218 AC_MSG_RESULT(yes);AC_DEFINE(WCOREFLAG,0200),
219 AC_MSG_RESULT(no),
220 AC_MSG_RESULT(no))])dnl
221 dnl
222 dnl
223 AC_DEFUN(GROFF_BROKEN_SPOOLER_FLAGS,
224 [AC_MSG_CHECKING([default value for grops -b option])
225 test -n "${BROKEN_SPOOLER_FLAGS}" || BROKEN_SPOOLER_FLAGS=7
226 AC_MSG_RESULT($BROKEN_SPOOLER_FLAGS)
227 AC_SUBST(BROKEN_SPOOLER_FLAGS)])dnl
228 dnl
229 dnl
230 AC_DEFUN(GROFF_PAGE,
231 [AC_MSG_CHECKING([default paper size])
232 if test -z "$PAGE"; then
233 descfile=
234 if test -r $prefix/share/groff/font/devps/DESC; then
235 descfile=$prefix/share/groff/font/devps/DESC
236 elif test -r $prefix/lib/groff/font/devps/DESC; then
237 descfile=$prefix/lib/groff/font/devps/DESC
238 else
239 for f in $prefix/share/groff/*/font/devps/DESC; do
240 if test -r $f; then
241 descfile=$f
242 break
243 fi
244 done
245 fi
246 if test -n "$descfile" \
247 && grep "^paperlength 841890" $descfile >/dev/null 2>&1; then
248 PAGE=A4
249 else
250 PAGE=letter
251 fi
252 fi
253 if test -z "$PAGE"; then
254 dom=`awk '([$]1 == "dom" || [$]1 == "search") { print [$]2; exit}' \
255 /etc/resolv.conf 2>/dev/null`
256 if test -z "$dom"; then
257 dom=`(domainname) 2>/dev/null | tr -d '+'`
258 if test -z "$dom"; then
259 dom=`(hostname) 2>/dev/null | grep '\.'`
260 fi
261 fi
262 changequote(,)dnl
263 # If the top-level domain is two letters and it's not `us' or `ca'
264 # then they probably use A4 paper.
265 case "$dom" in
266 *.[Uu][Ss]|*.[Cc][Aa]) ;;
267 *.[A-Za-z][A-Za-z]) PAGE=A4 ;;
268 esac
269 changequote([,])dnl
270 fi
271 test -n "$PAGE" || PAGE=letter
272 AC_MSG_RESULT($PAGE)
273 AC_SUBST(PAGE)])dnl
274 dnl
275 dnl
276 AC_DEFUN(GROFF_CXX_CHECK,
277 [AC_REQUIRE([AC_PROG_CXX])
278 AC_LANG_SAVE
279 AC_LANG_CPLUSPLUS
280 if test "$cross_compiling" = no; then
281 AC_MSG_CHECKING([that C++ compiler can compile simple program])
282 fi
283 AC_TRY_RUN([int main() { return 0; }],
284 AC_MSG_RESULT(yes),
285 AC_MSG_RESULT(no);AC_MSG_ERROR([a working C++ compiler is required]),
286 :)
287 if test "$cross_compiling" = no; then
288 AC_MSG_CHECKING([that C++ static constructors and destructors are called])
289 fi
290 AC_TRY_RUN([
291 extern "C" {
292 void _exit(int);
293 }
294 int i;
295 struct A {
296 char dummy;
297 A() { i = 1; }
298 ~A() { if (i == 1) _exit(0); }
299 };
300 A a;
301 int main() { return 1; }
302 ],
303 AC_MSG_RESULT(yes),
304 AC_MSG_RESULT(no);AC_MSG_ERROR([a working C++ compiler is required]),
305 :)
306 AC_MSG_CHECKING([that header files support C++])
307 AC_TRY_LINK([#include <stdio.h>],
308 [fopen(0, 0);],
309 AC_MSG_RESULT(yes),
310 AC_MSG_RESULT(no);AC_MSG_ERROR([header files do not support C++ (if you are using a version of gcc/g++ earlier than 2.5, you should install libg++)]))
311 AC_LANG_RESTORE])dnl
312 dnl
313 dnl
314 AC_DEFUN(GROFF_TMAC,
315 [AC_MSG_CHECKING([for prefix of system macro packages])
316 sys_tmac_prefix=
317 sys_tmac_file_prefix=
318 for d in /usr/share/lib/tmac /usr/lib/tmac; do
319 for t in "" tmac.; do
320 for m in an s m; do
321 f=$d/$t$m
322 if test -z "$sys_tmac_prefix" \
323 && test -f $f \
324 && grep '^\.if' $f >/dev/null 2>&1; then
325 sys_tmac_prefix=$d/$t
326 sys_tmac_file_prefix=$t
327 fi
328 done
329 done
330 done
331 AC_MSG_RESULT($sys_tmac_prefix)
332 AC_SUBST(sys_tmac_prefix)
333 tmac_wrap=
334 AC_MSG_CHECKING([which system macro packages should be made available])
335 if test "x$sys_tmac_file_prefix" = "xtmac."; then
336 for f in $sys_tmac_prefix*; do
337 suff=`echo $f | sed -e "s;$sys_tmac_prefix;;"`
338 case "$suff" in
339 e) ;;
340 *)
341 grep "Copyright.*Free Software Foundation" $f >/dev/null \
342 || tmac_wrap="$tmac_wrap $suff" ;;
343 esac
344 done
345 elif test -n "$sys_tmac_prefix"; then
346 files=`echo $sys_tmac_prefix*`
347 grep "\\.so" $files >conftest.sol
348 for f in $files; do
349 case "$f" in
350 ${sys_tmac_prefix}e) ;;
351 *.me) ;;
352 */ms.*) ;;
353 *)
354 b=`basename $f`
355 if grep "\\.so.*/$b\$" conftest.sol >/dev/null \
356 || grep -l "Copyright.*Free Software Foundation" $f >/dev/null; then
357 :
358 else
359 suff=`echo $f | sed -e "s;$sys_tmac_prefix;;"`
360 case "$suff" in
361 tmac.*) ;;
362 *) tmac_wrap="$tmac_wrap $suff" ;;
363 esac
364 fi
365 esac
366 done
367 rm -f conftest.sol
368 fi
369 AC_MSG_RESULT([$tmac_wrap])
370 AC_SUBST(tmac_wrap)])dnl
371 dnl
372 dnl
373 AC_DEFUN(GROFF_G,
374 [AC_MSG_CHECKING([for existing troff installation])
375 if test "x`(echo .tm '|n(.g' | tr '|' '\\\\' | troff -z -i 2>&1) 2>/dev/null`" = x0; then
376 AC_MSG_RESULT(yes)
377 g=g
378 else
379 AC_MSG_RESULT(no)
380 g=
381 fi
382 AC_SUBST(g)])dnl
383 dnl
384 dnl
385 dnl We need the path to install-sh to be absolute.
386 dnl
387 AC_DEFUN(GROFF_INSTALL_SH,
388 [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
389 ac_dir=`cd $ac_aux_dir; pwd`
390 ac_install_sh="$ac_dir/install-sh -c"])dnl
391 dnl
392 dnl
393 dnl At least one UNIX system, Apple Macintosh Rhapsody 5.5,
394 dnl does not have -lm.
395 dnl
396 AC_DEFUN(GROFF_LIBM,
397 [AC_CHECK_LIB(m,sin,LIBM=-lm)
398 AC_SUBST(LIBM)])dnl
399 dnl
400 dnl
401 dnl We need top_srcdir to be absolute.
402 dnl
403 AC_DEFUN(GROFF_SRCDIR,
404 [ac_srcdir_defaulted=no
405 srcdir=`cd $srcdir; pwd`])dnl
406 dnl
407 dnl
408 dnl This simplifies Makefile rules.
409 dnl
410 AC_DEFUN(GROFF_BUILDDIR,
411 [top_builddir=`pwd`
412 AC_SUBST(top_builddir)])dnl
413 dnl
414 dnl
415 dnl Check for EBCDIC - stolen from the OS390 Unix LYNX port
416 dnl
417 AC_DEFUN(GROFF_EBCDIC,
418 [AC_MSG_CHECKING([whether character set is EBCDIC])
419 AC_TRY_COMPILE(,
420 [/* Treat any failure as ASCII for compatibility with existing art.
421 Use compile-time rather than run-time tests for cross-compiler
422 tolerance. */
423 #if '0' != 240
424 make an error "Character set is not EBCDIC"
425 #endif],
426 groff_cv_ebcdic="yes"
427 TTYDEVDIRS="font/devcp1047"
428 AC_MSG_RESULT(yes)
429 AC_DEFINE(IS_EBCDIC_HOST),
430 groff_cv_ebcdic="no"
431 TTYDEVDIRS="font/devascii font/devlatin1 font/devutf8"
432 AC_MSG_RESULT(no))
433 AC_SUBST(TTYDEVDIRS)])dnl
434 dnl
435 dnl
436 dnl Check for OS/390 Unix. We test for EBCDIC also -- the Linux port (with
437 dnl gcc) to OS/390 uses ASCII internally.
438 dnl
439 AC_DEFUN(GROFF_OS390,
440 [groff_cv_os390="no"
441 if test "$groff_cv_ebcdic" = "yes"; then
442 AC_MSG_CHECKING([for OS/390 Unix])
443 case `uname` in
444 OS/390)
445 CFLAGS="$CFLAGS -D_ALL_SOURCE"
446 groff_cv_os390="yes"
447 AC_MSG_RESULT(yes) ;;
448 *)
449 AC_MSG_RESULT(no) ;;
450 esac
451 fi])dnl
452 dnl
453 dnl
454 dnl Finally, we must modify a base function of autoconf to replace the
455 dnl ASCII char `012' with its generic equivalent `\n' if we run under
456 dnl OS/390 Unix -- unfortunately, not all `tr' variants understand `\n',
457 dnl so this hack is necessary.
458 dnl
459 define([AC_OUTPUT_MAKE_DEFS],
460 [# Transform confdefs.h into DEFS.
461 dnl Using a here document instead of a string reduces the quoting nightmare.
462 # Protect against shell expansion while executing Makefile rules.
463 # Protect against Makefile macro expansion.
464 cat > conftest.defs <<\EOF
465 changequote(<<, >>)dnl
466 s%<<#define>> \([A-Za-z_][A-Za-z0-9_]*\) *\(.*\)%-D\1=\2%g
467 s%[ `~<<#>>$^&*(){}\\|;'"<>?]%\\&%g
468 s%\[%\\&%g
469 s%\]%\\&%g
470 s%\$%$$%g
471 changequote([, ])dnl
472 EOF
473 if test "$groff_cv_os390" = "yes"; then
474 DEFS=`sed -f conftest.defs confdefs.h | tr '\n' ' '`
475 else
476 DEFS=`sed -f conftest.defs confdefs.h | tr '\012' ' '`
477 fi
478 rm -f conftest.defs
479 ])dnl
480 dnl
481 dnl
482 dnl Check whether we need a declaration for a function.
483 dnl
484 dnl Stolen from GNU bfd.
485 dnl
486 AC_DEFUN(GROFF_NEED_DECLARATION,
487 [AC_MSG_CHECKING([whether $1 must be declared])
488 AC_LANG_SAVE
489 AC_LANG_CPLUSPLUS
490 AC_CACHE_VAL(groff_cv_decl_needed_$1,
491 [AC_TRY_COMPILE([
492 #include <stdio.h>
493 #ifdef HAVE_STRING_H
494 #include <string.h>
495 #else
496 #ifdef HAVE_STRINGS_H
497 #include <strings.h>
498 #endif
499 #endif
500 #ifdef HAVE_STDLIB_H
501 #include <stdlib.h>
502 #endif
503 #ifdef HAVE_UNISTD_H
504 #include <unistd.h>
505 #endif
506 #ifdef HAVE_MATH_H
507 #include <math.h>
508 #endif],
509 [char *(*pfn) = (char *(*)) $1],
510 groff_cv_decl_needed_$1=no,
511 groff_cv_decl_needed_$1=yes)])
512 AC_MSG_RESULT($groff_cv_decl_needed_$1)
513 if test $groff_cv_decl_needed_$1 = yes; then
514 AC_DEFINE([NEED_DECLARATION_]translit($1, [a-z], [A-Z]))
515 fi
516 AC_LANG_RESTORE])dnl
517 dnl
518 dnl
519 dnl Check for mkstemp() and its function prototype.
520 dnl
521 AC_DEFUN(GROFF_MKSTEMP,
522 [AC_CHECK_FUNC(mkstemp,
523 [AC_DEFINE(HAVE_MKSTEMP)
524 AC_MSG_CHECKING([for mkstemp prototype in <stdlib.h>])
525 AC_EGREP_CPP(mkstemp,
526 [#include <stdlib.h>],
527 AC_MSG_RESULT(yes);AC_DEFINE(HAVE_MKSTEMP_PROTO),
528 AC_MSG_RESULT(no))])])