fixincludes/configure.ac

   1 AC_PREREQ(2.59)
   2
   3 AC_INIT(fixincludes, [ ])
   4 AC_CONFIG_SRCDIR(inclhack.def)
   5 AC_CONFIG_AUX_DIR(..)
   6 AC_CANONICAL_SYSTEM
   7 AC_PROG_CC
   8
   9 # Figure out what compiler warnings we can enable.
  10 # See config/warnings.m4 for details.
  11
  12 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
  13                           -Wmissing-prototypes -Wold-style-definition \
  14                           -Wmissing-format-attribute -Wno-overlength-strings])
  15 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long])
  16
  17 # Only enable with --enable-werror-always until existing warnings are
  18 # corrected.
  19 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  20
  21 # Determine the noncanonical target name, for directory use.
  22 ACX_NONCANONICAL_TARGET
  23
  24 # Specify the local prefix
  25 local_prefix=
  26 AC_ARG_WITH(local-prefix,
  27 [  --with-local-prefix=DIR specifies directory to put local include],
  28 [case "${withval}" in
  29 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
  30 no)     ;;
  31 *)      local_prefix=$with_local_prefix ;;
  32 esac])
  33
  34 # Default local prefix if it is empty
  35 if test x$local_prefix = x; then
  36         local_prefix=/usr/local
  37 fi
  38
  39 # Choose one or two-process fix methodology.  Systems that cannot handle
  40 # bi-directional pipes must use the two process method.
  41 #
  42 AC_ARG_ENABLE([twoprocess],
  43 [  --enable-twoprocess       Use a separate process to apply the fixes],
  44 [if test "x$enable_twoprocess" = xyes; then
  45         TARGET=twoprocess
  46 else
  47         TARGET=oneprocess
  48 fi],
  49 [case $host in
  50         i?86-*-msdosdjgpp* | \
  51         i?86-*-mingw32* | \
  52         *-*-beos* )
  53                 TARGET=twoprocess
  54                 ;;
  55
  56         * )
  57                 TARGET=oneprocess
  58                 ;;
  59 esac])
  60 AC_SUBST(TARGET)
  61
  62 if test $TARGET = twoprocess; then
  63         AC_DEFINE(SEPARATE_FIX_PROC, 1,
  64                   [Define if testing and fixing are done by separate process])
  65 fi
  66
  67 case $host in
  68         vax-dec-bsd* )
  69                 AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
  70                 AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
  71                 ;;
  72 esac
  73
  74 AC_DEFINE_UNQUOTED([EXE_EXT], "$ac_exeext",
  75   [Defined to the executable file extension on the host system])
  76
  77 # Checks for header files.
  78 AC_HEADER_STDC
  79 AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
  80         sys/stat.h])
  81 define(fixincludes_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
  82   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
  83   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
  84   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
  85   putchar_unlocked putc_unlocked)
  86 AC_CHECK_FUNCS(fixincludes_UNLOCKED_FUNCS)
  87 AC_CHECK_DECLS(m4_split(m4_normalize(abort asprintf basename errno vasprintf fixincludes_UNLOCKED_FUNCS)))
  88
  89 # Checks for typedefs, structures, and compiler characteristics.
  90 AC_C_CONST
  91
  92 # Checks for library functions.
  93 gcc_AC_FUNC_MMAP_BLACKLIST
  94
  95 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  96 AC_ARG_ENABLE(maintainer-mode,
  97 [  --enable-maintainer-mode enable make rules and dependencies not useful
  98                           (and sometimes confusing) to the casual installer],
  99       USE_MAINTAINER_MODE=$enableval,
 100       USE_MAINTAINER_MODE=no)
 101 AC_MSG_RESULT($USE_MAINTAINER_MODE)
 102 if test "$USE_MAINTAINER_MODE" = yes; then
 103   MAINT=
 104 else
 105   MAINT='#'
 106 fi
 107 AC_SUBST(MAINT)
 108
 109 AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
 110 AC_CONFIG_FILES(Makefile mkheaders.almost:mkheaders.in)
 111 AC_OUTPUT