kvm/bios/rombios32start.S

   1 /////////////////////////////////////////////////////////////////////////
   2 // $Id: rombios32start.S,v 1.3 2006/10/02 06:29:38 vruppert Exp $
   3 /////////////////////////////////////////////////////////////////////////
   4 //
   5 //  32 bit Bochs BIOS init code
   6 //  Copyright (C) 2006 Fabrice Bellard
   7 //
   8 //  This library is free software; you can redistribute it and/or
   9 //  modify it under the terms of the GNU Lesser General Public
  10 //  License as published by the Free Software Foundation; either
  11 //  version 2 of the License, or (at your option) any later version.
  12 //
  13 //  This library is distributed in the hope that it will be useful,
  14 //  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 //  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 //  Lesser General Public License for more details.
  17 //
  18 //  You should have received a copy of the GNU Lesser General Public
  19 //  License along with this library; if not, write to the Free Software
  20 //  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301 USA
  21 #include "rombios.h"
  22
  23 .globl _start
  24 .globl smp_ap_boot_code_start
  25 .globl smp_ap_boot_code_end
  26 .global smm_relocation_start
  27 .global smm_relocation_end
  28 .global smm_code_start
  29 .global smm_code_end
  30
  31 _start:
  32   /* clear bss section */
  33   xor %eax, %eax
  34   mov $__bss_start, %edi
  35   mov $_end, %ecx
  36   sub %edi, %ecx
  37   rep stosb
  38
  39   jmp rombios32_init
  40
  41   .code16
  42 smp_ap_boot_code_start:
  43   xor %ax, %ax
  44   mov %ax, %ds
  45   xor %eax, %eax
  46   xor %edx, %edx
  47   mov $0x10, %ecx
  48   wrmsr
  49   incw CPU_COUNT_ADDR
  50 1:
  51   hlt
  52   jmp 1b
  53 smp_ap_boot_code_end:
  54
  55 /* code to relocate SMBASE to 0xa0000 */
  56 smm_relocation_start:
  57   mov $0x38000 + 0x7efc, %ebx
  58   addr32 mov (%ebx), %al  /* revision ID to see if x86_64 or x86 */
  59   cmp $0x64, %al
  60   je 1f
  61   mov $0x38000 + 0x7ef8, %ebx
  62   jmp 2f
  63 1:
  64   mov $0x38000 + 0x7f00, %ebx
  65 2:
  66   movl $0xa0000, %eax
  67   addr32 movl %eax, (%ebx)
  68   /* indicate to the BIOS that the SMM code was executed */
  69   mov $0x00, %al
  70   movw $0xb3, %dx
  71   outb %al, %dx
  72   rsm
  73 smm_relocation_end:
  74
  75 /* minimal SMM code to enable or disable ACPI */
  76 smm_code_start:
  77   movw $0xb2, %dx
  78   inb %dx, %al
  79   cmp $0xf0, %al
  80   jne 1f
  81
  82   /* ACPI disable */
  83   mov $PM_IO_BASE + 0x04, %dx /* PMCNTRL */
  84   inw %dx, %ax
  85   andw $~1, %ax
  86   outw %ax, %dx
  87
  88   jmp 2f
  89
  90 1:
  91   cmp $0xf1, %al
  92   jne 2f
  93
  94   /* ACPI enable */
  95   mov $PM_IO_BASE + 0x04, %dx /* PMCNTRL */
  96   inw %dx, %ax
  97   orw $1, %ax
  98   outw %ax, %dx
  99
 100 2:
 101   rsm
 102 smm_code_end: