gcc/ada/sem_aux.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- As a special exception,  if other files  instantiate  generics from this --
  22 -- unit, or you link  this unit with other files  to produce an executable, --
  23 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  24 -- covered  by the  GNU  General  Public  License.  This exception does not --
  25 -- however invalidate  any other reasons why  the executable file  might be --
  26 -- covered by the  GNU Public License.                                      --
  27 --                                                                          --
  28 -- GNAT was originally developed  by the GNAT team at  New York University. --
  29 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 --  Package containing utility procedures used throughout the compiler,
  34 --  and also by ASIS so dependencies are limited to ASIS included packages.
  35
  36 --  Historical note. Many of the routines here were originally in Einfo, but
  37 --  Einfo is supposed to be a relatively low level package dealing with the
  38 --  content of entities in the tree, so this package is used for routines that
  39 --  require more than minimal semantic knowledge.
  40
  41 with Alloc; use Alloc;
  42 with Namet; use Namet;
  43 with Table;
  44 with Types; use Types;
  45 with Sinfo; use Sinfo;
  46
  47 package Sem_Aux is
  48
  49    --------------------------------
  50    -- Obsolescent Warnings Table --
  51    --------------------------------
  52
  53    --  This table records entities for which a pragma Obsolescent with a
  54    --  message argument has been processed.
  55
  56    type OWT_Record is record
  57       Ent : Entity_Id;
  58       --  The entity to which the pragma applies
  59
  60       Msg : String_Id;
  61       --  The string containing the message
  62    end record;
  63
  64    package Obsolescent_Warnings is new Table.Table (
  65      Table_Component_Type => OWT_Record,
  66      Table_Index_Type     => Int,
  67      Table_Low_Bound      => 0,
  68      Table_Initial        => Alloc.Obsolescent_Warnings_Initial,
  69      Table_Increment      => Alloc.Obsolescent_Warnings_Increment,
  70      Table_Name           => "Obsolescent_Warnings");
  71
  72    procedure Initialize;
  73    --  Called at the start of compilation of each new main source file to
  74    --  initialize the allocation of the Obsolescent_Warnings table. Note that
  75    --  Initialize must not be called if Tree_Read is used.
  76
  77    procedure Tree_Read;
  78    --  Initializes Obsolescent_Warnings table from current tree file using the
  79    --  relevant Table.Tree_Read routine.
  80
  81    procedure Tree_Write;
  82    --  Writes out Obsolescent_Warnings table to current tree file using the
  83    --  relevant Table.Tree_Write routine.
  84
  85    -----------------
  86    -- Subprograms --
  87    -----------------
  88
  89    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id;
  90    --  The argument Id is a type or subtype entity. If the argument is a
  91    --  subtype then it returns the subtype or type from which the subtype was
  92    --  obtained, otherwise it returns Empty.
  93
  94    function Available_View (Ent : Entity_Id) return Entity_Id;
  95    --  Ent denotes an abstract state or a type that may come from a limited
  96    --  with clause. Return the non-limited view of Ent if there is one or Ent
  97    --  if this is not the case.
  98
  99    function Constant_Value (Ent : Entity_Id) return Node_Id;
 100    --  Ent is a variable, constant, named integer, or named real entity. This
 101    --  call obtains the initialization expression for the entity. Will return
 102    --  Empty for a deferred constant whose full view is not available or
 103    --  in some other cases of internal entities, which cannot be treated as
 104    --  constants from the point of view of constant folding. Empty is also
 105    --  returned for variables with no initialization expression.
 106
 107    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id;
 108    --  Typ is a signed integer subtype. This routine returns the standard
 109    --  unsigned type with the same Esize as the implementation base type of
 110    --  Typ, e.g. Long_Integer => Long_Unsigned.
 111
 112    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
 113    --  For any entity, Ent, returns the closest dynamic scope in which the
 114    --  entity is declared or Standard_Standard for library-level entities.
 115
 116    function First_Discriminant (Typ : Entity_Id) return Entity_Id;
 117    --  Typ is a type with discriminants. The discriminants are the first
 118    --  entities declared in the type, so normally this is equivalent to
 119    --  First_Entity. The exception arises for tagged types, where the tag
 120    --  itself is prepended to the front of the entity chain, so the
 121    --  First_Discriminant function steps past the tag if it is present.
 122
 123    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id;
 124    --  Typ is a type with discriminants. Gives the first discriminant stored
 125    --  in an object of this type. In many cases, these are the same as the
 126    --  normal visible discriminants for the type, but in the case of renamed
 127    --  discriminants, this is not always the case.
 128    --
 129    --  For tagged types, and untagged types which are root types or derived
 130    --  types but which do not rename discriminants in their root type, the
 131    --  stored discriminants are the same as the actual discriminants of the
 132    --  type, and hence this function is the same as First_Discriminant.
 133    --
 134    --  For derived untagged types that rename discriminants in the root type
 135    --  this is the first of the discriminants that occur in the root type. To
 136    --  be precise, in this case stored discriminants are entities attached to
 137    --  the entity chain of the derived type which are a copy of the
 138    --  discriminants of the root type. Furthermore their Is_Completely_Hidden
 139    --  flag is set since although they are actually stored in the object, they
 140    --  are not in the set of discriminants that is visible in the type.
 141    --
 142    --  For derived untagged types, the set of stored discriminants are the real
 143    --  discriminants from Gigi's standpoint, i.e. those that will be stored in
 144    --  actual objects of the type.
 145
 146    function First_Subtype (Typ : Entity_Id) return Entity_Id;
 147    --  Applies to all types and subtypes. For types, yields the first subtype
 148    --  of the type. For subtypes, yields the first subtype of the base type of
 149    --  the subtype.
 150
 151    function First_Tag_Component (Typ : Entity_Id) return Entity_Id;
 152    --  Typ must be a tagged record type. This function returns the Entity for
 153    --  the first _Tag field in the record type.
 154
 155    function Get_Binary_Nkind (Op : Entity_Id) return Node_Kind;
 156    --  Op must be an entity with an Ekind of E_Operator. This function returns
 157    --  the Nkind value that would be used to construct a binary operator node
 158    --  referencing this entity. It is an error to call this function if Ekind
 159    --  (Op) /= E_Operator.
 160
 161    function Get_Unary_Nkind (Op : Entity_Id) return Node_Kind;
 162    --  Op must be an entity with an Ekind of E_Operator. This function returns
 163    --  the Nkind value that would be used to construct a unary operator node
 164    --  referencing this entity. It is an error to call this function if Ekind
 165    --  (Op) /= E_Operator.
 166
 167    function Get_Rep_Item
 168      (E             : Entity_Id;
 169       Nam           : Name_Id;
 170       Check_Parents : Boolean := True) return Node_Id;
 171    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 172    --  rep item (pragma, attribute definition clause, or aspect specification)
 173    --  whose name matches the given name Nam. If Check_Parents is False then it
 174    --  only returns rep item that has been directly specified for E (and not
 175    --  inherited from its parents, if any). If one is found, it is returned,
 176    --  otherwise Empty is returned. A special case is that when Nam is
 177    --  Name_Priority, the call will also find Interrupt_Priority.
 178
 179    function Get_Rep_Item
 180      (E             : Entity_Id;
 181       Nam1          : Name_Id;
 182       Nam2          : Name_Id;
 183       Check_Parents : Boolean := True) return Node_Id;
 184    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 185    --  rep item (pragma, attribute definition clause, or aspect specification)
 186    --  whose name matches one of the given names Nam1 or Nam2. If Check_Parents
 187    --  is False then it only returns rep item that has been directly specified
 188    --  for E (and not inherited from its parents, if any). If one is found, it
 189    --  is returned, otherwise Empty is returned. A special case is that when
 190    --  one of the given names is Name_Priority, the call will also find
 191    --  Interrupt_Priority.
 192
 193    function Get_Rep_Pragma
 194      (E             : Entity_Id;
 195       Nam           : Name_Id;
 196       Check_Parents : Boolean := True) return Node_Id;
 197    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 198    --  representation pragma whose name matches the given name Nam. If
 199    --  Check_Parents is False then it only returns representation pragma that
 200    --  has been directly specified for E (and not inherited from its parents,
 201    --  if any). If one is found and if it is the first rep item in the list
 202    --  that matches Nam, it is returned, otherwise Empty is returned. A special
 203    --  case is that when Nam is Name_Priority, the call will also find
 204    --  Interrupt_Priority.
 205
 206    function Get_Rep_Pragma
 207      (E             : Entity_Id;
 208       Nam1          : Name_Id;
 209       Nam2          : Name_Id;
 210       Check_Parents : Boolean := True) return Node_Id;
 211    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 212    --  representation pragma whose name matches one of the given names Nam1 or
 213    --  Nam2. If Check_Parents is False then it only returns representation
 214    --  pragma that has been directly specified for E (and not inherited from
 215    --  its parents, if any). If one is found and if it is the first rep item in
 216    --  the list that matches one of the given names, it is returned, otherwise
 217    --  Empty is returned. A special case is that when one of the given names is
 218    --  Name_Priority, the call will also find Interrupt_Priority.
 219
 220    function Has_Rep_Item
 221      (E             : Entity_Id;
 222       Nam           : Name_Id;
 223       Check_Parents : Boolean := True) return Boolean;
 224    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 225    --  rep item (pragma, attribute definition clause, or aspect specification)
 226    --  with the given name Nam. If Check_Parents is False then it only checks
 227    --  for a rep item that has been directly specified for E (and not inherited
 228    --  from its parents, if any). If found then True is returned, otherwise
 229    --  False indicates that no matching entry was found.
 230
 231    function Has_Rep_Item
 232      (E             : Entity_Id;
 233       Nam1          : Name_Id;
 234       Nam2          : Name_Id;
 235       Check_Parents : Boolean := True) return Boolean;
 236    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 237    --  rep item (pragma, attribute definition clause, or aspect specification)
 238    --  with the given names Nam1 or Nam2. If Check_Parents is False then it
 239    --  only checks for a rep item that has been directly specified for E (and
 240    --  not inherited from its parents, if any). If found then True is returned,
 241    --  otherwise False indicates that no matching entry was found.
 242
 243    function Has_Rep_Pragma
 244      (E             : Entity_Id;
 245       Nam           : Name_Id;
 246       Check_Parents : Boolean := True) return Boolean;
 247    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 248    --  representation pragma with the given name Nam. If Check_Parents is False
 249    --  then it only checks for a representation pragma that has been directly
 250    --  specified for E (and not inherited from its parents, if any). If found
 251    --  and if it is the first rep item in the list that matches Nam then True
 252    --  is returned, otherwise False indicates that no matching entry was found.
 253
 254    function Has_Rep_Pragma
 255      (E             : Entity_Id;
 256       Nam1          : Name_Id;
 257       Nam2          : Name_Id;
 258       Check_Parents : Boolean := True) return Boolean;
 259    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 260    --  representation pragma with the given names Nam1 or Nam2. If
 261    --  Check_Parents is False then it only checks for a rep item that has been
 262    --  directly specified for E (and not inherited from its parents, if any).
 263    --  If found and if it is the first rep item in the list that matches one of
 264    --  the given names then True is returned, otherwise False indicates that no
 265    --  matching entry was found.
 266
 267    function Has_External_Tag_Rep_Clause (T : Entity_Id) return Boolean;
 268    --  Defined in tagged types. Set if an External_Tag rep. clause has been
 269    --  given for this type. Use to avoid the generation of the default
 270    --  External_Tag.
 271    --
 272    --  Note: we used to use an entity flag for this purpose, but that was wrong
 273    --  because it was not propagated from the private view to the full view. We
 274    --  could have added that propagation, but it would have been an annoying
 275    --  irregularity compared to other representation aspects, and the cost of
 276    --  looking up the aspect when needed is small.
 277
 278    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean;
 279    --  True if T has discriminants and is unconstrained, or is an array type
 280    --  whose element type Has_Unconstrained_Elements.
 281
 282    function Has_Variant_Part (Typ : Entity_Id) return Boolean;
 283    --  Return True if the first subtype of Typ is a discriminated record type
 284    --  which has a variant part. False otherwise.
 285
 286    function In_Generic_Body (Id : Entity_Id) return Boolean;
 287    --  Determine whether entity Id appears inside a generic body
 288
 289    function Initialization_Suppressed (Typ : Entity_Id) return Boolean;
 290    pragma Inline (Initialization_Suppressed);
 291    --  Returns True if initialization should be suppressed for the given type
 292    --  or subtype. This is true if Suppress_Initialization is set either for
 293    --  the subtype itself, or for the corresponding base type.
 294
 295    function Is_Body (N : Node_Id) return Boolean;
 296    --  Determine whether an arbitrary node denotes a body
 297
 298    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean;
 299    --  Ent is any entity. Returns True if Ent is a type entity where the type
 300    --  is required to be passed by copy, as defined in (RM 6.2(3)).
 301
 302    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean;
 303    --  Ent is any entity. Returns True if Ent is a type entity where the type
 304    --  is required to be passed by reference, as defined in (RM 6.2(4-9)).
 305
 306    function Is_Derived_Type (Ent : Entity_Id) return Boolean;
 307    --  Determines if the given entity Ent is a derived type. Result is always
 308    --  false if argument is not a type.
 309
 310    function Is_Generic_Formal (E : Entity_Id) return Boolean;
 311    --  Determine whether E is a generic formal parameter. In particular this is
 312    --  used to set the visibility of generic formals of a generic package
 313    --  declared with a box or with partial parameterization.
 314
 315    function Is_Indefinite_Subtype (Ent : Entity_Id) return Boolean;
 316    --  Ent is any entity. Determines if given entity is an unconstrained array
 317    --  type or subtype, a discriminated record type or subtype with no initial
 318    --  discriminant values or a class wide type or subtype and returns True if
 319    --  so. False for other type entities, or any entities that are not types.
 320
 321    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean;
 322    --  Implements definition in Ada 2012 RM-7.5 (8.1/3). This differs from the
 323    --  following predicate in that an untagged record with immutably limited
 324    --  components is NOT by itself immutably limited. This matters, e.g. when
 325    --  checking the legality of an access to the current instance.
 326
 327    function Is_Limited_View (Ent : Entity_Id) return Boolean;
 328    --  Ent is any entity. True for a type that is "inherently" limited (i.e.
 329    --  cannot become nonlimited). From the Ada 2005 RM-7.5(8.1/2), "a type with
 330    --  a part that is of a task, protected, or explicitly limited record type".
 331    --  These are the types that are defined as return-by-reference types in Ada
 332    --  95 (see RM95-6.5(11-16)). In Ada 2005, these are the types that require
 333    --  build-in-place for function calls. Note that build-in-place is allowed
 334    --  for other types, too. This is also used for identifying pure procedures
 335    --  whose calls should not be eliminated (RM 10.2.1(18/2)).
 336
 337    function Is_Limited_Type (Ent : Entity_Id) return Boolean;
 338    --  Ent is any entity. Returns true if Ent is a limited type (limited
 339    --  private type, limited interface type, task type, protected type,
 340    --  composite containing a limited component, or a subtype of any of
 341    --  these types). This older routine overlaps with the previous one, this
 342    --  should be cleaned up???
 343
 344    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id;
 345    --  Given a subtype Typ, this function finds out the nearest ancestor from
 346    --  which constraints and predicates are inherited. There is no simple link
 347    --  for doing this, consider:
 348    --
 349    --     subtype R is Integer range 1 .. 10;
 350    --     type T is new R;
 351    --
 352    --  In this case the nearest ancestor is R, but the Etype of T'Base will
 353    --  point to R'Base, so we have to go rummaging in the declarations to get
 354    --  this information. It is used for making sure we freeze this before we
 355    --  freeze Typ, and also for retrieving inherited predicate information.
 356    --  For the case of base types or first subtypes, there is no useful entity
 357    --  to return, so Empty is returned.
 358    --
 359    --  Note: this is similar to Ancestor_Subtype except that it also deals
 360    --  with the case of derived types.
 361
 362    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
 363    --  This is similar to Enclosing_Dynamic_Scope except that if Ent is itself
 364    --  a dynamic scope, then it is returned. Otherwise the result is the same
 365    --  as that returned by Enclosing_Dynamic_Scope.
 366
 367    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id;
 368    --  Tag must be an entity representing a _Tag field of a tagged record.
 369    --  The result returned is the next _Tag field in this record, or Empty
 370    --  if this is the last such field.
 371
 372    function Number_Discriminants (Typ : Entity_Id) return Pos;
 373    --  Typ is a type with discriminants, yields number of discriminants in type
 374
 375    function Object_Type_Has_Constrained_Partial_View
 376      (Typ  : Entity_Id;
 377       Scop : Entity_Id) return Boolean;
 378    --  Return True if type of object has attribute Has_Constrained_Partial_View
 379    --  set to True; in addition, within a generic body, return True if subtype
 380    --  of the object is a descendant of an untagged generic formal private or
 381    --  derived type, and the subtype is not an unconstrained array subtype
 382    --  (RM 3.3(23.10/3)).
 383
 384    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id;
 385    pragma Inline (Ultimate_Alias);
 386    --  Return the last entity in the chain of aliased entities of Prim. If Prim
 387    --  has no alias return Prim.
 388
 389    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id;
 390    --  Unit_Id is the simple name of a program unit, this function returns the
 391    --  corresponding xxx_Declaration node for the entity. Also applies to the
 392    --  body entities for subprograms, tasks and protected units, in which case
 393    --  it returns the subprogram, task or protected body node for it. The unit
 394    --  may be a child unit with any number of ancestors.
 395
 396    function Package_Specification (Pack_Id : Entity_Id) return Node_Id;
 397    --  Given an entity for a package or generic package, return corresponding
 398    --  package specification. Simplifies handling of child units, and better
 399    --  than the old idiom: Specification (Unit_Declaration_Node (Pack_Id)).
 400
 401 end Sem_Aux;