acinclude.m4

   1 # ===========================================================================
   2 #              http://autoconf-archive.cryp.to/acx_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also link it with them as well. e.g. you should link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threads programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #          LIBS="$PTHREAD_LIBS $LIBS"
  29 #          CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #          CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
  34 #   (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  37 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  38 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  39 #   will define HAVE_PTHREAD.
  40 #
  41 #   Please let the authors know if this macro fails on any platform, or if
  42 #   you have any other suggestions or comments. This macro was based on work
  43 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  44 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  45 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  46 #   grateful for the helpful feedback of numerous users.
  47 #
  48 # LICENSE
  49 #
  50 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  51 #
  52 #   This program is free software: you can redistribute it and/or modify it
  53 #   under the terms of the GNU General Public License as published by the
  54 #   Free Software Foundation, either version 3 of the License, or (at your
  55 #   option) any later version.
  56 #
  57 #   This program is distributed in the hope that it will be useful, but
  58 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  59 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  60 #   Public License for more details.
  61 #
  62 #   You should have received a copy of the GNU General Public License along
  63 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  64 #
  65 #   As a special exception, the respective Autoconf Macro's copyright owner
  66 #   gives unlimited permission to copy, distribute and modify the configure
  67 #   scripts that are the output of Autoconf when processing the Macro. You
  68 #   need not follow the terms of the GNU General Public License when using
  69 #   or distributing such scripts, even though portions of the text of the
  70 #   Macro appear in them. The GNU General Public License (GPL) does govern
  71 #   all other use of the material that constitutes the Autoconf Macro.
  72 #
  73 #   This special exception to the GPL applies to versions of the Autoconf
  74 #   Macro released by the Autoconf Archive. When you make and distribute a
  75 #   modified version of the Autoconf Macro, you may extend this special
  76 #   exception to the GPL to apply to your modified version as well.
  77
  78 AC_DEFUN([ACX_PTHREAD], [
  79 AC_REQUIRE([AC_CANONICAL_HOST])
  80 AC_LANG_SAVE
  81 AC_LANG_C
  82 acx_pthread_ok=no
  83
  84 # We used to check for pthread.h first, but this fails if pthread.h
  85 # requires special compiler flags (e.g. on True64 or Sequent).
  86 # It gets checked for in the link test anyway.
  87
  88 # First of all, check if the user has set any of the PTHREAD_LIBS,
  89 # etcetera environment variables, and if threads linking works using
  90 # them:
  91 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  92         save_CFLAGS="$CFLAGS"
  93         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  94         save_LIBS="$LIBS"
  95         LIBS="$PTHREAD_LIBS $LIBS"
  96         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
  97         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
  98         AC_MSG_RESULT($acx_pthread_ok)
  99         if test x"$acx_pthread_ok" = xno; then
 100                 PTHREAD_LIBS=""
 101                 PTHREAD_CFLAGS=""
 102         fi
 103         LIBS="$save_LIBS"
 104         CFLAGS="$save_CFLAGS"
 105 fi
 106
 107 # We must check for the threads library under a number of different
 108 # names; the ordering is very important because some systems
 109 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 110 # libraries is broken (non-POSIX).
 111
 112 # Create a list of thread flags to try.  Items starting with a "-" are
 113 # C compiler flags, and other items are library names, except for "none"
 114 # which indicates that we try without any flags at all, and "pthread-config"
 115 # which is a program returning the flags for the Pth emulation library.
 116
 117 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 118
 119 # The ordering *is* (sometimes) important.  Some notes on the
 120 # individual items follow:
 121
 122 # pthreads: AIX (must check this before -lpthread)
 123 # none: in case threads are in libc; should be tried before -Kthread and
 124 #       other compiler flags to prevent continual compiler warnings
 125 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 126 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 127 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 128 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 129 # -pthreads: Solaris/gcc
 130 # -mthreads: Mingw32/gcc, Lynx/gcc
 131 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 132 #      doesn't hurt to check since this sometimes defines pthreads too;
 133 #      also defines -D_REENTRANT)
 134 #      ... -mt is also the pthreads flag for HP/aCC
 135 # pthread: Linux, etcetera
 136 # --thread-safe: KAI C++
 137 # pthread-config: use pthread-config program (for GNU Pth library)
 138
 139 case "${host_cpu}-${host_os}" in
 140         *solaris*)
 141
 142         # On Solaris (at least, for some versions), libc contains stubbed
 143         # (non-functional) versions of the pthreads routines, so link-based
 144         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 145         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 146         # a function called by this macro, so we could check for that, but
 147         # who knows whether they'll stub that too in a future libc.)  So,
 148         # we'll just look for -pthreads and -lpthread first:
 149
 150         acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
 151         ;;
 152 esac
 153
 154 if test x"$acx_pthread_ok" = xno; then
 155 for flag in $acx_pthread_flags; do
 156
 157         case $flag in
 158                 none)
 159                 AC_MSG_CHECKING([whether pthreads work without any flags])
 160                 ;;
 161
 162                 -*)
 163                 AC_MSG_CHECKING([whether pthreads work with $flag])
 164                 PTHREAD_CFLAGS="$flag"
 165                 ;;
 166
 167                 pthread-config)
 168                 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
 169                 if test x"$acx_pthread_config" = xno; then continue; fi
 170                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 171                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 172                 ;;
 173
 174                 *)
 175                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 176                 PTHREAD_LIBS="-l$flag"
 177                 ;;
 178         esac
 179
 180         save_LIBS="$LIBS"
 181         save_CFLAGS="$CFLAGS"
 182         LIBS="$PTHREAD_LIBS $LIBS"
 183         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 184
 185         # Check for various functions.  We must include pthread.h,
 186         # since some functions may be macros.  (On the Sequent, we
 187         # need a special flag -Kthread to make this header compile.)
 188         # We check for pthread_join because it is in -lpthread on IRIX
 189         # while pthread_create is in libc.  We check for pthread_attr_init
 190         # due to DEC craziness with -lpthreads.  We check for
 191         # pthread_cleanup_push because it is one of the few pthread
 192         # functions on Solaris that doesn't have a non-functional libc stub.
 193         # We try pthread_create on general principles.
 194         AC_TRY_LINK([#include <pthread.h>],
 195                     [pthread_t th; pthread_join(th, 0);
 196                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 197                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 198                     [acx_pthread_ok=yes])
 199
 200         LIBS="$save_LIBS"
 201         CFLAGS="$save_CFLAGS"
 202
 203         AC_MSG_RESULT($acx_pthread_ok)
 204         if test "x$acx_pthread_ok" = xyes; then
 205                 break;
 206         fi
 207
 208         PTHREAD_LIBS=""
 209         PTHREAD_CFLAGS=""
 210 done
 211 fi
 212
 213 # Various other checks:
 214 if test "x$acx_pthread_ok" = xyes; then
 215         save_LIBS="$LIBS"
 216         LIBS="$PTHREAD_LIBS $LIBS"
 217         save_CFLAGS="$CFLAGS"
 218         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 219
 220         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 221         AC_MSG_CHECKING([for joinable pthread attribute])
 222         attr_name=unknown
 223         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 224             AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
 225                         [attr_name=$attr; break])
 226         done
 227         AC_MSG_RESULT($attr_name)
 228         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 229             AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
 230                                [Define to necessary symbol if this constant
 231                                 uses a non-standard name on your system.])
 232         fi
 233
 234         AC_MSG_CHECKING([if more special flags are required for pthreads])
 235         flag=no
 236         case "${host_cpu}-${host_os}" in
 237             *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
 238             *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
 239         esac
 240         AC_MSG_RESULT(${flag})
 241         if test "x$flag" != xno; then
 242             PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 243         fi
 244
 245         LIBS="$save_LIBS"
 246         CFLAGS="$save_CFLAGS"
 247
 248         # More AIX lossage: must compile with xlc_r or cc_r
 249         if test x"$GCC" != xyes; then
 250           AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
 251         else
 252           PTHREAD_CC=$CC
 253         fi
 254 else
 255         PTHREAD_CC="$CC"
 256 fi
 257
 258 AC_SUBST(PTHREAD_LIBS)
 259 AC_SUBST(PTHREAD_CFLAGS)
 260 AC_SUBST(PTHREAD_CC)
 261
 262 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 263 if test x"$acx_pthread_ok" = xyes; then
 264         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 265         :
 266 else
 267         acx_pthread_ok=no
 268         $2
 269 fi
 270 AC_LANG_RESTORE
 271 ])dnl ACX_PTHREAD