scm/output-lib.scm

   1 ;;;; output-lib.scm -- implement Scheme output helper functions
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 1998--2007 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   7
   8
   9
  10
  11 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  12 ;; general
  13 (define-public (grob::has-interface grob iface)
  14   (memq iface (ly:grob-interfaces grob)))
  15
  16 (define-public (make-stencil-boxer thickness padding callback)
  17
  18   "Return function that adds a box around the grob passed as argument."
  19   (lambda (grob)
  20
  21     (box-stencil (callback grob) thickness padding)))
  22
  23 (define-public (make-stencil-circler thickness padding callback)
  24   "Return function that adds a circle around the grob passed as argument."
  25
  26   (lambda (grob) (circle-stencil (callback grob) thickness padding)))
  27
  28 (define-public (print-circled-text-callback grob)
  29   (grob-interpret-markup grob (make-circle-markup
  30                    (ly:grob-property grob 'text))
  31              ))
  32
  33 (define-public (event-cause grob)
  34   (let*
  35       ((cause (ly:grob-property  grob 'cause)))
  36
  37     (cond
  38      ((ly:stream-event? cause) cause)
  39      ((ly:grob? cause) (event-cause cause))
  40      (else #f))))
  41
  42 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  43 ;; tablature
  44
  45 ;; The TabNoteHead tablatureFormat callback.
  46 ;; Compute the text grob-property
  47 (define-public (fret-number-tablature-format string
  48                                              context event)
  49   (let*
  50       ((tuning (ly:context-property context 'stringTunings))
  51        (pitch (ly:event-property event 'pitch))
  52        (is-harmonic (apply
  53                      functional-or
  54                      (map
  55                       (lambda (ev)
  56                         (eq? 'harmonic-event (ly:event-property ev 'class)))
  57                       (ly:event-property event 'articulations)))))
  58
  59
  60     (make-whiteout-markup
  61      (make-vcenter-markup
  62       (format
  63        "~a"
  64        (- (ly:pitch-semitones pitch)
  65           (list-ref tuning
  66                     ;; remove 1 because list index starts at 0 and guitar string at 1.
  67                     (- string 1))))))
  68     ))
  69
  70 ;; The 5-string banjo has got a extra string, the fifth (duh), wich
  71 ;; starts at the fifth fret on the neck. Frets on the fifth string
  72 ;; are referred to relative to the other frets:
  73 ;;   the "first fret" on the fifth string is really the sixth fret
  74 ;;   on the banjo neck.
  75 ;; We solve this by defining a new fret-number-tablature function:
  76 (define-public (fret-number-tablature-format-banjo string
  77                                              context event)
  78   (let*
  79       ((tuning (ly:context-property context 'stringTunings))
  80        (pitch (ly:event-property event 'pitch))
  81         )
  82   (make-whiteout-markup
  83    (make-vcenter-markup
  84     (let ((fret (- (ly:pitch-semitones pitch) (list-ref tuning (- string 1)))))
  85       (number->string (cond
  86                        ((and (> fret 0) (= string 5))
  87                         (+ fret 5))
  88                        (else fret))))))
  89   ))
  90
  91
  92 ; default tunings for common string instruments
  93 (define-public guitar-tuning '(4 -1 -5 -10 -15 -20))
  94 (define-public guitar-open-g-tuning '(2 -1 -5 -10 -17 -22))
  95 (define-public bass-tuning '(-17 -22 -27 -32))
  96 (define-public mandolin-tuning '(16 9 2 -5))
  97
  98 ;; tunings for 5-string banjo
  99 (define-public banjo-open-g-tuning '(2 -1 -5 -10 7))
 100 (define-public banjo-c-tuning '(2 -1 -5 -12 7))
 101 (define-public banjo-modal-tuning '(2 0 -5 -10 7))
 102 (define-public banjo-open-d-tuning '(2 -3 -6 -10 9))
 103 (define-public banjo-open-dm-tuning '(2 -3 -6 -10 9))
 104 ;; convert 5-string banjo tuning to 4-string by removing the 5th string
 105 (define-public (four-string-banjo tuning)
 106   (reverse (cdr (reverse tuning))))
 107
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109 ;; note heads
 110
 111
 112 (define-public (stem::calc-duration-log grob)
 113   (ly:duration-log
 114    (ly:event-property (event-cause grob) 'duration)))
 115
 116 (define-public (note-head::calc-duration-log grob)
 117   (min 2
 118        (ly:duration-log
 119         (ly:event-property (event-cause grob) 'duration))))
 120
 121 (define-public (dots::calc-dot-count grob)
 122   (ly:duration-dot-count
 123    (ly:event-property (event-cause grob) 'duration)))
 124
 125 (define-public (dots::calc-staff-position grob)
 126   (let*
 127       ((head (ly:grob-parent grob Y))
 128        (log (ly:grob-property head 'duration-log)))
 129
 130     (cond
 131      ((or (not (grob::has-interface head 'rest-interface))
 132          (not (integer? log))) 0)
 133      ((= log 7) 4)
 134      ((> log 4) 3)
 135      ((= log 0) -1)
 136      ((= log 1) 1)
 137      ((= log -1) 1)
 138      (else 0))))
 139
 140 (define (note-head::calc-tablature-stem-attachment grob)
 141   (cons 0.0 1.35))
 142
 143
 144
 145 ;; silly, use alist?
 146 (define-public (note-head::calc-glyph-name grob)
 147   (let*
 148       ((style (ly:grob-property grob 'style))
 149        (log (min 2 (ly:grob-property grob 'duration-log))))
 150
 151     (case style
 152       ;; "default" style is directly handled in note-head.cc as a
 153       ;; special case (HW says, mainly for performance reasons).
 154       ;; Therefore, style "default" does not appear in this case
 155       ;; statement.  -- jr
 156       ((xcircle) "2xcircle")
 157       ((harmonic) "0harmonic")
 158       ((harmonic-black) "2harmonic")
 159       ((harmonic-mixed) (if (<= log 1) "0harmonic"
 160                                        "2harmonic"))
 161       ((baroque)
 162        ;; Oops, I actually would not call this "baroque", but, for
 163        ;; backwards compatibility to 1.4, this is supposed to take
 164        ;; brevis, longa and maxima from the neo-mensural font and all
 165        ;; other note heads from the default font.  -- jr
 166        (if (< log 0)
 167            (string-append (number->string log) "neomensural")
 168            (number->string log)))
 169       ((mensural)
 170        (string-append (number->string log) (symbol->string style)))
 171       ((petrucci)
 172        (if (< log 0)
 173            (string-append (number->string log) "mensural")
 174            (string-append (number->string log) (symbol->string style))))
 175       ((neomensural)
 176        (string-append (number->string log) (symbol->string style)))
 177       (else
 178        (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 179            (symbol->string style)
 180            (string-append (number->string (max 0 log))
 181                           (symbol->string style)))))))
 182
 183 ;; TODO junk completely?
 184 (define (note-head-style->attachment-coordinates grob axis)
 185   "Return pair (X . Y), containing multipliers for the note head
 186 bounding box, where to attach the stem. e.g.: X==0 means horizontally
 187 centered, X==1 is at the right, X == -1 is at the left."
 188
 189   '(1.0 . 0.0))
 190
 191
 192 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 193 ;; bar numbers
 194
 195 (define-public ((every-nth-bar-number-visible n) barnum) (= 0 (modulo barnum n)))
 196
 197 (define-public ((modulo-bar-number-visible n m) barnum) (and (> barnum 1) (= m (modulo barnum n))))
 198
 199 (define-public ((set-bar-number-visibility n) tr)
 200   (let* ((bn (ly:context-property tr 'currentBarNumber)))
 201     (ly:context-set-property! tr 'barNumberVisibility (modulo-bar-number-visible n (modulo bn n)))))
 202
 203 (define-public (first-bar-number-invisible barnum) (> barnum 1))
 204
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;; break visibility
 207
 208 (define-public begin-of-line-visible
 209   #(#f #f #t))
 210 (define-public end-of-line-visible
 211   #(#t #f #f))
 212 (define-public end-of-line-invisible
 213   #(#f #t #t))
 214 (define-public spanbar-begin-of-line-invisible
 215   #(#t #f #f))
 216 (define-public all-visible #(#t #t #t))
 217 (define-public all-invisible #(#f #f #f))
 218 (define-public begin-of-line-invisible
 219   #(#t #t #f))
 220 (define-public center-invisible #(#t #f #t))
 221
 222 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 223 ;; Bar lines.
 224
 225 ;;
 226 ;; How should a  bar line behave at a break?
 227 (define bar-glyph-alist
 228   '((":|:" . (":|" . "|:"))
 229     (":|.|:" . (":|" . "|:"))
 230     (":|.:" . (":|" . "|:"))
 231     ("||:" . ("||" . "|:"))
 232     ("dashed" . ("dashed" . '()))
 233     ("|" . ("|" . ()))
 234     ("||:" . ("||" . "|:"))
 235     ("|s" . (() . "|"))
 236     ("|:" . ("|" . "|:"))
 237     ("|." . ("|." . ()))
 238
 239     ;; hmm... should we end with a bar line here?
 240     (".|" . ("|" . ".|"))
 241     (":|" . (":|" . ()))
 242     ("||" . ("||" . ()))
 243     (".|." . (".|." . ()))
 244     ("|.|" . ("|.|" . ()))
 245     ("" . ("" . ""))
 246     (":" . (":" . ""))
 247     ("." . ("." . ()))
 248     ("empty" . (() . ()))
 249     ("brace" . (() . "brace"))
 250     ("bracket" . (() . "bracket"))
 251     ))
 252
 253 (define-public (bar-line::calc-glyph-name grob)
 254   (let* (
 255          (glyph (ly:grob-property grob 'glyph))
 256          (dir (ly:item-break-dir grob))
 257          (result (assoc glyph  bar-glyph-alist))
 258          (glyph-name (if (= dir CENTER)
 259                          glyph
 260                          (if (and result (string? (index-cell (cdr result) dir)))
 261                              (index-cell (cdr result) dir)
 262                              #f)))
 263          )
 264     glyph-name))
 265
 266 (define-public (bar-line::calc-break-visibility grob)
 267   (let* ((glyph (ly:grob-property grob 'glyph))
 268          (result (assoc glyph bar-glyph-alist)))
 269     (if result
 270         (vector (string? (cadr result)) #t (string? (cddr result)))
 271         #(#f #f #f))))
 272
 273
 274 (define-public (shift-right-at-line-begin g)
 275   "Shift an item to the right, but only at the start of the line."
 276   (if (and (ly:item? g)
 277            (equal? (ly:item-break-dir g) RIGHT))
 278       (ly:grob-translate-axis! g 3.5 X)))
 279
 280
 281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 282 ;; Tuplets
 283
 284 (define-public (tuplet-number::calc-denominator-text grob)
 285   (number->string (ly:event-property (event-cause grob) 'denominator)))
 286
 287 (define-public (tuplet-number::calc-fraction-text grob)
 288   (let*
 289       ((ev (event-cause grob)))
 290
 291     (format "~a:~a"
 292             (ly:event-property ev 'denominator)
 293             (ly:event-property ev 'numerator))))
 294
 295 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 296 ;; Color
 297
 298 (define-public color? list?)
 299 (define-public (rgb-color r g b) (list r g b))
 300
 301 ; predefined colors
 302 (define-public black       '(0.0 0.0 0.0))
 303 (define-public white       '(1.0 1.0 1.0))
 304 (define-public red         '(1.0 0.0 0.0))
 305 (define-public green       '(0.0 1.0 0.0))
 306 (define-public blue        '(0.0 0.0 1.0))
 307 (define-public cyan        '(0.0 1.0 1.0))
 308 (define-public magenta     '(1.0 0.0 1.0))
 309 (define-public yellow      '(1.0 1.0 0.0))
 310
 311 (define-public grey        '(0.5 0.5 0.5))
 312 (define-public darkred     '(0.5 0.0 0.0))
 313 (define-public darkgreen   '(0.0 0.5 0.0))
 314 (define-public darkblue    '(0.0 0.0 0.5))
 315 (define-public darkcyan    '(0.0 0.5 0.5))
 316 (define-public darkmagenta '(0.5 0.0 0.5))
 317 (define-public darkyellow  '(0.5 0.5 0.0))
 318
 319 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 320 ;; key signature
 321
 322
 323 (define-public (key-signature-interface::alteration-position step alter c0-position)
 324   ;; TODO: memoize - this is mostly constant.
 325
 326   ;; fes, ges, as and bes typeset in lower octave
 327   (define FLAT_TOP_PITCH 2)
 328
 329   ;; ais and bis typeset in lower octave
 330   (define SHARP_TOP_PITCH 4)
 331
 332   (if (pair? step)
 333       (+ (cdr step) (* (car step) 7)  c0-position)
 334       (let*
 335           ((from-bottom-pos (modulo (+ 4 49 c0-position)  7))
 336            (p step)
 337            (c0 (- from-bottom-pos  4)))
 338
 339         (if
 340          (or (and (< alter 0) (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 341              (and (> alter 0) (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2))
 342              )
 343
 344          ;; Typeset below c_position
 345          (set! p (- p 7)))
 346
 347         ;; Provide for the four cases in which there's a glitch
 348         ;; it's a hack, but probably not worth
 349         ;; the effort of finding a nicer solution.
 350         ;; --dl.
 351         (cond
 352          ((and (= c0 2) (= p 3) (> alter 0))
 353           (set! p (- p 7)))
 354          ((and (= c0 -3) (= p -1) (> alter 0))
 355           (set! p (+ p 7)))
 356          ((and (= c0 -4) (= p -1) (< alter 0))
 357           (set! p (+ p 7)))
 358          ((and (= c0 -2) (= p -3) (< alter 0))
 359           (set! p (+ p 7))))
 360
 361         (+ c0 p))))
 362
 363
 364 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 365 ;; accidentals
 366
 367 (define-public (accidental-interface::calc-alteration grob)
 368   (ly:pitch-alteration  (ly:event-property (event-cause grob) 'pitch)))
 369
 370
 371 (define-public cancellation-glyph-name-alist
 372   '((0 . "accidentals.natural")))
 373
 374 (define-public standard-alteration-glyph-name-alist
 375      '(
 376        ;; ordered for optimal performance.
 377        (0 . "accidentals.natural")
 378        (-1/2 . "accidentals.flat")
 379        (1/2 . "accidentals.sharp")
 380
 381        (1 . "accidentals.doublesharp")
 382        (-1 . "accidentals.flatflat")
 383
 384        (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 385        (1/4 . "accidentals.sharp.slashslash.stem")
 386        (-1/4 . "accidentals.mirroredflat")
 387        (-3/4 . "accidentals.mirroredflat.flat")
 388        ))
 389
 390 ;; FIXME: standard vs default, alteration-FOO vs FOO-alteration
 391 (define-public alteration-default-glyph-name-alist standard-alteration-glyph-name-alist)
 392
 393 (define-public makam-alteration-glyph-name-alist
 394      '((1 . "accidentals.doublesharp")
 395        (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 396        (5/9 . "accidentals.sharp.slashslashslash.stem")
 397        (4/9 . "accidentals.sharp")
 398        (1/9 . "accidentals.sharp.slashslash.stem")
 399        (0 . "accidentals.natural")
 400        (-1/9 . "accidentals.mirroredflat")
 401        (-4/9 . "accidentals.flat.slash")
 402        (-5/9 . "accidentals.flat")
 403        (-8/9 . "accidentals.flat.slashslash")
 404        (-1 . "accidentals.flatflat")
 405        ))
 406
 407 (define-public alteration-hufnagel-glyph-name-alist
 408    '((-1/2 . "accidentals.hufnagelM1")
 409      (0 . "accidentals.vaticana0")
 410      (1/2 . "accidentals.mensural1")))
 411
 412 (define-public alteration-medicaea-glyph-name-alist
 413    '((-1/2 . "accidentals.medicaeaM1")
 414      (0 . "accidentals.vaticana0")
 415      (1/2 . "accidentals.mensural1")))
 416
 417 (define-public alteration-vaticana-glyph-name-alist
 418    '((-1/2 . "accidentals.vaticanaM1")
 419      (0 . "accidentals.vaticana0")
 420      (1/2 . "accidentals.mensural1")))
 421
 422 (define-public alteration-mensural-glyph-name-alist
 423    '((-1/2 . "accidentals.mensuralM1")
 424      (0 . "accidentals.vaticana0")
 425      (1/2 . "accidentals.mensural1")))
 426
 427
 428 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 429 ;; * Pitch Trill Heads
 430 ;; * Parentheses
 431
 432 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 433   (let* ((font (ly:grob-default-font grob))
 434          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 435          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 436
 437     (list lp rp)))
 438
 439
 440 (define-public (grob-interpret-markup grob text)
 441   (let*
 442       ((layout (ly:grob-layout grob))
 443        (defs (ly:output-def-lookup layout 'text-font-defaults))
 444        (props (ly:grob-alist-chain grob defs)))
 445
 446     (ly:text-interface::interpret-markup
 447      layout props text)))
 448
 449 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 450   (let* (
 451          (font (ly:grob-default-font grob))
 452          (lp (ly:stencil-aligned-to (ly:stencil-aligned-to (grob-interpret-markup grob (ly:wide-char->utf-8 #x2329))
 453                                                            Y CENTER)  X RIGHT))
 454          (rp (ly:stencil-aligned-to (ly:stencil-aligned-to (grob-interpret-markup grob (ly:wide-char->utf-8 #x232A))
 455                                                            Y CENTER) X LEFT))
 456          )
 457
 458     (list (stencil-whiteout lp)
 459           (stencil-whiteout rp))))
 460
 461 (define (parenthesize-elements grob . rest)
 462   (let*
 463       ((refp (if (null? rest)
 464                  grob
 465                  (car rest)))
 466        (elts (ly:grob-object grob 'elements))
 467        (x-ext (ly:relative-group-extent elts refp X))
 468        (stencils (ly:grob-property grob 'stencils))
 469        (lp (car stencils))
 470        (rp (cadr stencils))
 471        (padding (ly:grob-property grob 'padding 0.1)))
 472
 473     (ly:stencil-add
 474      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 475      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))
 476   ))
 477
 478
 479 (define (parentheses-item::print me)
 480   (let*
 481       ((elts (ly:grob-object me 'elements))
 482        (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 483        (x-ref (ly:grob-common-refpoint-of-array me elts X))
 484        (stencil (parenthesize-elements me x-ref))
 485        (elt-y-ext  (ly:relative-group-extent elts y-ref Y))
 486        (y-center (interval-center elt-y-ext)))
 487
 488     (ly:stencil-translate
 489      stencil
 490      (cons
 491       (-
 492        (ly:grob-relative-coordinate me x-ref X))
 493       (-
 494        y-center
 495        (ly:grob-relative-coordinate me y-ref Y))))
 496     ))
 497
 498
 499
 500 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 501 ;;
 502
 503 (define-public (chain-grob-member-functions grob value . funcs)
 504   (for-each
 505    (lambda (func)
 506      (set! value (func grob value)))
 507    funcs)
 508
 509   value)
 510
 511 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 512 ;; falls/doits
 513
 514 (define-public (bend::print spanner)
 515   (define (close  a b)
 516     (< (abs (- a b)) 0.01))
 517
 518   (let*
 519       ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 520        (left-span (ly:spanner-bound spanner LEFT))
 521        (dots (if (and (grob::has-interface left-span 'note-head-interface)
 522                       (ly:grob? (ly:grob-object left-span 'dot)))
 523                  (ly:grob-object left-span 'dot) #f))
 524
 525        (right-span (ly:spanner-bound spanner RIGHT))
 526        (thickness (* (ly:grob-property spanner 'thickness)
 527                      (ly:output-def-lookup (ly:grob-layout spanner)
 528                                            'line-thickness)))
 529        (padding (ly:grob-property spanner 'padding 0.5))
 530        (common (ly:grob-common-refpoint right-span
 531                                         (ly:grob-common-refpoint spanner
 532                                                                  left-span X)
 533                                         X))
 534        (common-y (ly:grob-common-refpoint spanner left-span Y))
 535        (left-x (+ padding
 536                   (max (interval-end (ly:grob-robust-relative-extent
 537                                       left-span common X))
 538                         (if (and
 539                              dots
 540                              (close (ly:grob-relative-coordinate dots common-y Y)
 541                                         (ly:grob-relative-coordinate spanner common-y Y)))
 542                             (interval-end (ly:grob-robust-relative-extent dots common X))
 543                             -10000) ;; TODO: use real infinity constant.
 544                         )))
 545        (right-x (- (interval-start
 546                     (ly:grob-robust-relative-extent right-span common X))
 547                    padding))
 548        (self-x (ly:grob-relative-coordinate spanner common X))
 549        (dx (- right-x left-x))
 550        (exp (list 'path thickness
 551                   `(quote
 552                     (rmoveto
 553                      ,(- left-x self-x) 0
 554
 555                      rcurveto
 556                      ,(/ dx 3)
 557                      0
 558                      ,dx ,(* 0.66 delta-y)
 559                      ,dx ,delta-y
 560                      )))))
 561
 562     (ly:make-stencil
 563      exp
 564      (cons (- left-x self-x) (- right-x self-x))
 565      (cons (min 0 delta-y)
 566            (max 0 delta-y)))))
 567
 568 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 569 ;; grace spacing
 570
 571
 572 (define-public (grace-spacing::calc-shortest-duration grob)
 573   (let*
 574      ((cols (ly:grob-object grob 'columns))
 575       (get-difference
 576        (lambda (idx)
 577          (ly:moment-sub (ly:grob-property
 578                          (ly:grob-array-ref cols (1+ idx)) 'when)
 579                         (ly:grob-property
 580                          (ly:grob-array-ref cols idx) 'when))))
 581
 582       (moment-min (lambda (x y)
 583                     (cond
 584                      ((and x y)
 585                       (if (ly:moment<? x y)
 586                             x
 587                             y))
 588                      (x x)
 589                      (y y)))))
 590
 591     (fold moment-min #f (map get-difference
 592                              (iota (1- (ly:grob-array-length cols)))))))
 593
 594
 595
 596 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 597 ;; fingering
 598
 599 (define-public (fingering::calc-text grob)
 600   (let*
 601       ((event (event-cause grob))
 602        (digit (ly:event-property event 'digit)))
 603
 604     (if (> digit 5)
 605         (ly:input-message (ly:event-property event 'origin)
 606                           "Warning: Fingering notation for finger number ~a" digit))
 607
 608     (number->string digit 10)
 609   ))
 610
 611 (define-public (string-number::calc-text grob)
 612   (let*
 613       ((digit (ly:event-property (event-cause  grob) 'string-number)))
 614
 615     (number->string digit 10)
 616   ))
 617
 618
 619 (define-public (stroke-finger::calc-text grob)
 620   (let*
 621       ((digit (ly:event-property (event-cause grob) 'digit))
 622        (text (ly:event-property (event-cause grob) 'text)))
 623
 624     (if (string? text)
 625         text
 626         (vector-ref (ly:grob-property grob 'digit-names)  (1- (max (min 5 digit) 1))))))
 627
 628 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 629 ;; dynamics
 630 (define-public (hairpin::calc-grow-direction grob)
 631   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 632       START
 633       STOP
 634       ))
 635
 636 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 637 ;; lyrics
 638
 639 (define-public (lyric-text::print grob)
 640   "Allow interpretation of tildes as lyric tieing marks."
 641
 642   (let*
 643       ((text (ly:grob-property grob 'text)))
 644
 645     (grob-interpret-markup grob
 646                (if (string? text)
 647                    (make-tied-lyric-markup text)
 648                    text))))
 649
 650 (define-public ((grob::calc-property-by-copy prop) grob)
 651   (ly:event-property (event-cause grob) prop))
 652
 653 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 654 ;; fret boards
 655
 656 (define-public (fret-board::calc-stencil grob)
 657     (grob-interpret-markup
 658       grob
 659       (make-fret-diagram-verbose-markup
 660         (ly:grob-property grob 'dot-placement-list))))
 661
 662 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 663 ;; scripts
 664
 665 (define-public (script-interface::calc-x-offset grob)
 666   (ly:grob-property grob 'positioning-done)
 667   (ly:self-alignment-interface::centered-on-x-parent grob))