scm/part-combiner.scm

   1 ;;;; part-combiner.scm -- Part combining, staff changes.
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2008     Han-Wen Nienhuys <hanwen@xs4all.nl>
   6
   7 ;; todo: figure out how to make module,
   8 ;; without breaking nested ly scopes
   9
  10 (define-class <Voice-state> ()
  11   (event-list #:init-value '() #:accessor events #:init-keyword #:events)
  12   (when-moment #:accessor when #:init-keyword #:when)
  13   (tuning #:accessor tuning #:init-keyword #:tuning)
  14   (split-index #:accessor split-index)
  15   (vector-index)
  16   (state-vector)
  17   ;;;
  18   ;; spanner-state is an alist
  19   ;; of (SYMBOL . RESULT-INDEX), which indicates where
  20   ;; said spanner was started.
  21   (spanner-state #:init-value '() #:accessor span-state))
  22
  23 (define-method (write (x <Voice-state> ) file)
  24   (display (when x) file)
  25   (display " evs = " file)
  26   (display (events x) file)
  27   (display " active = " file)
  28   (display (span-state x) file)
  29   (display "\n" file))
  30
  31 (define-method (note-events (vs <Voice-state>))
  32   (define (f? x)
  33     (equal? (ly:event-property  x 'class) 'note-event))
  34   (filter f? (events vs)))
  35
  36 (define-method (previous-voice-state (vs <Voice-state>))
  37   (let ((i (slot-ref vs 'vector-index))
  38         (v (slot-ref vs 'state-vector)))
  39     (if (< 0 i)
  40         (vector-ref v (1- i))
  41         #f)))
  42
  43 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  44
  45 (define-class <Split-state> ()
  46   (configuration #:init-value '() #:accessor configuration)
  47   (when-moment #:accessor when #:init-keyword #:when)
  48   ;; voice-states are states starting with the Split-state or later
  49   ;;
  50   (is #:init-keyword #:voice-states #:accessor voice-states)
  51   (synced  #:init-keyword #:synced #:init-value  #f #:getter synced?))
  52
  53
  54 (define-method (write (x <Split-state> ) f)
  55   (display (when x) f)
  56   (display " = " f)
  57   (display (configuration x) f)
  58   (if (synced? x)
  59       (display " synced "))
  60   (display "\n" f))
  61
  62 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  63
  64
  65 (define (previous-span-state vs)
  66   (let ((p (previous-voice-state vs)))
  67     (if p (span-state p) '())))
  68
  69 (define (make-voice-states evl)
  70   (let ((vec (list->vector (map (lambda (v)
  71                                   (make <Voice-state>
  72                                     #:when (caar v)
  73                                     #:tuning (cdar v)
  74                                     #:events (map car (cdr v))))
  75                                 evl))))
  76     (do ((i 0 (1+ i)))
  77         ((= i (vector-length vec)) vec)
  78       (slot-set! (vector-ref vec i) 'vector-index i)
  79       (slot-set! (vector-ref vec i) 'state-vector vec))))
  80
  81 (define (make-split-state vs1 vs2)
  82   "Merge lists VS1 and VS2, containing Voice-state objects into vector
  83 of Split-state objects, crosslinking the Split-state vector and
  84 Voice-state objects
  85 "
  86   (define (helper ss-idx ss-list idx1 idx2)
  87     (let* ((state1 (if (< idx1 (vector-length vs1)) (vector-ref vs1 idx1) #f))
  88            (state2 (if (< idx2 (vector-length vs2)) (vector-ref vs2 idx2) #f))
  89            (min (cond ((and state1 state2) (moment-min (when state1) (when state2)))
  90                       (state1 (when state1))
  91                       (state2 (when state2))
  92                       (else #f)))
  93            (inc1 (if (and state1 (equal? min (when state1))) 1 0))
  94            (inc2 (if (and state2 (equal? min (when state2))) 1 0))
  95            (ss-object (if min
  96                           (make <Split-state>
  97                             #:when min
  98                             #:voice-states (cons state1 state2)
  99                             #:synced (= inc1 inc2))
 100                           #f)))
 101       (if state1
 102           (set! (split-index state1) ss-idx))
 103       (if state2
 104           (set! (split-index state2) ss-idx))
 105       (if min
 106           (helper (1+ ss-idx)
 107                   (cons ss-object ss-list)
 108                   (+ idx1 inc1)
 109                   (+ idx2 inc2))
 110           ss-list)))
 111   (list->vector (reverse! (helper 0 '() 0  0) '())))
 112
 113 (define (analyse-spanner-states voice-state-vec)
 114
 115   (define (helper index active)
 116     "Analyse EVS at INDEX, given state ACTIVE."
 117
 118     (define (analyse-tie-start active ev)
 119       (if (equal? (ly:event-property ev 'class) 'tie-event)
 120           (acons 'tie (split-index (vector-ref voice-state-vec index))
 121                  active)
 122           active))
 123
 124     (define (analyse-tie-end active ev)
 125       (if (equal? (ly:event-property ev 'class) 'note-event)
 126           (assoc-remove! active 'tie)
 127           active))
 128
 129     (define (analyse-absdyn-end active ev)
 130       (if (or (equal? (ly:event-property ev 'class) 'absolute-dynamic-event)
 131               (and (equal? (ly:event-property ev 'class) 'crescendo-event)
 132                    (equal? STOP (ly:event-property ev 'span-direction))))
 133           (assoc-remove! (assoc-remove! active 'cresc) 'decr)
 134           active))
 135
 136     (define (active<? a b)
 137       (cond ((symbol<? (car a) (car b)) #t)
 138             ((symbol<? (car b) (car b)) #f)
 139             (else (< (cdr a) (cdr b)))))
 140
 141     (define (analyse-span-event active ev)
 142       (let* ((name (ly:event-property ev 'class))
 143              (key (cond ((equal? name 'slur-event) 'slur)
 144                         ((equal? name 'phrasing-slur-event) 'tie)
 145                         ((equal? name 'beam-event) 'beam)
 146                         ((equal? name 'crescendo-event) 'cresc)
 147                         ((equal? name 'decrescendo-event) 'decr)
 148                         (else #f)))
 149              (sp (ly:event-property ev 'span-direction)))
 150         (if (and (symbol? key) (ly:dir? sp))
 151             (if (= sp STOP)
 152                 (assoc-remove! active key)
 153                 (acons key
 154                        (split-index (vector-ref voice-state-vec index))
 155                        active))
 156             active)))
 157
 158     (define (analyse-events active evs)
 159       "Run all analyzers on ACTIVE and EVS"
 160       (define (run-analyzer analyzer active evs)
 161         (if (pair? evs)
 162             (run-analyzer analyzer (analyzer active (car evs)) (cdr evs))
 163             active))
 164       (define (run-analyzers analyzers active evs)
 165         (if (pair? analyzers)
 166             (run-analyzers (cdr analyzers)
 167                            (run-analyzer (car analyzers) active evs)
 168                            evs)
 169             active))
 170       (sort ;; todo: use fold or somesuch.
 171        (run-analyzers (list analyse-absdyn-end analyse-span-event
 172                             ;; note: tie-start/span comes after tie-end/absdyn.
 173                             analyse-tie-end analyse-tie-start)
 174                       active evs)
 175        active<?))
 176
 177     ;; must copy, since we use assoc-remove!
 178     (if (< index (vector-length voice-state-vec))
 179         (begin
 180           (set! active (analyse-events active (events (vector-ref voice-state-vec index))))
 181           (set! (span-state (vector-ref voice-state-vec index))
 182                 (list-copy active))
 183           (helper (1+ index) active))))
 184
 185   (helper 0 '()))
 186
 187 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 188 (define-public (recording-group-emulate music odef)
 189   "Interprets music according to odef, but stores all events in a chronological list, similar to the Recording_group_engraver in 2.8 and earlier"
 190   (let*
 191       ((context-list '())
 192        (now-mom (ly:make-moment 0 0))
 193        (global (ly:make-global-context odef))
 194        (mom-listener (ly:make-listener
 195                       (lambda (tev)
 196                         (set! now-mom (ly:event-property tev 'moment)))))
 197        (new-context-listener
 198         (ly:make-listener
 199          (lambda (sev)
 200              (let*
 201                  ((child (ly:event-property sev 'context))
 202                   (this-moment-list
 203                    (cons (ly:context-id child) '()))
 204                   (dummy
 205                    (set! context-list (cons this-moment-list context-list)))
 206                   (acc '())
 207                   (accumulate-event-listener
 208                    (ly:make-listener (lambda (ev)
 209                                        (set! acc (cons (cons ev #t) acc)))))
 210                   (save-acc-listener (ly:make-listener (lambda (tev)
 211                                                          (if (pair? acc)
 212                                                              (let ((this-moment (cons (cons now-mom (ly:context-property child 'instrumentTransposition))
 213                                                                                       acc)))
 214                                                                (set-cdr! this-moment-list (cons this-moment (cdr this-moment-list)))
 215                                                                (set! acc '())))))))
 216                (ly:add-listener accumulate-event-listener (ly:context-event-source child) 'music-event)
 217                (ly:add-listener save-acc-listener (ly:context-event-source global) 'OneTimeStep))))))
 218     (ly:add-listener new-context-listener (ly:context-events-below global) 'AnnounceNewContext)
 219     (ly:add-listener mom-listener (ly:context-event-source global) 'Prepare)
 220     (ly:interpret-music-expression (make-non-relative-music music) global)
 221     context-list))
 222
 223 (define-public (make-part-combine-music parser music-list)
 224   (let* ((m (make-music 'PartCombineMusic))
 225          (m1 (make-non-relative-music (context-spec-music (first music-list) 'Voice "one")))
 226          (m2  (make-non-relative-music  (context-spec-music (second music-list) 'Voice "two")))
 227          (listener (ly:parser-lookup parser 'partCombineListener))
 228          (evs2 (recording-group-emulate m2 listener))
 229          (evs1 (recording-group-emulate m1 listener)))
 230
 231     (set! (ly:music-property m 'elements) (list m1 m2))
 232     (set! (ly:music-property m 'split-list)
 233       (if (and (assoc "one" evs1) (assoc "two" evs2))
 234           (determine-split-list (reverse! (cdr (assoc "one" evs1)) '())
 235                                 (reverse! (cdr (assoc "two" evs2)) '()))
 236           '() ))
 237     m))
 238
 239 (define-public (determine-split-list evl1 evl2)
 240   "EVL1 and EVL2 should be ascending"
 241   (let* ((pc-debug #f)
 242          (chord-threshold 8)
 243          (voice-state-vec1 (make-voice-states evl1))
 244          (voice-state-vec2 (make-voice-states evl2))
 245          (result (make-split-state voice-state-vec1 voice-state-vec2)))
 246
 247     (define (analyse-time-step result-idx)
 248       (define (put x . index)
 249         "Put the result to X, starting from INDEX backwards.
 250
 251 Only set if not set previously.
 252 "
 253         (let ((i (if (pair? index) (car index) result-idx)))
 254           (if (and (<= 0 i)
 255                    (not (symbol? (configuration (vector-ref result i)))))
 256               (begin
 257                 (set! (configuration (vector-ref result i)) x)
 258                 (put x (1- i))))))
 259
 260       (define (copy-state-from state-vec vs)
 261         (define (copy-one-state key-idx)
 262           (let* ((idx (cdr key-idx))
 263                  (prev-ss (vector-ref result idx))
 264                  (prev (configuration prev-ss)))
 265             (if (symbol? prev)
 266                 (put prev))))
 267         (map copy-one-state (span-state vs)))
 268
 269       (define (analyse-notes now-state)
 270         (let* ((vs1 (car (voice-states now-state)))
 271                (vs2 (cdr (voice-states now-state)))
 272                (notes1 (note-events vs1))
 273                (durs1 (sort (map (lambda (x) (ly:event-property x 'duration))
 274                                  notes1)
 275                             ly:duration<?))
 276                (pitches1 (sort (map (lambda (x) (ly:event-property x 'pitch))
 277                                     notes1)
 278                                ly:pitch<?))
 279                (notes2 (note-events vs2))
 280                (durs2 (sort (map (lambda (x) (ly:event-property x 'duration))
 281                                  notes2)
 282                             ly:duration<?))
 283                (pitches2 (sort (map (lambda (x) (ly:event-property x 'pitch))
 284                                     notes2)
 285                                ly:pitch<?)))
 286           (cond ((> (length notes1) 1) (put 'apart))
 287                 ((> (length notes2) 1) (put 'apart))
 288                 ((= 1 (+ (length notes2) (length notes1))) (put 'apart))
 289                 ((and (= (length durs1) 1)
 290                       (= (length durs2) 1)
 291                       (not (equal? (car durs1) (car durs2))))
 292                  (put 'apart))
 293                 (else
 294                  (if (and (= (length pitches1) (length pitches2)))
 295                      (if (and (pair? pitches1)
 296                               (pair? pitches2)
 297                               (or
 298                                (< chord-threshold (ly:pitch-steps
 299                                                    (ly:pitch-diff (car pitches1)
 300                                                                   (car pitches2))))
 301
 302                                ;; voice crossings:
 303                                (> 0 (ly:pitch-steps (ly:pitch-diff (car pitches1)
 304                                                                    (car pitches2))))
 305                                ))
 306                          (put 'apart)
 307                          ;; copy previous split state from spanner state
 308                          (begin
 309                            (if (previous-voice-state vs1)
 310                                (copy-state-from voice-state-vec1
 311                                                 (previous-voice-state vs1)))
 312                            (if (previous-voice-state vs2)
 313                                (copy-state-from voice-state-vec2
 314                                                 (previous-voice-state vs2)))
 315                            (if (and (null? (span-state vs1)) (null? (span-state vs2)))
 316                                (put 'chords)))))))))
 317
 318       (if (< result-idx (vector-length result))
 319           (let* ((now-state (vector-ref result result-idx))
 320                  (vs1 (car (voice-states now-state)))
 321                  (vs2 (cdr (voice-states now-state))))
 322
 323             (cond ((not vs1) (put 'apart))
 324                   ((not vs2) (put 'apart))
 325                   (else
 326                    (let ((active1 (previous-span-state vs1))
 327                          (active2 (previous-span-state vs2))
 328                          (new-active1 (span-state vs1))
 329                          (new-active2 (span-state vs2)))
 330                      (if #f ; debug
 331                          (display (list (when now-state) result-idx
 332                                         active1 "->" new-active1
 333                                         active2 "->" new-active2
 334                                         "\n")))
 335                      (if (and (synced? now-state)
 336                               (equal? active1 active2)
 337                               (equal? new-active1 new-active2))
 338                          (analyse-notes now-state)
 339
 340                          ;; active states different:
 341                          (put 'apart)))
 342
 343                    ;; go to the next one, if it exists.
 344                    (analyse-time-step (1+ result-idx)))))))
 345
 346     (define (analyse-a2 result-idx)
 347       (if (< result-idx (vector-length result))
 348           (let* ((now-state (vector-ref result result-idx))
 349                  (vs1 (car (voice-states now-state)))
 350                  (vs2 (cdr (voice-states now-state))))
 351             (if (and (equal? (configuration now-state) 'chords)
 352                      vs1 vs2)
 353                 (let ((notes1 (note-events vs1))
 354                       (notes2 (note-events vs2)))
 355                   (cond ((and (= 1 (length notes1))
 356                               (= 1 (length notes2))
 357                               (equal? (ly:event-property (car notes1) 'pitch)
 358                                       (ly:event-property (car notes2) 'pitch)))
 359                          (set! (configuration now-state) 'unisono))
 360                         ((and (= 0 (length notes1))
 361                               (= 0 (length notes2)))
 362                          (set! (configuration now-state) 'unisilence)))))
 363             (analyse-a2 (1+ result-idx)))))
 364
 365     (define (analyse-solo12 result-idx)
 366
 367       (define (previous-config vs)
 368         (let* ((pvs (previous-voice-state vs))
 369                (spi (if pvs (split-index pvs) #f))
 370                (prev-split (if spi (vector-ref result spi) #f)))
 371           (if prev-split
 372               (configuration prev-split)
 373               'apart)))
 374
 375       (define (put-range x a b)
 376         ;; (display (list "put range "  x a b "\n"))
 377         (do ((i a (1+ i)))
 378             ((> i b) b)
 379           (set! (configuration (vector-ref result i)) x)))
 380
 381       (define (put x)
 382         ;; (display (list "putting "  x "\n"))
 383         (set! (configuration (vector-ref result result-idx)) x))
 384
 385       (define (current-voice-state now-state voice-num)
 386         (define vs ((if (= 1 voice-num) car cdr)
 387                     (voice-states now-state)))
 388         (if (or (not vs) (equal? (when now-state) (when vs)))
 389             vs
 390             (previous-voice-state vs)))
 391
 392       (define (try-solo type start-idx current-idx)
 393         "Find a maximum stretch that can be marked as solo. Only set
 394 the mark when there are no spanners active.
 395
 396       return next idx to analyse.
 397 "
 398         (if (< current-idx (vector-length result))
 399             (let* ((now-state (vector-ref result current-idx))
 400                    (solo-state (current-voice-state now-state (if (equal? type 'solo1) 1 2)))
 401                    (silent-state (current-voice-state now-state (if (equal? type 'solo1) 2 1)))
 402                    (silent-notes (if silent-state (note-events silent-state) '()))
 403                    (solo-notes (if solo-state (note-events solo-state) '())))
 404               ;; (display (list "trying " type " at "  (when now-state) solo-state silent-state  "\n"))
 405               (cond ((not (equal? (configuration now-state) 'apart))
 406                      current-idx)
 407                     ((> (length silent-notes) 0) start-idx)
 408                     ((not solo-state)
 409                      (put-range type start-idx current-idx)
 410                      current-idx)
 411                     ((and
 412                       (null? (span-state solo-state)))
 413
 414                      ;;
 415                      ;; This includes rests. This isn't a problem: long rests
 416                      ;; will be shared with the silent voice, and be marked
 417                      ;; as unisilence. Therefore, long rests won't
 418                      ;;  accidentally be part of a solo.
 419                      ;;
 420                      (put-range type start-idx current-idx)
 421                      (try-solo type (1+ current-idx) (1+  current-idx)))
 422                     (else
 423                      (try-solo type start-idx (1+ current-idx)))))
 424             ;; try-solo
 425             start-idx))
 426
 427       (define (analyse-moment result-idx)
 428         "Analyse 'apart starting at RESULT-IDX. Return next index. "
 429         (let* ((now-state (vector-ref result result-idx))
 430                (vs1 (current-voice-state now-state 1))
 431                (vs2 (current-voice-state now-state 2))
 432                ;; (vs1 (car (voice-states now-state)))
 433                ;; (vs2 (cdr (voice-states now-state)))
 434                (notes1 (if vs1 (note-events vs1) '()))
 435                (notes2 (if vs2 (note-events vs2) '()))
 436                (n1 (length notes1))
 437                (n2 (length notes2)))
 438           ;; (display (list "analyzing step " result-idx "  moment " (when now-state) vs1 vs2  "\n"))
 439           (max
 440            ;; we should always increase.
 441            (cond ((and (= n1 0) (= n2 0))
 442                   (put 'apart-silence)
 443                   (1+ result-idx))
 444                  ((and (= n2 0)
 445                        (equal? (when vs1) (when now-state))
 446                        (null? (previous-span-state vs1)))
 447                   (try-solo 'solo1 result-idx result-idx))
 448                  ((and (= n1 0)
 449                        (equal? (when vs2) (when now-state))
 450                        (null? (previous-span-state vs2)))
 451                   (try-solo 'solo2 result-idx result-idx))
 452
 453                  (else (1+ result-idx)))
 454            ;; analyse-moment
 455            (1+ result-idx))))
 456
 457       (if (< result-idx (vector-length result))
 458           (if (equal? (configuration (vector-ref result result-idx)) 'apart)
 459               (analyse-solo12 (analyse-moment result-idx))
 460               (analyse-solo12 (1+ result-idx))))) ; analyse-solo12
 461
 462     (analyse-spanner-states voice-state-vec1)
 463     (analyse-spanner-states voice-state-vec2)
 464     (if #f
 465         (begin
 466           (display voice-state-vec1)
 467           (display "***\n")
 468           (display voice-state-vec2)
 469           (display "***\n")
 470           (display result)
 471           (display "***\n")))
 472     (analyse-time-step 0)
 473     ;; (display result)
 474     (analyse-a2 0)
 475     ;;(display result)
 476     (analyse-solo12 0)
 477     ;; (display result)
 478     (set! result (map
 479                   (lambda (x) (cons (when x) (configuration x)))
 480                   (vector->list result)))
 481     (if #f ;; pc-debug
 482          (display result))
 483     result))
 484
 485
 486 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 487
 488 (define-public (add-quotable parser name mus)
 489   (let* ((tab (eval 'musicQuotes (current-module)))
 490          (context-list (recording-group-emulate (context-spec-music mus 'Voice)
 491                                                 (ly:parser-lookup parser 'partCombineListener))))
 492     (if (pair? context-list)
 493         (hash-set! tab name
 494                    ;; cdr : skip name string
 495                    (list->vector (reverse! (cdar context-list)
 496                                            '()))))))