gcc/ada/sem_aux.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2024, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  Package containing utility procedures used throughout the compiler.
  27
  28 --  Historical note. Many of the routines here were originally in Einfo, but
  29 --  Einfo is supposed to be a relatively low level package dealing with the
  30 --  content of entities in the tree, so this package is used for routines that
  31 --  require more than minimal semantic knowledge.
  32
  33 with Alloc;
  34 with Namet; use Namet;
  35 with Table;
  36 with Types; use Types;
  37
  38 package Sem_Aux is
  39
  40    --------------------------------
  41    -- Obsolescent Warnings Table --
  42    --------------------------------
  43
  44    --  This table records entities for which a pragma Obsolescent with a
  45    --  message argument has been processed.
  46
  47    type OWT_Record is record
  48       Ent : Entity_Id;
  49       --  The entity to which the pragma applies
  50
  51       Msg : String_Id;
  52       --  The string containing the message
  53    end record;
  54
  55    package Obsolescent_Warnings is new Table.Table (
  56      Table_Component_Type => OWT_Record,
  57      Table_Index_Type     => Int,
  58      Table_Low_Bound      => 0,
  59      Table_Initial        => Alloc.Obsolescent_Warnings_Initial,
  60      Table_Increment      => Alloc.Obsolescent_Warnings_Increment,
  61      Table_Name           => "Obsolescent_Warnings");
  62
  63    procedure Initialize;
  64    --  Called at the start of compilation of each new main source file to
  65    --  initialize the allocation of the Obsolescent_Warnings table.
  66
  67    -----------------
  68    -- Subprograms --
  69    -----------------
  70
  71    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id;
  72    --  The argument Typ is a type or subtype entity. If the argument is a
  73    --  subtype then it returns the subtype or type from which the subtype was
  74    --  obtained, otherwise it returns Empty.
  75
  76    --  WARNING: There is a matching C declaration of this subprogram in fe.h
  77
  78    function Available_View (Ent : Entity_Id) return Entity_Id;
  79    --  Ent denotes an abstract state or a type that may come from a limited
  80    --  with clause. Return the non-limited view of Ent if there is one or Ent
  81    --  if this is not the case.
  82
  83    function Constant_Value (Ent : Entity_Id) return Node_Id;
  84    --  Ent is a variable, constant, named integer, or named real entity. This
  85    --  call obtains the initialization expression for the entity. Will return
  86    --  Empty for a deferred constant whose full view is not available or
  87    --  in some other cases of internal entities, which cannot be treated as
  88    --  constants from the point of view of constant folding. Empty is also
  89    --  returned for variables with no initialization expression.
  90
  91    --  WARNING: There is a matching C declaration of this subprogram in fe.h
  92
  93    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id;
  94    --  Typ is a signed integer subtype. This routine returns the standard
  95    --  unsigned type with the same Esize as the implementation base type of
  96    --  Typ, e.g. Long_Integer => Long_Unsigned.
  97
  98    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
  99    --  For any entity, Ent, returns the closest dynamic scope in which the
 100    --  entity is declared or Standard_Standard for library-level entities.
 101
 102    function First_Discriminant (Typ : Entity_Id) return Entity_Id;
 103    --  Typ is a type with discriminants or unknown discriminants. The
 104    --  discriminants are the first entities declared in the type, so normally
 105    --  this is equivalent to First_Entity. The exception arises for tagged
 106    --  types, where the tag itself is prepended to the front of the entity
 107    --  chain, so the First_Discriminant function steps past the tag if it is
 108    --  present.  When called on a private type with unknown discriminants, the
 109    --  function always returns Empty.
 110
 111    --  WARNING: There is a matching C declaration of this subprogram in fe.h
 112
 113    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id;
 114    --  Typ is a type with discriminants. Gives the first discriminant stored
 115    --  in an object of this type. In many cases, these are the same as the
 116    --  normal visible discriminants for the type, but in the case of renamed
 117    --  discriminants, this is not always the case.
 118    --
 119    --  For tagged types, and untagged types which are root types or derived
 120    --  types but which do not rename discriminants in their root type, the
 121    --  stored discriminants are the same as the actual discriminants of the
 122    --  type, and hence this function is the same as First_Discriminant.
 123    --
 124    --  For derived untagged types that rename discriminants in the root type
 125    --  this is the first of the discriminants that occur in the root type. To
 126    --  be precise, in this case stored discriminants are entities attached to
 127    --  the entity chain of the derived type which are a copy of the
 128    --  discriminants of the root type. Furthermore their Is_Completely_Hidden
 129    --  flag is set since although they are actually stored in the object, they
 130    --  are not in the set of discriminants that is visible in the type.
 131    --
 132    --  For derived untagged types, the set of stored discriminants are the real
 133    --  discriminants from Gigi's standpoint, i.e. those that will be stored in
 134    --  actual objects of the type.
 135
 136    --  WARNING: There is a matching C declaration of this subprogram in fe.h
 137
 138    function First_Subtype (Typ : Entity_Id) return Entity_Id;
 139    --  Applies to all types and subtypes. For types, yields the first subtype
 140    --  of the type. For subtypes, yields the first subtype of the base type of
 141    --  the subtype.
 142
 143    --  WARNING: There is a matching C declaration of this subprogram in fe.h
 144
 145    function First_Tag_Component (Typ : Entity_Id) return Entity_Id;
 146    --  Typ must be a tagged record type. This function returns the Entity for
 147    --  the first _Tag field in the record type.
 148
 149    function Get_Called_Entity (Call : Node_Id) return Entity_Id;
 150    --  Obtain the entity of the entry, operator, or subprogram being invoked
 151    --  by call Call.
 152
 153    function Get_Rep_Item
 154      (E             : Entity_Id;
 155       Nam           : Name_Id;
 156       Check_Parents : Boolean := True) return Node_Id;
 157    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 158    --  rep item (pragma, attribute definition clause, or aspect specification)
 159    --  whose name matches the given name Nam. If Check_Parents is False then it
 160    --  only returns rep item that has been directly specified for E (and not
 161    --  inherited from its parents, if any). If one is found, it is returned,
 162    --  otherwise Empty is returned. A special case is that when Nam is
 163    --  Name_Priority, the call will also find Interrupt_Priority.
 164
 165    function Get_Rep_Item
 166      (E             : Entity_Id;
 167       Nam1          : Name_Id;
 168       Nam2          : Name_Id;
 169       Check_Parents : Boolean := True) return Node_Id;
 170    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 171    --  rep item (pragma, attribute definition clause, or aspect specification)
 172    --  whose name matches one of the given names Nam1 or Nam2. If Check_Parents
 173    --  is False then it only returns rep item that has been directly specified
 174    --  for E (and not inherited from its parents, if any). If one is found, it
 175    --  is returned, otherwise Empty is returned. A special case is that when
 176    --  one of the given names is Name_Priority, the call will also find
 177    --  Interrupt_Priority.
 178
 179    function Get_Rep_Pragma
 180      (E             : Entity_Id;
 181       Nam           : Name_Id;
 182       Check_Parents : Boolean := True) return Node_Id;
 183    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 184    --  representation pragma whose name matches the given name Nam. If
 185    --  Check_Parents is False then it only returns representation pragma that
 186    --  has been directly specified for E (and not inherited from its parents,
 187    --  if any). If one is found and if it is the first rep item in the list
 188    --  that matches Nam, it is returned, otherwise Empty is returned. A special
 189    --  case is that when Nam is Name_Priority, the call will also find
 190    --  Interrupt_Priority.
 191
 192    function Get_Rep_Pragma
 193      (E             : Entity_Id;
 194       Nam1          : Name_Id;
 195       Nam2          : Name_Id;
 196       Check_Parents : Boolean := True) return Node_Id;
 197    --  Searches the Rep_Item chain for a given entity E, for an instance of a
 198    --  representation pragma whose name matches one of the given names Nam1 or
 199    --  Nam2. If Check_Parents is False then it only returns representation
 200    --  pragma that has been directly specified for E (and not inherited from
 201    --  its parents, if any). If one is found and if it is the first rep item in
 202    --  the list that matches one of the given names, it is returned, otherwise
 203    --  Empty is returned. A special case is that when one of the given names is
 204    --  Name_Priority, the call will also find Interrupt_Priority.
 205
 206    function Has_Rep_Item
 207      (E             : Entity_Id;
 208       Nam           : Name_Id;
 209       Check_Parents : Boolean := True) return Boolean;
 210    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 211    --  rep item (pragma, attribute definition clause, or aspect specification)
 212    --  with the given name Nam. If Check_Parents is False then it only checks
 213    --  for a rep item that has been directly specified for E (and not inherited
 214    --  from its parents, if any). If found then True is returned, otherwise
 215    --  False indicates that no matching entry was found.
 216
 217    function Has_Rep_Item
 218      (E             : Entity_Id;
 219       Nam1          : Name_Id;
 220       Nam2          : Name_Id;
 221       Check_Parents : Boolean := True) return Boolean;
 222    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 223    --  rep item (pragma, attribute definition clause, or aspect specification)
 224    --  with the given names Nam1 or Nam2. If Check_Parents is False then it
 225    --  only checks for a rep item that has been directly specified for E (and
 226    --  not inherited from its parents, if any). If found then True is returned,
 227    --  otherwise False indicates that no matching entry was found.
 228
 229    function Has_Rep_Pragma
 230      (E             : Entity_Id;
 231       Nam           : Name_Id;
 232       Check_Parents : Boolean := True) return Boolean;
 233    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 234    --  representation pragma with the given name Nam. If Check_Parents is False
 235    --  then it only checks for a representation pragma that has been directly
 236    --  specified for E (and not inherited from its parents, if any). If found
 237    --  and if it is the first rep item in the list that matches Nam then True
 238    --  is returned, otherwise False indicates that no matching entry was found.
 239
 240    function Has_Rep_Pragma
 241      (E             : Entity_Id;
 242       Nam1          : Name_Id;
 243       Nam2          : Name_Id;
 244       Check_Parents : Boolean := True) return Boolean;
 245    --  Searches the Rep_Item chain for the given entity E, for an instance of a
 246    --  representation pragma with the given names Nam1 or Nam2. If
 247    --  Check_Parents is False then it only checks for a rep item that has been
 248    --  directly specified for E (and not inherited from its parents, if any).
 249    --  If found and if it is the first rep item in the list that matches one of
 250    --  the given names then True is returned, otherwise False indicates that no
 251    --  matching entry was found.
 252
 253    function Has_External_Tag_Rep_Clause (T : Entity_Id) return Boolean;
 254    --  Defined in tagged types. Set if an External_Tag rep. clause has been
 255    --  given for this type. Use to avoid the generation of the default
 256    --  External_Tag.
 257    --
 258    --  Note: we used to use an entity flag for this purpose, but that was wrong
 259    --  because it was not propagated from the private view to the full view. We
 260    --  could have added that propagation, but it would have been an annoying
 261    --  irregularity compared to other representation aspects, and the cost of
 262    --  looking up the aspect when needed is small.
 263
 264    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean;
 265    --  True if T has discriminants and is unconstrained, or is an array type
 266    --  whose element type Has_Unconstrained_Elements.
 267
 268    function Has_Variant_Part (Typ : Entity_Id) return Boolean;
 269    --  Return True if the first subtype of Typ is a discriminated record type
 270    --  which has a variant part. False otherwise.
 271
 272    function In_Generic_Body (Id : Entity_Id) return Boolean;
 273    --  Determine whether entity Id appears inside a generic body
 274
 275    function Initialization_Suppressed (Typ : Entity_Id) return Boolean;
 276    pragma Inline (Initialization_Suppressed);
 277    --  Returns True if initialization should be suppressed for the given type
 278    --  or subtype. This is true if Suppress_Initialization is set either for
 279    --  the subtype itself, or for the corresponding base type.
 280
 281    function Is_Body (N : Node_Id) return Boolean with Inline;
 282    --  Determine whether an arbitrary node denotes a body
 283
 284    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean;
 285    --  Ent is any entity. Returns True if Ent is a type entity where the type
 286    --  is required to be passed by copy, as defined in (RM 6.2(3)).
 287
 288    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean;
 289    --  Ent is any entity. Returns True if Ent is a type entity where the type
 290    --  is required to be passed by reference, as defined in (RM 6.2(4-9)).
 291
 292    --  WARNING: There is a matching C declaration of this subprogram in fe.h
 293
 294    function Is_Definite_Subtype (T : Entity_Id) return Boolean;
 295    --  T is a type entity. Returns True if T is a definite subtype.
 296    --  Indefinite subtypes are unconstrained arrays, unconstrained
 297    --  discriminated types without defaulted discriminants, class-wide types,
 298    --  and types with unknown discriminants. Definite subtypes are all others
 299    --  (elementary, constrained composites (including the case of records
 300    --  without discriminants), and types with defaulted discriminants).
 301
 302    function Is_Derived_Type (Ent : Entity_Id) return Boolean;
 303    --  Determines if the given entity Ent is a derived type. Result is always
 304    --  false if argument is not a type.
 305
 306    --  WARNING: There is a matching C declaration of this subprogram in fe.h
 307
 308    function Is_Generic_Formal (E : Entity_Id) return Boolean;
 309    --  Determine whether E is a generic formal parameter. In particular this is
 310    --  used to set the visibility of generic formals of a generic package
 311    --  declared with a box or with partial parameterization.
 312
 313    function Is_Limited_Type (Ent : Entity_Id) return Boolean;
 314    --  Ent is any entity. Returns true if Ent is a limited type (limited
 315    --  private type, limited interface type, task type, protected type,
 316    --  composite containing a limited component, or a subtype of any of
 317    --  these types). This older routine overlaps with the next ones, this
 318    --  should be cleaned up???
 319
 320    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean;
 321    --  Implements definition in Ada 2012 RM-7.5 (8.1/3). This differs from the
 322    --  following predicate in that an untagged record with immutably limited
 323    --  components is NOT by itself immutably limited. This matters, e.g. when
 324    --  checking the legality of an access to the current instance.
 325
 326    function Is_Inherently_Limited_Type (Ent : Entity_Id) return Boolean;
 327    --  Ent is any entity. True for a type that is "inherently" limited (i.e.
 328    --  cannot become nonlimited). From the Ada 2005 RM-7.5(8.1/2), "a type with
 329    --  a part that is of a task, protected, or explicitly limited record type".
 330    --  These are the types that are defined as return-by-reference types in Ada
 331    --  95 (see RM95-6.5(11-16)). In Ada 2005, these are the types that require
 332    --  build-in-place for function calls. Note that build-in-place is allowed
 333    --  for other types, too. This is also used for identifying pure procedures
 334    --  whose calls should not be eliminated (RM 10.2.1(18/2)).
 335
 336    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id;
 337    --  Given a subtype Typ, this function finds out the nearest ancestor from
 338    --  which constraints and predicates are inherited. There is no simple link
 339    --  for doing this, consider:
 340    --
 341    --     subtype R is Integer range 1 .. 10;
 342    --     type T is new R;
 343    --
 344    --  In this case the nearest ancestor is R, but the Etype of T'Base will
 345    --  point to R'Base, so we have to go rummaging in the declarations to get
 346    --  this information. It is used for making sure we freeze this before we
 347    --  freeze Typ, and also for retrieving inherited predicate information.
 348    --  For the case of base types or first subtypes, there is no useful entity
 349    --  to return, so Empty is returned.
 350    --
 351    --  Note: this is similar to Ancestor_Subtype except that it also deals
 352    --  with the case of derived types.
 353
 354    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id;
 355    --  This is similar to Enclosing_Dynamic_Scope except that if Ent is itself
 356    --  a dynamic scope, then it is returned. Otherwise the result is the same
 357    --  as that returned by Enclosing_Dynamic_Scope.
 358
 359    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id;
 360    --  Tag must be an entity representing a _Tag field of a tagged record.
 361    --  The result returned is the next _Tag field in this record, or Empty
 362    --  if this is the last such field.
 363
 364    function Number_Discriminants (Typ : Entity_Id) return Pos;
 365    --  Typ is a type with discriminants, yields number of discriminants in type
 366
 367    function Object_Type_Has_Constrained_Partial_View
 368      (Typ  : Entity_Id;
 369       Scop : Entity_Id) return Boolean;
 370    --  Return True if type of object has attribute Has_Constrained_Partial_View
 371    --  set to True; in addition, within a generic body, return True if subtype
 372    --  of the object is a descendant of an untagged generic formal private or
 373    --  derived type, and the subtype is not an unconstrained array subtype
 374    --  (RM 3.3(23.10/3)).
 375
 376    function Package_Body (E : Entity_Id) return Node_Id;
 377    --  Given an entity for a package, return the corresponding package body, if
 378    --  any, or else Empty.
 379
 380    function Package_Spec (E : Entity_Id) return Node_Id;
 381    --  Given an entity for a package spec, return the corresponding package
 382    --  spec if any, or else Empty.
 383
 384    function Package_Specification (E : Entity_Id) return Node_Id;
 385    --  Given an entity for a package, return the corresponding package
 386    --  specification.
 387
 388    function Subprogram_Body (E : Entity_Id) return Node_Id;
 389    --  Given an entity for a subprogram (spec or body), return the
 390    --  corresponding subprogram body if any, or else Empty.
 391
 392    function Subprogram_Body_Entity (E : Entity_Id) return Entity_Id;
 393    --  Given an entity for a subprogram (spec or body), return the entity
 394    --  corresponding to the subprogram body, which may be the same as E or
 395    --  Empty if no body is available.
 396
 397    function Subprogram_Spec (E : Entity_Id) return Node_Id;
 398    --  Given an entity for a subprogram spec, return the corresponding
 399    --  subprogram spec if any, or else Empty.
 400
 401    function Subprogram_Specification (E : Entity_Id) return Node_Id;
 402    --  Given an entity for a subprogram, return the corresponding subprogram
 403    --  specification. If the entity is an inherited subprogram without
 404    --  specification itself, return the specification of the inherited
 405    --  subprogram.
 406
 407    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id;
 408    pragma Inline (Ultimate_Alias);
 409    --  Return the last entity in the chain of aliased entities of Prim. If Prim
 410    --  has no alias return Prim.
 411
 412    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id;
 413    --  Unit_Id is the simple name of a program unit, this function returns the
 414    --  corresponding xxx_Declaration node for the entity. Also applies to the
 415    --  body entities for subprograms, tasks and protected units, in which case
 416    --  it returns the subprogram, task or protected body node for it. The unit
 417    --  may be a child unit with any number of ancestors.
 418
 419 end Sem_Aux;