mf/feta-banier.mf

   1 % flags
   2 %
   3
   4
   5 fet_begingroup("flags")
   6 save outer_path;
   7 path outer_path;
   8 % Flags pointing down overlap with  the notehead (in x-direction), so
   9 % the down-flag can be bigger
  10 upflag_width# = .750 black_notehead_width# + stemthickness#/2;
  11 downflag_width# = .833 black_notehead_width# + stemthickness#/2;
  12
  13 right_upflag_space# = .2 upflag_width#;
  14 right_downflag_space# = .2 downflag_width#;
  15
  16 %
  17 % Flags pointing down cannot overlap with the notehead in y-direction,
  18 % so they have less slant.
  19
  20 % Because of optical illusion, the utmost flag (bottom for
  21 % down-pointing, top for up-pointing) should be smaller than the other
  22 % flags.  Adobe Sonata doesn't do this correctly.  (Instead they have
  23 % an extension flag, which looks less elegant)
  24 %
  25
  26 save hip_thickness, foot_thickness;
  27 hip_thickness# = 1.3 stemthickness#;
  28 foot_thickness# =  hip_thickness#;
  29
  30 %
  31 % Inspired by Adobe Sonata and [Wanske]
  32 % for example, see POSTSCRIPT Language -- program design,
  33 % page 119, and [Wanske], p 41,42
  34 %
  35 def draw_flag(expr center, flare,
  36         dims, hip_depth, foot_wid, hip_thickness, foot_thickness)=
  37         clearxy;
  38
  39         penpos1(flare, 90);
  40         penpos2(whatever, 0);
  41         x2r - x2l = hip_thickness;
  42         penpos3(foot_thickness, 0) ;
  43
  44         z1r  = center;
  45         z2r = center + (xpart dims, -ypart(dims) * hip_depth);
  46         z3r = center + (xpart(dims) * foot_wid, -ypart dims);
  47
  48         outer_path := z3r{curl 0} .. z2r{up} .. {up}z1r;
  49
  50         penlabels(1, 2, 3);
  51         fill z1l{curl 0}
  52                 ..tension 1.1 .. z2l{down} ..
  53                 {curl 0} simple_serif(z3l, z3r, 80) &
  54                 outer_path & z1r -- cycle;
  55 enddef;
  56
  57 %
  58 % TODO: calc intersectpoint
  59 % TODO: calc incision_depth
  60 %
  61 def add_flag(expr yoff, flare, hip_wid_multiplier,
  62                 hip_dep_multiplier,
  63                 intersectpoint, hip_thickness, foot_thickness) =
  64         begingroup
  65         save prev_center, prev_xextreme, prev_yextreme;
  66         save rel_foot, ip, center, incision_depth;
  67         save prev_hipwid, prev_footdep, prev_hipdep, wid, dep, hip_dep;
  68         save hip_dep_ratio, foot_wid_ratio;
  69         pair prev_center, center, foot, prev_xextreme, prev_yextreme;
  70         pair ip, rel_foot;
  71
  72         incision_depth = 1.013;
  73         prev_center = point 2 of outer_path;
  74         prev_xextreme = point 1 of outer_path;
  75         prev_yextreme = point 0 of outer_path;
  76         prev_hipwid = xpart (prev_xextreme - prev_center);
  77         prev_footdep = -ypart (prev_yextreme - prev_center);
  78         prev_hipdep = -ypart(prev_xextreme - prev_center);
  79         ip = point intersectpoint of outer_path;
  80
  81         wid = prev_hipwid * hip_wid_multiplier;
  82         hip_dep = prev_hipdep * hip_dep_multiplier;
  83
  84         center = prev_center + (0,yoff);
  85         rel_foot = incision_depth [(wid, hip_dep), ip - center];
  86         dep = -ypart(rel_foot);
  87         foot_wid_ratio = xpart(rel_foot ) / wid;
  88         hip_dep_ratio = hip_dep / dep;
  89
  90         draw_flag(center, flare,
  91                 (wid, dep), hip_dep_ratio, foot_wid_ratio,
  92                 hip_thickness, foot_thickness);
  93         endgroup
  94 enddef;
  95
  96 fet_beginchar("8th Flag (up)", "u3", "eighthflag")
  97         save flare,
  98                 hip_depth_ratio, hip_width,
  99                 foot_depth, foot_width_ratio;
 100
 101         flare# = 1.0 staff_space#;
 102         hip_depth_ratio = .72;
 103         foot_width_ratio = .8;
 104         hip_width# = upflag_width# - hip_thickness#/2;
 105
 106         foot_depth# =  3 staff_space#;
 107
 108         set_char_box(stemthickness# /2, hip_width#
 109                 + stemthickness#/2 + right_upflag_space#,
 110                  foot_depth# + foot_thickness#/2, stemthickness#/2)
 111
 112         define_pixels(flare, hip_width, hip_thickness,
 113                 foot_depth, foot_thickness);
 114         draw_flag((stemthickness/2,0), flare,
 115                 (hip_width, foot_depth),
 116                 hip_depth_ratio, foot_width_ratio, hip_thickness, foot_thickness);
 117
 118         pickup pencircle scaled stemthickness;
 119         draw (0, 0) .. (0,-2 staff_space);
 120 fet_endchar;
 121
 122 fet_beginchar("16th Flag (up)", "u4", "sixteenthflag")
 123         save flare,
 124                 hip_depth_ratio, hip_width,
 125                 foot_depth, foot_width_ratio;
 126         save flagspace, total_depth, flag_count;
 127         total_depth# = 3.5 staff_space#;
 128         flag_count = 2;
 129         flare# = .85 staff_space#;
 130         flagspace# = .85 staff_space#;
 131         hip_depth_ratio = .72 ;
 132         hip_width# = upflag_width# - hip_thickness#/2;
 133         flagspace# + foot_depth# = total_depth#;
 134
 135         foot_width_ratio = .8;
 136
 137         set_char_box(stemthickness# /2, hip_width#
 138                 + stemthickness#/2 + right_upflag_space#,
 139                 total_depth# + foot_thickness#/2, stemthickness#/2)
 140
 141         define_pixels(flare, hip_width, hip_thickness,
 142                 flagspace,
 143                 foot_depth,  foot_thickness);
 144         draw_flag((stemthickness/2,- flagspace), flare,
 145                 (hip_width, foot_depth),
 146                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 147
 148         add_flag(flagspace, flare,
 149                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 150
 151         pickup pencircle scaled stemthickness;
 152         draw (0, 0) .. (0,-2 staff_space);
 153 fet_endchar;
 154
 155
 156 fet_beginchar("32nd Flag (up)", "u5", "thirtysecondflag")
 157         save flare,
 158                 hip_depth_ratio, hip_width,
 159                 foot_depth, foot_width_ratio;
 160         save flagspace, total_depth, flag_count;
 161         flag_count = 3;
 162         total_depth#=4.25 staff_space#;
 163         flare# = .85 staff_space#;
 164         flagspace# = .87 staff_space#;
 165         hip_depth_ratio = .72 ;
 166         hip_width# = upflag_width# - hip_thickness#/2;
 167         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 168
 169         foot_width_ratio = .8;
 170
 171         set_char_box(stemthickness# /2, hip_width#
 172                 + stemthickness#/2 + right_upflag_space#,
 173                 total_depth# + foot_thickness#/2, stemthickness#/2)
 174
 175         define_pixels(flare, hip_width, hip_thickness,
 176                 flagspace,
 177                 foot_depth,  foot_thickness);
 178
 179         draw_flag((stemthickness/2,- 2 flagspace), flare,
 180                 (hip_width, foot_depth),
 181                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 182
 183         add_flag(flagspace, flare,
 184                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 185
 186         add_flag(flagspace, flare,
 187                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 188
 189         pickup pencircle scaled stemthickness;
 190         draw (0, 0) .. (0,-2 staff_space);
 191 fet_endchar;
 192
 193 fet_beginchar("64th Flag (up)", "u6", "sixtyfourthflag")
 194         save flare,
 195                 hip_depth_ratio, hip_width,
 196                 foot_depth, foot_width_ratio;
 197         save flagspace, total_depth, flag_count;
 198
 199         flag_count = 4;
 200         flare# = .85 staff_space#;
 201         flagspace# = .9 staff_space#;
 202         hip_depth_ratio = .72 ;
 203         hip_width# = upflag_width# - hip_thickness#/2;
 204         total_depth# = 5.25 staff_space#;
 205         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 206
 207         foot_width_ratio = .8;
 208
 209         set_char_box(stemthickness# /2, hip_width#
 210                 + stemthickness#/2 + right_upflag_space#,
 211                 total_depth# + foot_thickness#/2, stemthickness#/2)
 212
 213         define_pixels(flare, hip_width, hip_thickness,
 214                 flagspace,
 215                 foot_depth,  foot_thickness);
 216
 217         draw_flag((stemthickness/2,- (flag_count-1)* flagspace), flare,
 218                 (hip_width, foot_depth),
 219                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 220
 221         add_flag(flagspace, flare,
 222                 .97, 1.00, 1.3, hip_thickness, foot_thickness);
 223
 224         add_flag(flagspace, flare,
 225                 1.00, 1.00, 1.25, hip_thickness, foot_thickness);
 226         add_flag(flagspace, flare,
 227                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 228         pickup pencircle scaled stemthickness;
 229         draw (0, 0) .. (0,-2 staff_space);
 230 fet_endchar;
 231
 232 fet_beginchar("grace dash (up)", "ugrace", "gracedash")
 233         save flare,
 234                 hip_depth_ratio, hip_width,
 235                 foot_depth;
 236
 237         flare# = 1.0 staff_space#;
 238         hip_depth_ratio = .72;
 239         hip_width# = upflag_width# - hip_thickness#/2;
 240
 241         foot_depth# =  3 staff_space#;
 242
 243         define_pixels(flare, hip_width, hip_thickness,
 244                 foot_depth, foot_thickness);
 245
 246         set_char_box(hip_width# * hip_depth_ratio,
 247           hip_width# + stemthickness#/2 + right_upflag_space#,
 248           foot_depth# * hip_depth_ratio, -flare#)
 249
 250         pickup pencircle scaled 1.5 stemthickness;
 251         draw (-b ,-d) ..
 252           (w, h);
 253 fet_endchar;
 254
 255 fet_beginchar("8th (down)", "d3", "deighthflag")
 256         save flare,
 257                 hip_depth_ratio, hip_width,
 258                 foot_depth, foot_width_ratio;
 259         save flagspace, total_depth, flag_count;
 260
 261         flag_count = 1;
 262         flare# = .99 staff_space#;
 263         flagspace# = .9 staff_space#;
 264         hip_depth_ratio = .72 ;
 265         hip_width# = downflag_width# - hip_thickness#/2;
 266         total_depth# = 2.85 staff_space#;
 267         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 268
 269         foot_width_ratio = .8;
 270
 271         set_char_box(stemthickness# /2, hip_width#
 272                 + stemthickness#/2 + right_downflag_space#,
 273                 total_depth# + foot_thickness#/2, stemthickness#/2)
 274
 275         define_pixels(flare, hip_width, hip_thickness,
 276                 flagspace,
 277                 foot_depth,  foot_thickness);
 278
 279         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 280                 (hip_width, foot_depth),
 281                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 282
 283
 284         pickup pencircle scaled stemthickness;
 285         draw (0, 0) .. (0,-2 staff_space);
 286         y_mirror_char;
 287 fet_endchar;
 288
 289 fet_beginchar("16th (down)", "d4", "dsixteenthflag")
 290         save flare,
 291                 hip_depth_ratio, hip_width,
 292                 foot_depth, foot_width_ratio;
 293         save flagspace, total_depth, flag_count;
 294
 295         flag_count = 2;
 296         flare# = .8 staff_space#;
 297         flagspace# = .9 staff_space#;
 298         hip_depth_ratio = .85 ;
 299         hip_width# = downflag_width# - hip_thickness#/2;
 300         total_depth# = 3.0 staff_space#;
 301         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 302
 303         foot_width_ratio = .95;
 304
 305         set_char_box(stemthickness# /2, hip_width#
 306                 + stemthickness#/2 + right_downflag_space#,
 307                 total_depth# + foot_thickness#/2, stemthickness#/2)
 308
 309         define_pixels(flare, hip_width, hip_thickness,
 310                 flagspace,
 311                 foot_depth,  foot_thickness);
 312
 313         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 314                 (hip_width, foot_depth),
 315                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 316         add_flag(flagspace, flare,
 317                 .95, 1.00, 1.25, hip_thickness, foot_thickness);
 318
 319
 320
 321         pickup pencircle scaled stemthickness;
 322         draw (0, 0) .. (0,-2 staff_space);
 323         y_mirror_char;
 324 fet_endchar;
 325
 326 fet_beginchar("32nd (down)", "d5", "dthirtysecondflag")
 327         save flare,
 328                 hip_depth_ratio, hip_width,
 329                 foot_depth, foot_width_ratio;
 330         save flagspace, total_depth, flag_count;
 331
 332         flag_count = 3;
 333         flare# = .84 staff_space#;
 334         flagspace# = .9 staff_space#;
 335         hip_depth_ratio = .85 ;
 336         hip_width# = downflag_width# - hip_thickness#/2;
 337         total_depth# = 3.85 staff_space#;
 338         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 339
 340         foot_width_ratio = .95;
 341
 342         set_char_box(stemthickness# /2, hip_width#
 343                 + stemthickness#/2 + right_downflag_space#,
 344                 total_depth# + foot_thickness#/2, stemthickness#/2)
 345
 346         define_pixels(flare, hip_width, hip_thickness,
 347                 flagspace,
 348                 foot_depth,  foot_thickness);
 349
 350         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 351                 (hip_width, foot_depth),
 352                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 353         add_flag(flagspace, flare,
 354                 .97, 1.00, 1.25, hip_thickness, foot_thickness);
 355
 356         add_flag(flagspace, flare,
 357                 .95, 1.05, 1.25, hip_thickness, foot_thickness);
 358
 359
 360
 361         pickup pencircle scaled stemthickness;
 362         draw (0, 0) .. (0,-2 staff_space);
 363         y_mirror_char;
 364 fet_endchar;
 365 fet_beginchar("64th (down)", "d6", "dsixtyfourthflag")
 366         save flare,
 367                 hip_depth_ratio, hip_width,
 368                 foot_depth, foot_width_ratio;
 369         save flagspace, total_depth, flag_count;
 370
 371         flag_count = 4;
 372         flare# = .8 staff_space#;
 373         flagspace# = .9 staff_space#;
 374         hip_depth_ratio = .85 ;
 375         hip_width# = downflag_width# - hip_thickness#/2;
 376         total_depth# = 4.35 staff_space#;
 377         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 378
 379         foot_width_ratio = .98;
 380
 381         set_char_box(stemthickness# /2, hip_width#
 382                 + stemthickness#/2 + right_downflag_space#,
 383                 total_depth# + foot_thickness#/2, stemthickness#/2)
 384
 385         define_pixels(flare, hip_width, hip_thickness,
 386                 flagspace,
 387                 foot_depth,  foot_thickness);
 388
 389         draw_flag((stemthickness/2,- (flag_count-1) *flagspace), flare,
 390                 (hip_width, foot_depth),
 391                 hip_depth_ratio,foot_width_ratio, hip_thickness, foot_thickness);
 392         add_flag(flagspace, flare,
 393                 .97, 1.20, 1.175, hip_thickness, foot_thickness);
 394         add_flag(flagspace, flare,
 395                 .97, 1.10, 1.175, hip_thickness, foot_thickness);
 396
 397         add_flag(.98 flagspace, flare,
 398                 .91, 1.05, 1.2, hip_thickness, foot_thickness);
 399
 400
 401
 402         pickup pencircle scaled stemthickness;
 403         draw (0, 0) .. (0,-2 staff_space);
 404         y_mirror_char;
 405 fet_endchar;
 406
 407
 408 fet_beginchar("grace dash (down)", "dgrace", "dgracedash")
 409         save flare, hip_depth_ratio, hip_width, foot_depth;
 410         save flagspace, total_depth, flag_count;
 411
 412         flag_count = 1;
 413         flare# = .99 staff_space#;
 414         flagspace# = .9 staff_space#;
 415         hip_depth_ratio = .72 ;
 416         hip_width# = downflag_width# - hip_thickness#/2;
 417         total_depth# = 2.85 staff_space#;
 418         (flag_count-1) * flagspace# + foot_depth# = total_depth#;
 419
 420         foot_width_ratio = .8;
 421
 422         define_pixels(flare, hip_width, hip_thickness,
 423                 flagspace, foot_depth);
 424
 425         set_char_box(hip_width# * hip_depth_ratio,
 426           hip_width# + stemthickness#/2 + right_downflag_space#,
 427           foot_depth# * hip_depth_ratio, -flare#)
 428
 429         pickup pencircle scaled 1.5 stemthickness;
 430         draw (-b, -d) .. (w,h);
 431         y_mirror_char;
 432 fet_endchar;
 433
 434 % ustem?
 435 %
 436 %
 437 % Stem characters so we can compose metronome markings with Feta
 438 % entirely.
 439 %
 440
 441 fet_beginchar("stem (up)", "stem", "stem")
 442         set_char_box(stemthickness#/2, stemthickness#/2, 0, 3.5staff_space#);
 443         pickup pencircle scaled stemthickness;
 444         draw (0, 0.2staff_space) .. (0, 3.5staff_space);
 445 fet_endchar;
 446
 447 % do we want this?
 448 fet_beginchar("stem (down)", "dstem", "dstem")
 449         set_char_box(stemthickness#/2, stemthickness#/2, 3.5staff_space#, 0);
 450         pickup pencircle scaled stemthickness;
 451         draw (0, -0.2staff_space) .. (0, -3.5staff_space);
 452 fet_endchar;
 453
 454
 455 fet_endgroup("flags");