fixincludes/configure.ac

   1
   2 AC_INIT(fixincludes, [ ])
   3 AC_CONFIG_SRCDIR(inclhack.def)
   4 AC_CONFIG_AUX_DIR(..)
   5 m4_sinclude(../libtool.m4)
   6 AC_CANONICAL_SYSTEM
   7 AC_PROG_CC
   8 AC_USE_SYSTEM_EXTENSIONS
   9 AC_PROG_SED
  10
  11 # Figure out what compiler warnings we can enable.
  12 # See config/warnings.m4 for details.
  13
  14 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  15                           -Wmissing-prototypes -Wold-style-definition \
  16                           -Wmissing-format-attribute -Wno-overlength-strings])
  17 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  18
  19 # Only enable with --enable-werror-always until existing warnings are
  20 # corrected.
  21 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  22
  23 # Determine the noncanonical target name, for directory use.
  24 ACX_NONCANONICAL_TARGET
  25
  26 # Specify the local prefix
  27 local_prefix=
  28 AC_ARG_WITH(local-prefix,
  29 [  --with-local-prefix=DIR specifies directory to put local include],
  30 [case "${withval}" in
  31 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
  32 no)     ;;
  33 *)      local_prefix=$with_local_prefix ;;
  34 esac])
  35
  36 # Default local prefix if it is empty
  37 if test x$local_prefix = x; then
  38         local_prefix=/usr/local
  39 fi
  40
  41 # Choose one or two-process fix methodology.  Systems that cannot handle
  42 # bi-directional pipes must use the two process method.
  43 #
  44 AC_ARG_ENABLE([twoprocess],
  45 [  --enable-twoprocess       Use a separate process to apply the fixes],
  46 [if test "x$enable_twoprocess" = xyes; then
  47         TARGET=twoprocess
  48 else
  49         TARGET=oneprocess
  50 fi],
  51 [case $host in
  52         i?86-*-msdosdjgpp* | \
  53         i?86-*-mingw32* | \
  54         x86_64-*-mingw32* | \
  55         *-*-beos* | \
  56         *-*-*vms*)
  57                 TARGET=twoprocess
  58                 ;;
  59
  60         * )
  61                 TARGET=oneprocess
  62                 ;;
  63 esac])
  64 AC_SUBST(TARGET)
  65
  66 if test $TARGET = twoprocess; then
  67         AC_DEFINE(SEPARATE_FIX_PROC, 1,
  68                   [Define if testing and fixing are done by separate process])
  69 fi
  70
  71 # Enable --enable-host-pie.
  72 AC_ARG_ENABLE(host-pie,
  73 [AS_HELP_STRING([--enable-host-pie],
  74        [build host code as PIE])],
  75 [PICFLAG=-fPIE; LD_PICFLAG=-pie], [])
  76 AC_SUBST(PICFLAG)
  77 AC_SUBST(LD_PICFLAG)
  78
  79 case $host in
  80         vax-dec-bsd* )
  81                 AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
  82                 AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
  83                 ;;
  84 esac
  85
  86 AC_DEFINE_UNQUOTED([EXE_EXT], "$ac_exeext",
  87   [Defined to the executable file extension on the host system])
  88
  89 # Checks for header files.
  90 AC_HEADER_STDC
  91 AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
  92         sys/stat.h])
  93 define(fixincludes_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  94   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  95   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  96   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  97   putchar_unlocked putc_unlocked)
  98 AC_CHECK_FUNCS(fixincludes_UNLOCKED_FUNCS)
  99 AC_CHECK_DECLS([abort, asprintf, basename(char *), errno, vasprintf, memmem])
 100 AC_CHECK_DECLS(m4_split(m4_normalize(fixincludes_UNLOCKED_FUNCS)))
 101
 102 # Checks for typedefs, structures, and compiler characteristics.
 103 AC_C_CONST
 104
 105 # Checks for library functions.
 106 GCC_AC_FUNC_MMAP_BLACKLIST
 107
 108 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
 109 AC_ARG_ENABLE(maintainer-mode,
 110 [  --enable-maintainer-mode enable make rules and dependencies not useful
 111                           (and sometimes confusing) to the casual installer],
 112       USE_MAINTAINER_MODE=$enableval,
 113       USE_MAINTAINER_MODE=no)
 114 AC_MSG_RESULT($USE_MAINTAINER_MODE)
 115 if test "$USE_MAINTAINER_MODE" = yes; then
 116   MAINT=
 117 else
 118   MAINT='#'
 119 fi
 120 AC_SUBST(MAINT)
 121 AC_DEFINE_UNQUOTED([SED_PROGRAM], "${SED}",
 122    [Defined to the best working sed program on the host system])
 123
 124 # Determine what GCC version number to use in filesystem paths.
 125 GCC_BASE_VER
 126
 127 AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
 128 AC_CONFIG_FILES(Makefile mkheaders.almost:mkheaders.in)
 129 AC_OUTPUT