fixincludes/configure.ac

   1 AC_PREREQ(2.59)
   2
   3 AC_INIT(fixincludes, [ ])
   4 AC_CONFIG_SRCDIR(inclhack.def)
   5 AC_CONFIG_AUX_DIR(..)
   6 AC_CANONICAL_SYSTEM
   7 AC_PROG_CC
   8
   9 # Determine the noncanonical target name, for directory use.
  10 ACX_NONCANONICAL_TARGET
  11
  12 # Specify the local prefix
  13 local_prefix=
  14 AC_ARG_WITH(local-prefix,
  15 [  --with-local-prefix=DIR specifies directory to put local include],
  16 [case "${withval}" in
  17 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
  18 no)     ;;
  19 *)      local_prefix=$with_local_prefix ;;
  20 esac])
  21
  22 # Default local prefix if it is empty
  23 if test x$local_prefix = x; then
  24         local_prefix=/usr/local
  25 fi
  26
  27 # Choose one or two-process fix methodology.  Systems that cannot handle
  28 # bi-directional pipes must use the two process method.
  29 #
  30 AC_ARG_ENABLE([twoprocess],
  31 [  --enable-twoprocess       Use a separate process to apply the fixes],
  32 [if test "x$enable_twoprocess" = xyes; then
  33         TARGET=twoprocess
  34 else
  35         TARGET=oneprocess
  36 fi],
  37 [case $host in
  38         i?86-*-msdosdjgpp* | \
  39         i?86-*-mingw32* | \
  40         *-*-beos* )
  41                 TARGET=twoprocess
  42                 ;;
  43
  44         * )
  45                 TARGET=oneprocess
  46                 ;;
  47 esac])
  48 AC_SUBST(TARGET)
  49
  50 if test $TARGET = twoprocess; then
  51         AC_DEFINE(SEPARATE_FIX_PROC, 1,
  52                   [Define if testing and fixing are done by separate process])
  53 fi
  54
  55 TL_AC_GCC_VERSION([$srcdir/..])
  56
  57 case $host in
  58         vax-dec-bsd* )
  59                 AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
  60                 AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
  61                 ;;
  62 esac
  63
  64 AC_DEFINE_UNQUOTED([EXE_EXT], "$ac_exeext",
  65   [Defined to the executable file extension on the host system])
  66
  67 # Checks for header files.
  68 AC_HEADER_STDC
  69 AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
  70         sys/stat.h])
  71 AC_CHECK_FUNCS(putc_unlocked fputc_unlocked fputs_unlocked \
  72         fwrite_unlocked fprintf_unlocked)
  73 AC_CHECK_DECLS([abort, errno, putc_unlocked, fputc_unlocked,
  74         fputs_unlocked, fwrite_unlocked, fprintf_unlocked])
  75
  76 # Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_CONST
  78
  79 # Checks for library functions.
  80 gcc_AC_FUNC_MMAP_BLACKLIST
  81
  82 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  83 AC_ARG_ENABLE(maintainer-mode,
  84 [  --enable-maintainer-mode enable make rules and dependencies not useful
  85                           (and sometimes confusing) to the casual installer],
  86       USE_MAINTAINER_MODE=$enableval,
  87       USE_MAINTAINER_MODE=no)
  88 AC_MSG_RESULT($USE_MAINTAINER_MODE)
  89 if test "$USE_MAINTAINER_MODE" = yes; then
  90   MAINT=
  91 else
  92   MAINT='#'
  93 fi
  94 AC_SUBST(MAINT)
  95
  96 AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
  97 AC_CONFIG_FILES(Makefile mkheaders)
  98 AC_OUTPUT