libatomic/testsuite/lib/libatomic.exp

   1 # This program is free software; you can redistribute it and/or modify
   2 # it under the terms of the GNU General Public License as published by
   3 # the Free Software Foundation; either version 2 of the License, or
   4 # (at your option) any later version.
   5 #
   6 # This program is distributed in the hope that it will be useful,
   7 # but WITHOUT ANY WARRANTY; without even the implied warranty of
   8 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
   9 # GNU General Public License for more details.
  10 #
  11 # You should have received a copy of the GNU General Public License
  12 # along with this program; if not, write to the Free Software
  13 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  14
  15 # Damn dejagnu for not having proper library search paths for load_lib.
  16 # We have to explicitly load everything that gcc-dg.exp wants to load.
  17
  18 proc load_gcc_lib { filename } {
  19     global srcdir loaded_libs
  20
  21     load_file $srcdir/../../gcc/testsuite/lib/$filename
  22     set loaded_libs($filename) ""
  23 }
  24
  25 load_lib dg.exp
  26
  27 # Required to use gcc-dg.exp - however, the latter should NOT be
  28 # loaded until ${tool}_target_compile is defined since it uses that
  29 # to determine default LTO options.
  30
  31 load_gcc_lib file-format.exp
  32 load_gcc_lib target-supports.exp
  33 load_gcc_lib target-utils.exp
  34 load_gcc_lib target-supports-dg.exp
  35 load_gcc_lib scanasm.exp
  36 load_gcc_lib scandump.exp
  37 load_gcc_lib scanlang.exp
  38 load_gcc_lib scanrtl.exp
  39 load_gcc_lib scansarif.exp
  40 load_gcc_lib scantree.exp
  41 load_gcc_lib scanltranstree.exp
  42 load_gcc_lib scanipa.exp
  43 load_gcc_lib scanwpaipa.exp
  44 load_gcc_lib multiline.exp
  45 load_gcc_lib prune.exp
  46 load_gcc_lib target-libpath.exp
  47 load_gcc_lib wrapper.exp
  48 load_gcc_lib gcc-defs.exp
  49 load_gcc_lib torture-options.exp
  50 load_gcc_lib timeout.exp
  51 load_gcc_lib timeout-dg.exp
  52 load_gcc_lib fortran-modules.exp
  53
  54 set dg-do-what-default run
  55
  56 #
  57 # GCC_UNDER_TEST is the compiler under test.
  58 #
  59
  60 set libatomic_compile_options ""
  61
  62 #
  63 # libatomic_init
  64 #
  65
  66 if [info exists TOOL_OPTIONS] {
  67     set multilibs [get_multilibs $TOOL_OPTIONS]
  68 } else {
  69     set multilibs [get_multilibs]
  70 }
  71
  72 proc libatomic_init { args } {
  73     global srcdir blddir objdir tool_root_dir
  74     global libatomic_initialized
  75     global tmpdir
  76     global blddir
  77     global gluefile wrap_flags
  78     global ALWAYS_CFLAGS
  79     global CFLAGS
  80     global TOOL_EXECUTABLE TOOL_OPTIONS
  81     global GCC_UNDER_TEST
  82     global TESTING_IN_BUILD_TREE
  83     global target_triplet
  84     global always_ld_library_path
  85
  86     set blddir [lookfor_file [get_multilibs] libatomic]
  87
  88     # We set LC_ALL and LANG to C so that we get the same error
  89     # messages as expected.
  90     setenv LC_ALL C
  91     setenv LANG C
  92
  93     if ![info exists GCC_UNDER_TEST] then {
  94         if [info exists TOOL_EXECUTABLE] {
  95             set GCC_UNDER_TEST $TOOL_EXECUTABLE
  96         } else {
  97             set GCC_UNDER_TEST "[find_gcc]"
  98         }
  99     }
 100
 101     if ![info exists tmpdir] {
 102         set tmpdir "/tmp"
 103     }
 104
 105     if [info exists gluefile] {
 106         unset gluefile
 107     }
 108
 109     if {![info exists CFLAGS]} {
 110         set CFLAGS ""
 111     }
 112
 113     # Locate libgcc.a so we don't need to account for different values of
 114     # SHLIB_EXT on different platforms
 115     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 116     if {$gccdir != ""} {
 117         set gccdir [file dirname $gccdir]
 118     }
 119
 120     # Compute what needs to be put into LD_LIBRARY_PATH
 121     set always_ld_library_path ".:${blddir}/.libs"
 122
 123     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 124     if {$gccdir != ""} {
 125         # Add AIX pthread directory first.
 126         if { [llength [glob -nocomplain ${gccdir}/pthread/libgcc_s*.a]] >= 1 } {
 127             append always_ld_library_path ":${gccdir}/pthread"
 128         }
 129         append always_ld_library_path ":${gccdir}"
 130         set compiler [lindex $GCC_UNDER_TEST 0]
 131
 132         if { [is_remote host] == 0 && [which $compiler] != 0 } {
 133           foreach i "[exec $compiler --print-multi-lib]" {
 134             set mldir ""
 135             regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
 136             set mldir [string trimright $mldir "\;@"]
 137             if { "$mldir" == "." } {
 138               continue
 139             }
 140             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 141               append always_ld_library_path ":${gccdir}/${mldir}"
 142             }
 143           }
 144         }
 145     }
 146
 147     set ALWAYS_CFLAGS ""
 148     if { $blddir != "" } {
 149         # If '--with-build-sysroot=[...]' was specified, use it for build-tree
 150         # testing.
 151         global SYSROOT_CFLAGS_FOR_TARGET
 152         lappend ALWAYS_CFLAGS "additional_flags=${SYSROOT_CFLAGS_FOR_TARGET}"
 153
 154         lappend ALWAYS_CFLAGS "additional_flags=-B${blddir}/"
 155         lappend ALWAYS_CFLAGS "additional_flags=-I${blddir}"
 156         if [istarget *-*-darwin*] {
 157             lappend ALWAYS_CFLAGS "additional_flags=-B${blddir}/.libs"
 158         } else {
 159             lappend ALWAYS_CFLAGS "ldflags=-L${blddir}/.libs"
 160         }
 161     }
 162     lappend ALWAYS_CFLAGS "additional_flags=-I${srcdir}/.."
 163
 164     if [istarget *-*-darwin\[89\]*] {
 165         lappend ALWAYS_CFLAGS "additional_flags=-shared-libgcc"
 166     }
 167
 168     if [info exists TOOL_OPTIONS] {
 169         lappend ALWAYS_CFLAGS "additional_flags=$TOOL_OPTIONS"
 170     }
 171
 172     # Make sure that lines are not wrapped.  That can confuse the
 173     # error-message parsing machinery.
 174     lappend ALWAYS_CFLAGS "additional_flags=-fmessage-length=0"
 175
 176     # Turn off builtin support for atomics so that we test the library.
 177     lappend ALWAYS_CFLAGS "additional_flags=-fno-inline-atomics"
 178     lappend ALWAYS_CFLAGS "ldflags=-latomic"
 179 }
 180
 181 #
 182 # libatomic_target_compile -- compile a source file
 183 #
 184
 185 proc libatomic_target_compile { source dest type options } {
 186     global blddir
 187     global libatomic_compile_options
 188     global gluefile wrap_flags
 189     global ALWAYS_CFLAGS
 190     global GCC_UNDER_TEST
 191     global lang_test_file
 192     global lang_library_path
 193     global lang_link_flags
 194
 195     if { [info exists lang_test_file] } {
 196         if { $blddir != "" } {
 197             lappend options "ldflags=-L${blddir}/${lang_library_path}"
 198         }
 199         lappend options "ldflags=${lang_link_flags}"
 200     }
 201
 202     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 203         lappend options "libs=${gluefile}"
 204         lappend options "ldflags=${wrap_flags}"
 205     }
 206
 207     lappend options "additional_flags=[libio_include_flags]"
 208     lappend options "timeout=[timeout_value]"
 209     lappend options "compiler=$GCC_UNDER_TEST"
 210
 211     set options [concat $libatomic_compile_options $options]
 212
 213     if [info exists ALWAYS_CFLAGS] {
 214         set options [concat "$ALWAYS_CFLAGS" $options]
 215     }
 216
 217     set options [dg-additional-files-options $options $source $dest $type]
 218
 219     set result [target_compile $source $dest $type $options]
 220
 221     return $result
 222 }
 223
 224 proc libatomic_option_help { } {
 225     send_user " --additional_options,OPTIONS\t\tUse OPTIONS to compile the testcase files. OPTIONS should be comma-separated.\n"
 226 }
 227
 228 proc libatomic_option_proc { option } {
 229     if [regexp "^--additional_options," $option] {
 230         global libatomic_compile_options
 231         regsub "--additional_options," $option "" option
 232         foreach x [split $option ","] {
 233             lappend libatomic_compile_options "additional_flags=$x"
 234         }
 235         return 1
 236     } else {
 237         return 0
 238     }
 239 }