recipes/openttd/openttd_0.7.4.bb

   1 DESCRIPTION = "Open source clone of the Microprose game 'Transport Tycoon Deluxe' - SDL edition."
   2 HOMEPAGE = "http://www.openttd.org"
   3 LICENSE = "GPLv2"
   4 DEPENDS = "libsdl-net libpng zlib freetype fontconfig"
   5 RRECOMMENDS_${PN} = "openttd-gfx openttd-sfx"
   6 PR = "r1"
   7
   8 inherit siteinfo sdl
   9
  10 SRC_URI ="http://binaries.openttd.org/releases/${PV}/${P}-source.tar.bz2 "
  11 SRC_URI_append_shr = " file://openttd.cfg"
  12
  13 APPIMAGE = "media/openttd.128.png"
  14
  15 do_configure() {
  16   # The way the OTTD configure system handles the application's directories
  17   # isn't the way autotools does it. Mainly prefix is always prepended even if
  18   # absolute binary-dir and data-dir is given.
  19
  20   ${S}/configure \
  21         --host=${TARGET_SYS} \
  22         --windres=${MACHINE_DISPLAY_WIDTH_PIXELS}x${MACHINE_DISPLAY_HEIGHT_PIXELS} \
  23         --os=UNIX \
  24         --endian=${SITEINFO_ENDIANNESS} \
  25         --prefix-dir=${prefix} \
  26         --binary-dir=bin \
  27         --with-midi=/bin/true \
  28         --with-zlib=${STAGING_LIBDIR} \
  29         --with-png \
  30         --with-freetype \
  31         --without-icu \
  32         --without-allegro \
  33         --cc-build=gcc \
  34         --cc-host=${TARGET_SYS}-gcc \
  35         --cxx-build=g++ \
  36         --cxx-host=${TARGET_SYS}-g++ \
  37         --strip=${TARGET_SYS}-strip \
  38         --install-dir=${D}
  39 }
  40
  41 do_install() {
  42         oe_runmake install
  43 }
  44
  45 do_install_append_shr() {
  46         install -d ${D}${datadir}/games/openttd/data/
  47         install -m 0644 ${WORKDIR}/openttd.cfg ${D}${datadir}/games/openttd/data/
  48 }
  49
  50 FILES_${PN} += "${datadir}"
  51
  52 SRC_URI[md5sum] = "30763b0dc6d77386a23261ad4b2cded8"
  53 SRC_URI[sha256sum] = "014286af4b978fec3845fe276d40d07789acd4ac67b5f489f9bdfdf0eed6ad27"