libatomic/testsuite/lib/libatomic.exp

   1 # This program is free software; you can redistribute it and/or modify
   2 # it under the terms of the GNU General Public License as published by
   3 # the Free Software Foundation; either version 2 of the License, or
   4 # (at your option) any later version.
   5 #
   6 # This program is distributed in the hope that it will be useful,
   7 # but WITHOUT ANY WARRANTY; without even the implied warranty of
   8 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9 # GNU General Public License for more details.
  10 #
  11 # You should have received a copy of the GNU General Public License
  12 # along with this program; if not, write to the Free Software
  13 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  14
  15 # Damn dejagnu for not having proper library search paths for load_lib.
  16 # We have to explicitly load everything that gcc-dg.exp wants to load.
  17
  18 proc load_gcc_lib { filename } {
  19     global srcdir loaded_libs
  20
  21     load_file $srcdir/../../gcc/testsuite/lib/$filename
  22     set loaded_libs($filename) ""
  23 }
  24
  25 load_lib dg.exp
  26
  27 # Required to use gcc-dg.exp - however, the latter should NOT be
  28 # loaded until ${tool}_target_compile is defined since it uses that
  29 # to determine default LTO options.
  30
  31 load_gcc_lib file-format.exp
  32 load_gcc_lib target-supports.exp
  33 load_gcc_lib target-utils.exp
  34 load_gcc_lib target-supports-dg.exp
  35 load_gcc_lib scanasm.exp
  36 load_gcc_lib scandump.exp
  37 load_gcc_lib scanlang.exp
  38 load_gcc_lib scanrtl.exp
  39 load_gcc_lib scantree.exp
  40 load_gcc_lib scanltranstree.exp
  41 load_gcc_lib scanipa.exp
  42 load_gcc_lib scanwpaipa.exp
  43 load_gcc_lib multiline.exp
  44 load_gcc_lib prune.exp
  45 load_gcc_lib target-libpath.exp
  46 load_gcc_lib wrapper.exp
  47 load_gcc_lib gcc-defs.exp
  48 load_gcc_lib torture-options.exp
  49 load_gcc_lib timeout.exp
  50 load_gcc_lib timeout-dg.exp
  51 load_gcc_lib fortran-modules.exp
  52
  53 set dg-do-what-default run
  54
  55 #
  56 # GCC_UNDER_TEST is the compiler under test.
  57 #
  58
  59 set libatomic_compile_options ""
  60
  61 #
  62 # libatomic_init
  63 #
  64
  65 if [info exists TOOL_OPTIONS] {
  66     set multilibs [get_multilibs $TOOL_OPTIONS]
  67 } else {
  68     set multilibs [get_multilibs]
  69 }
  70
  71 proc libatomic_init { args } {
  72     global srcdir blddir objdir tool_root_dir
  73     global libatomic_initialized
  74     global tmpdir
  75     global blddir
  76     global gluefile wrap_flags
  77     global ALWAYS_CFLAGS
  78     global CFLAGS
  79     global TOOL_EXECUTABLE TOOL_OPTIONS
  80     global GCC_UNDER_TEST
  81     global TESTING_IN_BUILD_TREE
  82     global target_triplet
  83     global always_ld_library_path
  84
  85     set blddir [lookfor_file [get_multilibs] libatomic]
  86
  87     # We set LC_ALL and LANG to C so that we get the same error
  88     # messages as expected.
  89     setenv LC_ALL C
  90     setenv LANG C
  91
  92     if ![info exists GCC_UNDER_TEST] then {
  93         if [info exists TOOL_EXECUTABLE] {
  94             set GCC_UNDER_TEST $TOOL_EXECUTABLE
  95         } else {
  96             set GCC_UNDER_TEST "[find_gcc]"
  97         }
  98     }
  99
 100     if ![info exists tmpdir] {
 101         set tmpdir "/tmp"
 102     }
 103
 104     if [info exists gluefile] {
 105         unset gluefile
 106     }
 107
 108     if {![info exists CFLAGS]} {
 109         set CFLAGS ""
 110     }
 111
 112     # Locate libgcc.a so we don't need to account for different values of
 113     # SHLIB_EXT on different platforms
 114     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 115     if {$gccdir != ""} {
 116         set gccdir [file dirname $gccdir]
 117     }
 118
 119     # Compute what needs to be put into LD_LIBRARY_PATH
 120     set always_ld_library_path ".:${blddir}/.libs"
 121
 122     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 123     if {$gccdir != ""} {
 124         # Add AIX pthread directory first.
 125         if { [llength [glob -nocomplain ${gccdir}/pthread/libgcc_s*.a]] >= 1 } {
 126             append always_ld_library_path ":${gccdir}/pthread"
 127         }
 128         append always_ld_library_path ":${gccdir}"
 129         set compiler [lindex $GCC_UNDER_TEST 0]
 130
 131         if { [is_remote host] == 0 && [which $compiler] != 0 } {
 132           foreach i "[exec $compiler --print-multi-lib]" {
 133             set mldir ""
 134             regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
 135             set mldir [string trimright $mldir "\;@"]
 136             if { "$mldir" == "." } {
 137               continue
 138             }
 139             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 140               append always_ld_library_path ":${gccdir}/${mldir}"
 141             }
 142           }
 143         }
 144     }
 145
 146     set ALWAYS_CFLAGS ""
 147     if { $blddir != "" } {
 148         lappend ALWAYS_CFLAGS "additional_flags=-B${blddir}/"
 149         lappend ALWAYS_CFLAGS "additional_flags=-I${blddir}"
 150         lappend ALWAYS_CFLAGS "ldflags=-L${blddir}/.libs"
 151     }
 152     lappend ALWAYS_CFLAGS "additional_flags=-I${srcdir}/.."
 153
 154     if [istarget *-*-darwin*] {
 155         lappend ALWAYS_CFLAGS "additional_flags=-shared-libgcc"
 156     }
 157
 158     if [info exists TOOL_OPTIONS] {
 159         lappend ALWAYS_CFLAGS "additional_flags=$TOOL_OPTIONS"
 160     }
 161
 162     # Make sure that lines are not wrapped.  That can confuse the
 163     # error-message parsing machinery.
 164     lappend ALWAYS_CFLAGS "additional_flags=-fmessage-length=0"
 165
 166     # Turn off builtin support for atomics so that we test the library.
 167     lappend ALWAYS_CFLAGS "additional_flags=-fno-inline-atomics"
 168     lappend ALWAYS_CFLAGS "ldflags=-latomic"
 169 }
 170
 171 #
 172 # libatomic_target_compile -- compile a source file
 173 #
 174
 175 proc libatomic_target_compile { source dest type options } {
 176     global blddir
 177     global libatomic_compile_options
 178     global gluefile wrap_flags
 179     global ALWAYS_CFLAGS
 180     global GCC_UNDER_TEST
 181     global lang_test_file
 182     global lang_library_path
 183     global lang_link_flags
 184
 185     if { [info exists lang_test_file] } {
 186         if { $blddir != "" } {
 187             lappend options "ldflags=-L${blddir}/${lang_library_path}"
 188         }
 189         lappend options "ldflags=${lang_link_flags}"
 190     }
 191
 192     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 193         lappend options "libs=${gluefile}"
 194         lappend options "ldflags=${wrap_flags}"
 195     }
 196
 197     lappend options "additional_flags=[libio_include_flags]"
 198     lappend options "timeout=[timeout_value]"
 199     lappend options "compiler=$GCC_UNDER_TEST"
 200
 201     set options [concat $libatomic_compile_options $options]
 202
 203     if [info exists ALWAYS_CFLAGS] {
 204         set options [concat "$ALWAYS_CFLAGS" $options]
 205     }
 206
 207     set options [dg-additional-files-options $options $source]
 208
 209     set result [target_compile $source $dest $type $options]
 210
 211     return $result
 212 }
 213
 214 proc libatomic_option_help { } {
 215     send_user " --additional_options,OPTIONS\t\tUse OPTIONS to compile the testcase files. OPTIONS should be comma-separated.\n"
 216 }
 217
 218 proc libatomic_option_proc { option } {
 219     if [regexp "^--additional_options," $option] {
 220         global libatomic_compile_options
 221         regsub "--additional_options," $option "" option
 222         foreach x [split $option ","] {
 223             lappend libatomic_compile_options "additional_flags=$x"
 224         }
 225         return 1
 226     } else {
 227         return 0
 228     }
 229 }