stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '\(^\| \)[0-9][0-9]*\.[0-9]' \
  36         | head -n 1 \
  37         | tr ' ' '\n' | sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' | grep '\(^\| \)[0-9][0-9]*\.[0-9]' | head -n 1\`\"
  38
  39     if test -z "$_ver"; then
  40         ## If empty, try date [fontforge]
  41         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  42             | head -n 1 \
  43             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  44     fi
  45     echo "$_ver"
  46     changequote([, ])#dnl
  47 ])
  48
  49 # Calculate simplistic numeric version from version string ($1)
  50 # As yet, we have no need for something more elaborate.
  51 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  52     echo "$1" | awk -F. '
  53     {
  54       if ([$]3) {three = [$]3}
  55       else {three = 0}
  56     }
  57     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  58 ])
  59
  60
  61 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  62 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  63     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  64 ])
  65
  66 # Check if tested program ($2) was found ($1).
  67 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  68 # We could abort here if a 'REQUIRED' program is not found
  69 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  70     STEPMAKE_CHECK_SEARCH_RESULT($1)
  71     if test $? -ne 0; then
  72         STEPMAKE_ADD_ENTRY($3, $2)
  73         if test "$3" = "REQUIRED"; then
  74             command="echo ERROR: $2 not found"
  75             # abort configure process here?
  76         else
  77             command="- echo $2 not found"
  78         fi
  79         eval "$1"='$command'
  80         false
  81     else
  82         true
  83     fi
  84 ])
  85
  86
  87 # Return if tested proram ($1) was found (true) or not (false).
  88 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  89     r="`eval echo '$'"$1"`"
  90     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  91         true
  92     else
  93         ##STEPMAKE_WARN(cannot find $2. $3)
  94         false
  95     fi
  96 ])
  97
  98
  99 # Check version of program ($1)
 100 # If version ($4: optional argument, supply if version cannot be
 101 # parsed using --version or -V ) is smaller than requested ($3), add
 102 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 103 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 104     r="`eval echo '$'"$1"`"
 105     AC_MSG_CHECKING([$r version])
 106     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 107     if test -n "$4"; then
 108         ver="$4"
 109     else
 110         ver=`STEPMAKE_GET_VERSION($exe)`
 111     fi
 112     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 113     req=`STEPMAKE_NUMERIC_VERSION($3)`
 114     AC_MSG_RESULT([$ver])
 115     if test "$num" -lt "$req"; then
 116         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 117     fi
 118     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 119     eval `echo $vervar=$num`
 120 ##    AC_SUBST(`eval echo $vervar`)
 121 ])
 122
 123 # Check version of program ($1)
 124 # If version is greater than or equals unsupported ($3),
 125 # add entry to unsupported list ($2, 'UNSUPPORTED')
 126 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 127     r="`eval echo '$'"$1"`"
 128     AC_MSG_CHECKING([$r version])
 129     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 130     ver=`STEPMAKE_GET_VERSION($exe)`
 131     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 132     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 133     AC_MSG_RESULT([$ver])
 134     if test "$num" -ge "$sup"; then
 135         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 136     fi
 137 ])
 138
 139 ### Macros to build configure.in
 140
 141
 142 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 143     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 144     if test "$BIBTEX2HTML" = "bib2html"; then
 145         BIBTEX2HTML_FLAGS='$< $(@)'
 146     else
 147         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 148     fi
 149     AC_SUBST(BIBTEX2HTML)
 150     AC_SUBST(BIBTEX2HTML_FLAGS)
 151 ])
 152
 153
 154 AC_DEFUN(STEPMAKE_BISON, [
 155     # ugh, automake: we want (and check for) bison
 156     AC_PROG_YACC
 157
 158     STEPMAKE_PROGS(BISON, bison, $1)
 159
 160     # urg.  should test functionality rather than version.
 161     if test "$BISON" = "bison" -a -n "$2"; then
 162         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 163     fi
 164 ])
 165
 166
 167 AC_DEFUN(STEPMAKE_COMPILE, [
 168     # -O is necessary to get inlining
 169     CFLAGS=${CFLAGS-""}
 170     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 171     LDFLAGS=${LDFLAGS-""}
 172     optimise_b=yes
 173     profile_b=no
 174     debug_b=yes
 175     pipe_b=yes
 176
 177     AC_ARG_ENABLE(debugging,
 178     [  --enable-debugging      compile with debugging info.  Default: on],
 179     [debug_b=$enableval])
 180
 181     AC_ARG_ENABLE(optimising,
 182     [  --enable-optimising     compile with optimising.  Default: on],
 183     [optimise_b=$enableval])
 184
 185     AC_ARG_ENABLE(profiling,
 186     [  --enable-profiling      compile with gprof support.  Default: off],
 187     [profile_b=$enableval])
 188
 189     AC_ARG_ENABLE(pipe,
 190     [  --enable-pipe           compile with -pipe.  Default: on],
 191     [pipe_b=$enableval])
 192
 193     if test "$optimise_b" = yes; then
 194         AC_DEFINE(NDEBUG)
 195         DEFINES="$DEFINES -DNDEBUG"
 196         OPTIMIZE=" -O2 -finline-functions"
 197     fi
 198
 199     if test $profile_b = yes; then
 200         EXTRA_LIBS="-pg"
 201         OPTIMIZE="$OPTIMIZE -pg"
 202     fi
 203
 204     if test $debug_b = yes; then
 205         OPTIMIZE="$OPTIMIZE -g"
 206     fi
 207
 208     AC_PROG_CC
 209     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 210     LD='$(CC)'
 211     AC_SUBST(LD)
 212
 213     # If -pipe requested, test if it works and add to CFLAGS.
 214     if test "$pipe_b" = yes; then
 215         save_cflags="$CFLAGS"
 216         CFLAGS=" -pipe $CFLAGS";
 217         AC_CACHE_CHECK([whether compiler understands -pipe],
 218             [stepmake_cflags_pipe],
 219             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 220                 [stepmake_cflags_pipe=yes],
 221                 [stepmake_cflags_pipe=no]))
 222         CFLAGS=$save_cflags
 223         if test $stepmake_cflags_pipe = yes; then
 224             OPTIMIZE="$OPTIMIZE -pipe"
 225         fi
 226     fi
 227
 228     CFLAGS="$CFLAGS $OPTIMIZE"
 229     CPPFLAGS=${CPPFLAGS-""}
 230
 231     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 232     save_cflags="$CFLAGS"
 233     case "$host" in
 234         alpha*-*-*)
 235             dnl should do compile test?
 236             AC_MSG_RESULT(-mieee)
 237             CFLAGS=" -mieee $CFLAGS"
 238             ;;
 239         *)
 240             AC_MSG_RESULT([none])
 241             ;;
 242     esac
 243
 244     AC_SUBST(cross_compiling)
 245     AC_SUBST(CFLAGS)
 246     AC_SUBST(CPPFLAGS)
 247     AC_SUBST(LDFLAGS)
 248     AC_SUBST(DEFINES)
 249     AC_SUBST(EXTRA_LIBS)
 250 ])
 251
 252 AC_DEFUN(STEPMAKE_CXX, [
 253     AC_LANG([C++])
 254     AC_PROG_CXX
 255     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 256
 257     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 258     LD='$(CXX)'
 259
 260     AC_SUBST(CXX)
 261     AC_SUBST(CXXFLAGS)
 262     AC_SUBST(LD)
 263 ])
 264
 265
 266 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 267     AC_CACHE_CHECK([whether explicit instantiation is needed],
 268         lily_cv_need_explicit_instantiation,
 269         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 270     template <class T> struct foo { static int baz; };
 271     template <class T> int foo<T>::baz = 1;
 272     ]], [[ return foo<int>::baz; ]])],[lily_cv_need_explicit_instantiation=no],[lily_cv_need_explicit_instantiation=yes]))
 273     if test x"$lily_cv_need_explicit_instantiation"x = x"yes"x; then
 274         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 275     fi
 276 ])
 277
 278
 279 AC_DEFUN(STEPMAKE_DATADIR, [
 280     if test "$datadir" = "\${prefix}/share"; then
 281             datadir='${prefix}/share'
 282     fi
 283     presome=${prefix}
 284     if test "$prefix" = "NONE"; then
 285         presome=${ac_default_prefix}
 286     fi
 287
 288     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 289
 290     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 291     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 292     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 293
 294     AC_SUBST(datadir)
 295     AC_SUBST(datarootdir)
 296     AC_SUBST(build_package_datadir)
 297     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 298     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 299 ])
 300
 301 ## ugh: cut & paste programming from datadir.
 302 AC_DEFUN(STEPMAKE_LIBDIR, [
 303
 304     if test "$libdir" = "\${exec_prefix}/lib"; then
 305         libdir='${exec_prefix}/lib'
 306     fi
 307     presome=$exec_prefix
 308     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 309
 310     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 311     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 312
 313     AC_SUBST(libdir)
 314     AC_SUBST(build_package_libdir)
 315     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 316     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 317 ])
 318
 319
 320 AC_DEFUN(STEPMAKE_END, [
 321     AC_SUBST(OPTIONAL)
 322     AC_SUBST(REQUIRED)
 323
 324     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 325     AC_OUTPUT
 326
 327     if test -n "$OPTIONAL"; then
 328         echo
 329         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 330     fi
 331
 332     if test -n "$REQUIRED"; then
 333         echo
 334         echo "ERROR: Please install required programs: $REQUIRED"
 335     fi
 336
 337     if test -n "$UNSUPPORTED"; then
 338         echo
 339         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 340     fi
 341
 342     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 343         echo
 344         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 345         if test -f config.cache ; then
 346             echo "Remove config.cache before rerunning ./configure"
 347         fi
 348     fi
 349
 350     if test -n "$REQUIRED$UNSUPPORTED"; then
 351         rm -f $srcdir/GNUmakefile
 352         exit 1
 353     fi
 354
 355     # regular in-place build
 356     # test for srcdir_build = yes ?
 357     if test "$srcdir_build" = "yes"; then
 358         rm -f $srcdir/GNUmakefile
 359         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 360         chmod 444 $srcdir/GNUmakefile
 361     else
 362         if test -f $srcdir/GNUmakefile; then
 363             cat <<EOF
 364 Source directory already configured.  Please clean the source directory
 365
 366      make -C $srcdir distclean
 367
 368 and rerun configure.
 369 EOF
 370             exit 2
 371         fi
 372
 373         for d in 2 3 4 ; do
 374             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 375                 mkdir -p $(dirname $mf)
 376                 cat <<EOF | $PYTHON -  > $mf
 377 print 'depth=' + ('../' * ( $d-1 ) )
 378 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 379 print 'include \$(configure-srcdir)/$mf'
 380 EOF
 381             done
 382             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 383                 mkdir -p $(dirname $mf)
 384                 cat <<EOF | $PYTHON -  > $mf
 385 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 386 print 'include \$(configure-srcdir)/$mf'
 387 EOF
 388             done
 389         done
 390
 391
 392         cat <<EOF > GNUmakefile
 393 depth = ./
 394 include config\$(if \$(conf),-\$(conf),).make
 395 include \$(configure-srcdir)/GNUmakefile.in
 396 EOF
 397         AC_SUBST(VPATH)
 398     fi
 399 ])
 400
 401
 402 AC_DEFUN(STEPMAKE_FLEX, [
 403     # ugh, automake: we want (and check for) flex
 404     # AC_PROG_LEX
 405     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 406
 407     # AC_PROG_LEX()
 408     # ugh, ugh
 409     ac_cv_prog_lex_root=lex.yy
 410     STEPMAKE_PROGS(FLEX, flex, $1)
 411 ])
 412
 413
 414 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 415     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 416     if test $? -ne 0; then
 417         warn='FlexLexer.h (flex package)'
 418         STEPMAKE_ADD_ENTRY($1, $warn)
 419     fi
 420     # check for yyFlexLexer.yy_current_buffer,
 421     # in 2.5.4 <= flex < 2.5.29
 422     AC_LANG_PUSH(C++)
 423     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 424         [stepmake_flexlexer_yy_current_buffer],
 425         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 426 using namespace std;
 427 #include <FlexLexer.h>
 428 class yy_flex_lexer: public yyFlexLexer
 429 {
 430   public:
 431     yy_flex_lexer ()
 432     {
 433       yy_current_buffer = 0;
 434     }
 435 };
 436 ]])],
 437             [stepmake_flexlexer_yy_current_buffer=yes],
 438             [stepmake_flexlexer_yy_current_buffer=no]))
 439     if test $stepmake_flexlexer_yy_current_buffer = yes; then
 440         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 441     fi
 442     AC_LANG_POP(C++)
 443 ])
 444
 445
 446
 447 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 448         AC_MSG_CHECKING([FlexLexer.h location])
 449
 450         # ugh.
 451         cat <<EOF > conftest.cc
 452 using namespace std;
 453 #include <FlexLexer.h>
 454 EOF
 455         FLEXLEXER_FILE=`$CXX -E conftest.cc | \
 456           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 457           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 458         rm conftest.cc
 459         AC_SUBST(FLEXLEXER_FILE)
 460         AC_MSG_RESULT($FLEXLEXER_FILE)
 461 ])
 462
 463 AC_DEFUN(STEPMAKE_GCC, [
 464     if test "$GCC" = "yes"; then
 465         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 466     else
 467         warn="$CC (Please install *GNU* cc)"
 468         STEPMAKE_ADD_ENTRY($1, $warn)
 469     fi
 470 ])
 471
 472 AC_DEFUN(STEPMAKE_GETTEXT, [
 473     presome=${prefix}
 474     if test "$prefix" = "NONE"; then
 475             presome=${ac_default_prefix}
 476     fi
 477     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 478
 479     AC_SUBST(localedir)
 480     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 481     # ouch.  autoconf <= 2.57's gettext check fails for
 482     # g++ >= 3.3 (with -std=gnu++98, the default).
 483     # While the check is OK for g++ -std=c++98,
 484     # LilyPond needs GNU g++, so who is to blame here?
 485     # Use a workaround until this is resolved:
 486     # for g++ >= 3.3, select C language.
 487     GCC_UNSUPPORTED=
 488     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 489     if test -n "$GCC_UNSUPPORTED"; then
 490         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 491         AC_MSG_WARN([Trying gcc, cross fingers.])
 492         AC_LANG_PUSH(C)
 493     fi
 494     AC_CHECK_LIB(intl, gettext)
 495     AC_CHECK_FUNCS(gettext)
 496     if test -n "$GCC_UNSUPPORTED"; then
 497         AC_LANG_POP(C)
 498     fi
 499 ])
 500
 501
 502 AC_DEFUN(STEPMAKE_GUILE, [
 503     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 504 ])
 505
 506
 507 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 508 #
 509 #   This macro runs the guile-config script, installed with Guile,
 510 #   to find out where Guile's header files and libraries are
 511 #   installed.  It sets two variables, marked for substitution, as
 512 #   by AC_SUBST.
 513 #
 514 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 515 #             code that uses Guile header files.  This is almost
 516 #             always just a -I flag.
 517 #
 518 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 519 #             program against Guile.  This includes -lguile for
 520 #             the Guile library itself, any libraries that Guile
 521 #             itself requires (like -lqthreads), and so on.  It may
 522 #             also include a -L flag to tell the compiler where to
 523 #             find the libraries.
 524
 525 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 526     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 527     if test -x $exe; then
 528         AC_MSG_CHECKING([guile compile flags])
 529         GUILE_CFLAGS="`$guile_config compile`"
 530         AC_MSG_RESULT($GUILE_CFLAGS)
 531         AC_MSG_CHECKING([guile link flags])
 532         GUILE_LDFLAGS="`$guile_config link`"
 533         AC_MSG_RESULT($GUILE_LDFLAGS)
 534     fi
 535     AC_SUBST(GUILE_CFLAGS)
 536     AC_SUBST(GUILE_LDFLAGS)
 537 ])
 538
 539
 540 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 541     ## First, let's just see if we can find Guile at all.
 542     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 543     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 544     AC_MSG_CHECKING([for guile-config])
 545     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 546         AC_MSG_RESULT([$guile_config])
 547         if ! $guile_config --version > /dev/null 2>&1 ; then
 548             AC_MSG_WARN([cannot execute $guile_config])
 549             AC_MSG_CHECKING([if we are cross compiling])
 550             GUILE_CONFIG='echo no guile-config'
 551         else
 552             GUILE_CONFIG=$guile_config
 553             break
 554         fi
 555     done
 556     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 557     if test $? -ne 0; then
 558         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 559     fi
 560
 561     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 562     # urg.  should test functionality rather than version.
 563     if test $? -eq 0 -a -n "$2"; then
 564         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 565     fi
 566
 567     AC_SUBST(GUILE_CONFIG)
 568
 569     guile_version="$ver"
 570     changequote(<<, >>)#dnl
 571     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 572     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 573     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 574     changequote([, ])#dnl
 575     STEPMAKE_GUILE_FLAGS
 576     save_CPPFLAGS="$CPPFLAGS"
 577     save_LIBS="$LIBS"
 578     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 579     LIBS="$GUILE_LDFLAGS $LIBS"
 580     AC_CHECK_HEADERS([libguile.h])
 581     AC_CHECK_LIB(guile, scm_boot_guile)
 582     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 583     if test "$libguile_b" = "no"; then
 584             warn='libguile (libguile-dev, guile-devel or guile-dev
 585    package).'
 586             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 587     fi
 588     CPPFLAGS="$save_CPPFLAGS"
 589     LIBS="$save_LIBS"
 590     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 591     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 592     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 593 ])
 594
 595
 596 AC_DEFUN(STEPMAKE_DLOPEN, [
 597     AC_CHECK_LIB(dl, dlopen)
 598     AC_CHECK_FUNCS(dlopen)
 599 ])
 600
 601 AC_DEFUN(STEPMAKE_GXX, [
 602     if test "$GXX" = "yes"; then
 603         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 604     else
 605         warn="$CXX (Please install *GNU* c++)"
 606         STEPMAKE_ADD_ENTRY($1, $warn)
 607     fi
 608 ])
 609
 610
 611 AC_DEFUN(STEPMAKE_INIT, [
 612
 613     AC_PREREQ(2.50)
 614     . $srcdir/VERSION
 615     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 616     MICRO_VERSION=$PATCH_LEVEL
 617     TOPLEVEL_VERSION=$FULL_VERSION
 618     if test x$MY_PATCH_LEVEL != x; then
 619         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 620     fi
 621     VERSION=$FULL_VERSION
 622     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 623     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 624     changequote(<<, >>)#dnl
 625     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 626     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 627     changequote([, ])#dnl
 628
 629     # No versioning on directory names of sub-packages
 630     # urg, urg
 631     stepmake=${datadir}/stepmake
 632     presome=${prefix}
 633     if test "$prefix" = "NONE"; then
 634             presome=${ac_default_prefix}
 635     fi
 636     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 637
 638     # urg, how is this supposed to work?
 639     if test "$program_prefix" = "NONE"; then
 640           program_prefix=
 641     fi
 642     if test "$program_suffix" = "NONE"; then
 643           program_suffix=
 644     fi
 645
 646     AC_MSG_CHECKING(Package)
 647     if test "$PACKAGE" = "STEPMAKE"; then
 648         AC_MSG_RESULT(Stepmake package!)
 649
 650         AC_MSG_CHECKING(builddir)
 651
 652         ugh_ugh_autoconf250_builddir="`pwd`"
 653
 654         if test "$srcdir" = "."; then
 655             srcdir_build=yes
 656         else
 657             srcdir_build=no
 658             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 659             package_srcdir="`dirname  $srcdir`"
 660         fi
 661         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 662
 663         (cd stepmake 2>/dev/null || mkdir stepmake)
 664         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 665         stepmake=stepmake
 666     else
 667         AC_MSG_RESULT($PACKAGE)
 668
 669         AC_MSG_CHECKING(builddir)
 670         ugh_ugh_autoconf250_builddir="`pwd`"
 671
 672         here_dir=$(cd . && pwd)
 673         full_src_dir=$(cd $srcdir && pwd)
 674
 675         if test "$full_src_dir" = "$here_dir"; then
 676             srcdir_build=yes
 677         else
 678             srcdir_build=no
 679         fi
 680         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 681
 682         AC_MSG_CHECKING(for stepmake)
 683         # Check for installed stepmake
 684         if test -d $stepmake; then
 685             AC_MSG_RESULT($stepmake)
 686         else
 687             stepmake="`cd $srcdir/stepmake; pwd`"
 688             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 689         fi
 690     fi
 691
 692     AC_SUBST(ugh_ugh_autoconf250_builddir)
 693
 694     # Use absolute directory for non-srcdir builds, so that build
 695     # dir can be moved.
 696     if test "$srcdir_build" = "no" ;  then
 697         srcdir="`cd $srcdir; pwd`"
 698     fi
 699
 700     AC_SUBST(srcdir)
 701     AC_SUBST(stepmake)
 702     AC_SUBST(package)
 703     AC_SUBST(PACKAGE)
 704     AC_SUBST(PACKAGE_NAME)
 705     AC_SUBST(VERSION)
 706     AC_SUBST(MAJOR_VERSION)
 707     AC_SUBST(MINOR_VERSION)
 708     AC_SUBST(MICRO_VERSION)
 709
 710     # stepmake nonstandard names
 711     AC_SUBST(PATCH_LEVEL)
 712     AC_SUBST(TOPLEVEL_VERSION)
 713
 714     # We don't need the upper case variant,
 715     # so stick to macros are uppercase convention.
 716     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 717     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 718     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 719     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 720     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 721
 722     if test -z "$package_depth"; then
 723         package_depth="."
 724     else
 725         package_depth="../$package_depth"
 726     fi
 727     export package_depth
 728     AC_SUBST(package_depth)
 729
 730     AUTOGENERATE="This file was automatically generated by configure"
 731     AC_SUBST(AUTOGENERATE)
 732
 733     CONFIGSUFFIX=
 734     AC_ARG_ENABLE(config,
 735     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 736                             do `make conf=CONF' to get output in ./out-CONF],
 737     [CONFIGURATION=$enableval])
 738
 739     ##'`#
 740
 741     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 742     CONFIGFILE=config$CONFIGSUFFIX
 743     AC_SUBST(CONFIGSUFFIX)
 744
 745     AC_CANONICAL_HOST
 746     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 747     STEPMAKE_PROGS(FIND, find, REQUIRED)
 748
 749     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 750
 751     if test "$(echo 2)" != "2" ||
 752         test "x`uname`" = "xHP-UX"; then
 753         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 754         AC_PATH_PROG(BASH, bash, $KSH)
 755         STEPMAKE_WARN(avoiding buggy /bin/sh)
 756         AC_PATH_PROG(SHELL, bash, $KSH)
 757     else
 758         SHELL=/bin/sh
 759         AC_PATH_PROG(BASH, bash, $SHELL)
 760     fi
 761     AC_SUBST(SHELL)
 762
 763     STEPMAKE_PYTHON(REQUIRED, 1.5)
 764
 765     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 766         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 767         if test "$?" = 1; then
 768             warn='make (Please install *GNU* make)'
 769             # STEPMAKE_WARN($warn)
 770             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 771         fi
 772     fi
 773
 774     ROOTSEP=':'
 775     DIRSEP='/'
 776     PATHSEP=':'
 777     LN=ln
 778     LN_S='ln -s'
 779     ZIP="zip -r -9"
 780
 781     AC_SUBST(program_prefix)
 782     AC_SUBST(program_suffix)
 783     AC_SUBST(ZIP)
 784     AC_SUBST(LN)
 785     AC_SUBST(LN_S)
 786     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 787     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 788     AC_SUBST(DIRSEP)
 789     AC_SUBST(PATHSEP)
 790     AC_SUBST(ROOTSEP)
 791
 792     STEPMAKE_DATADIR
 793     STEPMAKE_LIBDIR
 794 ])
 795
 796
 797 AC_DEFUN(STEPMAKE_KPATHSEA, [
 798
 799     AC_ARG_WITH(kpathsea-include,
 800         [  --with-kpathsea-include=DIR
 801                           location of the kpathsea include dir],[
 802             if test "$withval" = "yes" -o "$withval" = "no"; then
 803                 AC_MSG_WARN(Usage: --with-kpathsea-include=includedir)
 804             else
 805                 CPPFLAGS="$CPPFLAGS -I${withval}"
 806             fi
 807             ])
 808
 809     AC_ARG_WITH(kpathsea-lib,
 810         [  --with-kpathsea-lib=DIR location of the kpathsea lib dir],[
 811             if test "$withval" = "yes" -o "$withval" = "no"; then
 812                 AC_MSG_WARN(Usage: --with-kpathsea-lib=libdir)
 813             else
 814                 LDFLAGS="$LDFLAGS -L${withval}"
 815             fi
 816             ])
 817
 818     kpathsea_b=yes
 819     AC_ARG_ENABLE(kpathsea,
 820     [  --enable-kpathsea         use kpathsea lib.  Default: on],
 821     [kpathsea_b=$enableval])
 822
 823     save_LIBS="$LIBS"
 824     if test "$kpathsea_b" != "no"; then
 825         AC_CHECK_HEADERS([kpathsea/kpathsea.h],,kpathsea_b=no)
 826         AC_CHECK_LIB(kpathsea, kpse_find_file)
 827         AC_CHECK_FUNCS(kpse_find_file,,kpathsea_b=no)
 828         if test "$kpathsea_b" = "no"; then
 829             STEPMAKE_ADD_ENTRY(OPTIONAL, $warn)
 830         fi
 831     fi
 832
 833     save_CFLAGS="$CFLAGS"
 834     CFLAGS=`echo "-shared $CFLAGS" | sed -e 's/ -g//'`
 835     AC_MSG_CHECKING([for shared libkpathsea])
 836     AC_TRY_LINK([#include <kpathsea/kpathsea.h>],
 837                  [kpse_var_expand ("\$TEXMF");],
 838                  [have_libkpathsea_so=maybe;
 839                   shared_size=`wc -c conftest$ac_exeext`;
 840                   shared_size=`echo $shared_size | sed -e 's/ .*//g'`],
 841                  [have_libkpathsea_so=no])
 842
 843     if test "$have_libkpathsea_so" = "maybe"; then
 844         if test "$shared_size" -lt 40000 ; then
 845           have_libkpathsea_so=yes
 846         else
 847           have_libkpathsea_so=no
 848         fi
 849     fi
 850
 851     AC_MSG_RESULT($have_libkpathsea_so)
 852     if test "$have_libkpathsea_so" = "yes"; then
 853         AC_DEFINE(HAVE_LIBKPATHSEA_SO)
 854     fi
 855     CFLAGS="$save_CFLAGS"
 856
 857     KPATHSEA_LIBS="$LIBS"
 858     LIBS="$save_LIBS"
 859     AC_MSG_CHECKING(whether to use kpathsea)
 860     if test "$kpathsea_b" != no; then
 861         AC_MSG_RESULT(yes)
 862         KPATHSEA=1
 863     else
 864         AC_MSG_RESULT(no)
 865         KPATHSEA=0
 866     fi
 867
 868     AC_SUBST(KPATHSEA)
 869     AC_SUBST(KPATHSEA_LIBS)
 870     AC_SUBST(HAVE_LIBKPATHSEA_SO, $have_libkpathsea_so)
 871     AC_DEFINE_UNQUOTED(KPATHSEA, $KPATHSEA)
 872 ])
 873
 874
 875 AC_DEFUN(STEPMAKE_LIB, [
 876     STEPMAKE_PROGS(AR, ar, $1)
 877     AC_PROG_RANLIB
 878     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 879 ])
 880
 881
 882 AC_DEFUN(STEPMAKE_LIBTOOL, [
 883     # libtool.info ...
 884     # **Never** try to set library version numbers so that they correspond
 885     # to the release number of your package.  This is an abuse that only
 886     # fosters misunderstanding of the purpose of library versions.
 887
 888     REVISION=$PATCH_LEVEL
 889     # CURRENT=$MINOR_VERSION
 890     CURRENT=`expr $MINOR_VERSION + 1`
 891     # AGE=`expr $MAJOR_VERSION + 1`
 892     AGE=$MAJOR_VERSION
 893     AC_SUBST(CURRENT)
 894     AC_SUBST(REVISION)
 895     AC_SUBST(AGE)
 896 ])
 897
 898
 899 AC_DEFUN(STEPMAKE_LOCALE, [
 900     lang=English
 901     ALL_LINGUAS="en nl"
 902
 903     # with/enable ??
 904     AC_ARG_WITH(localedir,
 905     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 906     localedir=$with_localedir,
 907     localedir='${prefix}/share/locale')
 908
 909     AC_ARG_WITH(lang,
 910     [  --with-lang=LANG        use LANG as language to emit messages],
 911     language=$with_lang,
 912     language=English)
 913
 914     AC_MSG_CHECKING(language)
 915     case "$language" in
 916       En* | en* | Am* | am* | US* | us*)
 917             lang=English;;
 918       NL | nl | Du* | du* | Ned* | ned*)
 919             lang=Dutch;;
 920       "")
 921             lang=English;;
 922       *)
 923             lang=unknown;;
 924     esac
 925     AC_MSG_RESULT($lang)
 926
 927     if test "$lang" = "unknown" ; then
 928         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 929     fi
 930
 931 ])
 932
 933
 934 AC_DEFUN(STEPMAKE_MAKEINFO, [
 935     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 936 ])
 937
 938
 939 AC_DEFUN(STEPMAKE_MAN, [
 940     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 941     AC_SUBST(GROFF)
 942     STEPMAKE_PROGS(TROFF, troff, $1)
 943     AC_SUBST(TROFF)
 944     STEPMAKE_PROGS(TBL, tbl, $1)
 945     AC_SUBST(TBL)
 946 ])
 947
 948
 949 AC_DEFUN(STEPMAKE_MSGFMT, [
 950     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 951 ])
 952
 953
 954 # Check for program ($2), set full path result to ($1).
 955 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 956 AC_DEFUN(STEPMAKE_PATH_PROG, [
 957     AC_CHECK_PROGS($1, $2, no)
 958     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 959     if test $? -eq 0; then
 960         AC_PATH_PROG($1, $2)
 961         if test -n "$4"; then
 962             STEPMAKE_CHECK_VERSION($1, $3, $4)
 963         fi
 964     fi
 965 ])
 966
 967
 968 # Check for program in set of names ($2), set result to ($1) .
 969 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 970 # If exists, and a minimal version ($4) is required
 971 AC_DEFUN(STEPMAKE_PROGS, [
 972     AC_CHECK_PROGS($1, $2, no)
 973     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 974     if test $? -eq 0 -a -n "$4"; then
 975         STEPMAKE_CHECK_VERSION($1, $3, $4)
 976     fi
 977 ])
 978
 979
 980 AC_DEFUN(STEPMAKE_PERL, [
 981     STEPMAKE_PATH_PROG(PERL, perl, $1)
 982 ])
 983
 984
 985 AC_DEFUN(STEPMAKE_PYTHON, [
 986     unset pv
 987     AC_MSG_CHECKING([for python])
 988     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 989         AC_MSG_RESULT([$python])
 990         if ! $python -V > /dev/null 2>&1 ; then
 991             #AC_MSG_WARN([cannot execute $python])
 992             PYTHON='echo no python'
 993         else
 994             unset pv
 995             STEPMAKE_CHECK_VERSION(python, pv, $2)
 996             if test -z "$pv"; then
 997                 PYTHON=$python
 998                 break
 999             fi
1000         fi
1001     done
1002     if test -n "$pv"; then
1003         STEPMAKE_ADD_ENTRY($1, $pv)
1004     fi
1005     # clear cached value since arg 2 might point us to a new binary
1006     unset ac_cv_path_PYTHON
1007
1008     AC_PATH_PROG(PYTHON, $PYTHON)
1009     AC_SUBST(PYTHON)
1010 ])
1011
1012 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
1013     AC_ARG_WITH(python-include,
1014         [  --with-python-include=DIR
1015                           location of the python include dir],[
1016             if test "$withval" = "yes" -o "$withval" = "no"; then
1017                 AC_MSG_WARN(Usage: --with-python-include=includedir)
1018             else
1019                 PYTHON_CFLAGS="-I${withval}"
1020             fi
1021             ])
1022
1023     AC_ARG_WITH(python-lib,
1024         [  --with-python-lib=NAME  name of the python lib],[
1025             if test "$withval" = "yes" -o "$withval" = "no"; then
1026                 AC_MSG_WARN(Usage: --with-python-lib=name)
1027             else
1028                 LDFLAGS="$LDFLAGS -l${withval}"
1029             fi
1030             ])
1031
1032     if test "$cross_compiling" = "no" -a -z "$PYTHON_CFLAGS"; then
1033         changequote(<<, >>)#dnl
1034         # alternatively, for python >= 2.0
1035         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
1036         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
1037         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
1038         changequote([, ])#dnl
1039     fi
1040
1041     if test "$cross_compiling" = "yes" -a -z "$PYTHON_CFLAGS"; then
1042         PYTHON_CFLAGS=`python-config --cflags`
1043         PYTHON_LDFLAGS=`python-config --ldflags`
1044     fi
1045
1046     if test -z "$PYTHON_HEADER"; then
1047         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1048         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1049     fi
1050
1051     if test -z "$PYTHON_HEADER"; then
1052         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1053         STEPMAKE_ADD_ENTRY($1, $warn)
1054     fi
1055 ])
1056
1057
1058
1059 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1060     AC_LANG_PUSH(C++)
1061     AC_CACHE_CHECK([for stl.data () method],
1062         [stepmake_stl_data_method],
1063         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1064 #include <vector>
1065 using namespace std;
1066 vector <int> v;
1067 void *p = v.data ();
1068 ]])],
1069             [stepmake_stl_data_method=yes],
1070             [stepmake_stl_data_method=no]))
1071     if test $stepmake_stl_data_method = yes; then
1072         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1073     fi
1074     AC_LANG_POP(C++)
1075 ])
1076
1077
1078 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1079     # ugh
1080     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1081 ])
1082
1083 AC_DEFUN(STEPMAKE_TEXMF, [
1084     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1085     # STEPMAKE_PROGS(INIMETAFONT, inimf inimfont "$METAFONT -ini", $1)
1086
1087     AC_MSG_CHECKING(for working metafont mode)
1088     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1089     for MFMODE in $modelist; do
1090         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1091         if test -f mfput.tfm; then
1092             break;
1093         fi
1094     done
1095     AC_MSG_RESULT($MFMODE)
1096
1097     rm -f mfput.*
1098
1099     AC_SUBST(MFMODE)
1100 ])
1101
1102
1103 AC_DEFUN(STEPMAKE_WARN, [
1104     AC_MSG_WARN($1)
1105     warn_b=yes
1106 ])
1107
1108
1109 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1110 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1111 dnl also defines GSTUFF_PKG_ERRORS on error
1112 AC_DEFUN(PKG_CHECK_MODULES, [
1113   succeeded=no
1114
1115   if test -z "$PKG_CONFIG"; then
1116     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1117   fi
1118
1119   if test "$PKG_CONFIG" = "no" ; then
1120      echo "*** The pkg-config script could not be found. Make sure it is"
1121      echo "*** in your path, or set the PKG_CONFIG environment variable"
1122      echo "*** to the full path to pkg-config."
1123      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1124   else
1125      PKG_CONFIG_MIN_VERSION=0.9.0
1126      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1127         AC_MSG_CHECKING(for $2)
1128
1129         if $PKG_CONFIG --exists "$2" ; then
1130             AC_MSG_RESULT(yes)
1131             succeeded=yes
1132
1133             AC_MSG_CHECKING($1_CFLAGS)
1134             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1135             AC_MSG_RESULT($$1_CFLAGS)
1136
1137             AC_MSG_CHECKING($1_LIBS)
1138             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1139             AC_MSG_RESULT($$1_LIBS)
1140         else
1141             $1_CFLAGS=""
1142             $1_LIBS=""
1143             ## If we have a custom action on failure, don't print errors, but
1144             ## do set a variable so people can do so.
1145             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1146             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1147         fi
1148
1149         AC_SUBST($1_CFLAGS)
1150         AC_SUBST($1_LIBS)
1151      fi
1152   fi
1153
1154   if test $succeeded = yes; then
1155      ifelse([$3], , :, [$3])
1156   else
1157      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1158   fi
1159 ])
1160
1161 AC_DEFUN(STEPMAKE_FREETYPE2, [
1162     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1163     if test "$have_freetype2" = yes; then
1164         AC_DEFINE(HAVE_FREETYPE2)
1165         save_CPPFLAGS="$CPPFLAGS"
1166         save_LIBS="$LIBS"
1167         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1168         LIBS="$FREETYPE2_LIBS $LIBS"
1169         AC_SUBST(FREETYPE2_CFLAGS)
1170         AC_SUBST(FREETYPE2_LIBS)
1171         CPPFLAGS="$save_CPPFLAGS"
1172         LIBS="$save_LIBS"
1173     else
1174         # UGR
1175         #r="lib$1-dev or $1-devel"
1176         r="libfreetype6-dev or freetype?-devel"
1177         ver="`pkg-config --modversion $1`"
1178         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1179     fi
1180 ])
1181
1182 AC_DEFUN(STEPMAKE_GTK2, [
1183     PKG_CHECK_MODULES(GTK2, $1 >= $3, have_gtk2=yes, true)
1184     if test "$have_gtk2" = yes ; then
1185         AC_DEFINE(HAVE_GTK2)
1186         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1187         save_CPPFLAGS="$CPPFLAGS"
1188         save_LIBS="$LIBS"
1189         CPPFLAGS="$GTK2_CFLAGS $CPPFLAGS"
1190         LIBS="$GTK2_LIBS $LIBS"
1191         AC_SUBST(GTK2_CFLAGS)
1192         AC_SUBST(GTK2_LIBS)
1193         CPPFLAGS="$save_CPPFLAGS"
1194         LIBS="$save_LIBS"
1195     else
1196         # UGR
1197         # r="lib$1-dev or $1-devel"
1198         r="libgtk2.0-dev or gtk2-devel"
1199         ver="`pkg-config --modversion $1`"
1200         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1201     fi
1202 ])
1203
1204 AC_DEFUN(STEPMAKE_PANGO, [
1205     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1206     if test "$have_pango16" = yes ; then
1207         AC_DEFINE(HAVE_PANGO16)
1208         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1209         save_CPPFLAGS="$CPPFLAGS"
1210         save_LIBS="$LIBS"
1211         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1212         LIBS="$PANGO_LIBS $LIBS"
1213         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1214         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1215         AC_SUBST(PANGO_CFLAGS)
1216         AC_SUBST(PANGO_LIBS)
1217         CPPFLAGS="$save_CPPFLAGS"
1218         LIBS="$save_LIBS"
1219     else
1220         # UGR
1221         #r="lib$1-dev or $1-devel"
1222         r="libpango1.0-dev or pango1.0-devel"
1223         ver="`pkg-config --modversion $1`"
1224         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1225     fi
1226 ])
1227
1228 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1229     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1230     if test "$have_pangoft2" = yes ; then
1231         AC_DEFINE(HAVE_PANGO16)
1232         AC_DEFINE(HAVE_PANGO_FT2)
1233         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1234         save_CPPFLAGS="$CPPFLAGS"
1235         save_LIBS="$LIBS"
1236         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1237         LIBS="$PANGO_FT2_LIBS $LIBS"
1238         AC_CHECK_HEADERS([pango/pangoft2.h])
1239         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1240         AC_SUBST(PANGO_FT2_CFLAGS)
1241         AC_SUBST(PANGO_FT2_LIBS)
1242         CPPFLAGS="$save_CPPFLAGS"
1243         LIBS="$save_LIBS"
1244     else
1245         # UGR
1246         #r="lib$1-dev or $1-devel"e
1247         r="libpango1.0-dev or pango?-devel"
1248         ver="`pkg-config --modversion $1`"
1249         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1250     fi
1251 ])
1252
1253 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1254     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1255     if test "$have_fontconfig" = yes ; then
1256         AC_DEFINE(HAVE_FONTCONFIG)
1257         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1258         save_CPPFLAGS="$CPPFLAGS"
1259         save_LIBS="$LIBS"
1260         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1261         LIBS="$FONTCONFIG_LIBS $LIBS"
1262         AC_SUBST(FONTCONFIG_CFLAGS)
1263         AC_SUBST(FONTCONFIG_LIBS)
1264         CPPFLAGS="$save_CPPFLAGS"
1265         LIBS="$save_LIBS"
1266     else
1267         r="lib$1-dev or $1-devel"
1268         ver="`pkg-config --modversion $1`"
1269         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1270     fi
1271 ])
1272
1273 AC_DEFUN(STEPMAKE_WINDOWS, [
1274     AC_CYGWIN
1275     AC_MINGW32
1276
1277     if test "$CYGWIN" = "yes"; then
1278         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1279         program_suffix=.exe
1280         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1281     elif test "$MINGW32" = "yes"; then
1282         LN='cp -r'
1283         LN_S='cp -r'
1284         program_suffix=.exe
1285         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1286         PATHSEP=';'
1287     fi
1288
1289     AC_SUBST(LN)
1290     AC_SUBST(LN_S)
1291     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1292     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1293     AC_SUBST(DIRSEP)
1294     AC_SUBST(PATHSEP)
1295     AC_SUBST(program_suffix)
1296
1297     AC_MSG_CHECKING([for some flavor of Windows])
1298     if test "$CYGWIN$MINGW32" = "nono"; then
1299         PLATFORM_WINDOWS=no
1300     else
1301         PLATFORM_WINDOWS=yes
1302     fi
1303     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1304     AC_SUBST(PLATFORM_WINDOWS)
1305     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1306     AC_SUBST(WINDRES)
1307 ])