pkgs/development/compilers/ocaml/3.11.1.nix

   1 { stdenv, fetchurl, ncurses, x11 }:
   2
   3 let
   4    useX11 = stdenv.isi686 || stdenv.isx86_64;
   5    useNativeCompilers = stdenv.isi686 || stdenv.isx86_64 || stdenv.isMips;
   6    inherit (stdenv.lib) optionals optionalString;
   7 in
   8
   9 stdenv.mkDerivation rec {
  10
  11   name = "ocaml-3.11.1";
  12
  13   src = fetchurl {
  14     url = "http://caml.inria.fr/pub/distrib/ocaml-3.11/${name}.tar.bz2";
  15     sha256 = "8c36a28106d4b683a15c547dfe4cb757a53fa9247579d1cc25bd06a22cc62e50";
  16   };
  17
  18   # Needed to avoid a SIGBUS on the final executable on mips
  19   NIX_CFLAGS_COMPILE = if stdenv.isMips then "-fPIC" else "";
  20
  21   patches = optionals stdenv.isDarwin [ ./gnused-on-osx-fix.patch ];
  22
  23   prefixKey = "-prefix ";
  24   configureFlags = ["-no-tk"] ++ optionals useX11 [ "-x11lib" x11 ];
  25   buildFlags = "world" + optionalString useNativeCompilers " bootstrap world.opt";
  26   buildInputs = [ncurses] ++ optionals useX11 [ x11 ];
  27   installTargets = "install" + optionalString useNativeCompilers " installopt";
  28   prePatch = ''
  29     CAT=$(type -tp cat)
  30     sed -e "s@/bin/cat@$CAT@" -i config/auto-aux/sharpbang
  31     patch -p0 < ${./mips64.patch}
  32   '';
  33   postBuild = ''
  34     ensureDir $out/include
  35     ln -sv $out/lib/ocaml/caml $out/include/caml
  36   '';
  37
  38   meta = {
  39     homepage = http://caml.inria.fr/ocaml;
  40     licenses = [ "QPL" /* compiler */ "LGPLv2" /* library */ ];
  41     description = "Objective Caml, the most popular variant of the Caml language";
  42
  43     longDescription =
  44       '' Objective Caml is the most popular variant of the Caml language.
  45          From a language standpoint, it extends the core Caml language with a
  46          fully-fledged object-oriented layer, as well as a powerful module
  47          system, all connected by a sound, polymorphic type system featuring
  48          type inference.
  49
  50          The Objective Caml system is an industrial-strength implementation
  51          of this language, featuring a high-performance native-code compiler
  52          (ocamlopt) for 9 processor architectures (IA32, PowerPC, AMD64,
  53          Alpha, Sparc, Mips, IA64, HPPA, StrongArm), as well as a bytecode
  54          compiler (ocamlc) and an interactive read-eval-print loop (ocaml)
  55          for quick development and portability.  The Objective Caml
  56          distribution includes a comprehensive standard library, a replay
  57          debugger (ocamldebug), lexer (ocamllex) and parser (ocamlyacc)
  58          generators, a pre-processor pretty-printer (camlp4) and a
  59          documentation generator (ocamldoc).
  60        '';
  61
  62     platforms = stdenv.lib.platforms.linux ++ stdenv.lib.platforms.darwin;
  63     maintainers = [
  64       stdenv.lib.maintainers.z77z
  65     ];
  66   };
  67
  68 }