lilypond-texi2html.init

   1 #!/usr/bin/env perl
   2 # -*- coding: utf-8; -*-
   3
   4 ### texi2html customization script for Lilypond
   5 ### Author: Reinhold Kainhofer <reinhold@kainhofer.com>, 2008.
   6 ###         Some code parts copied from texi2html and adapted. These functions
   7 ###         were written mainly by Patrice Dumas
   8 ### License: GPLv2+
   9 ###
  10 ###
  11 ### Features implemented here:
  12 ### -) For split manuals, the main page is index.html.
  13 ### -) All @unnumbered* sections are placed into the same file
  14 ###    (implemented by split_at_numbered_sections)
  15 ### -) Use our custom CSS file, with IE-specific fixes in another CSS file,
  16 ###    impelmented by lilypond_css_lines
  17 ### -) TOC (folded, with the current page highlighted) in an overflown <div>
  18 ###    is added to every page; implemented by:
  19 ###           lilypond_print_element_header -- building of the TOC
  20 ###           lilypond_toc_body -- generation of customized TOC output
  21 ###           lilypond_print_page_head -- start <div id="main">
  22 ###           print_lilypond_page_foot -- closing id=main, output of footer & TOC
  23 ### -) External refs are formatted only as "Text of the node" (not as >>see
  24 ###    "NODE" section "SECTION" in "BOOK"<< like with default texi2html). Also,
  25 ###    the leading "(book-name)" is removed.
  26 ###    Implemented by overriding lilypond_external_ref
  27 ### -) Navigation bars on top/bottom of the page and between sections are not
  28 ###    left-aligned, but use a combination of left/center/right aligned table
  29 ###    cells; For this, I heavily extend the texi2html code to allow for
  30 ###    differently aligned cells and for multi-line tables);
  31 ###    Implemented in lilypond_print_navigation
  32 ### -) Different formatting than the default: example uses the same formatting
  33 ###    as quote.
  34 ### -) Allow translated section titles: All section titles can be translated,
  35 ###    the original (English) title is associated with @translationof. This is
  36 ###    needed, because the file name / anchor is generated from the original
  37 ###    English title, since otherwise language-autoselection would break with
  38 ###    posted links.
  39 ###    Since it is then no longer possible to obtain the file name from the
  40 ###    section title, I keep a sectionname<=>filename/anchor around. This way,
  41 ###    xrefs from other manuals can simply load that map and retrieve the
  42 ###    correct file name for the link. Implemented in:
  43 ###           lilypond_unknown (handling of @translationof, in case
  44 ###                             extract_texi_filenames.py messes up...)
  45 ###           lilypond_element_file_name (correct file name: use the map)
  46 ###           lilypond_element_target_name (correct anchor: use the map)
  47 ###           lilypond_init_map (read in the externally created map from disk)
  48 ###           lilypond_external_href (load the map for xrefs, use the correct
  49 ###                                   link target)
  50 ### -) The HTML anchors for all sections are derived from the node name /
  51 ###    section title (pre-generated in the .xref-map file). Implemented by:
  52 ###           lilypond_element_target_name (adjust section anchors)
  53 ### -) Use the standard footnote format "<sup>nr</sup> text" instead of the
  54 ###    ugly format of texi2html (<h3>(nr)</h3><p>text</p>). Implemented in
  55 ###           makeinfo_like_foot_line_and_ref
  56 ###           makeinfo_like_foot_lines
  57 ###           makeinfo_like_paragraph
  58 ###
  59 ###
  60 ### Useful helper functions:
  61 ### -) texinfo_file_name($node_name): returns a texinfo-compatible file name
  62 ###    for the given string $node_name (whitespace trimmed/replaced by -,
  63 ###    non-standard chars replaced by _xxxx (ascii char code) and forced to
  64 ###    start with a letter by prepending t_g if necessary)
  65
  66
  67 package Texi2HTML::Config;
  68
  69 #############################################################################
  70 ### TRANSLATIONS
  71 #############################################################################
  72
  73 use utf8;
  74 my $LY_LANGUAGES = {};
  75 $LY_LANGUAGES->{'fr'} = {
  76     'Back to Documentation Index' => 'Retour à l\'accueil de la documentation',
  77 };
  78 $LY_LANGUAGES->{'es'} = {
  79     'Back to Documentation Index' => 'Volver al índice de la documentación',
  80 };
  81 $LY_LANGUAGES->{'de'} = {
  82     'Back to Documentation Index' => '',
  83 };
  84
  85
  86 sub ly_get_string () {
  87     my $lang = $Texi2HTML::THISDOC{current_lang};
  88     my $string = shift;
  89     if ($lang and $lang ne "en" and $LY_LANGUAGES->{$lang}->{$string}) {
  90         return $LY_LANGUAGES->{$lang}->{$string};
  91     } else {
  92         return $string;
  93     }
  94 }
  95
  96
  97 #############################################################################
  98 ###  SETTINGS FOR TEXI2HTML
  99 #############################################################################
 100
 101 @Texi2HTML::Config::CSS_REFS      = (
 102     {FILENAME => "lilypond-mccarty.css", TITLE => "Patrick McCarty's design"}
 103 );
 104 @Texi2HTML::Config::ALT_CSS_REFS      = (
 105     {FILENAME => "lilypond.css", TITLE => "Andrew Hawryluk's design" },
 106     {FILENAME => "lilypond-blue.css", TITLE => "Kurt Kroon's blue design" },
 107 );
 108 $Texi2HTML::Config::USE_ACCESSKEY = 1;
 109 $Texi2HTML::Config::USE_LINKS     = 1;
 110 $Texi2HTML::Config::USE_REL_REV   = 1;
 111 $Texi2HTML::Config::SPLIT_INDEX   = 0;
 112 $Texi2HTML::Config::SEPARATED_FOOTNOTES = 0; # Print footnotes on same page, not separated
 113 if ($Texi2HTML::Config::SPLIT eq 'section') {
 114   $Texi2HTML::Config::element_file_name    = \&lilypond_element_file_name;
 115 }
 116 $Texi2HTML::Config::element_target_name  = \&lilypond_element_target_name;
 117 $Texi2HTML::Config::print_element_header = \&lilypond_print_element_header;
 118 $Texi2HTML::Config::print_page_foot      = \&print_lilypond_page_foot;
 119 $Texi2HTML::Config::print_navigation     = \&lilypond_print_navigation;
 120 $Texi2HTML::Config::external_ref         = \&lilypond_external_ref;
 121 $Texi2HTML::Config::external_href        = \&lilypond_external_href;
 122 $Texi2HTML::Config::toc_body             = \&lilypond_toc_body;
 123 $Texi2HTML::Config::css_lines            = \&lilypond_css_lines;
 124 $Texi2HTML::Config::unknown              = \&lilypond_unknown;
 125 $Texi2HTML::Config::print_page_head      = \&lilypond_print_page_head;
 126 # $Texi2HTML::Config::foot_line_and_ref    = \&lilypond_foot_line_and_ref;
 127 $Texi2HTML::Config::foot_line_and_ref  = \&makeinfo_like_foot_line_and_ref;
 128 $Texi2HTML::Config::foot_lines         = \&makeinfo_like_foot_lines;
 129 $Texi2HTML::Config::paragraph          = \&makeinfo_like_paragraph;
 130
 131
 132
 133 # Examples should be formatted similar to quotes:
 134 $Texi2HTML::Config::complex_format_map->{'example'} = {
 135   'begin' => q{"<blockquote><pre class=\"example\">"},
 136   'end' => q{"</pre></blockquote>\n"},
 137   'style' => 'code',
 138  };
 139
 140 %Texi2HTML::config::misc_pages_targets = (
 141    'Overview' => 'Overview',
 142    'Contents' => 'Contents',
 143    'About' => 'About'
 144 );
 145
 146
 147 my @section_to_filename;
 148
 149
 150
 151
 152 #############################################################################
 153 ###  DEBUGGING
 154 #############################################################################
 155
 156 use Data::Dumper;
 157 $Data::Dumper::Maxdepth = 2;
 158
 159 sub print_element_info($)
 160 {
 161   my $element = shift;
 162   print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n";
 163   print "Element: $element\n";
 164   print Dumper($element);
 165 }
 166
 167
 168
 169
 170
 171 #############################################################################
 172 ###  HELPER FUNCTIONS
 173 #############################################################################
 174
 175 # Convert a given node name to its proper file name (normalization as explained
 176 # in the texinfo manual:
 177 # http://www.gnu.org/software/texinfo/manual/texinfo/html_node/HTML-Xref-Node-Name-Expansion.html
 178 sub texinfo_file_name($)
 179 {
 180   my $text = shift;
 181   my $result = '';
 182   # File name normalization by texinfo:
 183   # 1/2: letters and numbers are left unchanged
 184   # 3/4: multiple, leading and trailing whitespace is removed
 185   $text = main::normalise_space($text);
 186   # 5/6: all remaining spaces are converted to '-', all other 7- or 8-bit
 187   #      chars are replaced by _xxxx (xxxx=ascii character code)
 188   while ($text ne '') {
 189     if ($text =~ s/^([A-Za-z0-9]+)//o) { # number or letter stay unchanged
 190       $result .= $1;
 191     } elsif ($text =~ s/^ //o) { # space -> '-'
 192       $result .= '-';
 193     } elsif ($text =~ s/^(.)//o) { # Otherwise use _xxxx (ascii char code)
 194       my $ccode = ord($1);
 195       if ( $ccode <= 0xFFFF ) {
 196         $result .= sprintf("_%04x", $ccode);
 197       } else {
 198         $result .= sprintf("__%06x", $ccode);
 199       }
 200     }
 201   }
 202   # 7: if name does not begin with a letter, prepend 't_g' (so it starts with a letter)
 203   if ($result !~ /^[a-zA-Z]/) {
 204     $result = 't_g' . $result;
 205   }
 206   # DONE
 207   return $result
 208 }
 209
 210
 211 # Load a file containing a nodename<=>filename map (tab-sepatared, i.e.
 212 # NODENAME\tFILENAME\tANCHOR
 213 # Returns a ref to a hash "Node title" => ["FilenameWithoutExt", "Anchor"]
 214 sub load_map_file ($)
 215 {
 216     my $mapfile = shift;
 217     my $node_map = ();
 218
 219     if (open(XREFFILE, $mapfile)) {
 220         my $line;
 221         while ( $line = <XREFFILE> ) {
 222             # parse the tab-separated entries and insert them into the map:
 223             chomp($line);
 224             my @entries = split(/\t/, $line);
 225             if (scalar (@entries) == 3) {
 226               $node_map->{$entries[0]} = [$entries[1], $entries[2]];
 227             } else {
 228               print STDERR "Invalid entry in the node file $mapfile: $line\n";
 229             }
 230         }
 231         close (XREFFILE);
 232     } else {
 233         print STDERR "WARNING: Unable to load the map file $mapfile\n";
 234     }
 235     return $node_map;
 236 }
 237
 238
 239 # Split the given path into dir and basename (with .texi removed). Used mainly
 240 # to get the path/basename of the original texi input file
 241 sub split_texi_filename ($)
 242 {
 243   my $docu = shift;
 244   my ($docu_dir, $docu_name);
 245   if ($docu =~ /(.*\/)/) {
 246     chop($docu_dir = $1);
 247     $docu_name = $docu;
 248     $docu_name =~ s/.*\///;
 249   } else {
 250      $docu_dir = '.';
 251      $docu_name = $docu;
 252   }
 253   $docu_name =~ s/\.te?x(i|info)?$//;
 254   return ($docu_dir, $docu_name);
 255 }
 256
 257
 258
 259
 260
 261 #############################################################################
 262 ###  CSS HANDLING
 263 #############################################################################
 264
 265 # Include our standard CSS file, not hard-coded CSS code directly in the HTML!
 266 # For IE, conditionally include the lilypond-ie-fixes.css style sheet
 267 sub lilypond_css_lines ($$)
 268 {
 269     my $import_lines = shift;
 270     my $rule_lines = shift;
 271     return if (defined($Texi2HTML::THISDOC{'CSS_LINES'}));
 272     if (@$rule_lines or @$import_lines)
 273     {
 274         $Texi2HTML::THISDOC{'CSS_LINES'} = "<style type=\"text/css\">\n<!--\n";
 275         $Texi2HTML::THISDOC{'CSS_LINES'} .= join('',@$import_lines) . "\n" if (@$import_lines);
 276         $Texi2HTML::THISDOC{'CSS_LINES'} .= join('',@$rule_lines) . "\n" if (@$rule_lines);
 277         $Texi2HTML::THISDOC{'CSS_LINES'} .= "-->\n</style>\n";
 278     }
 279     foreach my $ref (@CSS_REFS)
 280     {
 281         $Texi2HTML::THISDOC{'CSS_LINES'} .= "<link rel=\"stylesheet\" type=\"text/css\" title=\"$ref->{TITLE}\" href=\"$ref->{FILENAME}\">\n";
 282     }
 283     foreach my $ref (@Texi2HTML::Config::ALT_CSS_REFS)
 284     {
 285         $Texi2HTML::THISDOC{'CSS_LINES'} .= "<link rel=\"alternate stylesheet\" type=\"text/css\" href=\"$ref->{FILENAME}\" title=\"$ref->{TITLE}\">\n";
 286     }
 287     $Texi2HTML::THISDOC{'CSS_LINES'} .= "<!--[if lte IE 7]>\n<link href=\"lilypond-ie-fixes.css\" rel=\"stylesheet\" type=\"text/css\">\n<![endif]-->\n";
 288 }
 289
 290
 291
 292
 293
 294 #############################################################################
 295 ###  SPLITTING BASED ON NUMBERED SECTIONS
 296 #############################################################################
 297
 298 my $lastfilename;
 299 my $docnr = 0;
 300 my $node_to_filename_map = ();
 301
 302
 303 # This function makes sure that files are only generated for numbered sections,
 304 # but not for unnumbered ones. It is called after texi2html has done its own
 305 # splitting and simply returns the filename for the node given as first argument
 306 # Nodes with the same filename will be printed out to the same filename, so
 307 # this really all we need. Also, make sure that the file names for sections
 308 # are derived from the section title. We also might want to name the anchors
 309 # according to node titles, which works by simply overriding the id element of
 310 # the $element hash.
 311 # If an external nodename<=>filename/anchor map file is found (loaded in
 312 # lilypond_init_out, use the externally created values, otherwise use the
 313 # same logic here.
 314 sub lilypond_element_file_name($$$)
 315 {
 316   my $element = shift;
 317   my $type = shift;
 318   my $docu_name = shift;
 319   my $docu_ext = $Texi2HTML::Config::EXTENSION;
 320
 321   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 322   # the snippets page does not use nodes for the snippets, so in this case
 323   # we'll have to use the section name!
 324   if ($node_name eq '') {
 325     $node_name = main::remove_texi($element->{'texi'});
 326   }
 327
 328   # If we have an entry in the section<=>filename map, use that one, otherwise
 329   # generate the filename/anchor here. In the latter case, external manuals
 330   # will not be able to retrieve the file name for xrefs!!! Still, I already
 331   # had that code, so I'll leave it in in case something goes wrong with the
 332   # extract_texi_filenames.py script in the lilypond build process!
 333   if (exists ($node_to_filename_map->{$node_name})) {
 334     (my $filename, my $anchor) = @{$node_to_filename_map->{$node_name}};
 335     $filename .= ".$docu_ext" if (defined($docu_ext));
 336
 337     # unnumbered sections (except those at top-level!) always go to the same
 338     # file as the previous numbered section
 339     if (not ($element->{number}) and not ($lastfilename eq '') and ($element->{level} > 1)) {
 340       $filename = $lastfilename;
 341     }
 342     if (($filename eq $lastfilename)) {
 343       $$element{doc_nr} = $docnr;
 344     } else {
 345       $docnr += 1;
 346       $$element{doc_nr} = $docnr;
 347       $lastfilename = $filename;
 348     }
 349     return $filename;
 350
 351   } elsif ($type eq "top" or $type eq "toc" or $type eq "doc" or $type eq "stoc" or $type eq "foot" or $type eq "about") {
 352     return;
 353   } else {
 354     print STDERR "WARNING: Node '$node_name' was NOT found in the map\n"
 355         unless ($node_name eq '') or ($element->{'tag'} eq 'unnumberedsec')
 356                or ($node_name =~ /NOT REALLY USED/);
 357
 358     # Numbered sections will get a filename Node_title, unnumbered sections will use
 359     # the file name of the previous numbered section:
 360     if (($element->{number}) or ($lastfilename eq '') or ($element->{level} == 1)) {
 361       # normalize to the same file name as texinfo
 362       if ($element->{translationof}) {
 363         $node_name = main::remove_texi($element->{translationof});
 364       }
 365       my $filename = texinfo_file_name($node_name);
 366       $filename .= ".$docu_ext" if (defined($docu_ext));
 367       $docnr += 1;
 368       $$element{doc_nr} = $docnr;
 369       $lastfilename = $filename;
 370       return $filename;
 371     } else {
 372       $$element{doc_nr} = $docnr;
 373       return $lastfilename;
 374     }
 375   }
 376
 377   return;
 378 }
 379
 380 sub lilypond_element_target_name($$$)
 381 {
 382   my $element = shift;
 383   my $target = shift;
 384   my $id = shift;
 385   # Target is based on node name (or sec name for secs without node attached)
 386   my $node_name = main::remove_texi($element->{'node_ref'}->{'texi'});
 387   if ($node_name eq '') {
 388     $node_name = main::remove_texi($element->{'texi'});
 389   }
 390
 391   # If we have an entry in the section<=>filename map, use that one, otherwise
 392   # generate the anchor here.
 393   if (exists ($node_to_filename_map->{$node_name})) {
 394     (my $filename, $target) = @{$node_to_filename_map->{$node_name}};
 395   } else {
 396     my $anchor = $node_name;
 397     if ($element->{translationof}) {
 398       $anchor = main::remove_texi($element->{translationof});
 399     }
 400     # normalize to the same file name as texinfo
 401     $target = texinfo_file_name($anchor);
 402   }
 403   # TODO: Once texi2html correctly prints out the target and not the id for
 404   #       the sections, change this back to ($id, $target)
 405   return ($target, $target);
 406 }
 407
 408
 409 ## Load the map file for the corrently processed texi file. We do this
 410 #  using a command init handler, since texi2html does not have any
 411 #  other hooks that are called after THISDOC is filled but before phase 2
 412 #  of the texi2html conversion.
 413 sub lilypond_init_map ()
 414 {
 415     my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 416     my $map_filename = main::locate_include_file ("${docu_name}.$Texi2HTML::THISDOC{current_lang}.xref-map")
 417         || main::locate_include_file ("${docu_name}.xref-map");
 418     $node_to_filename_map = load_map_file ($map_filename);
 419 }
 420 push @Texi2HTML::Config::command_handler_init, \&lilypond_init_map;
 421
 422
 423
 424 #############################################################################
 425 ###  CLEANER LINK TITLE FOR EXTERNAL REFS
 426 #############################################################################
 427
 428 # The default formatting of external refs returns e.g.
 429 # "(lilypond-internals)Timing_translator", so we remove all (...) from the
 430 # file_and_node argument. Also, we want only a very simple format, so we don't
 431 # even call the default handler!
 432 sub lilypond_external_ref($$$$$$)
 433 {
 434   my $type = shift;
 435   my $section = shift;
 436   my $book = shift;
 437   my $file_node = shift;
 438   my $href = shift;
 439   my $cross_ref = shift;
 440
 441   my $displaytext = '';
 442
 443   # 1) if we have a cross ref name, that's the text to be displayed:
 444   # 2) For the top node, use the (printable) name of the manual, unless we
 445   #    have an explicit cross ref name
 446   # 3) In all other cases use the section name
 447   if ($cross_ref ne '') {
 448     $displaytext = $cross_ref;
 449   } elsif (($section eq '') or ($section eq 'Top')) {
 450     $displaytext = $book;
 451   } else {
 452     $displaytext = $section;
 453   }
 454
 455   $displaytext = &$anchor('', $href, $displaytext) if ($displaytext ne '');
 456   return &$I('%{node_file_href}', { 'node_file_href' => $displaytext });
 457
 458 #  Default: format as "see <a ..>NODE</a> section 'SECTION' in BOOK". We don't want this!
 459 #   return t2h_default_external_ref($type, $section, $book, $file_node, $href, $cross_ref);
 460 }
 461
 462
 463
 464
 465
 466 #############################################################################
 467 ###  HANDLING TRANSLATED SECTIONS: handle @translationof, secname<->filename
 468 ###                  map stored on disk, xrefs in other manuals load that map
 469 #############################################################################
 470
 471
 472 # Try to make use of @translationof to generate files according to the original
 473 # English section title...
 474 sub lilypond_unknown($$$$$)
 475 {
 476     my $macro = shift;
 477     my $line = shift;
 478     my $pass = shift;
 479     my $stack = shift;
 480     my $state = shift;
 481
 482     # the @translationof macro provides the original English section title,
 483     # which should be used for file/anchor naming, while the title will be
 484     # translated to each language
 485     # It is already used by extract_texi_filenames.py, so this should not be
 486     # necessary here at all. Still, I'll leave the code in just in case the
 487     # python script messed up ;-)
 488     if ($pass == 1 and $macro eq "translationof") {
 489       if (ref($state->{'element'}) eq 'HASH') {
 490         $state->{'element'}->{'translationof'} = main::normalise_space($line);
 491       }
 492       return ('', 1, undef, undef);
 493     } else {
 494       return t2h_default_unknown($macro, $line, $pass, $stack, $state);
 495     }
 496 }
 497
 498
 499
 500
 501 my %translated_books = ();
 502 # Construct a href to an external source of information.
 503 # node is the node with texinfo @-commands
 504 # node_id is the node transliterated and transformed as explained in the
 505 #         texinfo manual
 506 # node_xhtml_id is the node transformed such that it is unique and can
 507 #     be used to make an html cross ref as explained in the texinfo manual
 508 # file is the file in '(file)node'
 509 sub lilypond_external_href($$$)
 510 {
 511   my $node = shift;
 512   my $node_id = shift;
 513   my $node_hxmlt_id = shift;
 514   my $file = shift;
 515   my $original_func = \&t2h_default_external_href;
 516
 517   # 1) Keep a hash of book->section_map
 518   # 2) if not file in keys hash => try to load the map (assign empty map if
 519   #    non-existent => will load only once!)
 520   # 3) if node in the section=>(file, anchor) map, replace node_id and
 521   #    node_xhtml_id by the map's values
 522   # 4) call the t2h_default_external_href with these values (or the old ones if not found)
 523
 524   if (($node_id ne '') and defined($file) and ($node_id ne 'Top')) {
 525     my $map_name = $file;
 526     $map_name =~ s/-big-page//;
 527
 528     # Load the map if we haven't done so already
 529     if (!exists($translated_books{$map_name})) {
 530       my ($docu_dir, $docu_name) = split_texi_filename ($Texi2HTML::THISDOC{'input_file_name'});
 531       my $map_filename = main::locate_include_file ("${map_name}.$Texi2HTML::THISDOC{current_lang}.xref-map")
 532           || main::locate_include_file ("${map_name}.xref-map");
 533       $translated_books{$map_name} = load_map_file ($map_filename);
 534     }
 535
 536     # look up translation. use these values instead of the old filename/anchor
 537     my $section_name_map = $translated_books{$map_name};
 538     my $node_text = main::remove_texi($node);
 539     if (defined($section_name_map->{$node_text})) {
 540       ($node_id, $node_hxmlt_id) = @{$section_name_map->{$node_text}};
 541     } else {
 542       print STDERR "WARNING: Unable to find node '$node_text' in book $map_name.\n";
 543     }
 544   }
 545
 546   if (defined $file) {
 547     return &$original_func($node, $node_id, $node_hxmlt_id, $file);
 548   } else {
 549     return &$original_func($node, $node_id, $node_hxmlt_id);
 550   }
 551 }
 552
 553
 554
 555
 556
 557 #############################################################################
 558 ###  CUSTOM TOC FOR EACH PAGE (in a frame on the left)
 559 #############################################################################
 560
 561 my $page_toc_depth = 2;
 562 my @default_toc = [];
 563
 564 # recursively generate the TOC entries for the element and its children (which
 565 # are only shown up to maxlevel. All ancestors of the current element are also
 566 # shown with their immediate children, irrespective of their level.
 567 # Unnumbered entries are only printed out if they are at top-level or 2nd level
 568 # or their parent element is an ancestor of the currently viewed node.
 569 # The conditions to call this method to print the entry for a child node is:
 570 # -) the parent is an ancestor of the current page node
 571 # -) the parent is a numbered element at top-level toplevel (i.e. show numbered
 572 #    and unnumbered 2nd-level children of numbered nodes)
 573 # -) the child element is a numbered node below level maxlevel
 574 sub generate_ly_toc_entries($$$)
 575 {
 576   my $element = shift;
 577   my $element_path = shift;
 578   my $maxlevel = shift;
 579   # Skip undefined sections, plus all sections generated by index splitting
 580   return() if (not defined($element) or exists($element->{'index_page'}));
 581   my @result = ();
 582   my $level = $element->{'toc_level'};
 583   my $is_parent_of_current = $element->{'id'} && $element_path->{$element->{'id'}};
 584   my $ind = '  ' x $level;
 585   my $this_css_class = $is_parent_of_current ? " class=\"toc_current\"" : "";
 586
 587   my $entry = "$ind<li$this_css_class>" . &$anchor ($element->{'tocid'}, "$element->{'file'}#$element->{'target'}",$element->{'text'});
 588
 589   push (@result, $entry);
 590   my $children = $element->{'section_childs'};
 591   if (defined($children) and (ref($children) eq "ARRAY")) {
 592     my $force_children = $is_parent_of_current or ($level == 1 and $element->{'number'});
 593     my @child_result = ();
 594     foreach my $c (@$children) {
 595       my $is_numbered_child = defined ($c->{'number'});
 596       my $below_maxlevel = $c->{'toc_level'} le $maxlevel;
 597       if ($force_children or ($is_numbered_child and $below_maxlevel)) {
 598         my @child_res = generate_ly_toc_entries($c, $element_path, $maxlevel);
 599         push (@child_result, @child_res);
 600       }
 601     }
 602     # if no child nodes were generated, e.g. for the index, where expanded pages
 603     # are ignored, don't generate a list at all...
 604     if (@child_result) {
 605       push (@result, "\n$ind<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 606       push (@result, @child_result);
 607       push (@result, "$ind</ul>\n");
 608     }
 609   }
 610   push (@result, "$ind</li>\n");
 611   return @result;
 612 }
 613
 614
 615 # Print a customized TOC, containing only the first two levels plus the whole
 616 # path to the current page
 617 sub lilypond_generate_page_toc_body($)
 618 {
 619     my $element = shift;
 620     my $current_element = $element;
 621     my %parentelements;
 622     $parentelements{$element->{'id'}} = 1;
 623     # Find the path to the current element
 624     while ( defined($current_element->{'sectionup'}) and
 625            ($current_element->{'sectionup'} ne $current_element) )
 626     {
 627       $parentelements{$current_element->{'sectionup'}->{'id'}} = 1
 628               if ($current_element->{'sectionup'}->{'id'} ne '');
 629       $current_element = $current_element->{'sectionup'};
 630     }
 631     return () if not defined($current_element);
 632     # Create the toc entries recursively
 633     my @toc_entries = ("<div class=\"contents\">\n", "<ul$NO_BULLET_LIST_ATTRIBUTE>\n");
 634     my $children = $current_element->{'section_childs'};
 635     foreach ( @$children ) {
 636       push (@toc_entries, generate_ly_toc_entries($_, \%parentelements, $page_toc_depth));
 637     }
 638     push (@toc_entries, "</ul>\n");
 639     push (@toc_entries, "</div>\n");
 640     return @toc_entries;
 641 }
 642
 643 sub lilypond_print_toc_div ($$)
 644 {
 645   my $fh = shift;
 646   my $tocref = shift;
 647   my @lines = @$tocref;
 648   # use default TOC if no custom lines have been generated
 649   @lines = @default_toc if (not @lines);
 650   if (@lines) {
 651
 652     print $fh "\n\n<div id=\"tocframe\">\n";
 653
 654     # Remove the leading "GNU LilyPond --- " from the manual title
 655     my $topname = $Texi2HTML::NAME{'Top'};
 656     $topname =~ s/^GNU LilyPond(:| &[mn]dash;) //;
 657
 658     # construct the top-level Docs index (relative path and including language!)
 659     my $lang = $Texi2HTML::THISDOC{current_lang};
 660     if ($lang and $lang ne "en") {
 661       $lang .= ".";
 662     } else {
 663       $lang = "";
 664     }
 665     my $reldir = "";
 666     $reldir = "../" if ($Texi2HTML::Config::SPLIT eq 'section');
 667     my $uplink = $reldir."index.${lang}html";
 668
 669     print $fh "<p class=\"toc_uplink\"><a href=\"$uplink\"
 670          title=\"Documentation Index\">&lt;&lt; " .
 671          &ly_get_string ('Back to Documentation Index') .
 672          "</a></p>\n";
 673
 674     print $fh '<h4 class="toc_header"> ' . &$anchor('',
 675                                     $Texi2HTML::HREF{'Top'},
 676                                     $topname,
 677                                     'title="Start of the manual"'
 678                                    ) . "</h4>\n";
 679     foreach my $line (@lines) {
 680       print $fh $line;
 681     }
 682     print $fh "</div>\n\n";
 683   }
 684 }
 685
 686 # Create the custom TOC for this page (partially folded, current page is
 687 # highlighted) and store it in a global variable. The TOC is written out after
 688 # the html contents (but positioned correctly using CSS), so that browsers with
 689 # css turned off still show the contents first.
 690 our @this_page_toc = ();
 691 sub lilypond_print_element_header
 692 {
 693   my $first_in_page = shift;
 694   my $previous_is_top = shift;
 695   if ($first_in_page and not @this_page_toc) {
 696     if (defined($Texi2HTML::THIS_ELEMENT)) {
 697       # Create the TOC for this page
 698       @this_page_toc = lilypond_generate_page_toc_body($Texi2HTML::THIS_ELEMENT);
 699     }
 700   }
 701   return T2H_DEFAULT_print_element_header( $first_in_page, $previous_is_top);
 702 }
 703
 704 # Generate the HTML output for the TOC
 705 sub lilypond_toc_body($)
 706 {
 707     my $elements_list = shift;
 708     # Generate a default TOC for pages without THIS_ELEMENT
 709     @default_toc = lilypond_generate_page_toc_body(@$elements_list[0]);
 710     return T2H_GPL_toc_body($elements_list);
 711 }
 712
 713 # Print out the TOC in a <div> at the beginning of the page
 714 sub lilypond_print_page_head($)
 715 {
 716     my $fh = shift;
 717     T2H_DEFAULT_print_page_head($fh);
 718     print $fh "<div id=\"main\">\n";
 719 }
 720
 721 # Print out the TOC in a <div> at the end of th page, which will be formatted as a
 722 # sidebar mimicking a TOC frame
 723 sub print_lilypond_page_foot($)
 724 {
 725   my $fh = shift;
 726   my $program_string = &$program_string();
 727 #   print $fh "<p><font size='-1'>$program_string</font><br>$PRE_BODY_CLOSE</p>\n";
 728   print $fh "<!-- FOOTER -->\n\n";
 729   print $fh "<!-- end div#main here -->\n</div>\n\n";
 730
 731   # Print the TOC frame and reset the TOC:
 732   lilypond_print_toc_div ($fh, \@this_page_toc);
 733   @this_page_toc = ();
 734
 735   # Close the page:
 736   print $fh "</body>\n</html>\n";
 737 }
 738
 739
 740
 741
 742
 743 #############################################################################
 744 ###  NICER / MORE FLEXIBLE NAVIGATION PANELS
 745 #############################################################################
 746
 747 sub get_navigation_text
 748 {
 749   my $button = shift;
 750   my $text = $NAVIGATION_TEXT{$button};
 751   if ( ($button eq 'Back') or ($button eq 'FastBack') ) {
 752     $text = $text . $Texi2HTML::NODE{$button} . "&nbsp;";
 753   } elsif ( ($button eq 'Forward') or ($button eq 'FastForward') ) {
 754     $text = "&nbsp;" . $Texi2HTML::NODE{$button} . $text;
 755   } elsif ( $button eq 'Up' ) {
 756     $text = "&nbsp;".$text.":&nbsp;" . $Texi2HTML::NODE{$button} . "&nbsp;";
 757   }
 758   return $text;
 759 }
 760
 761
 762 # Don't automatically create left-aligned table cells for every link, but
 763 # instead create a <td> only on an appropriate '(left|right|center)-aligned-cell-n'
 764 # button text. It's alignment as well as the colspan will be taken from the
 765 # name of the button. Also, add 'newline' button text to create a new table
 766 # row. The texts of the buttons are generated by get_navigation_text and
 767 # will contain the name of the next/previous section/chapter.
 768 sub lilypond_print_navigation
 769 {
 770     my $buttons = shift;
 771     my $vertical = shift;
 772     my $spacing = 1;
 773     my $result = "<table class=\"nav_table\">\n";
 774
 775     $result .= "<tr>" unless $vertical;
 776     my $beginofline = 1;
 777     foreach my $button (@$buttons)
 778     {
 779         $result .= qq{<tr valign="top" align="left">\n} if $vertical;
 780         # Allow (left|right|center)-aligned-cell and newline as buttons!
 781         if ( $button =~ /^(.*)-aligned-cell-(.*)$/ )
 782         {
 783           $result .= qq{</td>} unless $beginofline;
 784           $result .= qq{<td valign="middle" align="$1" colspan="$2">};
 785           $beginofline = 0;
 786         }
 787         elsif ( $button eq 'newline' )
 788         {
 789           $result .= qq{</td>} unless $beginofline;
 790           $result .= qq{</tr>};
 791           $result .= qq{<tr>};
 792           $beginofline = 1;
 793
 794         }
 795         elsif (ref($button) eq 'CODE')
 796         {
 797             $result .= &$button($vertical);
 798         }
 799         elsif (ref($button) eq 'SCALAR')
 800         {
 801             $result .= "$$button" if defined($$button);
 802         }
 803         elsif (ref($button) eq 'ARRAY')
 804         {
 805             my $text = $button->[1];
 806             my $button_href = $button->[0];
 807             # verify that $button_href is simple text and text is a reference
 808             if (defined($button_href) and !ref($button_href)
 809                and defined($text) and (ref($text) eq 'SCALAR') and defined($$text))
 810             {             # use given text
 811                 if ($Texi2HTML::HREF{$button_href})
 812                 {
 813                   my $anchor_attributes = '';
 814                   if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button_href})) and ($BUTTONS_ACCESSKEY{$button_href} ne ''))
 815                   {
 816                       $anchor_attributes = "accesskey=\"$BUTTONS_ACCESSKEY{$button_href}\"";
 817                   }
 818                   if ($USE_REL_REV and (defined($BUTTONS_REL{$button_href})) and ($BUTTONS_REL{$button_href} ne ''))
 819                   {
 820                       $anchor_attributes .= " rel=\"$BUTTONS_REL{$button_href}\"";
 821                   }
 822                   $result .=  "" .
 823                         &$anchor('',
 824                                     $Texi2HTML::HREF{$button_href},
 825                                     get_navigation_text($$text),
 826                                     $anchor_attributes
 827                                    );
 828                 }
 829                 else
 830                 {
 831                   $result .=  get_navigation_text($$text);
 832                 }
 833             }
 834         }
 835         elsif ($button eq ' ')
 836         {                       # handle space button
 837             $result .=
 838                 ($ICONS && $ACTIVE_ICONS{' '}) ?
 839                     &$button_icon_img($BUTTONS_NAME{$button}, $ACTIVE_ICONS{' '}) :
 840                         $NAVIGATION_TEXT{' '};
 841             #next;
 842         }
 843         elsif ($Texi2HTML::HREF{$button})
 844         {                       # button is active
 845             my $btitle = $BUTTONS_GOTO{$button} ?
 846                 'title="' . $BUTTONS_GOTO{$button} . '"' : '';
 847             if ($USE_ACCESSKEY and (defined($BUTTONS_ACCESSKEY{$button})) and ($BUTTONS_ACCESSKEY{$button} ne ''))
 848             {
 849                 $btitle .= " accesskey=\"$BUTTONS_ACCESSKEY{$button}\"";
 850             }
 851             if ($USE_REL_REV and (defined($BUTTONS_REL{$button})) and ($BUTTONS_REL{$button} ne ''))
 852             {
 853                 $btitle .= " rel=\"$BUTTONS_REL{$button}\"";
 854             }
 855             if ($ICONS && $ACTIVE_ICONS{$button})
 856             {                   # use icon
 857                 $result .= '' .
 858                     &$anchor('',
 859                         $Texi2HTML::HREF{$button},
 860                         &$button_icon_img($BUTTONS_NAME{$button},
 861                                    $ACTIVE_ICONS{$button},
 862                                    $Texi2HTML::SIMPLE_TEXT{$button}),
 863                         $btitle
 864                       );
 865             }
 866             else
 867             {                   # use text
 868                 $result .=
 869                     '[' .
 870                         &$anchor('',
 871                                     $Texi2HTML::HREF{$button},
 872                                     get_navigation_text($button),
 873                                     $btitle
 874                                    ) .
 875                                        ']';
 876             }
 877         }
 878         else
 879         {                       # button is passive
 880             $result .=
 881                 $ICONS && $PASSIVE_ICONS{$button} ?
 882                     &$button_icon_img($BUTTONS_NAME{$button},
 883                                           $PASSIVE_ICONS{$button},
 884                                           $Texi2HTML::SIMPLE_TEXT{$button}) :
 885
 886                                               "[" . get_navigation_text($button) . "]";
 887         }
 888         $result .= "</td>\n" if $vertical;
 889         $result .= "</tr>\n" if $vertical;
 890     }
 891     $result .= "</td>" unless $beginofline;
 892     $result .= "</tr>" unless $vertical;
 893     $result .= "</table>\n";
 894     return $result;
 895 }
 896
 897
 898 @Texi2HTML::Config::SECTION_BUTTONS =
 899     ('left-aligned-cell-1', 'FastBack',
 900      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 901      'right-aligned-cell-1', 'FastForward',
 902      'newline',
 903      'left-aligned-cell-2', 'Back',
 904      'center-aligned-cell-1', 'Up',
 905      'right-aligned-cell-2', 'Forward'
 906     );
 907
 908 # buttons for misc stuff
 909 @Texi2HTML::Config::MISC_BUTTONS = ('center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About');
 910
 911 # buttons for chapter file footers
 912 # (and headers but only if SECTION_NAVIGATION is false)
 913 @Texi2HTML::Config::CHAPTER_BUTTONS =
 914     ('left-aligned-cell-1', 'FastBack',
 915      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 916      'right-aligned-cell-1', 'FastForward',
 917     );
 918
 919 # buttons for section file footers
 920 @Texi2HTML::Config::SECTION_FOOTER_BUTTONS =
 921     ('left-aligned-cell-1', 'FastBack',
 922      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 923      'right-aligned-cell-1', 'FastForward',
 924      'newline',
 925      'left-aligned-cell-2', 'Back',
 926      'center-aligned-cell-1', 'Up',
 927      'right-aligned-cell-2', 'Forward'
 928     );
 929
 930 @Texi2HTML::Config::NODE_FOOTER_BUTTONS =
 931     ('left-aligned-cell-1', 'FastBack',
 932      'center-aligned-cell-3', 'Top', 'Contents', 'Index', 'About',
 933      'right-aligned-cell-1', 'FastForward',
 934      'newline',
 935      'left-aligned-cell-2', 'Back',
 936      'center-aligned-cell-1', 'Up',
 937      'right-aligned-cell-2', 'Forward'
 938     );
 939
 940
 941
 942
 943
 944 #############################################################################
 945 ###  FOOTNOTE FORMATTING
 946 #############################################################################
 947
 948 # Format footnotes in a nicer way: Instead of printing the number in a separate
 949 # (nr) heading line, use the standard way of prepending <sup>nr</sup> immediately
 950 # before the fn text.
 951
 952
 953 # The following code is copied from texi2html's examples/makeinfo.init and
 954 # should be updated when texi2html makes some changes there!
 955
 956 my $makekinfo_like_footnote_absolute_number = 0;
 957
 958 sub makeinfo_like_foot_line_and_ref($$$$$$$$)
 959 {
 960     my $foot_num = shift;
 961     my $relative_num = shift;
 962     my $footid = shift;
 963     my $docid = shift;
 964     my $from_file = shift;
 965     my $footnote_file = shift;
 966     my $lines = shift;
 967     my $state = shift;
 968
 969     $makekinfo_like_footnote_absolute_number++;
 970
 971     # this is a bit obscure, this allows to add an anchor only if formatted
 972     # as part of the document.
 973     $docid = '' if ($state->{'outside_document'} or $state->{'multiple_pass'});
 974
 975     if ($from_file eq $footnote_file)
 976     {
 977         $from_file = $footnote_file = '';
 978     }
 979
 980     my $foot_anchor = "<sup>" . &$anchor($docid, "$footnote_file#$footid", $relative_num) . "</sup>";
 981     $foot_anchor = &$anchor($docid, "$footnote_file#$footid", "($relative_num)") if ($state->{'preformatted'});
 982
 983 #    unshift @$lines, "<li>";
 984 #    push @$lines, "</li>\n";
 985     return ($lines, $foot_anchor);
 986 }
 987
 988 sub makeinfo_like_foot_lines($)
 989 {
 990     my $lines = shift;
 991     unshift @$lines, "<hr>\n<h4>$Texi2HTML::I18n::WORDS->{'Footnotes_Title'}</h4>\n";
 992 #<ol type=\"1\">\n";
 993 #    push @$lines, "</ol>";
 994     return $lines;
 995 }
 996
 997 my %makekinfo_like_paragraph_in_footnote_nr;
 998
 999 sub makeinfo_like_paragraph ($$$$$$$$$$$$$)
1000 {
1001     my $text = shift;
1002     my $align = shift;
1003     my $indent = shift;
1004     my $paragraph_command = shift;
1005     my $paragraph_command_formatted = shift;
1006     my $paragraph_number = shift;
1007     my $format = shift;
1008     my $item_nr = shift;
1009     my $enumerate_style = shift;
1010     my $number = shift;
1011     my $command_stack_at_end = shift;
1012     my $command_stack_at_begin = shift;
1013     my $state = shift;
1014 #print STDERR "format: $format\n" if (defined($format));
1015 #print STDERR "paragraph @$command_stack_at_end; @$command_stack_at_begin\n";
1016     $paragraph_command_formatted = '' if (!defined($paragraph_command_formatted) or
1017           exists($special_list_commands{$format}->{$paragraph_command}));
1018     return '' if ($text =~ /^\s*$/);
1019     foreach my $style(t2h_collect_styles($command_stack_at_begin))
1020     {
1021        $text = t2h_begin_style($style, $text);
1022     }
1023     foreach my $style(t2h_collect_styles($command_stack_at_end))
1024     {
1025        $text = t2h_end_style($style, $text);
1026     }
1027     if (defined($paragraph_number) and defined($$paragraph_number))
1028     {
1029          $$paragraph_number++;
1030          return $text  if (($format eq 'itemize' or $format eq 'enumerate') and
1031             ($$paragraph_number == 1));
1032     }
1033     my $open = '<p';
1034     if ($align)
1035     {
1036         $open .= " align=\"$paragraph_style{$align}\"";
1037     }
1038     my $footnote_text = '';
1039     if (defined($command_stack_at_begin->[0]) and $command_stack_at_begin->[0] eq 'footnote')
1040     {
1041         my $state = $Texi2HTML::THISDOC{'state'};
1042         $makekinfo_like_paragraph_in_footnote_nr{$makekinfo_like_footnote_absolute_number}++;
1043         if ($makekinfo_like_paragraph_in_footnote_nr{$makekinfo_like_footnote_absolute_number} <= 1)
1044         {
1045            $open.=' class="footnote"';
1046            my $document_file = $state->{'footnote_document_file'};
1047            if ($document_file eq $state->{'footnote_footnote_file'})
1048            {
1049                $document_file = '';
1050            }
1051            my $docid = $state->{'footnote_place_id'};
1052            my $doc_state = $state->{'footnote_document_state'};
1053            $docid = '' if ($doc_state->{'outside_document'} or $doc_state->{'multiple_pass'});
1054            my $foot_label = &$anchor($state->{'footnote_footnote_id'},
1055                  $document_file . "#$state->{'footnote_place_id'}",
1056                  "$state->{'footnote_number_in_page'}");
1057            $footnote_text = "<small>[${foot_label}]</small> ";
1058         }
1059     }
1060     return $open.'>'.$footnote_text.$text.'</p>';
1061 }
1062
1063
1064 #############################################################################
1065 ###  OTHER SETTINGS
1066 #############################################################################
1067
1068 # For split pages, use index.html as start page!
1069 if ($Texi2HTML::Config::SPLIT eq 'section') {
1070   $Texi2HTML::Config::TOP_FILE = 'index.html';
1071 }
1072
1073
1074 return 1;