?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
Implement -mmemcpy-strategy= and -mmemset-strategy= options
[official-gcc.git] / gcc / ada / exp_intr.adb
blob7302f0770122a3e1be5e1afcc34ae9c4ae015820
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT COMPILER COMPONENTS --
4 -- --
5 -- E X P _ I N T R --
6 -- --
7 -- B o d y --
8 -- --
9 -- Copyright (C) 1992-2013, Free Software Foundation, Inc. --
10 -- --
11 -- GNAT is free software; you can redistribute it and/or modify it under --
12 -- terms of the GNU General Public License as published by the Free Soft- --
13 -- ware Foundation; either version 3, or (at your option) any later ver- --
14 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License --
17 -- for more details. You should have received a copy of the GNU General --
18 -- Public License distributed with GNAT; see file COPYING3. If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license. --
20 -- --
21 -- GNAT was originally developed by the GNAT team at New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc. --
23 -- --
24 ------------------------------------------------------------------------------
25
26 with Atree; use Atree;
27 with Checks; use Checks;
28 with Einfo; use Einfo;
29 with Elists; use Elists;
30 with Errout; use Errout;
31 with Exp_Atag; use Exp_Atag;
32 with Exp_Ch4; use Exp_Ch4;
33 with Exp_Ch7; use Exp_Ch7;
34 with Exp_Ch11; use Exp_Ch11;
35 with Exp_Code; use Exp_Code;
36 with Exp_Fixd; use Exp_Fixd;
37 with Exp_Util; use Exp_Util;
38 with Freeze; use Freeze;
39 with Namet; use Namet;
40 with Nmake; use Nmake;
41 with Nlists; use Nlists;
42 with Opt; use Opt;
43 with Restrict; use Restrict;
44 with Rident; use Rident;
45 with Rtsfind; use Rtsfind;
46 with Sem; use Sem;
47 with Sem_Aux; use Sem_Aux;
48 with Sem_Eval; use Sem_Eval;
49 with Sem_Res; use Sem_Res;
50 with Sem_Type; use Sem_Type;
51 with Sem_Util; use Sem_Util;
52 with Sinfo; use Sinfo;
53 with Sinput; use Sinput;
54 with Snames; use Snames;
55 with Stand; use Stand;
56 with Stringt; use Stringt;
57 with Targparm; use Targparm;
58 with Tbuild; use Tbuild;
59 with Uintp; use Uintp;
60 with Urealp; use Urealp;
61
62 package body Exp_Intr is
63
64 -----------------------
65 -- Local Subprograms --
66 -----------------------
67
68 procedure Expand_Binary_Operator_Call (N : Node_Id);
69 -- Expand a call to an intrinsic arithmetic operator when the operand
70 -- types or sizes are not identical.
71
72 procedure Expand_Is_Negative (N : Node_Id);
73 -- Expand a call to the intrinsic Is_Negative function
74
75 procedure Expand_Dispatching_Constructor_Call (N : Node_Id);
76 -- Expand a call to an instantiation of Generic_Dispatching_Constructor
77 -- into a dispatching call to the actual subprogram associated with the
78 -- Constructor formal subprogram, passing it the Parameters actual of
79 -- the call to the instantiation and dispatching based on call's Tag
80 -- parameter.
81
82 procedure Expand_Exception_Call (N : Node_Id; Ent : RE_Id);
83 -- Expand a call to Exception_Information/Message/Name. The first
84 -- parameter, N, is the node for the function call, and Ent is the
85 -- entity for the corresponding routine in the Ada.Exceptions package.
86
87 procedure Expand_Import_Call (N : Node_Id);
88 -- Expand a call to Import_Address/Longest_Integer/Value. The parameter
89 -- N is the node for the function call.
90
91 procedure Expand_Shift (N : Node_Id; E : Entity_Id; K : Node_Kind);
92 -- Expand an intrinsic shift operation, N and E are from the call to
93 -- Expand_Intrinsic_Call (call node and subprogram spec entity) and
94 -- K is the kind for the shift node
95
96 procedure Expand_Unc_Conversion (N : Node_Id; E : Entity_Id);
97 -- Expand a call to an instantiation of Unchecked_Conversion into a node
98 -- N_Unchecked_Type_Conversion.
99
100 procedure Expand_Unc_Deallocation (N : Node_Id);
101 -- Expand a call to an instantiation of Unchecked_Deallocation into a node
102 -- N_Free_Statement and appropriate context.
103
104 procedure Expand_To_Address (N : Node_Id);
105 procedure Expand_To_Pointer (N : Node_Id);
106 -- Expand a call to corresponding function, declared in an instance of
107 -- System.Address_To_Access_Conversions.
108
109 procedure Expand_Source_Info (N : Node_Id; Nam : Name_Id);
110 -- Rewrite the node by the appropriate string or positive constant.
111 -- Nam can be one of the following:
112 -- Name_File - expand string that is the name of source file
113 -- Name_Line - expand integer line number
114 -- Name_Source_Location - expand string of form file:line
115 -- Name_Enclosing_Entity - expand string with name of enclosing entity
116
117 ---------------------------------
118 -- Expand_Binary_Operator_Call --
119 ---------------------------------
120
121 procedure Expand_Binary_Operator_Call (N : Node_Id) is
122 T1 : constant Entity_Id := Underlying_Type (Etype (Left_Opnd (N)));
123 T2 : constant Entity_Id := Underlying_Type (Etype (Right_Opnd (N)));
124 TR : constant Entity_Id := Etype (N);
125 T3 : Entity_Id;
126 Res : Node_Id;
127
128 Siz : constant Uint := UI_Max (RM_Size (T1), RM_Size (T2));
129 -- Maximum of operand sizes
130
131 begin
132 -- Nothing to do if the operands have the same modular type
133
134 if Base_Type (T1) = Base_Type (T2)
135 and then Is_Modular_Integer_Type (T1)
136 then
137 return;
138 end if;
139
140 -- Use Unsigned_32 for sizes of 32 or below, else Unsigned_64
141
142 if Siz > 32 then
143 T3 := RTE (RE_Unsigned_64);
144 else
145 T3 := RTE (RE_Unsigned_32);
146 end if;
147
148 -- Copy operator node, and reset type and entity fields, for
149 -- subsequent reanalysis.
150
151 Res := New_Copy (N);
152 Set_Etype (Res, T3);
153
154 case Nkind (N) is
155 when N_Op_And =>
156 Set_Entity (Res, Standard_Op_And);
157 when N_Op_Or =>
158 Set_Entity (Res, Standard_Op_Or);
159 when N_Op_Xor =>
160 Set_Entity (Res, Standard_Op_Xor);
161 when others =>
162 raise Program_Error;
163 end case;
164
165 -- Convert operands to large enough intermediate type
166
167 Set_Left_Opnd (Res,
168 Unchecked_Convert_To (T3, Relocate_Node (Left_Opnd (N))));
169 Set_Right_Opnd (Res,
170 Unchecked_Convert_To (T3, Relocate_Node (Right_Opnd (N))));
171
172 -- Analyze and resolve result formed by conversion to target type
173
174 Rewrite (N, Unchecked_Convert_To (TR, Res));
175 Analyze_And_Resolve (N, TR);
176 end Expand_Binary_Operator_Call;
177
178 -----------------------------------------
179 -- Expand_Dispatching_Constructor_Call --
180 -----------------------------------------
181
182 -- Transform a call to an instantiation of Generic_Dispatching_Constructor
183 -- of the form:
184
185 -- GDC_Instance (The_Tag, Parameters'Access)
186
187 -- to a class-wide conversion of a dispatching call to the actual
188 -- associated with the formal subprogram Construct, designating The_Tag
189 -- as the controlling tag of the call:
190
191 -- T'Class (Construct'Actual (Params)) -- Controlling tag is The_Tag
192
193 -- which will eventually be expanded to the following:
194
195 -- T'Class (The_Tag.all (Construct'Actual'Index).all (Params))
196
197 -- A class-wide membership test is also generated, preceding the call, to
198 -- ensure that the controlling tag denotes a type in T'Class.
199
200 procedure Expand_Dispatching_Constructor_Call (N : Node_Id) is
201 Loc : constant Source_Ptr := Sloc (N);
202 Tag_Arg : constant Node_Id := First_Actual (N);
203 Param_Arg : constant Node_Id := Next_Actual (Tag_Arg);
204 Subp_Decl : constant Node_Id := Parent (Parent (Entity (Name (N))));
205 Inst_Pkg : constant Node_Id := Parent (Subp_Decl);
206 Act_Rename : Node_Id;
207 Act_Constr : Entity_Id;
208 Iface_Tag : Node_Id := Empty;
209 Cnstr_Call : Node_Id;
210 Result_Typ : Entity_Id;
211
212 begin
213 -- Remove side effects from tag argument early, before rewriting
214 -- the dispatching constructor call, as Remove_Side_Effects relies
215 -- on Tag_Arg's Parent link properly attached to the tree (once the
216 -- call is rewritten, the Parent is inconsistent as it points to the
217 -- rewritten node, which is not the syntactic parent of the Tag_Arg
218 -- anymore).
219
220 Remove_Side_Effects (Tag_Arg);
221
222 -- The subprogram is the third actual in the instantiation, and is
223 -- retrieved from the corresponding renaming declaration. However,
224 -- freeze nodes may appear before, so we retrieve the declaration
225 -- with an explicit loop.
226
227 Act_Rename := First (Visible_Declarations (Inst_Pkg));
228 while Nkind (Act_Rename) /= N_Subprogram_Renaming_Declaration loop
229 Next (Act_Rename);
230 end loop;
231
232 Act_Constr := Entity (Name (Act_Rename));
233 Result_Typ := Class_Wide_Type (Etype (Act_Constr));
234
235 if Is_Interface (Etype (Act_Constr)) then
236
237 -- If the result type is not known to be a parent of Tag_Arg then we
238 -- need to locate the tag of the secondary dispatch table.
239
240 if not Is_Ancestor (Etype (Result_Typ), Etype (Tag_Arg),
241 Use_Full_View => True)
242 and then Tagged_Type_Expansion
243 then
244 -- Obtain the reference to the Ada.Tags service before generating
245 -- the Object_Declaration node to ensure that if this service is
246 -- not available in the runtime then we generate a clear error.
247
248 declare
249 Fname : constant Node_Id :=
250 New_Reference_To (RTE (RE_Secondary_Tag), Loc);
251
252 begin
253 pragma Assert (not Is_Interface (Etype (Tag_Arg)));
254
255 Iface_Tag :=
256 Make_Object_Declaration (Loc,
257 Defining_Identifier => Make_Temporary (Loc, 'V'),
258 Object_Definition =>
259 New_Reference_To (RTE (RE_Tag), Loc),
260 Expression =>
261 Make_Function_Call (Loc,
262 Name => Fname,
263 Parameter_Associations => New_List (
264 Relocate_Node (Tag_Arg),
265 New_Reference_To
266 (Node (First_Elmt (Access_Disp_Table
267 (Etype (Etype (Act_Constr))))),
268 Loc))));
269 Insert_Action (N, Iface_Tag);
270 end;
271 end if;
272 end if;
273
274 -- Create the call to the actual Constructor function
275
276 Cnstr_Call :=
277 Make_Function_Call (Loc,
278 Name => New_Occurrence_Of (Act_Constr, Loc),
279 Parameter_Associations => New_List (Relocate_Node (Param_Arg)));
280
281 -- Establish its controlling tag from the tag passed to the instance
282 -- The tag may be given by a function call, in which case a temporary
283 -- should be generated now, to prevent out-of-order insertions during
284 -- the expansion of that call when stack-checking is enabled.
285
286 if Present (Iface_Tag) then
287 Set_Controlling_Argument (Cnstr_Call,
288 New_Occurrence_Of (Defining_Identifier (Iface_Tag), Loc));
289 else
290 Set_Controlling_Argument (Cnstr_Call,
291 Relocate_Node (Tag_Arg));
292 end if;
293
294 -- Rewrite and analyze the call to the instance as a class-wide
295 -- conversion of the call to the actual constructor.
296
297 Rewrite (N, Convert_To (Result_Typ, Cnstr_Call));
298 Analyze_And_Resolve (N, Etype (Act_Constr));
299
300 -- Do not generate a run-time check on the built object if tag
301 -- checks are suppressed for the result type or VM_Target /= No_VM
302
303 if Tag_Checks_Suppressed (Etype (Result_Typ))
304 or else not Tagged_Type_Expansion
305 then
306 null;
307
308 -- Generate a class-wide membership test to ensure that the call's tag
309 -- argument denotes a type within the class. We must keep separate the
310 -- case in which the Result_Type of the constructor function is a tagged
311 -- type from the case in which it is an abstract interface because the
312 -- run-time subprogram required to check these cases differ (and have
313 -- one difference in their parameters profile).
314
315 -- Call CW_Membership if the Result_Type is a tagged type to look for
316 -- the tag in the table of ancestor tags.
317
318 elsif not Is_Interface (Result_Typ) then
319 declare
320 Obj_Tag_Node : Node_Id := New_Copy_Tree (Tag_Arg);
321 CW_Test_Node : Node_Id;
322
323 begin
324 Build_CW_Membership (Loc,
325 Obj_Tag_Node => Obj_Tag_Node,
326 Typ_Tag_Node =>
327 New_Reference_To (
328 Node (First_Elmt (Access_Disp_Table (
329 Root_Type (Result_Typ)))), Loc),
330 Related_Nod => N,
331 New_Node => CW_Test_Node);
332
333 Insert_Action (N,
334 Make_Implicit_If_Statement (N,
335 Condition =>
336 Make_Op_Not (Loc, CW_Test_Node),
337 Then_Statements =>
338 New_List (Make_Raise_Statement (Loc,
339 New_Occurrence_Of (RTE (RE_Tag_Error), Loc)))));
340 end;
341
342 -- Call IW_Membership test if the Result_Type is an abstract interface
343 -- to look for the tag in the table of interface tags.
344
345 else
346 Insert_Action (N,
347 Make_Implicit_If_Statement (N,
348 Condition =>
349 Make_Op_Not (Loc,
350 Make_Function_Call (Loc,
351 Name => New_Occurrence_Of (RTE (RE_IW_Membership), Loc),
352 Parameter_Associations => New_List (
353 Make_Attribute_Reference (Loc,
354 Prefix => New_Copy_Tree (Tag_Arg),
355 Attribute_Name => Name_Address),
356
357 New_Reference_To (
358 Node (First_Elmt (Access_Disp_Table (
359 Root_Type (Result_Typ)))), Loc)))),
360 Then_Statements =>
361 New_List (
362 Make_Raise_Statement (Loc,
363 Name => New_Occurrence_Of (RTE (RE_Tag_Error), Loc)))));
364 end if;
365 end Expand_Dispatching_Constructor_Call;
366
367 ---------------------------
368 -- Expand_Exception_Call --
369 ---------------------------
370
371 -- If the function call is not within an exception handler, then the call
372 -- is replaced by a null string. Otherwise the appropriate routine in
373 -- Ada.Exceptions is called passing the choice parameter specification
374 -- from the enclosing handler. If the enclosing handler lacks a choice
375 -- parameter, then one is supplied.
376
377 procedure Expand_Exception_Call (N : Node_Id; Ent : RE_Id) is
378 Loc : constant Source_Ptr := Sloc (N);
379 P : Node_Id;
380 E : Entity_Id;
381
382 begin
383 -- Climb up parents to see if we are in exception handler
384
385 P := Parent (N);
386 loop
387 -- Case of not in exception handler, replace by null string
388
389 if No (P) then
390 Rewrite (N,
391 Make_String_Literal (Loc,
392 Strval => ""));
393 exit;
394
395 -- Case of in exception handler
396
397 elsif Nkind (P) = N_Exception_Handler then
398
399 -- Handler cannot be used for a local raise, and furthermore, this
400 -- is a violation of the No_Exception_Propagation restriction.
401
402 Set_Local_Raise_Not_OK (P);
403 Check_Restriction (No_Exception_Propagation, N);
404
405 -- If no choice parameter present, then put one there. Note that
406 -- we do not need to put it on the entity chain, since no one will
407 -- be referencing it by normal visibility methods.
408
409 if No (Choice_Parameter (P)) then
410 E := Make_Temporary (Loc, 'E');
411 Set_Choice_Parameter (P, E);
412 Set_Ekind (E, E_Variable);
413 Set_Etype (E, RTE (RE_Exception_Occurrence));
414 Set_Scope (E, Current_Scope);
415 end if;
416
417 Rewrite (N,
418 Make_Function_Call (Loc,
419 Name => New_Occurrence_Of (RTE (Ent), Loc),
420 Parameter_Associations => New_List (
421 New_Occurrence_Of (Choice_Parameter (P), Loc))));
422 exit;
423
424 -- Keep climbing!
425
426 else
427 P := Parent (P);
428 end if;
429 end loop;
430
431 Analyze_And_Resolve (N, Standard_String);
432 end Expand_Exception_Call;
433
434 ------------------------
435 -- Expand_Import_Call --
436 ------------------------
437
438 -- The function call must have a static string as its argument. We create
439 -- a dummy variable which uses this string as the external name in an
440 -- Import pragma. The result is then obtained as the address of this
441 -- dummy variable, converted to the appropriate target type.
442
443 procedure Expand_Import_Call (N : Node_Id) is
444 Loc : constant Source_Ptr := Sloc (N);
445 Ent : constant Entity_Id := Entity (Name (N));
446 Str : constant Node_Id := First_Actual (N);
447 Dum : constant Entity_Id := Make_Temporary (Loc, 'D');
448
449 begin
450 Insert_Actions (N, New_List (
451 Make_Object_Declaration (Loc,
452 Defining_Identifier => Dum,
453 Object_Definition =>
454 New_Occurrence_Of (Standard_Character, Loc)),
455
456 Make_Pragma (Loc,
457 Chars => Name_Import,
458 Pragma_Argument_Associations => New_List (
459 Make_Pragma_Argument_Association (Loc,
460 Expression => Make_Identifier (Loc, Name_Ada)),
461
462 Make_Pragma_Argument_Association (Loc,
463 Expression => Make_Identifier (Loc, Chars (Dum))),
464
465 Make_Pragma_Argument_Association (Loc,
466 Chars => Name_Link_Name,
467 Expression => Relocate_Node (Str))))));
468
469 Rewrite (N,
470 Unchecked_Convert_To (Etype (Ent),
471 Make_Attribute_Reference (Loc,
472 Prefix => Make_Identifier (Loc, Chars (Dum)),
473 Attribute_Name => Name_Address)));
474
475 Analyze_And_Resolve (N, Etype (Ent));
476 end Expand_Import_Call;
477
478 ---------------------------
479 -- Expand_Intrinsic_Call --
480 ---------------------------
481
482 procedure Expand_Intrinsic_Call (N : Node_Id; E : Entity_Id) is
483 Nam : Name_Id;
484
485 begin
486 -- If an external name is specified for the intrinsic, it is handled
487 -- by the back-end: leave the call node unchanged for now.
488
489 if Present (Interface_Name (E)) then
490 return;
491 end if;
492
493 -- If the intrinsic subprogram is generic, gets its original name
494
495 if Present (Parent (E))
496 and then Present (Generic_Parent (Parent (E)))
497 then
498 Nam := Chars (Generic_Parent (Parent (E)));
499 else
500 Nam := Chars (E);
501 end if;
502
503 if Nam = Name_Asm then
504 Expand_Asm_Call (N);
505
506 elsif Nam = Name_Divide then
507 Expand_Decimal_Divide_Call (N);
508
509 elsif Nam = Name_Exception_Information then
510 Expand_Exception_Call (N, RE_Exception_Information);
511
512 elsif Nam = Name_Exception_Message then
513 Expand_Exception_Call (N, RE_Exception_Message);
514
515 elsif Nam = Name_Exception_Name then
516 Expand_Exception_Call (N, RE_Exception_Name_Simple);
517
518 elsif Nam = Name_Generic_Dispatching_Constructor then
519 Expand_Dispatching_Constructor_Call (N);
520
521 elsif Nam_In (Nam, Name_Import_Address,
522 Name_Import_Largest_Value,
523 Name_Import_Value)
524 then
525 Expand_Import_Call (N);
526
527 elsif Nam = Name_Is_Negative then
528 Expand_Is_Negative (N);
529
530 elsif Nam = Name_Rotate_Left then
531 Expand_Shift (N, E, N_Op_Rotate_Left);
532
533 elsif Nam = Name_Rotate_Right then
534 Expand_Shift (N, E, N_Op_Rotate_Right);
535
536 elsif Nam = Name_Shift_Left then
537 Expand_Shift (N, E, N_Op_Shift_Left);
538
539 elsif Nam = Name_Shift_Right then
540 Expand_Shift (N, E, N_Op_Shift_Right);
541
542 elsif Nam = Name_Shift_Right_Arithmetic then
543 Expand_Shift (N, E, N_Op_Shift_Right_Arithmetic);
544
545 elsif Nam = Name_Unchecked_Conversion then
546 Expand_Unc_Conversion (N, E);
547
548 elsif Nam = Name_Unchecked_Deallocation then
549 Expand_Unc_Deallocation (N);
550
551 elsif Nam = Name_To_Address then
552 Expand_To_Address (N);
553
554 elsif Nam = Name_To_Pointer then
555 Expand_To_Pointer (N);
556
557 elsif Nam_In (Nam, Name_File,
558 Name_Line,
559 Name_Source_Location,
560 Name_Enclosing_Entity)
561 then
562 Expand_Source_Info (N, Nam);
563
564 -- If we have a renaming, expand the call to the original operation,
565 -- which must itself be intrinsic, since renaming requires matching
566 -- conventions and this has already been checked.
567
568 elsif Present (Alias (E)) then
569 Expand_Intrinsic_Call (N, Alias (E));
570
571 elsif Nkind (N) in N_Binary_Op then
572 Expand_Binary_Operator_Call (N);
573
574 -- The only other case is where an external name was specified, since
575 -- this is the only way that an otherwise unrecognized name could
576 -- escape the checking in Sem_Prag. Nothing needs to be done in such
577 -- a case, since we pass such a call to the back end unchanged.
578
579 else
580 null;
581 end if;
582 end Expand_Intrinsic_Call;
583
584 ------------------------
585 -- Expand_Is_Negative --
586 ------------------------
587
588 procedure Expand_Is_Negative (N : Node_Id) is
589 Loc : constant Source_Ptr := Sloc (N);
590 Opnd : constant Node_Id := Relocate_Node (First_Actual (N));
591
592 begin
593
594 -- We replace the function call by the following expression
595
596 -- if Opnd < 0.0 then
597 -- True
598 -- else
599 -- if Opnd > 0.0 then
600 -- False;
601 -- else
602 -- Float_Unsigned!(Float (Opnd)) /= 0
603 -- end if;
604 -- end if;
605
606 Rewrite (N,
607 Make_If_Expression (Loc,
608 Expressions => New_List (
609 Make_Op_Lt (Loc,
610 Left_Opnd => Duplicate_Subexpr (Opnd),
611 Right_Opnd => Make_Real_Literal (Loc, Ureal_0)),
612
613 New_Occurrence_Of (Standard_True, Loc),
614
615 Make_If_Expression (Loc,
616 Expressions => New_List (
617 Make_Op_Gt (Loc,
618 Left_Opnd => Duplicate_Subexpr_No_Checks (Opnd),
619 Right_Opnd => Make_Real_Literal (Loc, Ureal_0)),
620
621 New_Occurrence_Of (Standard_False, Loc),
622
623 Make_Op_Ne (Loc,
624 Left_Opnd =>
625 Unchecked_Convert_To
626 (RTE (RE_Float_Unsigned),
627 Convert_To
628 (Standard_Float,
629 Duplicate_Subexpr_No_Checks (Opnd))),
630 Right_Opnd =>
631 Make_Integer_Literal (Loc, 0)))))));
632
633 Analyze_And_Resolve (N, Standard_Boolean);
634 end Expand_Is_Negative;
635
636 ------------------
637 -- Expand_Shift --
638 ------------------
639
640 -- This procedure is used to convert a call to a shift function to the
641 -- corresponding operator node. This conversion is not done by the usual
642 -- circuit for converting calls to operator functions (e.g. "+"(1,2)) to
643 -- operator nodes, because shifts are not predefined operators.
644
645 -- As a result, whenever a shift is used in the source program, it will
646 -- remain as a call until converted by this routine to the operator node
647 -- form which Gigi is expecting to see.
648
649 -- Note: it is possible for the expander to generate shift operator nodes
650 -- directly, which will be analyzed in the normal manner by calling Analyze
651 -- and Resolve. Such shift operator nodes will not be seen by Expand_Shift.
652
653 procedure Expand_Shift (N : Node_Id; E : Entity_Id; K : Node_Kind) is
654 Entyp : constant Entity_Id := Etype (E);
655 Left : constant Node_Id := First_Actual (N);
656 Loc : constant Source_Ptr := Sloc (N);
657 Right : constant Node_Id := Next_Actual (Left);
658 Ltyp : constant Node_Id := Etype (Left);
659 Rtyp : constant Node_Id := Etype (Right);
660 Typ : constant Entity_Id := Etype (N);
661 Snode : Node_Id;
662
663 begin
664 Snode := New_Node (K, Loc);
665 Set_Right_Opnd (Snode, Relocate_Node (Right));
666 Set_Chars (Snode, Chars (E));
667 Set_Etype (Snode, Base_Type (Entyp));
668 Set_Entity (Snode, E);
669
670 if Compile_Time_Known_Value (Type_High_Bound (Rtyp))
671 and then Expr_Value (Type_High_Bound (Rtyp)) < Esize (Ltyp)
672 then
673 Set_Shift_Count_OK (Snode, True);
674 end if;
675
676 if Typ = Entyp then
677
678 -- Note that we don't call Analyze and Resolve on this node, because
679 -- it already got analyzed and resolved when it was a function call.
680
681 Set_Left_Opnd (Snode, Relocate_Node (Left));
682 Rewrite (N, Snode);
683 Set_Analyzed (N);
684
685 else
686
687 -- If the context type is not the type of the operator, it is an
688 -- inherited operator for a derived type. Wrap the node in a
689 -- conversion so that it is type-consistent for possible further
690 -- expansion (e.g. within a lock-free protected type).
691
692 Set_Left_Opnd (Snode,
693 Unchecked_Convert_To (Base_Type (Entyp), Relocate_Node (Left)));
694 Rewrite (N, Unchecked_Convert_To (Typ, Snode));
695
696 -- Analyze and resolve result formed by conversion to target type
697
698 Analyze_And_Resolve (N, Typ);
699 end if;
700 end Expand_Shift;
701
702 ------------------------
703 -- Expand_Source_Info --
704 ------------------------
705
706 procedure Expand_Source_Info (N : Node_Id; Nam : Name_Id) is
707 Loc : constant Source_Ptr := Sloc (N);
708 Ent : Entity_Id;
709
710 procedure Write_Entity_Name (E : Entity_Id);
711 -- Recursive procedure to construct string for qualified name of
712 -- enclosing program unit. The qualification stops at an enclosing
713 -- scope has no source name (block or loop). If entity is a subprogram
714 -- instance, skip enclosing wrapper package.
715
716 -----------------------
717 -- Write_Entity_Name --
718 -----------------------
719
720 procedure Write_Entity_Name (E : Entity_Id) is
721 SDef : Source_Ptr;
722 TDef : constant Source_Buffer_Ptr :=
723 Source_Text (Get_Source_File_Index (Sloc (E)));
724
725 begin
726 -- Nothing to do if at outer level
727
728 if Scope (E) = Standard_Standard then
729 null;
730
731 -- If scope comes from source, write its name
732
733 elsif Comes_From_Source (Scope (E)) then
734 Write_Entity_Name (Scope (E));
735 Add_Char_To_Name_Buffer ('.');
736
737 -- If in wrapper package skip past it
738
739 elsif Is_Wrapper_Package (Scope (E)) then
740 Write_Entity_Name (Scope (Scope (E)));
741 Add_Char_To_Name_Buffer ('.');
742
743 -- Otherwise nothing to output (happens in unnamed block statements)
744
745 else
746 null;
747 end if;
748
749 -- Loop to output the name
750
751 -- is this right wrt wide char encodings ??? (no!)
752
753 SDef := Sloc (E);
754 while TDef (SDef) in '0' .. '9'
755 or else TDef (SDef) >= 'A'
756 or else TDef (SDef) = ASCII.ESC
757 loop
758 Add_Char_To_Name_Buffer (TDef (SDef));
759 SDef := SDef + 1;
760 end loop;
761 end Write_Entity_Name;
762
763 -- Start of processing for Expand_Source_Info
764
765 begin
766 -- Integer cases
767
768 if Nam = Name_Line then
769 Rewrite (N,
770 Make_Integer_Literal (Loc,
771 Intval => UI_From_Int (Int (Get_Logical_Line_Number (Loc)))));
772 Analyze_And_Resolve (N, Standard_Positive);
773
774 -- String cases
775
776 else
777 Name_Len := 0;
778
779 case Nam is
780 when Name_File =>
781 Get_Decoded_Name_String
782 (Reference_Name (Get_Source_File_Index (Loc)));
783
784 when Name_Source_Location =>
785 Build_Location_String (Loc);
786
787 when Name_Enclosing_Entity =>
788
789 -- Skip enclosing blocks to reach enclosing unit
790
791 Ent := Current_Scope;
792 while Present (Ent) loop
793 exit when Ekind (Ent) /= E_Block
794 and then Ekind (Ent) /= E_Loop;
795 Ent := Scope (Ent);
796 end loop;
797
798 -- Ent now points to the relevant defining entity
799
800 Write_Entity_Name (Ent);
801
802 when others =>
803 raise Program_Error;
804 end case;
805
806 Rewrite (N,
807 Make_String_Literal (Loc,
808 Strval => String_From_Name_Buffer));
809 Analyze_And_Resolve (N, Standard_String);
810 end if;
811
812 Set_Is_Static_Expression (N);
813 end Expand_Source_Info;
814
815 ---------------------------
816 -- Expand_Unc_Conversion --
817 ---------------------------
818
819 procedure Expand_Unc_Conversion (N : Node_Id; E : Entity_Id) is
820 Func : constant Entity_Id := Entity (Name (N));
821 Conv : Node_Id;
822 Ftyp : Entity_Id;
823 Ttyp : Entity_Id;
824
825 begin
826 -- Rewrite as unchecked conversion node. Note that we must convert
827 -- the operand to the formal type of the input parameter of the
828 -- function, so that the resulting N_Unchecked_Type_Conversion
829 -- call indicates the correct types for Gigi.
830
831 -- Right now, we only do this if a scalar type is involved. It is
832 -- not clear if it is needed in other cases. If we do attempt to
833 -- do the conversion unconditionally, it crashes 3411-018. To be
834 -- investigated further ???
835
836 Conv := Relocate_Node (First_Actual (N));
837 Ftyp := Etype (First_Formal (Func));
838
839 if Is_Scalar_Type (Ftyp) then
840 Conv := Convert_To (Ftyp, Conv);
841 Set_Parent (Conv, N);
842 Analyze_And_Resolve (Conv);
843 end if;
844
845 -- The instantiation of Unchecked_Conversion creates a wrapper package,
846 -- and the target type is declared as a subtype of the actual. Recover
847 -- the actual, which is the subtype indic. in the subtype declaration
848 -- for the target type. This is semantically correct, and avoids
849 -- anomalies with access subtypes. For entities, leave type as is.
850
851 -- We do the analysis here, because we do not want the compiler
852 -- to try to optimize or otherwise reorganize the unchecked
853 -- conversion node.
854
855 Ttyp := Etype (E);
856
857 if Is_Entity_Name (Conv) then
858 null;
859
860 elsif Nkind (Parent (Ttyp)) = N_Subtype_Declaration then
861 Ttyp := Entity (Subtype_Indication (Parent (Etype (E))));
862
863 elsif Is_Itype (Ttyp) then
864 Ttyp :=
865 Entity (Subtype_Indication (Associated_Node_For_Itype (Ttyp)));
866 else
867 raise Program_Error;
868 end if;
869
870 Rewrite (N, Unchecked_Convert_To (Ttyp, Conv));
871 Set_Etype (N, Ttyp);
872 Set_Analyzed (N);
873
874 if Nkind (N) = N_Unchecked_Type_Conversion then
875 Expand_N_Unchecked_Type_Conversion (N);
876 end if;
877 end Expand_Unc_Conversion;
878
879 -----------------------------
880 -- Expand_Unc_Deallocation --
881 -----------------------------
882
883 -- Generate the following Code :
884
885 -- if Arg /= null then
886 -- <Finalize_Call> (.., T'Class(Arg.all), ..); -- for controlled types
887 -- Free (Arg);
888 -- Arg := Null;
889 -- end if;
890
891 -- For a task, we also generate a call to Free_Task to ensure that the
892 -- task itself is freed if it is terminated, ditto for a simple protected
893 -- object, with a call to Finalize_Protection. For composite types that
894 -- have tasks or simple protected objects as components, we traverse the
895 -- structures to find and terminate those components.
896
897 procedure Expand_Unc_Deallocation (N : Node_Id) is
898 Arg : constant Node_Id := First_Actual (N);
899 Loc : constant Source_Ptr := Sloc (N);
900 Typ : constant Entity_Id := Etype (Arg);
901 Desig_T : constant Entity_Id := Designated_Type (Typ);
902 Rtyp : constant Entity_Id := Underlying_Type (Root_Type (Typ));
903 Pool : constant Entity_Id := Associated_Storage_Pool (Rtyp);
904 Stmts : constant List_Id := New_List;
905 Needs_Fin : constant Boolean := Needs_Finalization (Desig_T);
906
907 Finalizer_Data : Finalization_Exception_Data;
908
909 Blk : Node_Id := Empty;
910 Deref : Node_Id;
911 Final_Code : List_Id;
912 Free_Arg : Node_Id;
913 Free_Node : Node_Id;
914 Gen_Code : Node_Id;
915
916 Arg_Known_Non_Null : constant Boolean := Known_Non_Null (N);
917 -- This captures whether we know the argument to be non-null so that
918 -- we can avoid the test. The reason that we need to capture this is
919 -- that we analyze some generated statements before properly attaching
920 -- them to the tree, and that can disturb current value settings.
921
922 begin
923 -- Nothing to do if we know the argument is null
924
925 if Known_Null (N) then
926 return;
927 end if;
928
929 -- Processing for pointer to controlled type
930
931 if Needs_Fin then
932 Deref :=
933 Make_Explicit_Dereference (Loc,
934 Prefix => Duplicate_Subexpr_No_Checks (Arg));
935
936 -- If the type is tagged, then we must force dispatching on the
937 -- finalization call because the designated type may not be the
938 -- actual type of the object.
939
940 if Is_Tagged_Type (Desig_T)
941 and then not Is_Class_Wide_Type (Desig_T)
942 then
943 Deref := Unchecked_Convert_To (Class_Wide_Type (Desig_T), Deref);
944
945 elsif not Is_Tagged_Type (Desig_T) then
946
947 -- Set type of result, to force a conversion when needed (see
948 -- exp_ch7, Convert_View), given that Deep_Finalize may be
949 -- inherited from the parent type, and we need the type of the
950 -- expression to see whether the conversion is in fact needed.
951
952 Set_Etype (Deref, Desig_T);
953 end if;
954
955 -- The finalization call is expanded wrapped in a block to catch any
956 -- possible exception. If an exception does occur, then Program_Error
957 -- must be raised following the freeing of the object and its removal
958 -- from the finalization collection's list. We set a flag to record
959 -- that an exception was raised, and save its occurrence for use in
960 -- the later raise.
961 --
962 -- Generate:
963 -- Abort : constant Boolean :=
964 -- Exception_Occurrence (Get_Current_Excep.all.all) =
965 -- Standard'Abort_Signal'Identity;
966 -- <or>
967 -- Abort : constant Boolean := False; -- no abort
968
969 -- E : Exception_Occurrence;
970 -- Raised : Boolean := False;
971 --
972 -- begin
973 -- [Deep_]Finalize (Obj);
974 -- exception
975 -- when others =>
976 -- Raised := True;
977 -- Save_Occurrence (E, Get_Current_Excep.all.all);
978 -- end;
979
980 Build_Object_Declarations (Finalizer_Data, Stmts, Loc);
981
982 Final_Code := New_List (
983 Make_Block_Statement (Loc,
984 Handled_Statement_Sequence =>
985 Make_Handled_Sequence_Of_Statements (Loc,
986 Statements => New_List (
987 Make_Final_Call (Obj_Ref => Deref, Typ => Desig_T)),
988 Exception_Handlers => New_List (
989 Build_Exception_Handler (Finalizer_Data)))));
990
991 -- For .NET/JVM, detach the object from the containing finalization
992 -- collection before finalizing it.
993
994 if VM_Target /= No_VM and then Is_Controlled (Desig_T) then
995 Prepend_To (Final_Code,
996 Make_Detach_Call (New_Copy_Tree (Arg)));
997 end if;
998
999 -- If aborts are allowed, then the finalization code must be
1000 -- protected by an abort defer/undefer pair.
1001
1002 if Abort_Allowed then
1003 Prepend_To (Final_Code,
1004 Build_Runtime_Call (Loc, RE_Abort_Defer));
1005
1006 Blk :=
1007 Make_Block_Statement (Loc, Handled_Statement_Sequence =>
1008 Make_Handled_Sequence_Of_Statements (Loc,
1009 Statements => Final_Code,
1010 At_End_Proc =>
1011 New_Occurrence_Of (RTE (RE_Abort_Undefer_Direct), Loc)));
1012
1013 Append (Blk, Stmts);
1014 else
1015 Append_List_To (Stmts, Final_Code);
1016 end if;
1017 end if;
1018
1019 -- For a task type, call Free_Task before freeing the ATCB
1020
1021 if Is_Task_Type (Desig_T) then
1022 declare
1023 Stat : Node_Id := Prev (N);
1024 Nam1 : Node_Id;
1025 Nam2 : Node_Id;
1026
1027 begin
1028 -- An Abort followed by a Free will not do what the user expects,
1029 -- because the abort is not immediate. This is worth a warning.
1030
1031 while Present (Stat)
1032 and then not Comes_From_Source (Original_Node (Stat))
1033 loop
1034 Prev (Stat);
1035 end loop;
1036
1037 if Present (Stat)
1038 and then Nkind (Original_Node (Stat)) = N_Abort_Statement
1039 then
1040 Stat := Original_Node (Stat);
1041 Nam1 := First (Names (Stat));
1042 Nam2 := Original_Node (First (Parameter_Associations (N)));
1043
1044 if Nkind (Nam1) = N_Explicit_Dereference
1045 and then Is_Entity_Name (Prefix (Nam1))
1046 and then Is_Entity_Name (Nam2)
1047 and then Entity (Prefix (Nam1)) = Entity (Nam2)
1048 then
1049 Error_Msg_N ("abort may take time to complete??", N);
1050 Error_Msg_N ("\deallocation might have no effect??", N);
1051 Error_Msg_N ("\safer to wait for termination??", N);
1052 end if;
1053 end if;
1054 end;
1055
1056 Append_To
1057 (Stmts, Cleanup_Task (N, Duplicate_Subexpr_No_Checks (Arg)));
1058
1059 -- For composite types that contain tasks, recurse over the structure
1060 -- to build the selectors for the task subcomponents.
1061
1062 elsif Has_Task (Desig_T) then
1063 if Is_Record_Type (Desig_T) then
1064 Append_List_To (Stmts, Cleanup_Record (N, Arg, Desig_T));
1065
1066 elsif Is_Array_Type (Desig_T) then
1067 Append_List_To (Stmts, Cleanup_Array (N, Arg, Desig_T));
1068 end if;
1069 end if;
1070
1071 -- Same for simple protected types. Eventually call Finalize_Protection
1072 -- before freeing the PO for each protected component.
1073
1074 if Is_Simple_Protected_Type (Desig_T) then
1075 Append_To (Stmts,
1076 Cleanup_Protected_Object (N, Duplicate_Subexpr_No_Checks (Arg)));
1077
1078 elsif Has_Simple_Protected_Object (Desig_T) then
1079 if Is_Record_Type (Desig_T) then
1080 Append_List_To (Stmts, Cleanup_Record (N, Arg, Desig_T));
1081 elsif Is_Array_Type (Desig_T) then
1082 Append_List_To (Stmts, Cleanup_Array (N, Arg, Desig_T));
1083 end if;
1084 end if;
1085
1086 -- Normal processing for non-controlled types
1087
1088 Free_Arg := Duplicate_Subexpr_No_Checks (Arg);
1089 Free_Node := Make_Free_Statement (Loc, Empty);
1090 Append_To (Stmts, Free_Node);
1091 Set_Storage_Pool (Free_Node, Pool);
1092
1093 -- Attach to tree before analysis of generated subtypes below
1094
1095 Set_Parent (Stmts, Parent (N));
1096
1097 -- Deal with storage pool
1098
1099 if Present (Pool) then
1100
1101 -- Freeing the secondary stack is meaningless
1102
1103 if Is_RTE (Pool, RE_SS_Pool) then
1104 null;
1105
1106 -- If the pool object is of a simple storage pool type, then attempt
1107 -- to locate the type's Deallocate procedure, if any, and set the
1108 -- free operation's procedure to call. If the type doesn't have a
1109 -- Deallocate (which is allowed), then the actual will simply be set
1110 -- to null.
1111
1112 elsif Present (Get_Rep_Pragma
1113 (Etype (Pool), Name_Simple_Storage_Pool_Type))
1114 then
1115 declare
1116 Pool_Type : constant Entity_Id := Base_Type (Etype (Pool));
1117 Dealloc_Op : Entity_Id;
1118 begin
1119 Dealloc_Op := Get_Name_Entity_Id (Name_Deallocate);
1120 while Present (Dealloc_Op) loop
1121 if Scope (Dealloc_Op) = Scope (Pool_Type)
1122 and then Present (First_Formal (Dealloc_Op))
1123 and then Etype (First_Formal (Dealloc_Op)) = Pool_Type
1124 then
1125 Set_Procedure_To_Call (Free_Node, Dealloc_Op);
1126 exit;
1127 else
1128 Dealloc_Op := Homonym (Dealloc_Op);
1129 end if;
1130 end loop;
1131 end;
1132
1133 -- Case of a class-wide pool type: make a dispatching call to
1134 -- Deallocate through the class-wide Deallocate_Any.
1135
1136 elsif Is_Class_Wide_Type (Etype (Pool)) then
1137 Set_Procedure_To_Call (Free_Node, RTE (RE_Deallocate_Any));
1138
1139 -- Case of a specific pool type: make a statically bound call
1140
1141 else
1142 Set_Procedure_To_Call (Free_Node,
1143 Find_Prim_Op (Etype (Pool), Name_Deallocate));
1144 end if;
1145 end if;
1146
1147 if Present (Procedure_To_Call (Free_Node)) then
1148
1149 -- For all cases of a Deallocate call, the back-end needs to be able
1150 -- to compute the size of the object being freed. This may require
1151 -- some adjustments for objects of dynamic size.
1152 --
1153 -- If the type is class wide, we generate an implicit type with the
1154 -- right dynamic size, so that the deallocate call gets the right
1155 -- size parameter computed by GIGI. Same for an access to
1156 -- unconstrained packed array.
1157
1158 if Is_Class_Wide_Type (Desig_T)
1159 or else
1160 (Is_Array_Type (Desig_T)
1161 and then not Is_Constrained (Desig_T)
1162 and then Is_Packed (Desig_T))
1163 then
1164 declare
1165 Deref : constant Node_Id :=
1166 Make_Explicit_Dereference (Loc,
1167 Duplicate_Subexpr_No_Checks (Arg));
1168 D_Subtyp : Node_Id;
1169 D_Type : Entity_Id;
1170
1171 begin
1172 -- Perform minor decoration as it is needed by the side effect
1173 -- removal mechanism.
1174
1175 Set_Etype (Deref, Desig_T);
1176 Set_Parent (Deref, Free_Node);
1177 D_Subtyp := Make_Subtype_From_Expr (Deref, Desig_T);
1178
1179 if Nkind (D_Subtyp) in N_Has_Entity then
1180 D_Type := Entity (D_Subtyp);
1181
1182 else
1183 D_Type := Make_Temporary (Loc, 'A');
1184 Insert_Action (Deref,
1185 Make_Subtype_Declaration (Loc,
1186 Defining_Identifier => D_Type,
1187 Subtype_Indication => D_Subtyp));
1188 end if;
1189
1190 -- Force freezing at the point of the dereference. For the
1191 -- class wide case, this avoids having the subtype frozen
1192 -- before the equivalent type.
1193
1194 Freeze_Itype (D_Type, Deref);
1195
1196 Set_Actual_Designated_Subtype (Free_Node, D_Type);
1197 end;
1198
1199 end if;
1200 end if;
1201
1202 -- Ada 2005 (AI-251): In case of abstract interface type we must
1203 -- displace the pointer to reference the base of the object to
1204 -- deallocate its memory, unless we're targetting a VM, in which case
1205 -- no special processing is required.
1206
1207 -- Generate:
1208 -- free (Base_Address (Obj_Ptr))
1209
1210 if Is_Interface (Directly_Designated_Type (Typ))
1211 and then Tagged_Type_Expansion
1212 then
1213 Set_Expression (Free_Node,
1214 Unchecked_Convert_To (Typ,
1215 Make_Function_Call (Loc,
1216 Name => New_Reference_To (RTE (RE_Base_Address), Loc),
1217 Parameter_Associations => New_List (
1218 Unchecked_Convert_To (RTE (RE_Address), Free_Arg)))));
1219
1220 -- Generate:
1221 -- free (Obj_Ptr)
1222
1223 else
1224 Set_Expression (Free_Node, Free_Arg);
1225 end if;
1226
1227 -- Only remaining step is to set result to null, or generate a raise of
1228 -- Constraint_Error if the target object is "not null".
1229
1230 if Can_Never_Be_Null (Etype (Arg)) then
1231 Append_To (Stmts,
1232 Make_Raise_Constraint_Error (Loc,
1233 Reason => CE_Access_Check_Failed));
1234
1235 else
1236 declare
1237 Lhs : constant Node_Id := Duplicate_Subexpr_No_Checks (Arg);
1238 begin
1239 Set_Assignment_OK (Lhs);
1240 Append_To (Stmts,
1241 Make_Assignment_Statement (Loc,
1242 Name => Lhs,
1243 Expression => Make_Null (Loc)));
1244 end;
1245 end if;
1246
1247 -- Generate a test of whether any earlier finalization raised an
1248 -- exception, and in that case raise Program_Error with the previous
1249 -- exception occurrence.
1250
1251 -- Generate:
1252 -- if Raised and then not Abort then
1253 -- raise Program_Error; -- for .NET and
1254 -- -- restricted RTS
1255 -- <or>
1256 -- Raise_From_Controlled_Operation (E); -- all other cases
1257 -- end if;
1258
1259 if Needs_Fin then
1260 Append_To (Stmts, Build_Raise_Statement (Finalizer_Data));
1261 end if;
1262
1263 -- If we know the argument is non-null, then make a block statement
1264 -- that contains the required statements, no need for a test.
1265
1266 if Arg_Known_Non_Null then
1267 Gen_Code :=
1268 Make_Block_Statement (Loc,
1269 Handled_Statement_Sequence =>
1270 Make_Handled_Sequence_Of_Statements (Loc,
1271 Statements => Stmts));
1272
1273 -- If the argument may be null, wrap the statements inside an IF that
1274 -- does an explicit test to exclude the null case.
1275
1276 else
1277 Gen_Code :=
1278 Make_Implicit_If_Statement (N,
1279 Condition =>
1280 Make_Op_Ne (Loc,
1281 Left_Opnd => Duplicate_Subexpr (Arg),
1282 Right_Opnd => Make_Null (Loc)),
1283 Then_Statements => Stmts);
1284 end if;
1285
1286 -- Rewrite the call
1287
1288 Rewrite (N, Gen_Code);
1289 Analyze (N);
1290
1291 -- If we generated a block with an At_End_Proc, expand the exception
1292 -- handler. We need to wait until after everything else is analyzed.
1293
1294 if Present (Blk) then
1295 Expand_At_End_Handler
1296 (Handled_Statement_Sequence (Blk), Entity (Identifier (Blk)));
1297 end if;
1298 end Expand_Unc_Deallocation;
1299
1300 -----------------------
1301 -- Expand_To_Address --
1302 -----------------------
1303
1304 procedure Expand_To_Address (N : Node_Id) is
1305 Loc : constant Source_Ptr := Sloc (N);
1306 Arg : constant Node_Id := First_Actual (N);
1307 Obj : Node_Id;
1308
1309 begin
1310 Remove_Side_Effects (Arg);
1311
1312 Obj := Make_Explicit_Dereference (Loc, Relocate_Node (Arg));
1313
1314 Rewrite (N,
1315 Make_If_Expression (Loc,
1316 Expressions => New_List (
1317 Make_Op_Eq (Loc,
1318 Left_Opnd => New_Copy_Tree (Arg),
1319 Right_Opnd => Make_Null (Loc)),
1320 New_Occurrence_Of (RTE (RE_Null_Address), Loc),
1321 Make_Attribute_Reference (Loc,
1322 Prefix => Obj,
1323 Attribute_Name => Name_Address))));
1324
1325 Analyze_And_Resolve (N, RTE (RE_Address));
1326 end Expand_To_Address;
1327
1328 -----------------------
1329 -- Expand_To_Pointer --
1330 -----------------------
1331
1332 procedure Expand_To_Pointer (N : Node_Id) is
1333 Arg : constant Node_Id := First_Actual (N);
1334
1335 begin
1336 Rewrite (N, Unchecked_Convert_To (Etype (N), Arg));
1337 Analyze (N);
1338 end Expand_To_Pointer;
1339
1340 end Exp_Intr;
Mirror of the offical gcc git repository hosted at gcc.gnu.org