configure.ac

   1 dnl Process with autoconf to generate configure script   -*- sh -*-
   2
   3 AC_INIT(LyX,1.6.1,[lyx-devel@lists.lyx.org],[lyx])
   4 AC_SUBST(LYX_DATE, ["Sat, Dec 13, 2008"])
   5 AC_PREREQ(2.52)
   6 AC_CONFIG_SRCDIR(src/main.cpp)
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 AC_CONFIG_AUX_DIR(config)
  10
  11 # First check the version
  12 LYX_CHECK_VERSION
  13 LYX_VERSION_SUFFIX
  14 # Check how the files should be packaged
  15 AC_CANONICAL_TARGET
  16 LYX_USE_PACKAGING
  17 # We need to define these variables here and the no-define option of
  18 # AM_INIT_AUTOMAKE above because we alter $PACKAGE in LYX_USE_PACKAGING.
  19 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  20
  21 dnl default maintainer mode to true for development versions
  22 if test "${enable_maintainer_mode+set}" != set; then
  23   enable_maintainer_mode=$lyx_devel_version
  24 fi
  25 AM_MAINTAINER_MODE
  26
  27 save_PACKAGE=$PACKAGE
  28 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-define 1.5])
  29 PACKAGE=$save_PACKAGE
  30
  31 ### Set the execute permissions of the various scripts correctly
  32 for file in config/install-sh config/mkinstalldirs ; do
  33   chmod 755 ${srcdir}/${file}
  34 done
  35
  36 ### Check for programs
  37 dnl AC_PROG_MAKE_SET
  38 dnl AC_PROG_INSTALL
  39
  40 # Check for installed python
  41 AM_PATH_PYTHON(2.3.4,, :)
  42
  43 # Work around a problem in automake 1.4: when invoking install-strip,
  44 # INSTALL_PROGRAM is changed to 'install -s', and since
  45 # INSTALL_SCRIPT==INSTALL_PROGRAM, we get errors with fileutils-4.0
  46 # which returns an error condition when stripping fails.
  47 INSTALL_SCRIPT='${INSTALL}'
  48
  49 ### we will also need a C compiler to compile GNU gettext
  50 AC_PROG_CC
  51 AC_USE_SYSTEM_EXTENSIONS
  52
  53 ### we need to know the byte order for unicode conversions
  54 AC_C_BIGENDIAN
  55
  56 ### check which frontend we want to use
  57 LYX_USE_FRONTENDS
  58
  59 ### Check for a C++ compiler
  60 LYX_PROG_CXX
  61 ### Some checks on what the C++ compiler can(not) do
  62 AC_LANG(C++)
  63 dnl we do not need that currently (and probably all our supported
  64 dnl compiler allow that)
  65 dnl LYX_CXX_PARTIAL
  66 dnl LYX_CXX_EXPLICIT
  67 dnl LYX_CXX_GLOBAL_CSTD
  68 dnl LYX_STD_COUNT
  69 dnl we disable rtti for now
  70 dnl LYX_CXX_RTTI
  71 dnl AC_CHECK_HEADERS(ostream istream sstream locale limits ios)
  72 dnl LYX_CXX_STL_MODERN_STREAMS
  73
  74 ### Objective-C compiler
  75 AC_PROG_OBJC
  76 _AM_DEPENDENCIES([OBJC])
  77
  78 ### and now some special lyx flags.
  79 AC_ARG_ENABLE(assertions,
  80   AC_HELP_STRING([--enable-assertions],[add runtime sanity checks in the program]),,
  81   [if test $lyx_devel_version = yes -o $lyx_prerelease = yes ; then
  82         enable_assertions=yes;
  83     else
  84         enable_assertions=no;
  85     fi;])
  86 if test "x$enable_assertions" = xyes ; then
  87    lyx_flags="assertions $lyx_flags"
  88    AC_DEFINE(ENABLE_ASSERTIONS,1,
  89     [Define if you want assertions to be enabled in the code])
  90 fi
  91
  92 ### Library Files
  93 dnl AC_CHECK_LIB(m, sin)
  94
  95 ### Add extra directories to check for libraries.
  96 LYX_WITH_DIR([extra-lib],[extra library directory],extra_lib, NONE)
  97 LYX_LOOP_DIR($lyx_cv_extra_lib,LYX_ADD_LIB_DIR(lyx_ldflags,$dir))
  98 test ! x"$lyx_ldflags" = x && LDFLAGS="$lyx_ldflags $LDFLAGS"
  99
 100 ### Add extra directories to check for include files.
 101 LYX_WITH_DIR([extra-inc],[extra include directory],extra_inc, NONE)
 102 LYX_LOOP_DIR($lyx_cv_extra_inc,LYX_ADD_INC_DIR(lyx_cppflags,$dir))
 103 test ! x"$lyx_cppflags" = x && CPPFLAGS="$lyx_cppflags $CPPFLAGS"
 104
 105 ### Add both includes and libraries
 106 LYX_WITH_DIR([extra-prefix],[extra lib+include directory],extra_prefix, NONE, ${prefix})
 107 LYX_LOOP_DIR($lyx_cv_extra_prefix,[
 108 LYX_ADD_INC_DIR(CPPFLAGS,$dir/include)
 109   LYX_ADD_LIB_DIR(LDFLAGS,$dir/lib)])
 110
 111 ### These are needed in windows
 112 AC_CHECK_LIB(shlwapi, main, [LIBSHLWAPI=-lshlwapi])
 113 AC_SUBST(LIBSHLWAPI)
 114 AC_CHECK_LIB(gdi32, main)
 115
 116 AC_ARG_WITH(aiksaurus,
 117   [  --without-aiksaurus     do not use the Aiksaurus library],
 118   [lyx_use_aiksaurus=$withval])
 119 if test x$lyx_use_aiksaurus != xno; then
 120 AC_CHECK_LIB(Aiksaurus, main,
 121         [AC_DEFINE(HAVE_LIBAIKSAURUS,1,[Define this if you have the AikSaurus library])
 122          AIKSAURUS_LIBS="-lAiksaurus"
 123          lyx_flags="aiksaurus $lyx_flags"
 124         ])
 125 AC_CHECK_HEADER(Aiksaurus.h,[
 126   ac_cv_header_aiksaurus_h=yes
 127   lyx_cv_aiksaurus_h_location="<Aiksaurus.h>"])
 128 AC_CHECK_HEADER(Aiksaurus/Aiksaurus.h,[
 129   ac_cv_header_aiksaurus_h=yes
 130   lyx_cv_aiksaurus_h_location="<Aiksaurus/Aiksaurus.h>"])
 131 AC_DEFINE_UNQUOTED(AIKSAURUS_H_LOCATION,$lyx_cv_aiksaurus_h_location,[Location of Aiksaurus.h])
 132 fi
 133 AC_SUBST(AIKSAURUS_LIBS)
 134
 135 LYX_USE_INCLUDED_BOOST
 136
 137 # Needed for our char_type
 138 AC_CHECK_SIZEOF(wchar_t)
 139
 140 ### Setup libtool
 141 dnl Dirty trick ahead: disable libtool checking for a fortran compiler
 142 dnl see http://permalink.gmane.org/gmane.comp.gnu.libtool.general/6699
 143 dnl Note that this will reportedly not be needed with libtool 2.0
 144 m4_undefine([AC_PROG_F77])
 145 m4_defun([AC_PROG_F77],[])
 146
 147 AC_DISABLE_SHARED
 148 #AC_DISABLE_STATIC
 149 AC_LIBTOOL_WIN32_DLL
 150 #AM_PROG_LIBTOOL
 151 LYX_PROG_LIBTOOL
 152
 153 ### We need iconv for unicode support (Qt4 frontend requires it too)
 154 AM_ICONV
 155 if test "$am_cv_func_iconv" = no; then
 156   LYX_ERROR([Cannot find required library iconv])
 157 else
 158   LIBS="$LIBS $LIBICONV"
 159 fi
 160
 161 ### check for compression support
 162 AC_CHECK_HEADERS(zlib.h,
 163  [AC_CHECK_LIB(z, gzopen, [LIBS="$LIBS -lz"], LYX_LIB_ERROR(libz,zlib))],
 164  [LYX_LIB_ERROR(zlib.h,zlib)])
 165
 166
 167 ### check which frontend we want to use
 168
 169 dnl The code below is not in a macro, because this would cause big
 170 dnl problems with the AC_REQUIRE contained in QT_DO_IT_ALL.
 171 for frontend in $FRONTENDS ; do
 172   case "$frontend" in
 173     qt4)
 174           QT4_DO_IT_ALL
 175           FRONTENDS_PROGS="$FRONTENDS_PROGS lyx-qt4\$(EXEEXT)"
 176           FRONTENDS_SUBDIRS="$FRONTENDS_SUBDIRS qt4"
 177           RPM_FRONTEND="qt4"
 178           FRONTEND_INFO="${FRONTEND_INFO}\
 179   Qt 4 Frontend:\n\
 180       Qt 4 version:\t\t${QT4_VERSION}\n"
 181 dnl qt 4 build will fail without moc or uic
 182           if test -z "$MOC4"; then
 183             LYX_ERROR([moc 4 binary not found !])
 184           fi
 185           if test -z "$UIC4"; then
 186             LYX_ERROR([uic 4 binary not found !])
 187           fi
 188           if test -z "$QT4_LIB"; then
 189             LYX_ERROR([qt 4 library not found !])
 190           fi
 191       ;;
 192     *)
 193           LYX_ERROR(Unknown frontend '$frontend');;
 194   esac
 195 done
 196
 197 # fix the value of the prefixes.
 198 test "x$prefix" = xNONE && prefix=$default_prefix
 199 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 200 if echo $prefix |grep ' ' >/dev/null 2>/dev/null ; then
 201   LYX_WARNING([The installation prefix \"${prefix}\" contains a space, which
 202    causes problems with the Makefiles. The installation will be done in
 203    directory \"`pwd`/installprefix\" instead. Please move its contents to
 204    the right place after installation.])
 205   prefix=`pwd`/installprefix
 206 fi
 207
 208 ### Setup GNU gettext
 209 dnl GNU gettext is written in C
 210 AC_LANG_PUSH(C)
 211 dnl Dirty trick ahead: disable macro AC_GNU_SOURCE because it triggers a bug with autoconf 2.62.
 212 dnl this can be removed if gettext is been updated to avoid that.
 213 m4_undefine([AC_GNU_SOURCE])
 214 m4_defun([AC_GNU_SOURCE],[])
 215 AM_GNU_GETTEXT
 216 AM_GNU_GETTEXT_VERSION([0.16.1])
 217 AC_LANG_POP(C)
 218
 219 # some standard header files
 220 AC_HEADER_DIRENT
 221 AC_HEADER_MAJOR
 222 AC_CHECK_HEADERS(sys/time.h sys/types.h sys/select.h strings.h locale.h io.h process.h NewAPIs.h utime.h sys/utime.h)
 223
 224 # some standard structures
 225 AC_HEADER_STAT
 226 AC_HEADER_TIME
 227
 228 # some standard types
 229 AC_CHECK_TYPE(mode_t,[AC_DEFINE(HAVE_MODE_T, 1, [Define this to 1 if your compiler supports the mode_t type.])])
 230 AC_TYPE_OFF_T
 231 AC_TYPE_PID_T
 232 AC_TYPE_SIGNAL
 233 AC_TYPE_SIZE_T
 234 AC_TYPE_UID_T
 235
 236 AC_CHECK_FUNCS(strerror)
 237 LYX_CHECK_DECL(istreambuf_iterator, iterator)
 238 LYX_CHECK_DECL(mkstemp,[unistd.h stdlib.h])
 239
 240 # Check the form of mkdir()
 241 AC_FUNC_MKDIR
 242
 243 dnl This is a slight hack: the tests generated by autoconf 2.52 do not
 244 dnl work correctly because of some conflict with stdlib.h with g++ 2.96
 245 dnl We aim to remove this eventually, since we should test as much as
 246 dnl possible with the compiler which will use the functions (JMarc)
 247 AC_LANG_PUSH(C)
 248 AC_CHECK_FUNCS(chmod close _close getpid _getpid lstat mkfifo mkstemp mktemp open _open pclose _pclose popen _popen readlink)
 249 AC_LANG_POP(C)
 250
 251 LYX_CHECK_SPELL_ENGINES
 252
 253 lyx_client_subdir=true
 254 AC_LANG_PUSH(C)
 255 dnl LIBS already contains some X extra libs that may interfere.
 256 save_LIBS="$LIBS"
 257 LIBS=
 258 AC_CHECK_FUNCS(fcntl,
 259   [AC_SEARCH_LIBS([gethostbyname], [nsl])
 260    AC_SEARCH_LIBS([socket], [socket], [],
 261      [AC_CHECK_LIB([socket], [socket], [LIBS="-lsocket -lnsl $LIBS"],
 262                 [], [-lnsl])])],
 263   [lyx_client_subdir=false])
 264 AC_SUBST(SOCKET_LIBS,$LIBS)
 265 LIBS="$save_LIBS"
 266 AM_CONDITIONAL(BUILD_CLIENT_SUBDIR, $lyx_client_subdir)
 267 AC_LANG_POP(C)
 268
 269 lyx_win_res=false;
 270 case ${host} in
 271     *mingw*|*cygwin*) lyx_win_res=true;;
 272 esac
 273 AM_CONDITIONAL(LYX_WIN_RESOURCE, $lyx_win_res)
 274 LYX_SET_VERSION_INFO
 275
 276 AC_FUNC_SELECT_ARGTYPES
 277
 278 ### Some information on what just happened
 279 real_bindir=`eval "echo \`eval \"echo ${bindir}\"\`"`
 280 real_pkgdatadir=`eval "echo \`eval \"echo \\\`eval \\\"echo ${pkgdatadir}\\\"\\\`\"\`"`
 281 real_localedir=`eval "echo \`eval \"echo ${datadir}/locale\"\`"`
 282 VERSION_INFO="Configuration\n\
 283   Host type:                    ${host}\n\
 284   Special build flags:          ${lyx_flags}\n\
 285   C   Compiler:                 ${CC} ${CC_VERSION}\n\
 286   C   Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CFLAGS}\n\
 287   C   Compiler flags:           ${CPPFLAGS} ${CFLAGS}\n\
 288   C++ Compiler:                 ${CXX} ${CXX_VERSION}\n\
 289   C++ Compiler LyX flags:       ${AM_CPPFLAGS} ${AM_CXXFLAGS}\n\
 290   C++ Compiler flags:           ${CPPFLAGS} ${CXXFLAGS}\n\
 291   Linker flags:                 ${AM_LDFLAGS}\n\
 292   Linker user flags:            ${LDFLAGS}\n\
 293 ${FRONTEND_INFO}\
 294   Packaging:                    ${lyx_use_packaging}\n\
 295   LyX binary dir:               ${real_bindir}\n\
 296   LyX files dir:                ${real_pkgdatadir}\n"
 297
 298 AC_SUBST(VERSION_INFO)
 299 AC_SUBST(RPM_FRONTEND)
 300 AC_SUBST(AM_CPPFLAGS)
 301 AC_SUBST(AM_CXXFLAGS)
 302 AC_SUBST(AM_CFLAGS)
 303 AC_SUBST(AM_LDFLAGS)
 304 AC_SUBST(real_pkgdatadir)
 305
 306 ## Some config.h stuff
 307
 308 AH_TOP([
 309 /* -*- C++ -*- */
 310 /*
 311  * \file config.h
 312  * This file is part of LyX, the document processor.
 313  * Licence details can be found in the file COPYING.
 314  *
 315  * This is the compilation configuration file for LyX.
 316  * It was generated by autoconfs configure.
 317  * You might want to change some of the defaults if something goes wrong
 318  * during the compilation.
 319  */
 320
 321 #ifndef _CONFIG_H
 322 #define _CONFIG_H
 323 ])
 324
 325 AH_BOTTOM([
 326 /************************************************************
 327  ** You should not need to change anything beyond this point */
 328
 329 #ifndef HAVE_STRERROR
 330 #if defined(__cplusplus)
 331 extern "C"
 332 #endif
 333 char * strerror(int n);
 334 #endif
 335
 336 #if defined(HAVE_OSTREAM) && defined(HAVE_LOCALE) && defined(HAVE_SSTREAM)
 337 #  define USE_BOOST_FORMAT 1
 338 #else
 339 #  define USE_BOOST_FORMAT 0
 340 #endif
 341
 342 #define BOOST_USER_CONFIG <config.h>
 343
 344 #if !defined(ENABLE_ASSERTIONS)
 345 #  define BOOST_DISABLE_ASSERTS 1
 346 #endif
 347 #define BOOST_ENABLE_ASSERT_HANDLER 1
 348
 349 #define BOOST_DISABLE_THREADS 1
 350 #define BOOST_NO_WREGEX 1
 351 #define BOOST_NO_WSTRING 1
 352
 353 #ifdef __CYGWIN__
 354 #  define BOOST_POSIX 1
 355 #  define BOOST_POSIX_API 1
 356 #  define BOOST_POSIX_PATH 1
 357 #endif
 358
 359 #if defined(HAVE_NEWAPIS_H)
 360 #  define WANT_GETFILEATTRIBUTESEX_WRAPPER 1
 361 #endif
 362
 363 /*
 364  * the FreeBSD libc uses UCS4, but libstdc++ has no proper wchar_t
 365  * support compiled in:
 366  * http://gcc.gnu.org/onlinedocs/libstdc++/faq/index.html#3_9
 367  * And we are not interested at all what libc
 368  * does: What we need is a 32bit wide wchar_t, and a libstdc++ that
 369  * has the needed wchar_t support and uses UCS4. Whether it
 370  * implements this with the help of libc, or whether it has own code
 371  * does not matter for us, because we do not use libc directly (Georg)
 372 */
 373 #if defined(HAVE_WCHAR_T) && SIZEOF_WCHAR_T == 4 && !defined(__FreeBSD__) && !defined(__FreeBSD_kernel__)
 374 #  define USE_WCHAR_T
 375 #endif
 376
 377 #endif
 378 ])
 379
 380
 381 AC_ARG_ENABLE(monolithic-boost,
 382   AC_HELP_STRING([--enable-monolithic-boost],
 383                 [Use monolithic boost compilations]),,
 384   [enable_monolithic_boost=no])
 385 AM_CONDITIONAL(MONOLITHIC_BOOST, test "$enable_monolithic_boost" = "yes")
 386
 387 AC_ARG_ENABLE(monolithic-client,
 388   AC_HELP_STRING([--enable-monolithic-client],
 389                 [Use monolithic client compilations]),,
 390   [enable_monolithic_client=no])
 391 AM_CONDITIONAL(MONOLITHIC_CLIENT, test "$enable_monolithic_client" = "yes")
 392
 393 AC_ARG_ENABLE(monolithic-insets,
 394   AC_HELP_STRING([--enable-monolithic-insets],
 395                 [Use monolithic insets compilations]),,
 396   [enable_monolithic_insets=no])
 397 AM_CONDITIONAL(MONOLITHIC_INSETS, test "$enable_monolithic_insets" = "yes")
 398
 399 AC_ARG_ENABLE(monolithic-mathed,
 400   AC_HELP_STRING([--enable-monolithic-mathed],
 401                 [Use monolithic mathed compilations]),,
 402   [enable_monolithic_mathed=no])
 403 AM_CONDITIONAL(MONOLITHIC_MATHED, test "$enable_monolithic_mathed" = "yes")
 404
 405 AC_ARG_ENABLE(monolithic-core,
 406   AC_HELP_STRING([--enable-monolithic-core],
 407                 [Use monolithic core files compilations]),,
 408   [enable_monolithic_core=no])
 409 AM_CONDITIONAL(MONOLITHIC_CORE, test "$enable_monolithic_core" = "yes")
 410
 411 AC_ARG_ENABLE(monolithic-tex2lyx,
 412   AC_HELP_STRING([--enable-monolithic-tex2lyx],
 413                 [Use monolithic tex2lyx compilations]),,
 414   [enable_monolithic_tex2lyx=no])
 415 AM_CONDITIONAL(MONOLITHIC_TEX2LYX, test "$enable_monolithic_tex2lyx" = "yes")
 416
 417 AC_ARG_ENABLE(monolithic-frontend-qt4,
 418   AC_HELP_STRING([--enable-monolithic-frontend-qt4],
 419                 [Use monolithic compilation of the Qt 4 frontend. Only recommended with > 512 MB of RAM]),,
 420   [enable_monolithic_frontend_qt4=no])
 421 AM_CONDITIONAL(MONOLITHIC_FRONTEND_QT4, test "$enable_monolithic_frontend_qt4" = "yes")
 422
 423 MSYS_AC_CANONICAL_PATH(lyx_abs_top_srcdir, ${srcdir})
 424 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_localedir, ${real_localedir})
 425 MSYS_AC_CANONICAL_PATH(lyx_abs_installed_datadir, ${real_pkgdatadir})
 426
 427 AC_DEFINE_UNQUOTED([LYX_ABS_TOP_SRCDIR],
 428         "${lyx_abs_top_srcdir}", [Top source directory])
 429 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_LOCALEDIR],
 430         "${lyx_abs_installed_localedir}",[Hard coded locale directory])
 431 AC_DEFINE_UNQUOTED([LYX_ABS_INSTALLED_DATADIR],
 432         "${lyx_abs_installed_datadir}",[Hard system support directory])
 433 AC_DEFINE_UNQUOTED([PROGRAM_SUFFIX],
 434         "${version_suffix}",[Program version suffix])
 435
 436 AC_DEFINE_UNQUOTED([LYX_DATE],"$LYX_DATE",[Date of release])
 437 AC_DEFINE_UNQUOTED([VERSION_INFO],"$VERSION_INFO",[Full version info])
 438 AC_DEFINE_UNQUOTED([LYX_DIR_VER],"$lyx_dir_ver",[Versioned env var for system dir])
 439 AC_DEFINE_UNQUOTED([LYX_USERDIR_VER],"$lyx_userdir_ver",[Versioned env var for user dir])
 440 AC_DEFINE_UNQUOTED([LYX_MAJOR_VERSION],$lyx_major,[Major version number])
 441 AC_DEFINE_UNQUOTED([LYX_MINOR_VERSION],$lyx_minor,[Minor version number])
 442 AC_DEFINE_UNQUOTED([LYX_RELEASE_LEVEL],$lyx_release,[Release version number])
 443 AC_DEFINE_UNQUOTED([LYX_RELEASE_PATCH],$lyx_patch,[Patch version number])
 444
 445 AC_CONFIG_FILES([Makefile \
 446       lyx.1:lyx.1in \
 447       boost/Makefile \
 448       config/Makefile \
 449       development/Makefile \
 450       development/MacOSX/Makefile \
 451       development/MacOSX/Info.plist \
 452       development/MacOSX/lyxrc.dist \
 453       development/MacOSX/spotlight/Makefile \
 454       development/lyx.spec \
 455       intl/Makefile \
 456       lib/Makefile \
 457       lib/doc/Makefile \
 458       lib/lyx2lyx/lyx2lyx_version.py \
 459       lib/lyx2lyx/Makefile \
 460       m4/Makefile \
 461       po/Makefile.in \
 462       sourcedoc/Doxyfile \
 463       sourcedoc/Makefile \
 464       src/client/Makefile \
 465       src/Makefile \
 466       src/tex2lyx/Makefile \
 467       src/support/Makefile \
 468       src/frontends/Makefile \
 469       src/frontends/qt4/Makefile
 470 ])
 471
 472
 473 AC_OUTPUT
 474
 475 # show version information
 476 echo
 477 printf "$VERSION_INFO"
 478 echo
 479
 480 # Display a final warning if there has been a LYX_ERROR
 481 LYX_CHECK_ERRORS