dev-util/insight/insight-6.8.ebuild

   1 # Copyright 1999-2008 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: /var/cvsroot/gentoo-x86/dev-util/insight/insight-6.8.ebuild,v 1.1 2008/07/12 12:21:10 tester Exp $
   4
   5 inherit eutils flag-o-matic
   6
   7 export CTARGET=${CTARGET:-${CHOST}}
   8 if [[ ${CTARGET} == ${CHOST} ]] ; then
   9         if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
  10                 export CTARGET=${CATEGORY/cross-}
  11         fi
  12 fi
  13
  14 DESCRIPTION="A graphical interface to the GNU debugger"
  15 HOMEPAGE="http://sourceware.org/insight/"
  16 SRC_URI="ftp://sources.redhat.com/pub/${PN}/releases/${P}-1.tar.bz2"
  17
  18 LICENSE="GPL-2 LGPL-2"
  19 [[ ${CTARGET} != ${CHOST} ]] \
  20         && SLOT="${CTARGET}" \
  21         || SLOT="0"
  22 KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
  23 IUSE="nls"
  24
  25 RDEPEND="sys-libs/ncurses
  26         x11-libs/libX11"
  27 DEPEND="${RDEPEND}
  28         nls? ( sys-devel/gettext )"
  29
  30 S="${WORKDIR}/${P}-1"
  31
  32 src_unpack() {
  33         unpack ${A}
  34         cd "${S}"
  35         epatch "${FILESDIR}"/${PN}-6.6-DESTDIR.patch
  36         epatch "${FILESDIR}"/${PN}-6.6-burn-paths.patch
  37
  38         cd "${S}/tk"
  39         epatch "${FILESDIR}"/tkImgGIF.patch
  40 }
  41
  42 src_compile() {
  43         append-flags -fno-strict-aliasing # tcl code sucks
  44         strip-linguas -u bfd/po opcodes/po
  45         econf \
  46                 --disable-werror \
  47                 $(use_enable nls) \
  48                 --enable-gdbtk \
  49                 --disable-tui \
  50                 --datadir=/usr/share/${PN} \
  51                 || die
  52         emake || die
  53 }
  54
  55 src_install() {
  56         # the tcl-related subdirs are not parallel safe
  57         emake -j1 DESTDIR="${D}" install || die
  58
  59         # Don't install docs when building a cross-insight
  60         if [[ ${CTARGET} == ${CHOST} ]] ; then
  61                 dodoc gdb/gdbtk/{README,TODO}
  62         fi
  63
  64         # the gui tcl code does not consider any of the configure
  65         # options given it ... instead, it requires the path to
  66         # be /usr/share/redhat/...
  67         mv "${D}"/usr/share/${PN}/redhat "${D}"/usr/share/ || die
  68
  69         # scrub all the cruft we dont want
  70         local x
  71         cd "${D}"/usr/bin
  72         for x in * ; do
  73                 [[ ${x} != *insight ]] && rm -f ${x}
  74         done
  75         cd "${D}"
  76         rm -rf usr/{include,man,share/{info,locale,man}}
  77         rm -rf usr/lib*
  78 }