scm/ly-syntax-constructors.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2006--2011 Erik Sandberg <mandolaerik@gmail.com>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; TODO: use separate module for syntax
  19 ;; constructors. Also create wrapper around the constructor?
  20 (defmacro define-ly-syntax (args . body)
  21   `(define-public ,args ,(cons 'begin body)))
  22
  23 ;; A ly-syntax constructor takes two extra parameters, parser and
  24 ;; location. These are mainly used for reporting errors and
  25 ;; warnings. This function is a syntactic sugar which uses the
  26 ;; location arg to set the origin of the returned music object; this
  27 ;; behaviour is usually desired
  28 (defmacro define-ly-syntax-loc (args . body)
  29   `(define-public ,args
  30      (let ((m ,(cons 'begin body)))
  31        (set! (ly:music-property m 'origin) ,(third args))
  32        m)))
  33 ;; Like define-ly-syntax-loc, but adds parser and location
  34 ;; parameters. Useful for simple constructors that don't need to
  35 ;; report errors.
  36 (defmacro define-ly-syntax-simple (args . body)
  37   `(define-public ,(cons* (car args)
  38                           'parser
  39                           'location
  40                           (cdr args))
  41      (let ((m ,(cons 'begin body)))
  42        (set! (ly:music-property m 'origin) location)
  43        m)))
  44
  45 ;; Music function: Apply function and check return value.
  46 (define-ly-syntax-loc (music-function parser loc fun args)
  47   (let ((m (apply fun (cons* parser loc args))))
  48     (if (ly:music? m)
  49         m
  50         (begin
  51           (ly:parser-error parser (_ "Music head function must return Music object") loc)
  52           (make-music 'Music)))))
  53
  54 (define-ly-syntax-simple (void-music)
  55   (make-music 'Music))
  56
  57 (define-ly-syntax-simple (sequential-music mlist)
  58   (make-sequential-music mlist))
  59
  60 (define-ly-syntax-simple (simultaneous-music mlist)
  61   (make-simultaneous-music mlist))
  62
  63 (define-ly-syntax-simple (event-chord mlist)
  64   (make-music 'EventChord
  65               'elements mlist))
  66
  67 (define-ly-syntax-simple (unrelativable-music mus)
  68   (make-music 'UnrelativableMusic
  69               'element mus))
  70
  71 (define-ly-syntax-simple (context-change type id)
  72   (make-music 'ContextChange
  73               'change-to-type type
  74               'change-to-id id))
  75
  76 (define-ly-syntax-simple (voice-separator)
  77   (make-music 'VoiceSeparator))
  78
  79 (define-ly-syntax-simple (bar-check)
  80   (make-music 'BarCheck))
  81
  82 (define-ly-syntax-simple (time-scaled-music fraction music)
  83   (make-music 'TimeScaledMusic
  84               'element (ly:music-compress music (ly:make-moment (car fraction) (cdr fraction)))
  85               'numerator (car fraction)
  86               'denominator (cdr fraction)))
  87
  88 (define-ly-syntax-simple (transpose-music pitch music)
  89   (make-music 'TransposedMusic
  90               'element (ly:music-transpose music pitch)))
  91
  92 (define-ly-syntax-simple (tempo text duration tempo)
  93   (let* ((range-tempo? (pair? tempo))
  94          (tempo-count (if range-tempo?
  95                           (round (/ (+ (car tempo) (cdr tempo)) 2))
  96                           tempo))
  97          (props (list
  98                  (make-property-set 'tempoWholesPerMinute
  99                                     (ly:moment-mul (ly:make-moment tempo-count 1)
 100                                                    (ly:duration-length duration)))
 101                  (make-property-set 'tempoUnitDuration duration)
 102                  (make-property-set 'tempoUnitCount tempo))))
 103     (set! props (cons
 104                  (if text (make-property-set 'tempoText text)
 105                      (make-property-unset 'tempoText))
 106                  props))
 107     (context-spec-music
 108      (make-sequential-music props)
 109      'Score)))
 110
 111 (define-ly-syntax-simple (tempoText text)
 112   (context-spec-music
 113    (make-sequential-music
 114     (list
 115      (make-property-unset 'tempoUnitDuration)
 116      (make-property-unset 'tempoUnitCount)
 117      (make-property-set 'tempoText text)))
 118    'Score))
 119
 120 (define-ly-syntax-simple (skip-music dur)
 121   (make-music 'SkipMusic
 122               'duration dur))
 123
 124 (define-ly-syntax-simple (repeat type num body alts)
 125   (make-repeat type num body alts))
 126
 127 (define (script-to-mmrest-text music)
 128   "Extract @code{'direction} and @code{'text} from @var{music}, and transform
 129 into a @code{MultiMeasureTextEvent}."
 130
 131   (if (memq 'script-event (ly:music-property music 'types))
 132       (let* ((location (ly:music-property music 'origin))
 133              (dir (ly:music-property music 'direction))
 134              (tags (ly:music-property music 'tags))
 135              (p (make-music 'MultiMeasureTextEvent
 136                             'origin location
 137                             'tags tags
 138                             'text (ly:music-property music 'text))))
 139         (if (ly:dir? dir)
 140             (set! (ly:music-property p 'direction) dir))
 141         p)
 142       music))
 143
 144 (define-ly-syntax (multi-measure-rest parser location duration articulations)
 145   (make-music 'MultiMeasureRestMusic
 146               'articulations (map script-to-mmrest-text articulations)
 147               'duration duration
 148               'origin location))
 149
 150 (define-ly-syntax (repetition-chord parser location previous-chord repetition-function duration articulations)
 151   (make-music 'RepeatedChord
 152               'original-chord previous-chord
 153               'element (repetition-function previous-chord location duration articulations)
 154               'origin location))
 155
 156 (define-ly-syntax-simple (context-specification type id mus ops create-new)
 157   (let* ((type-sym (if (symbol? type) type (string->symbol type)))
 158          (csm (context-spec-music mus type-sym id)))
 159     (set! (ly:music-property csm 'property-operations) ops)
 160     (if create-new (set! (ly:music-property csm 'create-new) #t))
 161     csm))
 162
 163 (define-ly-syntax (property-operation parser location once ctx music-type symbol . args)
 164   (let* ((props (case music-type
 165                   ((PropertySet) (list 'value (car args)))
 166                   ((PropertyUnset) '())
 167                   ((OverrideProperty) (list 'grob-value (car args)
 168                                             'grob-property-path (if (list? (cadr args))
 169                                                                     (cadr args)
 170                                                                     (cdr args))
 171                                             'pop-first #t))
 172                   ((RevertProperty)
 173                    (if (list? (car args))
 174                        (list 'grob-property-path (car args))
 175                        (list 'grob-property-path args)))
 176                   (else (ly:error (_ "Invalid property operation ~a") music-type))))
 177          (oprops (if once (cons* 'once once props) props))
 178          (m (apply make-music music-type
 179                    'symbol symbol
 180                    'origin location
 181                    oprops)))
 182     (make-music 'ContextSpeccedMusic
 183                 'element m
 184                 'context-type ctx
 185                 'origin location)))
 186
 187 ;; TODO: It seems that this function rarely returns anything useful.
 188 (define (get-first-context-id type mus)
 189   "Find the name of a ContextSpeccedMusic with given type"
 190   (let ((id (ly:music-property mus 'context-id)))
 191     (if (and (eq? (ly:music-property mus 'type) 'ContextSpeccedMusic)
 192              (eq? (ly:music-property mus 'context-type) type)
 193              (string? id)
 194              (not (string-null? id)))
 195         id
 196         '())))
 197
 198 (define unique-counter -1)
 199 (define (get-next-unique-voice-name)
 200   (set! unique-counter (1+ unique-counter))
 201   (call-with-output-string (lambda (p) (format p "uniqueContext~s" unique-counter))))
 202
 203 (define (lyric-combine-music sync music loc)
 204   ;; CompletizeExtenderEvent is added following the last lyric in MUSIC
 205   ;; to signal to the Extender_engraver that any pending extender should
 206   ;; be completed if the lyrics end before the associated voice.
 207   (append! (ly:music-property music 'elements)
 208            (list (make-music 'CompletizeExtenderEvent)))
 209   (make-music 'LyricCombineMusic
 210               'element music
 211               'associated-context sync
 212               'origin loc))
 213
 214 (define-ly-syntax (lyric-combine parser location voice music)
 215   (lyric-combine-music voice music location))
 216
 217 (define-ly-syntax (add-lyrics parser location music addlyrics-list)
 218   (let* ((existing-voice-name (get-first-context-id 'Voice music))
 219          (voice-name (if (string? existing-voice-name)
 220                          existing-voice-name
 221                          (get-next-unique-voice-name)))
 222          (voice (if (string? existing-voice-name)
 223                     (music)
 224                     (make-music 'ContextSpeccedMusic
 225                                 'element music
 226                                 'context-type 'Voice
 227                                 'context-id voice-name
 228                                 'origin (ly:music-property music 'origin))))
 229          (lyricstos (map (lambda (mus)
 230                            (let* ((loc (ly:music-property mus 'origin))
 231                                   (lyr (lyric-combine-music voice-name mus loc)))
 232                              (make-music 'ContextSpeccedMusic
 233                                          'create-new #t
 234                                          'context-type 'Lyrics
 235                                          'element lyr
 236                                          'origin loc)))
 237                          addlyrics-list)))
 238     (make-simultaneous-music (cons voice lyricstos))))
 239
 240 (define-ly-syntax (make-mark-set parser location label)
 241   "Make the music for the \\mark command."
 242   (let* ((set (and (integer? label)
 243                    (context-spec-music (make-property-set 'rehearsalMark label)
 244                                       'Score)))
 245          (ev (make-music 'MarkEvent))
 246          (ch (make-event-chord (list ev))))
 247
 248     (set! (ly:music-property ev 'origin) location)
 249     (if set
 250         (make-sequential-music (list set ch))
 251         (begin
 252           (set! (ly:music-property ev 'label) label)
 253           ch))))
 254
 255 (define-ly-syntax (partial parser location dur)
 256   "Make a partial measure."
 257
 258   ;; We use `descend-to-context' here instead of `context-spec-music' to
 259   ;; ensure \partial still works if the Timing_translator is moved
 260     (descend-to-context
 261      (context-spec-music (make-music 'PartialSet
 262                                      'origin location
 263                                      'partial-duration dur)
 264                          'Timing)
 265      'Score))