configure.in

   1 dnl configure.in   -*-shell-script-*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.60)
   5
   6 # Bootstrap the init proces.
   7 AC_INIT
   8
   9 # Bootstrap StepMake configure
  10 # For user package:
  11 AC_CONFIG_AUX_DIR([stepmake/bin])
  12
  13 # For stepmake package:
  14 # AC_CONFIG_AUX_DIR(bin)
  15
  16
  17 STEPMAKE_INIT
  18
  19 # List a file that identifies your package.
  20 AC_CONFIG_SRCDIR([lily/main.cc])
  21
  22 # Move to aclocal.m4?
  23 AC_CONFIG_HEADERS([$CONFIGFILE.hh:config.hh.in])
  24
  25 # Uncomment the configuration options your package needs.
  26
  27 DOCUMENTATION=yes
  28 AC_ARG_ENABLE(documentation,
  29     [AS_HELP_STRING([--enable-documentation],
  30                     [build Documentation.  Default: on])],
  31     [DOCUMENTATION=$enableval])
  32 AC_SUBST(DOCUMENTATION)
  33
  34 AC_ARG_WITH(ncsb-dir,
  35     [AS_HELP_STRING([--with-ncsb-dir=DIR],
  36                     [location of Century Schoolbook fonts.])],
  37     [NCSB_DIR=$withval],
  38     [NCSB_DIR=""])
  39
  40 reloc_b=no
  41 AC_ARG_ENABLE(relocation,
  42     [AS_HELP_STRING([--enable-relocation],
  43                     [compile with dynamic relocation.  Default: off])],
  44     [reloc_b=$enableval])
  45
  46 rpath_b=no
  47 AC_ARG_ENABLE(rpath,
  48     [AS_HELP_STRING([--enable-rpath],
  49                     [hardcode runtime library path.  Default: off])],
  50     [rpath_b=$enableval])
  51
  52 LINK_GXX_STATICALLY=no
  53 AC_ARG_ENABLE(static-gxx,
  54     [AS_HELP_STRING([--enable-static-gxx],
  55                     [link libstdc++.a statically.  Default: off])],
  56     [LINK_GXX_STATICALLY=$enableval])
  57 AC_SUBST(LINK_GXX_STATICALLY)
  58
  59 # must come before any header checks
  60 STEPMAKE_COMPILE
  61
  62 AC_CHECK_PROG(FCLIST, fc-list, fc-list)
  63 AC_MSG_CHECKING([New Century Schoolbook PFB files])
  64 AC_SUBST(NCSB_SOURCE_FILES)
  65 if test "$NCSB_DIR" != "" ;  then
  66   NCSB_SOURCE_FILES=""
  67   for f in c059013l c059016l c059033l c059036l; do
  68     if test ! -f "$NCSB_DIR/$f.pfb"; then
  69       STEPMAKE_WARN($NCSB_DIR does not contain $f.pfb.)
  70     else
  71       NCSB_SOURCE_FILES="$NCSB_DIR/$f.pfb $NCSB_SOURCE_FILES"
  72     fi
  73   done
  74 else
  75   if test "$FCLIST" != ""; then
  76     for style in Roman Italic "Bold Italic" Bold; do
  77       NCSB_FILE=`$FCLIST "Century Schoolbook L:style=$style:foundry=urw:fontformat=Type 1" file \
  78                 | head -n 1`
  79       NCSB_FILE=`echo $NCSB_FILE | sed 's/^\(.*\):$/\1/g'`
  80       NCSB_FILE=`$PYTHON "$srcdir/scripts/auxiliar/readlink.py" $NCSB_FILE`
  81       NCSB_SOURCE_FILES="$NCSB_FILE $NCSB_SOURCE_FILES"
  82     done
  83   else
  84     AC_MSG_RESULT(not found)
  85     echo "Can't find Century Schoolbook files. Install FontConfig's fc-list,"
  86     echo "or use --with-ncsb-dir"
  87   fi
  88 fi
  89 AC_MSG_RESULT($NCSB_SOURCE_FILES)
  90
  91 AC_LANG([C++])
  92
  93 STEPMAKE_PYTHON(REQUIRED, 2.4)
  94 STEPMAKE_GCC(REQUIRED, 3.4)
  95
  96 STEPMAKE_CXX(REQUIRED)
  97 STEPMAKE_GXX(REQUIRED, 3.4)
  98 STEPMAKE_CXXTEMPLATE
  99 STEPMAKE_STL_DATA_METHOD
 100 STEPMAKE_LIB(REQUIRED)
 101 STEPMAKE_DLOPEN
 102 # Do not use bison 1.50 and 1.75.
 103 # 1.29 is required fr %locations, but I'm not sure it's enough --ns
 104 STEPMAKE_BISON(OPTIONAL, 1.29)
 105 STEPMAKE_FLEX(REQUIRED)
 106 STEPMAKE_FLEXLEXER(REQUIRED)
 107 STEPMAKE_FLEXLEXER_LOCATION
 108 STEPMAKE_LOCALE
 109 STEPMAKE_GETTEXT
 110 STEPMAKE_MSGFMT(REQUIRED)
 111 STEPMAKE_TEXMF(REQUIRED)
 112 STEPMAKE_TEXMF_DIRS
 113 STEPMAKE_GUILE_DEVEL(REQUIRED, 1.8.2)
 114
 115 # check for 2 typedefs added in Guile 1.9
 116 save_CXXFLAGS="$CXXFLAGS"
 117 CXXFLAGS="$GUILE_CFLAGS $CXXFLAGS"
 118 AC_CHECK_TYPES([scm_t_hash_fold_fn, scm_t_hash_handle_fn],
 119                [AC_DEFINE(HAVE_GUILE_HASH_FUNC)], [],
 120                [#include <libguile.h>])
 121 CXXFLAGS="$save_CXXFLAGS"
 122
 123 ## check rational bugfix.
 124 save_CPPFLAGS="$CPPFLAGS"
 125 CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 126 AC_MSG_CHECKING(GUILE rational bugfix)
 127 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <libguile.h>
 128 #ifdef SCM_FRACTION_REDUCED_BIT
 129 #error
 130 #endif
 131 ]])],[AC_MSG_RESULT(ok)],[REQUIRED="$REQUIRED GUILE-with-rational-bugfix"
 132 AC_MSG_RESULT(Must have patched GUILE rational support. See INSTALL.txt)])
 133 CPPFLAGS="$save_CPPFLAGS"
 134
 135
 136 STEPMAKE_PYTHON_DEVEL(REQUIRED)
 137
 138 STEPMAKE_PATH_PROG(GHOSTSCRIPT, gs, OPTIONAL, 8.60)
 139
 140 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, REQUIRED, 20050624)
 141 # For svg woff fonts to work, version 20100501 is required but
 142 # the build does not break; leave optional until distros ship it.
 143 STEPMAKE_PATH_PROG(FONTFORGE, fontforge, OPTIONAL, 20100501)
 144
 145 STEPMAKE_PATH_PROG(T1ASM, t1asm, REQUIRED)
 146
 147 AC_CHECK_HEADERS([assert.h grp.h libio.h pwd.h sys/stat.h wchar.h fpu_control.h])
 148 AC_CHECK_HEADERS([sstream])
 149 AC_HEADER_STAT
 150 AC_FUNC_MEMCMP
 151 AC_FUNC_VPRINTF
 152 AC_CHECK_FUNCS([chroot fopencookie gettext isinf memmem snprintf vsnprintf])
 153
 154 STEPMAKE_PROGS(PKG_CONFIG, pkg-config, REQUIRED, 0.9.0)
 155
 156 AC_MSG_CHECKING(whether to enable dynamic relocation)
 157 if test "$reloc_b" = "yes"; then
 158     AC_DEFINE(ARGV0_RELOCATION)
 159 fi
 160 AC_MSG_RESULT($reloc_b)
 161
 162 AC_MSG_CHECKING(for rpath linkage)
 163 if test "$rpath_b" = "yes"; then
 164     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,\\\$\$ORIGIN/../lib"
 165 elif test "$rpath_b" != "no"; then
 166     LDFLAGS="$LDFLAGS -Wl,-rpath -Wl,$rpath_b"
 167 fi
 168 AC_MSG_RESULT($rpath_b)
 169
 170 HOST_ARCH=`$CC -dumpmachine`
 171 AC_SUBST(HOST_ARCH)
 172
 173 STEPMAKE_PANGO_FT2(pangoft2, REQUIRED, 1.6.0)
 174 STEPMAKE_FONTCONFIG(fontconfig, REQUIRED, 2.4.0)
 175 STEPMAKE_FREETYPE2(freetype2, REQUIRED, 2.1.10)
 176
 177 STEPMAKE_WINDOWS
 178
 179 ## Optional tools for building documentation, website, extra fonts.
 180
 181 # guile executable for some scripts
 182 STEPMAKE_GUILE(OPTIONAL)
 183
 184 # perl for help2man.
 185 STEPMAKE_PERL(OPTIONAL)
 186
 187 STEPMAKE_PROGS(MAKEINFO, makeinfo, REQUIRED, 4.11)
 188 STEPMAKE_PROGS(TEXI2HTML, texi2html, OPTIONAL, 1.82)
 189 STEPMAKE_PROGS(DBLATEX, dblatex, OPTIONAL)
 190 STEPMAKE_PROGS(PDFLATEX, pdflatex, OPTIONAL)
 191
 192 AC_DEFINE_UNQUOTED(FLOWER_VERSION, "${FULL_FLOWER_VERSION}")
 193
 194 # must also have local.make if configure fails.
 195 touch local.make
 196
 197 if test "$reloc_b$rpath_b" = "yesno"; then
 198     STEPMAKE_WARN([Using --enable-relocation without --enable-rpath.  LilyPond may have trouble finding libraries.])
 199 fi
 200
 201 # Gather requirements and generate output.
 202 STEPMAKE_END
 203
 204 test -n "$CONFIGURATION" && mc=" conf=$CONFIGURATION" || mc=""
 205
 206 if make top-doc 1>/dev/null 2>&1; then
 207     rm -f INSTALL.txt && ln Documentation/topdocs/out/INSTALL.txt .
 208     rm -f README.txt && ln Documentation/topdocs/out/README.txt .
 209 fi
 210
 211 cat <<EOF
 212
 213 Type:
 214     make$mc all       to build LilyPond
 215     make$mc install   to install LilyPond
 216     make$mc help      to see all possible targets
 217
 218 Edit local.make for local Makefile overrides.
 219
 220
 221 EOF