src/src.pro

   1 TEMPLATE = subdirs
   2
   3 # this order is important
   4 unset(SRC_SUBDIRS)
   5 win32:SRC_SUBDIRS += src_winmain
   6 wince*:{
   7   SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_script src_testlib
   8 } else {
   9     SRC_SUBDIRS += src_tools_bootstrap src_tools_moc src_tools_rcc src_tools_uic src_corelib src_xml src_network src_gui src_sql src_script src_testlib
  10     contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
  11     contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
  12     !cross_compile {
  13         contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
  14     }
  15 }
  16 win32:{
  17     SRC_SUBDIRS += src_activeqt
  18     !wince*: SRC_SUBDIRS += src_tools_idc
  19 }
  20
  21 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
  22 contains(QT_CONFIG, openvg): SRC_SUBDIRS += src_openvg
  23 contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
  24 contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
  25 contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
  26 contains(QT_CONFIG, webkit)  {
  27     #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
  28     SRC_SUBDIRS += src_webkit
  29 }
  30 contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
  31 SRC_SUBDIRS += src_plugins
  32
  33 src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
  34 src_winmain.target = sub-winmain
  35 src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
  36 src_tools_bootstrap.target = sub-tools-bootstrap
  37 src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
  38 src_tools_moc.target = sub-moc
  39 src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
  40 src_tools_rcc.target = sub-rcc
  41 src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
  42 src_tools_uic.target = sub-uic
  43 src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
  44 src_corelib.target = sub-corelib
  45 src_xml.subdir = $$QT_SOURCE_TREE/src/xml
  46 src_xml.target = sub-xml
  47 src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
  48 src_xmlpatterns.target = sub-xmlpatterns
  49 src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
  50 src_dbus.target = sub-dbus
  51 src_gui.subdir = $$QT_SOURCE_TREE/src/gui
  52 src_gui.target = sub-gui
  53 src_sql.subdir = $$QT_SOURCE_TREE/src/sql
  54 src_sql.target = sub-sql
  55 src_network.subdir = $$QT_SOURCE_TREE/src/network
  56 src_network.target = sub-network
  57 src_svg.subdir = $$QT_SOURCE_TREE/src/svg
  58 src_svg.target = sub-svg
  59 src_script.subdir = $$QT_SOURCE_TREE/src/script
  60 src_script.target = sub-script
  61 src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
  62 src_scripttools.target = sub-scripttools
  63 src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
  64 src_opengl.target = sub-opengl
  65 src_openvg.subdir = $$QT_SOURCE_TREE/src/openvg
  66 src_openvg.target = sub-openvg
  67 src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
  68 src_qt3support.target = sub-qt3support
  69 src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
  70 src_phonon.target = sub-phonon
  71 src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
  72 src_tools_uic3.target = sub-uic3
  73 src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
  74 src_activeqt.target = sub-activeqt
  75 src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
  76 src_tools_idc.target = sub-idc
  77 src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
  78 src_plugins.target = sub-plugins
  79 src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
  80 src_testlib.target = sub-testlib
  81 src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
  82 src_javascriptcore.target = sub-javascriptcore
  83 src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
  84 src_webkit.target = sub-webkit
  85
  86 #CONFIG += ordered
  87 !wince*:!ordered {
  88    src_tools_moc.depends = src_tools_bootstrap
  89    src_tools_rcc.depends = src_tools_bootstrap
  90    src_tools_uic.depends = src_tools_bootstrap
  91    src_corelib.depends = src_tools_moc src_tools_rcc
  92    src_gui.depends = src_corelib src_tools_uic
  93    embedded: src_gui.depends += src_network
  94    src_xml.depends = src_corelib
  95    src_xmlpatterns.depends = src_corelib src_network
  96    src_dbus.depends = src_corelib src_xml
  97    src_svg.depends = src_xml src_gui
  98    src_script.depends = src_corelib
  99    src_scripttools.depends = src_script src_gui src_network
 100    src_network.depends = src_corelib
 101    src_opengl.depends = src_gui
 102    src_openvg.depends = src_gui
 103    src_sql.depends = src_corelib
 104    src_testlib.depends = src_corelib
 105    src_qt3support.depends = src_gui src_xml src_network src_sql
 106    src_phonon.depends = src_gui
 107    src_tools_uic3.depends = src_qt3support src_xml
 108    src_tools_idc.depends = src_corelib
 109    src_tools_activeqt.depends = src_tools_idc src_gui
 110    src_plugins.depends = src_gui src_sql src_svg
 111    contains(QT_CONFIG, webkit)  {
 112       src_webkit.depends = src_gui src_sql src_network src_xml
 113       #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
 114    }
 115    contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
 116    contains(QT_CONFIG, dbus):{
 117       src_plugins.depends += src_dbus
 118       src_phonon.depends +=  src_dbus
 119    }
 120 }
 121
 122 # This creates a sub-src rule
 123 sub_src_target.CONFIG = recursive
 124 sub_src_target.recurse = $$SRC_SUBDIRS
 125 sub_src_target.target = sub-src
 126 sub_src_target.recurse_target =
 127 QMAKE_EXTRA_TARGETS += sub_src_target
 128
 129 # This gives us a top level debug/release
 130 EXTRA_DEBUG_TARGETS =
 131 EXTRA_RELEASE_TARGETS =
 132 for(subname, SRC_SUBDIRS) {
 133    subdir = $$subname
 134    !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
 135    subpro = $$subdir/$${basename(subdir)}.pro
 136    !exists($$subpro):next()
 137    subtarget = $$replace(subdir, [^A-Za-z0-9], _)
 138    reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
 139    subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
 140    subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
 141    subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
 142    SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
 143    !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
 144        #debug
 145        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 146        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
 147        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 148        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 149        #release
 150        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 151        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
 152        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 153        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 154     } else { #do not have a real debug target/release
 155        #debug
 156        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 157        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 158        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 159        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 160        #release
 161        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 162        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 163        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 164        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 165    }
 166 }
 167 debug.depends = $$EXTRA_DEBUG_TARGETS
 168 release.depends = $$EXTRA_RELEASE_TARGETS
 169 QMAKE_EXTRA_TARGETS += debug release
 170
 171 SUBDIRS += $$SRC_SUBDIRS
 172