configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT
   3
   4 AC_CONFIG_HEADERS([src/include/config.h:src/include/config.hin])
   5 AC_CONFIG_SRCDIR([src/roff/groff/groff.cpp])
   6
   7 # checks for programs
   8 AC_PROG_CC
   9 AC_PROG_CXX
  10 GROFF_CXX_CHECK
  11 GROFF_EBCDIC
  12 GROFF_OS390
  13 GROFF_PRINT
  14 AC_PATH_PROG([PERLPATH], [perl], [/usr/bin/perl])
  15 GROFF_PROG_YACC
  16 AC_PROG_RANLIB
  17 GROFF_INSTALL_SH
  18 GROFF_INSTALL_INFO
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21
  22 # use a dummy substitution if no csh hack is necessary to avoid errors
  23 # with non-GNU sed programs
  24 GROFF_CSH_HACK([SH_SCRIPT_SED_CMD='1s/.*/:/'], [SH_SCRIPT_SED_CMD='1s/a/a/'])
  25 AC_SUBST([SH_SCRIPT_SED_CMD])
  26
  27 # checks for headers
  28 AC_CHECK_HEADERS([stdlib.h unistd.h dirent.h limits.h sys/dir.h \
  29                   string.h strings.h math.h sys/time.h])
  30 GROFF_ISC_SYSV3
  31 GROFF_POSIX
  32
  33 # checks for header stuff
  34 GROFF_SRAND
  35 GROFF_NEED_DECLARATION([gettimeofday])
  36 GROFF_NEED_DECLARATION([hypot])
  37 GROFF_NEED_DECLARATION([popen])
  38 GROFF_NEED_DECLARATION([pclose])
  39 GROFF_NEED_DECLARATION([putenv])
  40 GROFF_NEED_DECLARATION([rand])
  41 GROFF_NEED_DECLARATION([snprintf])
  42 GROFF_NEED_DECLARATION([srand])
  43 GROFF_NEED_DECLARATION([strcasecmp])
  44 GROFF_NEED_DECLARATION([strncasecmp])
  45 GROFF_NEED_DECLARATION([vfprintf])
  46 GROFF_NEED_DECLARATION([vsnprintf])
  47 GROFF_SYS_NERR
  48 GROFF_SYS_ERRLIST
  49 GROFF_OSFCN_H
  50 GROFF_LIMITS_H
  51 GROFF_STDINT_H
  52 GROFF_INTTYPES_H
  53
  54 # checks for typedefs
  55 GROFF_UNSIGNED_LONG_LONG
  56 GROFF_UINTMAX_T
  57 GROFF_TIME_T
  58 AC_TYPE_SIGNAL
  59 GROFF_STRUCT_EXCEPTION
  60
  61 # checks for libraries
  62 GROFF_LIBC
  63 GROFF_LIBM
  64
  65 # checks for functions
  66 AC_FUNC_MMAP
  67 saved_libs="$LIBS"
  68 LIBS="$LIBS $LIBC $LIBM"
  69 AC_REPLACE_FUNCS([fmod getcwd putenv snprintf strcasecmp \
  70                   strerror strncasecmp strtol])
  71 # vsnprintf is in the same source file as snprintf
  72 AC_CHECK_FUNCS([vsnprintf], [], [AC_LIBOBJ([snprintf])])
  73 LIBS="$saved_libs"
  74 AC_CHECK_FUNCS([gettimeofday isatty kill rename setlocale strsep])
  75 GROFF_MKSTEMP
  76 AC_CHECK_DECLS([sys_siglist])
  77
  78 # checks for compiler characteristics
  79 GROFF_ARRAY_DELETE
  80 GROFF_TRADITIONAL_CPP
  81
  82 # checks for operating system services
  83 GROFF_WCOREFLAG
  84
  85 # other random stuff
  86 GROFF_BROKEN_SPOOLER_FLAGS
  87 GROFF_PAGE
  88 GROFF_G
  89 GROFF_TMAC
  90 GROFF_HTML_PROGRAMS
  91 GROFF_PNMTOPS_NOSETPAGE
  92
  93 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
  94 AC_CONFIG_FILES([Makefile doc/Makefile src/xditview/Imakefile])
  95 AC_OUTPUT
  96
  97 AC_MSG_NOTICE([
  98
  99   Configuration completed.
 100
 101   You can now say `make' to compile the groff package and `make install'
 102   to install it afterwards.
 103
 104   If you want to compile xditview, change the directory to `src/xditview'
 105   and follow the instructions given in the file `INSTALL'.
 106 ])