configure.in

   1 dnl Process this file with autoconf 2.53 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.53)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_LN_S
  52 AC_PROG_MAKE_SET
  53 if test -f nasm.c; then
  54   # we're building in the source dir, so we don't need this check at all
  55   ac_cv_prog_make_vpathok=yes
  56 else
  57   AC_PROG_MAKE_VPATHOK
  58 fi
  59 AC_PROG_INSTALL
  60
  61 dnl If we have gcc, add appropriate options
  62 PA_ADD_CFLAGS([-W])
  63 PA_ADD_CFLAGS([-Wall])
  64 PA_ADD_CFLAGS([-std=c99])
  65 PA_ADD_CFLAGS([-pedantic])
  66
  67 dnl Look for "nroff" or "groff"
  68 AC_CHECK_PROGS(NROFF, nroff, echo)
  69 AC_SUBST(NROFF)
  70
  71 dnl Checks for header files.
  72 AC_HEADER_STDC
  73 if test $ac_cv_header_stdc = no; then
  74   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  75 fi
  76
  77 AC_CHECK_HEADERS(limits.h)
  78 if test $ac_cv_header_limits_h = no; then
  79   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
  80 fi
  81
  82 dnl Check for <inttypes.h> or add a substitute version
  83 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
  84
  85 dnl The standard header for str*casecmp is <strings.h>
  86 AC_CHECK_HEADERS(strings.h)
  87
  88 dnl Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_CONST
  90 AC_TYPE_SIZE_T
  91
  92 dnl Checks for library functions.
  93 AC_SUBST(XOBJS)
  94
  95 AC_CHECK_FUNCS(strcspn, ,
  96   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
  97
  98 AC_CHECK_FUNCS(strspn, ,
  99   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 100
 101 missing=true
 102 AC_CHECK_FUNCS([vsnprintf _vsnprintf], missing=false)
 103 if $missing; then
 104    XOBJS="$XOBJS lib/vsnprintf.o"
 105 fi
 106
 107 missing=true
 108 AC_CHECK_FUNCS([snprintf _snprintf], missing=false)
 109 if $missing; then
 110    XOBJS="$XOBJS lib/snprintf.o"
 111 fi
 112
 113 AC_CHECK_FUNCS(strcasecmp stricmp)
 114 AC_CHECK_FUNCS(strncasecmp strnicmp)
 115 AC_CHECK_FUNCS(strsep)
 116
 117 AC_CHECK_FUNCS(getuid)
 118 AC_CHECK_FUNCS(getgid)
 119
 120 if test $ac_cv_prog_make_vpathok = no; then
 121   echo Copying generated srcs into build directory to compensate for VPATH breakage
 122   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 123     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 124   done
 125 fi
 126
 127 AC_OUTPUT_COMMANDS([mkdir -p output])
 128 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)