recipes/openttd/openttd_0.7.4.bb

   1 require openttd.inc
   2
   3 # lzo2 not neccessary yet in 0.7.4
   4 DEPENDS = "libsdl-net libpng zlib freetype fontconfig"
   5
   6 # Using the tar.bz2 for this release (they are missing for later releases).
   7 SRC_URI ="http://binaries.openttd.org/releases/${PV}/${P}-source.tar.bz2"
   8
   9 # Version 0.7.4 can only handle opengfx
  10 RRECOMMENDS_${PN} = "openttd-gfx"
  11
  12 PR = "r3"
  13
  14 # Override this function from openttd.inc because this 0.7.4's configure does not understand the 'lzo2' specific
  15 # options and stops on seeing unknown options (Unlike what the real autotools would do. Hooray to people writing their
  16 # own build systems!).
  17 do_configure() {
  18   # The way the OTTD configure system handles the application's directories
  19   # isn't the way autotools does it. Mainly prefix is always prepended even if
  20   # absolute binary-dir and data-dir is given.
  21
  22   ${S}/configure \
  23         --host=${TARGET_SYS} \
  24         --windres=${MACHINE_DISPLAY_WIDTH_PIXELS}x${MACHINE_DISPLAY_HEIGHT_PIXELS} \
  25         --os=UNIX \
  26         --endian=${SITEINFO_ENDIANNESS} \
  27         --prefix-dir=${prefix} \
  28         --binary-dir=bin \
  29         --with-midi=/bin/true \
  30         --with-zlib=${STAGING_LIBDIR} \
  31         --with-png \
  32         --with-freetype \
  33         --without-icu \
  34         --without-allegro \
  35         --cc-build='${BUILD_CC}' \
  36         --cc-host='${CC}' \
  37         --cxx-build='${BUILD_CXX}' \
  38         --cxx-host='${CXX}' \
  39         --strip='${STRIP}' \
  40         --install-dir=${D}
  41 }
  42
  43 do_install_append() {
  44         # Provide a placeholder sample.cat to allow the game being started.
  45         install -d ${D}${datadir}/games/openttd/data/
  46         touch ${D}${datadir}/games/openttd/data/sample.cat
  47 }
  48
  49 SRC_URI_append_shr = " file://openttd.cfg"
  50
  51 do_install_append_shr() {
  52         install -d ${D}${datadir}/games/openttd/data/
  53         install -m 0644 ${WORKDIR}/openttd.cfg ${D}${datadir}/games/openttd/data/
  54 }
  55
  56 SRC_URI[md5sum] = "30763b0dc6d77386a23261ad4b2cded8"
  57 SRC_URI[sha256sum] = "014286af4b978fec3845fe276d40d07789acd4ac67b5f489f9bdfdf0eed6ad27"